SL/DB/Helper/Payment.pm

   1 package SL::DB::Helper::Payment;
   2
   3 use strict;
   4
   5 use parent qw(Exporter);
   6 our @EXPORT = qw(pay_invoice);
   7 our @EXPORT_OK = qw(skonto_date skonto_charts amount_less_skonto within_skonto_period percent_skonto reference_account reference_amount open_amount open_percent remaining_skonto_days skonto_amount check_skonto_configuration valid_skonto_amount get_payment_suggestions validate_payment_type open_sepa_transfer_amount get_payment_select_options_for_bank_transaction exchangerate forex);
   8 our %EXPORT_TAGS = (
   9   "ALL" => [@EXPORT, @EXPORT_OK],
  10 );
  11
  12 require SL::DB::Chart;
  13 use Data::Dumper;
  14 use DateTime;
  15 use SL::DATEV qw(:CONSTANTS);
  16 use SL::Locale::String qw(t8);
  17 use List::Util qw(sum);
  18 use SL::DB::Exchangerate;
  19 use SL::DB::Currency;
  20 use Carp;
  21
  22 #
  23 # Public functions not exported by default
  24 #
  25
  26 sub pay_invoice {
  27   my ($self, %params) = @_;
  28
  29   require SL::DB::Tax;
  30
  31   my $is_sales = ref($self) eq 'SL::DB::Invoice';
  32   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign depending on ar/ap
  33   my @new_acc_ids;
  34   my $paid_amount = 0; # the amount that will be later added to $self->paid, should be in default currency
  35
  36   # default values if not set
  37   $params{payment_type} = 'without_skonto' unless $params{payment_type};
  38   validate_payment_type($params{payment_type});
  39
  40   # check for required parameters and optional params depending on payment_type
  41   Common::check_params(\%params, qw(chart_id transdate));
  42   if ( $params{'payment_type'} eq 'without_skonto' && abs($params{'amount'}) < 0) {
  43     croak "invalid amount for payment_type 'without_skonto': $params{'amount'}\n";
  44   }
  45   if ($params{'payment_type'} eq 'free_skonto') {
  46     # we dont like too much automagic for this payment type.
  47     # we force caller input for amount and skonto amount
  48     Common::check_params(\%params, qw(amount skonto_amount));
  49     # secondly we dont want to handle credit notes and purchase credit notes
  50     croak("Cannot use 'free skonto' for credit or debit notes") if ($params{amount} <= 0 || $params{skonto_amount} <= 0);
  51     # both amount have to be rounded
  52     $params{skonto_amount} = _round($params{skonto_amount});
  53     $params{amount}        = _round($params{amount});
  54     # lastly skonto_amount has to be smaller than the open invoice amount or payment amount ;-)
  55     if ($params{skonto_amount} > abs($self->open_amount) || $params{skonto_amount} > $params{amount}) {
  56       croak("Skonto amount higher than the payment or invoice amount");
  57     }
  58   }
  59
  60   my $transdate_obj;
  61   if (ref($params{transdate} eq 'DateTime')) {
  62     $transdate_obj = $params{transdate};
  63   } else {
  64    $transdate_obj = $::locale->parse_date_to_object($params{transdate});
  65   };
  66   croak t8('Illegal date') unless ref $transdate_obj;
  67
  68   # check for closed period
  69   my $closedto = $::locale->parse_date_to_object($::instance_conf->get_closedto);
  70   if ( ref $closedto && $transdate_obj < $closedto ) {
  71     croak t8('Cannot post payment for a closed period!');
  72   };
  73
  74   # check for maximum number of future days
  75   if ( $::instance_conf->get_max_future_booking_interval > 0 ) {
  76     croak t8('Cannot post transaction above the maximum future booking date!') if $transdate_obj > DateTime->now->add( days => $::instance_conf->get_max_future_booking_interval );
  77   };
  78
  79   # currency is either passed or use the invoice currency if it differs from the default currency
  80   my ($exchangerate,$currency);
  81   if ($params{currency} || $params{currency_id} || $self->currency_id != $::instance_conf->get_currency_id) {
  82     if ($params{currency} || $params{currency_id} ) { # currency was specified
  83       $currency = SL::DB::Manager::Currency->find_by(name => $params{currency}) || SL::DB::Manager::Currency->find_by(id => $params{currency_id});
  84     } else { # use invoice currency
  85       $currency = SL::DB::Manager::Currency->find_by(id => $self->currency_id);
  86     };
  87     die "no currency" unless $currency;
  88     if ($currency->id == $::instance_conf->get_currency_id) {
  89       $exchangerate = 1;
  90     } else {
  91       my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $currency->id,
  92                                                         transdate   => $transdate_obj,
  93                                                        );
  94       if ($rate) {
  95         $exchangerate = $is_sales ? $rate->buy : $rate->sell;
  96       } else {
  97         die "No exchange rate for " . $transdate_obj->to_kivitendo;
  98       };
  99     };
 100   } else { # no currency param given or currency is the same as default_currency
 101     $exchangerate = 1;
 102   };
 103
 104   # options with_skonto_pt and difference_as_skonto don't require the parameter
 105   # amount, but if amount is passed, make sure it matches the expected value
 106   if ( $params{'payment_type'} eq 'difference_as_skonto' ) {
 107     croak "amount $params{amount} doesn't match open amount " . $self->open_amount . ", diff = " . ($params{amount}-$self->open_amount) if $params{amount} && abs($self->open_amount - $params{amount} ) > 0.0000001;
 108   } elsif ( $params{'payment_type'} eq 'with_skonto_pt' ) {
 109     croak "amount $params{amount} doesn't match amount less skonto: " . $self->amount_less_skonto . "\n" if $params{amount} && abs($self->amount_less_skonto - $params{amount} ) > 0.0000001;
 110     croak "payment type with_skonto_pt can't be used if payments have already been made" if $self->paid != 0;
 111   };
 112
 113   # absolute skonto amount for invoice, use as reference sum to see if the
 114   # calculated skontos add up
 115   # only needed for payment_term "with_skonto_pt"
 116
 117   my $skonto_amount_check = $self->skonto_amount; # variable should be zero after calculating all skonto
 118   my $total_open_amount   = $self->open_amount;
 119
 120   # account where money is paid to/from: bank account or cash
 121   my $account_bank = SL::DB::Manager::Chart->find_by(id => $params{chart_id});
 122   croak "can't find bank account with id " . $params{chart_id} unless ref $account_bank;
 123
 124   my $reference_account = $self->reference_account;
 125   croak "can't find reference account (link = AR/AP) for invoice" unless ref $reference_account;
 126
 127   my $memo   = $params{memo}   // '';
 128   my $source = $params{source} // '';
 129
 130   my $rounded_params_amount = _round( $params{amount} ); # / $exchangerate);
 131   my $fx_gain_loss_amount = 0; # for fx_gain and fx_loss
 132
 133   my $db = $self->db;
 134   $db->with_transaction(sub {
 135     my $new_acc_trans;
 136
 137     # all three payment type create 1 AR/AP booking (the paid part)
 138     # difference_as_skonto creates n skonto bookings (1 for each buchungsgruppe type)
 139     # with_skonto_pt creates 1 bank booking and n skonto bookings (1 for each buchungsgruppe type)
 140     # without_skonto creates 1 bank booking
 141
 142     # as long as there is no automatic tax, payments are always booked with
 143     # taxkey 0
 144
 145     unless ( $params{payment_type} eq 'difference_as_skonto' ) {
 146       # cases with_skonto_pt, free_skonto and without_skonto
 147
 148       # for case with_skonto_pt we need to know the corrected amount at this
 149       # stage if we are going to use $params{amount}
 150
 151       my $pay_amount = $rounded_params_amount;
 152       $pay_amount = $self->amount_less_skonto if $params{payment_type} eq 'with_skonto_pt';
 153
 154       # bank account and AR/AP
 155       $paid_amount += $pay_amount * $exchangerate;
 156
 157       my $amount = (-1 * $pay_amount) * $mult;
 158
 159
 160       # total amount against bank, do we already know this by now?
 161       $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 162                                                    chart_id   => $account_bank->id,
 163                                                    chart_link => $account_bank->link,
 164                                                    amount     => $amount,
 165                                                    transdate  => $transdate_obj,
 166                                                    source     => $source,
 167                                                    memo       => $memo,
 168                                                    project_id => $params{project_id} ? $params{project_id} : undef,
 169                                                    taxkey     => 0,
 170                                                    tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 171       $new_acc_trans->save;
 172
 173       push @new_acc_ids, $new_acc_trans->acc_trans_id;
 174       # deal with fxtransaction
 175       if ( $self->currency_id != $::instance_conf->get_currency_id ) {
 176         my $fxamount = _round($amount - ($amount * $exchangerate));
 177         $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 178                                                      chart_id       => $account_bank->id,
 179                                                      chart_link     => $account_bank->link,
 180                                                      amount         => $fxamount * -1,
 181                                                      transdate      => $transdate_obj,
 182                                                      source         => $source,
 183                                                      memo           => $memo,
 184                                                      taxkey         => 0,
 185                                                      fx_transaction => 1,
 186                                                      tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 187         $new_acc_trans->save;
 188         push @new_acc_ids, $new_acc_trans->acc_trans_id;
 189         # if invoice exchangerate differs from exchangerate of payment
 190         # deal with fxloss and fxamount
 191         if ($self->exchangerate and $self->exchangerate != 1 and $self->exchangerate != $exchangerate) {
 192           my $fxgain_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxgain_accno_id) || die "Can't determine fxgain chart";
 193           my $fxloss_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxloss_accno_id) || die "Can't determine fxloss chart";
 194           my $gain_loss_amount = _round($amount * ($exchangerate - $self->exchangerate ) * -1,2);
 195           my $gain_loss_chart = $gain_loss_amount > 0 ? $fxgain_chart : $fxloss_chart;
 196           $fx_gain_loss_amount = $gain_loss_amount;
 197
 198           $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 199                                                        chart_id       => $gain_loss_chart->id,
 200                                                        chart_link     => $gain_loss_chart->link,
 201                                                        amount         => $gain_loss_amount,
 202                                                        transdate      => $transdate_obj,
 203                                                        source         => $source,
 204                                                        memo           => $memo,
 205                                                        taxkey         => 0,
 206                                                        fx_transaction => 0,
 207                                                        tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 208           $new_acc_trans->save;
 209           push @new_acc_ids, $new_acc_trans->acc_trans_id;
 210
 211         }
 212       }
 213     }
 214     # better everything except without_skonto
 215     if ($params{payment_type} eq 'difference_as_skonto' or $params{payment_type} eq 'with_skonto_pt'
 216         or $params{payment_type} eq 'free_skonto' ) {
 217
 218       my $total_skonto_amount;
 219       if ( $params{payment_type} eq 'with_skonto_pt' ) {
 220         $total_skonto_amount = $self->skonto_amount;
 221       } elsif ( $params{payment_type} eq 'difference_as_skonto' ) {
 222         $total_skonto_amount = $self->open_amount;
 223       } elsif ( $params{payment_type} eq 'free_skonto') {
 224         $total_skonto_amount = $params{skonto_amount};
 225       }
 226       my @skonto_bookings = $self->skonto_charts($total_skonto_amount);
 227
 228       # error checking:
 229       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 230         my $calculated_skonto_sum  = sum map { $_->{skonto_amount} } @skonto_bookings;
 231         croak "calculated skonto for difference_as_skonto = $calculated_skonto_sum doesn't add up open amount: " . $self->open_amount unless _round($calculated_skonto_sum) == _round($self->open_amount);
 232       };
 233
 234       my $reference_amount = $total_skonto_amount;
 235
 236       # create an acc_trans entry for each result of $self->skonto_charts
 237       foreach my $skonto_booking ( @skonto_bookings ) {
 238         next unless $skonto_booking->{'chart_id'};
 239         next unless $skonto_booking->{'skonto_amount'} != 0;
 240         my $amount = -1 * $skonto_booking->{skonto_amount};
 241         $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 242                                                      chart_id   => $skonto_booking->{'chart_id'},
 243                                                      chart_link => SL::DB::Manager::Chart->find_by(id => $skonto_booking->{'chart_id'})->link,
 244                                                      amount     => $amount * $mult,
 245                                                      transdate  => $transdate_obj,
 246                                                      source     => $params{source},
 247                                                      taxkey     => 0,
 248                                                      tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 249
 250         # the acc_trans entries are saved individually, not added to $self and then saved all at once
 251         $new_acc_trans->save;
 252         push @new_acc_ids, $new_acc_trans->acc_trans_id;
 253
 254         $reference_amount -= abs($amount);
 255         $paid_amount      += -1 * $amount * $exchangerate;
 256         $skonto_amount_check -= $skonto_booking->{'skonto_amount'};
 257       };
 258       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 259           die "difference_as_skonto calculated incorrectly, sum of calculated payments doesn't add up to open amount $total_open_amount, reference_amount = $reference_amount\n" unless _round($reference_amount) == 0;
 260       }
 261     }
 262
 263     my $arap_amount = 0;
 264
 265     if ( $params{payment_type} eq 'difference_as_skonto' ) {
 266       $arap_amount = $total_open_amount;
 267     } elsif ( $params{payment_type} eq 'without_skonto' ) {
 268       $arap_amount = $rounded_params_amount;
 269     } elsif ( $params{payment_type} eq 'with_skonto_pt' ) {
 270       # this should be amount + sum(amount+skonto), but while we only allow
 271       # with_skonto_pt for completely unpaid invoices we just use the value
 272       # from the invoice
 273       $arap_amount = $total_open_amount;
 274     } elsif ( $params{payment_type} eq 'free_skonto' ) {
 275       # we forced positive values and forced rounding at the beginning
 276       # therefore the above comment can be safely applied for this payment type
 277       $arap_amount = $params{amount} + $params{skonto_amount};
 278     }
 279
 280     # regardless of payment_type there is always only exactly one arap booking
 281     # TODO: compare $arap_amount to running total
 282     my $arap_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 283                                                   chart_id   => $reference_account->id,
 284                                                   chart_link => $reference_account->link,
 285                                                   amount     => _round($arap_amount * $mult * $exchangerate - $fx_gain_loss_amount),
 286                                                   transdate  => $transdate_obj,
 287                                                   source     => '', #$params{source},
 288                                                   taxkey     => 0,
 289                                                   tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 290     $arap_booking->save;
 291     push @new_acc_ids, $arap_booking->acc_trans_id;
 292
 293     $fx_gain_loss_amount *= -1 if $self->is_sales;
 294     $self->paid($self->paid + _round($paid_amount) + $fx_gain_loss_amount) if $paid_amount;
 295     $self->datepaid($transdate_obj);
 296     $self->save;
 297
 298     # make sure transactions will be reloaded the next time $self->transactions
 299     # is called, as pay_invoice saves the acc_trans objects individually rather
 300     # than adding them to the transaction relation array.
 301     $self->forget_related('transactions');
 302
 303     my $datev_check = 0;
 304     if ( $is_sales )  {
 305       if ( (  $self->invoice && $::instance_conf->get_datev_check_on_sales_invoice  ) ||
 306            ( !$self->invoice && $::instance_conf->get_datev_check_on_ar_transaction )) {
 307         $datev_check = 1;
 308       }
 309     } else {
 310       if ( (  $self->invoice && $::instance_conf->get_datev_check_on_purchase_invoice ) ||
 311            ( !$self->invoice && $::instance_conf->get_datev_check_on_ap_transaction   )) {
 312         $datev_check = 1;
 313       }
 314     }
 315
 316     if ( $datev_check ) {
 317
 318       my $datev = SL::DATEV->new(
 319         dbh        => $db->dbh,
 320         trans_id   => $self->{id},
 321       );
 322
 323       $datev->generate_datev_data;
 324
 325       if ($datev->errors) {
 326         # this exception should be caught by with_transaction, which handles the rollback
 327         die join "\n", $::locale->text('DATEV check returned errors:'), $datev->errors;
 328       }
 329     }
 330
 331     1;
 332
 333   }) || die t8('error while paying invoice #1 : ', $self->invnumber) . $db->error . "\n";
 334   return wantarray ? @new_acc_ids : 1;
 335 }
 336
 337 sub skonto_date {
 338
 339   my $self = shift;
 340
 341   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 342
 343   my $skonto_date;
 344
 345   if ( $is_sales ) {
 346     return undef unless ref $self->payment_terms;
 347     return undef unless $self->payment_terms->terms_skonto > 0;
 348     $skonto_date = DateTime->from_object(object => $self->transdate)->add(days => $self->payment_terms->terms_skonto);
 349   } else {
 350     return undef unless ref $self->vendor->payment_terms;
 351     return undef unless $self->vendor->payment_terms->terms_skonto > 0;
 352     $skonto_date = DateTime->from_object(object => $self->transdate)->add(days => $self->vendor->payment_terms->terms_skonto);
 353   };
 354
 355   return $skonto_date;
 356 };
 357
 358 sub reference_account {
 359   my $self = shift;
 360
 361   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 362
 363   require SL::DB::Manager::AccTransaction;
 364
 365   my $link_filter = $is_sales ? 'AR' : 'AP';
 366
 367   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 368      trans_id   => $self->id,
 369      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 370   );
 371
 372   return undef unless ref $acc_trans;
 373
 374   my $reference_account = SL::DB::Manager::Chart->find_by(id => $acc_trans->chart_id);
 375
 376   return $reference_account;
 377 };
 378
 379 sub reference_amount {
 380   my $self = shift;
 381
 382   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 383
 384   require SL::DB::Manager::AccTransaction;
 385
 386   my $link_filter = $is_sales ? 'AR' : 'AP';
 387
 388   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 389      trans_id   => $self->id,
 390      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 391   );
 392
 393   return undef unless ref $acc_trans;
 394
 395   # this should be the same as $self->amount
 396   return $acc_trans->amount;
 397 };
 398
 399
 400 sub open_amount {
 401   my $self = shift;
 402
 403   # in the future maybe calculate this from acc_trans
 404
 405   # if the difference is 0.01 Cent this may end up as 0.009999999999998
 406   # numerically, so round this value when checking for cent threshold >= 0.01
 407
 408   return ($self->amount // 0) - ($self->paid // 0);
 409 };
 410
 411 sub open_percent {
 412   my $self = shift;
 413
 414   return 0 if $self->amount == 0;
 415   my $open_percent;
 416   if ( $self->open_amount < 0 ) {
 417     # overpaid, currently treated identically
 418     $open_percent = $self->open_amount * 100 / $self->amount;
 419   } else {
 420     $open_percent = $self->open_amount * 100 / $self->amount;
 421   };
 422
 423   return _round($open_percent) || 0;
 424 };
 425
 426 sub skonto_amount {
 427   my $self = shift;
 428
 429   return $self->amount - $self->amount_less_skonto;
 430 };
 431
 432 sub remaining_skonto_days {
 433   my $self = shift;
 434
 435   return undef unless ref $self->skonto_date;
 436
 437   my $dur = DateTime::Duration->new($self->skonto_date - DateTime->today);
 438   return $dur->delta_days();
 439
 440 };
 441
 442 sub percent_skonto {
 443   my $self = shift;
 444
 445   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 446
 447   my $percent_skonto = 0;
 448
 449   if ( $is_sales ) {
 450     return undef unless ref $self->payment_terms;
 451     return undef unless $self->payment_terms->percent_skonto > 0;
 452     $percent_skonto = $self->payment_terms->percent_skonto;
 453   } else {
 454     return undef unless ref $self->vendor->payment_terms;
 455     return undef unless $self->vendor->payment_terms->terms_skonto > 0;
 456     $percent_skonto = $self->vendor->payment_terms->percent_skonto;
 457   };
 458
 459   return $percent_skonto;
 460 };
 461
 462 sub amount_less_skonto {
 463   # amount that has to be paid if skonto applies, always return positive rounded values
 464   # no, rare case, but credit_notes and negative ap have negative amounts
 465   # and therefore this comment may be misguiding
 466   # the result is rounded so we can directly compare it with the user input
 467   my $self = shift;
 468
 469   my $percent_skonto = $self->percent_skonto || 0;
 470
 471   return _round($self->amount - ( $self->amount * $percent_skonto) );
 472
 473 };
 474
 475 sub check_skonto_configuration {
 476   my $self = shift;
 477
 478   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 479
 480   my $skonto_configured = 1; # default is assume skonto works
 481
 482   # my $transactions = $self->transactions;
 483   foreach my $transaction (@{ $self->transactions }) {
 484     # find all transactions with an AR_amount or AP_amount link
 485     my $tax = SL::DB::Manager::Tax->get_first( where => [taxkey => $transaction->taxkey, id => $transaction->tax_id ]);
 486     croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 487
 488     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->chart_link) };
 489     if ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) {
 490       $skonto_configured = 0 unless $tax->skonto_sales_chart_id;
 491     } elsif ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) {
 492       $skonto_configured = 0 unless $tax->skonto_purchase_chart_id;
 493     };
 494   };
 495
 496   return $skonto_configured;
 497 };
 498
 499 sub open_sepa_transfer_amount {
 500   my $self = shift;
 501
 502   my ($vc, $key, $type);
 503   if ( ref($self) eq 'SL::DB::Invoice' ) {
 504     $vc   = 'customer';
 505     $key  = 'ap_id';
 506     $type = 'ar';
 507   } else {
 508     $vc   = 'vendor';
 509     $key  = 'ap_id';
 510     $type = 'ap';
 511   };
 512
 513   my $sql = qq|SELECT SUM(sei.amount) AS amount FROM sepa_export_items sei | .
 514             qq| LEFT JOIN sepa_export se ON (sei.sepa_export_id = se.id)   | .
 515             qq| WHERE $key = ? AND NOT se.closed AND (se.vc = '$vc')       |;
 516
 517   my ($open_sepa_amount) = $self->db->dbh->selectrow_array($sql, undef, $self->id);
 518
 519   return $open_sepa_amount || 0;
 520
 521 };
 522
 523
 524 sub skonto_charts {
 525   my $self = shift;
 526
 527   # TODO: use param for amount, may also want to calculate skonto_amounts by
 528   # passing percentage in the future
 529
 530   my $amount = shift || $self->skonto_amount;
 531
 532   croak "no amount passed to skonto_charts" unless abs(_round($amount)) >= 0.01;
 533
 534   # TODO: check whether there are negative values in invoice / acc_trans ... credited items
 535
 536   # don't check whether skonto applies, because user may want to override this
 537   # return undef unless $self->percent_skonto;  # for is_sales
 538   # return undef unless $self->vendor->payment_terms->percent_skonto;  # for purchase
 539
 540   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 541
 542   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign
 543
 544   my @skonto_charts;  # resulting array with all income/expense accounts that have to be corrected
 545
 546   # calculate effective skonto (percentage) in difference_as_skonto mode
 547   # only works if there are no negative acc_trans values
 548   my $effective_skonto_rate = $amount ? $amount / $self->amount : 0;
 549
 550   # checks:
 551   my $total_skonto_amount  = 0;
 552   my $total_rounding_error = 0;
 553
 554   my $reference_ARAP_amount = 0;
 555
 556   # my $transactions = $self->transactions;
 557   foreach my $transaction (@{ $self->transactions }) {
 558     # find all transactions with an AR_amount or AP_amount link
 559     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->{chart_link}) };
 560     # second condition is that we can determine an automatic Skonto account for each AR_amount entry
 561
 562     if ( ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) or ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) ) {
 563         # $reference_ARAP_amount += $transaction->{amount} * $mult;
 564
 565         # quick hack that works around problem of non-unique tax keys in SKR04
 566         # ? use tax_id in acc_trans
 567         my $tax = SL::DB::Manager::Tax->get_first( where => [id => $transaction->{tax_id}]);
 568         croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 569
 570         if ( $is_sales ) {
 571           die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $transaction->{taxkey} , $tax->taxdescription , $tax->rate*100) unless ref $tax->skonto_sales_chart;
 572         } else {
 573           die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $transaction->{taxkey} , $tax->taxdescription , $tax->rate*100) unless ref $tax->skonto_purchase_chart;
 574         };
 575
 576         my $skonto_amount_unrounded;
 577
 578         my $skonto_percent_abs = $self->amount ? abs($transaction->amount * (1 + $tax->rate) * 100 / $self->amount) : 0;
 579
 580         my $transaction_amount = abs($transaction->{amount} * (1 + $tax->rate));
 581         my $transaction_skonto_percent = abs($transaction_amount/$self->amount); # abs($transaction->{amount} * (1 + $tax->rate));
 582
 583
 584         $skonto_amount_unrounded   = abs($amount * $transaction_skonto_percent);
 585         my $skonto_amount_rounded  = _round($skonto_amount_unrounded);
 586         my $rounding_error         = $skonto_amount_unrounded - $skonto_amount_rounded;
 587         my $rounded_rounding_error = _round($rounding_error);
 588
 589         $total_rounding_error += $rounding_error;
 590         $total_skonto_amount  += $skonto_amount_rounded;
 591
 592         my $rec = {
 593           # skonto_percent_abs: relative part of amount + tax to the total invoice amount
 594           'skonto_percent_abs'     => $skonto_percent_abs,
 595           'chart_id'               => $is_sales ? $tax->skonto_sales_chart->id : $tax->skonto_purchase_chart->id,
 596           'skonto_amount'          => $skonto_amount_rounded,
 597           # 'rounding_error'         => $rounding_error,
 598           # 'rounded_rounding_error' => $rounded_rounding_error,
 599         };
 600
 601         push @skonto_charts, $rec;
 602       };
 603   };
 604
 605   # if the rounded sum of all rounding_errors reaches 0.01 this sum is
 606   # subtracted from the largest skonto_amount
 607   my $rounded_total_rounding_error = abs(_round($total_rounding_error));
 608
 609   if ( $rounded_total_rounding_error > 0 ) {
 610     my $highest_amount_pos = 0;
 611     my $highest_amount = 0;
 612     my $i = -1;
 613     foreach my $ref ( @skonto_charts ) {
 614       $i++;
 615       if ( $ref->{skonto_amount} > $highest_amount ) {
 616         $highest_amount     = $ref->{skonto_amount};
 617         $highest_amount_pos = $i;
 618       };
 619     };
 620     $skonto_charts[$i]->{skonto_amount} -= $rounded_total_rounding_error;
 621   };
 622
 623   return @skonto_charts;
 624 };
 625
 626
 627 sub within_skonto_period {
 628   my $self = shift;
 629   my $dateref = shift || DateTime->now->truncate( to => 'day' );
 630
 631   return undef unless ref $dateref eq 'DateTime';
 632   return 0 unless $self->skonto_date;
 633
 634   # return 1 if requested date (or today) is inside skonto period
 635   # this will also return 1 if date is before the invoice date
 636   return $dateref <= $self->skonto_date;
 637 };
 638
 639 sub valid_skonto_amount {
 640   my $self = shift;
 641   my $amount = shift || 0;
 642   my $max_skonto_percent = 0.10;
 643
 644   return 0 unless $amount > 0;
 645
 646   # does this work for other currencies?
 647   return ($self->amount*$max_skonto_percent) > $amount;
 648 };
 649
 650 sub get_payment_select_options_for_bank_transaction {
 651   my ($self, $bt_id, %params) = @_;
 652
 653
 654   # CAVEAT template code expects with_skonto_pt at position 1 for visual help
 655   # due to skonto_charts, we cannot offer skonto for credit notes and neg ap
 656   my $skontoable = $self->amount > 0 ? 1 : 0;
 657   my @options;
 658   if(!$self->skonto_date) {
 659     push(@options, { payment_type => 'without_skonto', display => t8('without skonto'), selected => 1 });
 660     # wrong call to presenter or not implemented? disabled option is ignored
 661     # push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt'), disabled => 1 });
 662     push(@options, { payment_type => 'free_skonto', display => t8('free skonto') }) if $skontoable;
 663     return @options;
 664   }
 665   # valid skonto date, check if skonto is preferred
 666   my $bt = SL::DB::BankTransaction->new(id => $bt_id)->load;
 667   if ($self->skonto_date && $self->within_skonto_period($bt->transdate)) {
 668     push(@options, { payment_type => 'without_skonto', display => t8('without skonto') });
 669     push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt'), selected => 1 }) if $skontoable;
 670   } else {
 671     push(@options, { payment_type => 'without_skonto', display => t8('without skonto') , selected => 1 });
 672     push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt')}) if $skontoable;
 673   }
 674   push(@options, { payment_type => 'free_skonto', display => t8('free skonto') }) if $skontoable;
 675   return @options;
 676 }
 677
 678 sub exchangerate {
 679   my ($self) = @_;
 680
 681   return 1 if $self->currency_id == $::instance_conf->get_currency_id;
 682
 683   die "transdate isn't a DateTime object:" . ref($self->transdate) unless ref($self->transdate) eq 'DateTime';
 684   my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $self->currency_id,
 685                                                     transdate   => $self->transdate,
 686                                                    );
 687   return undef unless $rate;
 688
 689   return $self->is_sales ? $rate->buy : $rate->sell; # also undef if not defined
 690 };
 691
 692 sub get_payment_suggestions {
 693
 694   my ($self, %params) = @_;
 695
 696   my $open_amount = $self->open_amount;
 697   $open_amount   -= $self->open_sepa_transfer_amount if $params{sepa};
 698
 699   $self->{invoice_amount_suggestion} = $open_amount;
 700   undef $self->{payment_select_options};
 701   push(@{$self->{payment_select_options}} , { payment_type => 'without_skonto',  display => t8('without skonto') });
 702   if ( $self->within_skonto_period ) {
 703     # If there have been no payments yet suggest amount_less_skonto, otherwise the open amount
 704     if ( $open_amount &&                   # invoice amount not 0
 705          $open_amount == $self->amount &&  # no payments yet, or sum of payments and sepa export amounts is zero
 706          $self->check_skonto_configuration) {
 707       $self->{invoice_amount_suggestion} = $self->amount_less_skonto;
 708       push(@{$self->{payment_select_options}} , { payment_type => 'with_skonto_pt',  display => t8('with skonto acc. to pt') , selected => 1 });
 709     } else {
 710       if ( ( $self->valid_skonto_amount($self->open_amount) || $self->valid_skonto_amount($open_amount) ) and not $params{sepa} ) {
 711         $self->{invoice_amount_suggestion} = $open_amount;
 712         # only suggest difference_as_skonto if open_amount exactly matches skonto_amount
 713         # AND we aren't in SEPA mode
 714         my $selected = 0;
 715         $selected = 1 if _round($open_amount) == _round($self->skonto_amount);
 716         push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => $selected });
 717       };
 718     };
 719   } else {
 720     # invoice was configured with skonto, but skonto date has passed, or no skonto available
 721     $self->{invoice_amount_suggestion} = $open_amount;
 722     # difference_as_skonto doesn't make any sense for SEPA transfer, as this doesn't cause any actual payment
 723     if ( $self->valid_skonto_amount($self->open_amount) && not $params{sepa} ) {
 724       push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => 0 });
 725     };
 726   };
 727   return 1;
 728 };
 729
 730 # locales for payment type
 731 #
 732 # $main::locale->text('without_skonto')
 733 # $main::locale->text('with_skonto_pt')
 734 # $main::locale->text('difference_as_skonto')
 735 #
 736
 737 sub validate_payment_type {
 738   my $payment_type = shift;
 739
 740   my %allowed_payment_types = map { $_ => 1 } qw(without_skonto with_skonto_pt difference_as_skonto free_skonto);
 741   croak "illegal payment type: $payment_type, must be one of: " . join(' ', keys %allowed_payment_types) unless $allowed_payment_types{ $payment_type };
 742
 743   return 1;
 744 }
 745
 746 sub forex {
 747   my ($self) = @_;
 748   $self->currency_id == $::instance_conf->get_currency_id ? return 0 : return 1;
 749 };
 750
 751 sub _round {
 752   my $value = shift;
 753   my $num_dec = 2;
 754   return $::form->round_amount($value, 2);
 755 }
 756
 757 1;
 758
 759 __END__
 760
 761 =pod
 762
 763 =head1 NAME
 764
 765 SL::DB::Helper::Payment  Mixin providing helper methods for paying C<Invoice>
 766                          and C<PurchaseInvoice> objects and using skonto
 767
 768 =head1 SYNOPSIS
 769
 770 In addition to actually causing a payment via pay_invoice this helper contains
 771 many methods that help in determining information about the status of the
 772 invoice, such as the remaining open amount, whether skonto applies, until which
 773 date skonto applies, the skonto amount and relative percentages, what to do
 774 with skonto, ...
 775
 776 To prevent duplicate code this was all added in this mixin rather than directly
 777 in SL::DB::Invoice and SL::DB::PurchaseInvoice.
 778
 779 =over 4
 780
 781 =item C<pay_invoice %params>
 782
 783 Create a payment booking for an existing invoice object (type ar/ap/is/ir) via
 784 a configured bank account.
 785
 786 This function deals with all the acc_trans entries and also updates paid and datepaid.
 787 The params C<transdate> and C<chart_id> are mandantory.
 788 If the default payment ('without_skonto') is used the param amount is also
 789 mandantory.
 790 If the payment type ('free_skonto') is used the number params skonto_amount and amount
 791 are as well mandantory and need to be positive. Furthermore the skonto amount has
 792 to be lower than the payment or open invoice amount.
 793
 794 Transdate can either be a date object or a date string.
 795 Chart_id is the id of the payment booking chart.
 796 Amount is either a postive or negative number, but never 0.
 797
 798
 799 Example:
 800
 801   my $ap   = SL::DB::Manager::PurchaseInvoice->find_by( invnumber => '1');
 802   my $bank = SL::DB::Manager::BankAccount->find_by( name => 'Bank');
 803   $ap->pay_invoice(chart_id      => $bank->chart_id,
 804                    amount        => $ap->open_amount,
 805                    transdate     => DateTime->now->to_kivitendo,
 806                    memo          => 'foobar',
 807                    source        => 'barfoo',
 808                    payment_type  => 'without_skonto',  # default if not specified
 809                    project_id    => 25,
 810                   );
 811
 812 or with skonto:
 813   $ap->pay_invoice(chart_id      => $bank->chart_id,
 814                    amount        => $ap->amount,       # doesn't need to be specified
 815                    transdate     => DateTime->now->to_kivitendo,
 816                    memo          => 'foobar',
 817                    source        => 'barfoo',
 818                    payment_type  => 'with_skonto',
 819                   );
 820
 821 or in a certain currency:
 822   $ap->pay_invoice(chart_id      => $bank->chart_id,
 823                    amount        => 500,
 824                    currency      => 'USD',
 825                    transdate     => DateTime->now->to_kivitendo,
 826                    memo          => 'foobar',
 827                    source        => 'barfoo',
 828                    payment_type  => 'with_skonto_pt',
 829                   );
 830
 831 Allowed payment types are:
 832   without_skonto with_skonto_pt difference_as_skonto
 833
 834 The option C<payment_type> allows for a basic skonto mechanism.
 835
 836 C<without_skonto> is the default mode, "amount" is paid to the account in
 837 chart_id. This can also be used for partial payments and corrections via
 838 negative amounts.
 839
 840 C<with_skonto_pt> can't be used for partial payments. When used on unpaid
 841 invoices the whole amount is paid, with the skonto part automatically being
 842 booked according to the skonto chart configured in the tax settings for each
 843 tax key. If an amount is passed it is ignored and the actual configured skonto
 844 amount is used.
 845
 846 C<difference_as_skonto> can only be used after partial payments have been made,
 847 the whole specified amount is booked according to the skonto charts configured
 848 in the tax settings for each tax key.
 849
 850 So passing amount doesn't have any effect for the cases C<with_skonto_pt> and
 851 C<difference_as_skonto>, as all necessary values are taken from the stored
 852 invoice.
 853
 854 The skonto modes automatically calculate the relative amounts for a mix of
 855 taxes, e.g. items with 7% and 19% in one invoice. There is a helper method
 856 skonto_charts, which calculates the relative percentages according to the
 857 amounts in acc_trans (which are grouped by tax).
 858
 859 There is currently no way of excluding certain items in an invoice from having
 860 skonto applied to them.  If this feature was added to parts the calculation
 861 method of relative skonto would have to be completely rewritten using the
 862 invoice items rather than acc_trans.
 863
 864 The skonto modes also still don't automatically correct the tax, this still has
 865 to be done manually. Therefore all payments generated by pay_invoice have
 866 taxkey 0.
 867
 868 There is currently no way to directly pay an invoice via this method if the
 869 effective skonto differs from the skonto according to the payment terms
 870 configured for the invoice/vendor.
 871
 872 In this case one has to pay in two steps: first the actual paid amount via
 873 "without skonto", and then the remainder via "difference_as_skonto". The user
 874 has to there actively decide whether to accept the differing skonto.
 875
 876 Because of the way skonto_charts works the calculation doesn't work if there
 877 are negative values in acc_trans. E.g. one invoice with a positive value for
 878 19% tax and a negative value for the acc_trans line with 7%
 879
 880 Skonto doesn't/shouldn't apply if the invoice contains credited items.
 881
 882 If no amount is given the whole open amout is paid.
 883
 884 If neither currency or currency_id are given as params, the currency of the
 885 invoice is assumed to be the payment currency.
 886
 887 If successful the return value will be 1 in scalar context or in list context
 888 the two ids (acc_trans_id) of the newly created bookings.
 889
 890 =item C<reference_account>
 891
 892 Returns a chart object which is the chart of the invoice with link AR or AP.
 893
 894 Example (1200 is the AR account for SKR04):
 895   my $invoice = invoice(invnumber => '144');
 896   $invoice->reference_account->accno
 897   # 1200
 898
 899 =item C<percent_skonto>
 900
 901 Returns the configured skonto percentage of the payment terms of an invoice,
 902 e.g. 0.02 for 2%. Payment terms come from invoice settings for ar, from vendor
 903 settings for ap.
 904
 905 =item C<amount_less_skonto>
 906
 907 If the invoice has a payment term (via ar for sales, via vendor for purchase),
 908 calculate the amount to be paid in the case of skonto.  This doesn't check,
 909 whether skonto applies (i.e. skonto doesn't wasn't exceeded), it just subtracts
 910 the configured percentage (e.g. 2%) from the total amount.
 911
 912 The returned value is rounded to two decimals.
 913
 914 =item C<skonto_date>
 915
 916 The date up to which skonto may be taken. This is calculated from the invoice
 917 date + the number of days configured in the payment terms.
 918
 919 This method can also be used to determine whether skonto applies for the
 920 invoice, as it returns undef if there is no payment term or skonto days is set
 921 to 0.
 922
 923 =item C<within_skonto_period [DATE]>
 924
 925 Returns 0 or 1.
 926
 927 Checks whether the invoice has payment terms configured, and whether the date
 928 is within the skonto max date. If no date is passed the current date is used.
 929
 930 You can also pass a dateref object as a parameter to check whether skonto
 931 applies for that date rather than the current date.
 932
 933 =item C<valid_skonto_amount>
 934
 935 Takes an amount as an argument and checks whether the amount is less than 10%
 936 of the total amount of the invoice. The value of 10% is currently hardcoded in
 937 the method. This method is currently used to check whether to offer the payment
 938 option "difference as skonto".
 939
 940 Example:
 941  if ( $invoice->valid_skonto_amount($invoice->open_amount) ) {
 942    # ... do something
 943  }
 944
 945 =item C<skonto_charts [$amount]>
 946
 947 Returns a list of chart_ids and some calculated numbers that can be used for
 948 paying the invoice with skonto. This function will automatically calculate the
 949 relative skonto amounts even if the invoice contains several types of taxes
 950 (e.g. 7% and 19%).
 951
 952 Example usage:
 953   my $invoice = SL::DB::Manager::Invoice->find_by(invnumber => '211');
 954   my @skonto_charts = $invoice->skonto_charts;
 955
 956 or with the total skonto amount as an argument:
 957   my @skonto_charts = $invoice->skonto_charts($invoice->open_amount);
 958
 959 The following values are generated for each chart:
 960
 961 =over 2
 962
 963 =item C<chart_id>
 964
 965 The chart id of the skonto amount to be booked.
 966
 967 =item C<skonto_amount>
 968
 969 The total amount to be paid to the account
 970
 971 =item C<skonto_percent>
 972
 973 The relative percentage of that skonto chart. This can be useful if the actual
 974 ekonto that is paid deviates from the granted skonto, e.g. customer effectively
 975 pays 2.6% skonto instead of 2%, and we accept this. Then we can still calculate
 976 the relative skonto amounts for different taxes based on the absolute
 977 percentages. Used for case C<difference_as_skonto>.
 978
 979 =item C<skonto_percent_abs>
 980
 981 The absolute percentage of that skonto chart in relation to the total amount.
 982 Used to calculate skonto_amount for case C<with_skonto_pt>.
 983
 984 =back
 985
 986 If the invoice contains several types of taxes then skonto_charts can be used
 987 to calculate the relative amounts.
 988
 989 Example in console of an invoice with 100 Euro at 7% and 100 Euro at 19% with
 990 tax not included:
 991
 992   my $invoice = invoice(invnumber => '144');
 993   $invoice->amount
 994   226.00000
 995   $invoice->payment_terms->percent_skonto
 996   0.02
 997   $invoice->skonto_charts
 998   pp $invoice->skonto_charts
 999   #             $VAR1 = {
1000   #               'chart_id'       => 128,
1001   #               'skonto_amount'  => '2.14',
1002   #               'skonto_percent' => '47.3451327433627'
1003   #             };
1004   #             $VAR2 = {
1005   #               'chart_id'       => 130,
1006   #               'skonto_amount'  => '2.38',
1007   #               'skonto_percent' => '52.654867256637'
1008   #             };
1009
1010 C<skonto_charts> always returns positive values (abs) for C<skonto_amount> and
1011 C<skonto_percent>.
1012
1013 C<skonto_charts> generates one entry for each acc_trans entry. ar and ap
1014 bookings only have one acc_trans entry for each taxkey (e.g. 7% and 19%).  This
1015 is because all the items are grouped according to the Buchungsgruppen mechanism
1016 and the totals are written to acc_trans.  For is and ir it is possible to have
1017 several acc_trans entries with the same tax. In this case skonto_charts
1018 generates a skonto booking for each acc_trans income/expense entry.
1019
1020 In the future this function may also be used to calculate the corrections for
1021 the income tax.
1022
1023 =item C<open_amount>
1024
1025 Unrounded total open amount of invoice (amount - paid).
1026 Doesn't take into account pending SEPA transfers.
1027
1028 =item C<open_percent>
1029
1030 Percentage of the invoice that is still unpaid, e.g. 100,00 if no payments have
1031 been made yet, 0,00 if fully paid.
1032
1033 =item C<remaining_skonto_days>
1034
1035 How many days skonto can still be taken, calculated from current day. Returns 0
1036 if current day is the max skonto date, and negative number if skonto date has
1037 already passed.
1038
1039 Returns undef if skonto is not configured for that invoice.
1040
1041 =item C<get_payment_suggestions %params>
1042
1043 Creates data intended for an L.select_tag dropdown that can be used in a
1044 template. Depending on the rules it will choose from the options
1045 without_skonto, with_skonto_pt and difference_as_skonto, and select the most
1046 likely one.
1047
1048 If the parameter "sepa" is passed, the SEPA export payments that haven't been
1049 executed yet are considered when determining the open amount of the invoice.
1050
1051 The current rules are:
1052
1053 =over 2
1054
1055 =item * without_skonto is always an option
1056
1057 =item * with_skonto_pt is only offered if there haven't been any payments yet and the current date is within the skonto period.
1058
1059 =item * difference_as_skonto is only offered if there have already been payments made and the open amount is smaller than 10% of the total amount.
1060
1061 with_skonto_pt will only be offered, if all the AR_amount/AP_amount have a
1062 taxkey with a configured skonto chart
1063
1064 =back
1065
1066 It will also fill $self->{invoice_amount_suggestion} with either the open
1067 amount, or if with_skonto_pt is selected, with amount_less_skonto, so the
1068 template can fill the input with the likely amount.
1069
1070 Example in console:
1071   my $ar = invoice( invnumber => '257');
1072   $ar->get_payment_suggestions;
1073   print $ar->{invoice_amount_suggestion} . "\n";
1074   # 97.23
1075   pp $ar->{payment_select_options}
1076   # $VAR1 = [
1077   #         {
1078   #           'display' => 'ohne Skonto',
1079   #           'payment_type' => 'without_skonto'
1080   #         },
1081   #         {
1082   #           'display' => 'mit Skonto nach ZB',
1083   #           'payment_type' => 'with_skonto_pt',
1084   #           'selected' => 1
1085   #         }
1086   #       ];
1087
1088 The resulting array $ar->{payment_select_options} can be used in a template
1089 select_tag using value_key and title_key:
1090
1091 [% L.select_tag('payment_type_' _ loop.count, invoice.payment_select_options, value_key => 'payment_type', title_key => 'display', id => 'payment_type_' _ loop.count) %]
1092
1093 It would probably make sense to have different rules for the pre-selected items
1094 for sales and purchase, and to also make these rules configurable in the
1095 defaults. E.g. when creating a SEPA bank transfer for vendor invoices a company
1096 might always want to pay quickly making use of skonto, while another company
1097 might always want to pay as late as possible.
1098
1099 =item C<get_payment_select_options_for_bank_transaction $banktransaction_id %params>
1100
1101 Make suggestion for a skonto payment type by returning an HTML blob of the options
1102 of a HTML drop-down select with the most likely option preselected.
1103
1104 This is a helper function for BankTransaction/ajax_payment_suggestion and
1105 template/webpages/bank_transactions/invoices.html
1106
1107 We are working with an existing payment, so difference_as_skonto never makes sense.
1108
1109 If skonto is not possible (skonto_date does not exists) simply return
1110 the single 'no skonto' option as a visual hint.
1111
1112 If skonto is possible (skonto_date exists), add two possibilities:
1113 without_skonto and with_skonto_pt if payment date is within skonto_date,
1114 preselect with_skonto_pt, otherwise preselect without skonto.
1115
1116 =item C<exchangerate>
1117
1118 Returns 1 immediately if the record uses the default currency.
1119
1120 Returns the exchangerate in database format for the invoice according to that
1121 invoice's transdate, returning 'buy' for sales, 'sell' for purchases.
1122
1123 If no exchangerate can be found for that day undef is returned.
1124
1125 =item C<forex>
1126
1127 Returns 1 if record uses a different currency, 0 if the default currency is used.
1128
1129 =back
1130
1131 =head1 TODO AND CAVEATS
1132
1133 =over 4
1134
1135 =item *
1136
1137 when looking at open amount, maybe consider that there may already be queued
1138 amounts in SEPA Export
1139
1140 =item * C<skonto_charts>
1141
1142 Cannot handle negative skonto amounts, will always calculate the skonto amount
1143 for credit notes or negative ap transactions with a positive sign.
1144
1145
1146 =back
1147
1148 =head1 AUTHOR
1149
1150 G. Richardson E<lt>grichardson@kivitendo-premium.de<gt>
1151
1152 =cut