SL/DB/Helper/Payment.pm

   1 package SL::DB::Helper::Payment;
   2
   3 use strict;
   4
   5 use parent qw(Exporter);
   6 our @EXPORT = qw(pay_invoice);
   7 our @EXPORT_OK = qw(skonto_date skonto_charts amount_less_skonto within_skonto_period percent_skonto reference_account reference_amount open_amount open_percent remaining_skonto_days skonto_amount check_skonto_configuration valid_skonto_amount get_payment_suggestions validate_payment_type open_sepa_transfer_amount get_payment_select_options_for_bank_transaction exchangerate forex);
   8 our %EXPORT_TAGS = (
   9   "ALL" => [@EXPORT, @EXPORT_OK],
  10 );
  11
  12 require SL::DB::Chart;
  13 use Data::Dumper;
  14 use DateTime;
  15 use SL::DATEV qw(:CONSTANTS);
  16 use SL::Locale::String qw(t8);
  17 use List::Util qw(sum);
  18 use SL::DB::Exchangerate;
  19 use SL::DB::Currency;
  20 use Carp;
  21
  22 #
  23 # Public functions not exported by default
  24 #
  25
  26 sub pay_invoice {
  27   my ($self, %params) = @_;
  28
  29   require SL::DB::Tax;
  30
  31   my $is_sales = ref($self) eq 'SL::DB::Invoice';
  32   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign depending on ar/ap
  33   my @new_acc_ids;
  34   my $paid_amount = 0; # the amount that will be later added to $self->paid, should be in default currency
  35
  36   # default values if not set
  37   $params{payment_type} = 'without_skonto' unless $params{payment_type};
  38   validate_payment_type($params{payment_type});
  39
  40   # check for required parameters and optional params depending on payment_type
  41   Common::check_params(\%params, qw(chart_id transdate));
  42   if ( $params{'payment_type'} eq 'without_skonto' && abs($params{'amount'}) < 0) {
  43     croak "invalid amount for payment_type 'without_skonto': $params{'amount'}\n";
  44   }
  45   if ($params{'payment_type'} eq 'free_skonto') {
  46     # we dont like too much automagic for this payment type.
  47     # we force caller input for amount and skonto amount
  48     Common::check_params(\%params, qw(amount skonto_amount));
  49     # secondly we dont want to handle credit notes and purchase credit notes
  50     croak("Cannot use 'free skonto' for credit or debit notes") if ($params{amount} <= 0 || $params{skonto_amount} <= 0);
  51     # both amount have to be rounded
  52     $params{skonto_amount} = _round($params{skonto_amount});
  53     $params{amount}        = _round($params{amount});
  54     # lastly skonto_amount has to be smaller than the open invoice amount or payment amount ;-)
  55     if ($params{skonto_amount} > abs($self->open_amount) || $params{skonto_amount} > $params{amount}) {
  56       croak("Skonto amount higher than the payment or invoice amount");
  57     }
  58   }
  59
  60   my $transdate_obj;
  61   if (ref($params{transdate}) eq 'DateTime') {
  62     $transdate_obj = $params{transdate};
  63   } else {
  64     $transdate_obj = $::locale->parse_date_to_object($params{transdate});
  65   };
  66   croak t8('Illegal date') unless ref $transdate_obj;
  67
  68   # check for closed period
  69   my $closedto = $::locale->parse_date_to_object($::instance_conf->get_closedto);
  70   if ( ref $closedto && $transdate_obj < $closedto ) {
  71     croak t8('Cannot post payment for a closed period!');
  72   };
  73
  74   # check for maximum number of future days
  75   if ( $::instance_conf->get_max_future_booking_interval > 0 ) {
  76     croak t8('Cannot post transaction above the maximum future booking date!') if $transdate_obj > DateTime->now->add( days => $::instance_conf->get_max_future_booking_interval );
  77   };
  78
  79   # currency is either passed or use the invoice currency if it differs from the default currency
  80   # TODO remove
  81   my ($exchangerate,$currency);
  82   if ($params{currency} || $params{currency_id} || $self->currency_id != $::instance_conf->get_currency_id) {
  83     if ($params{currency} || $params{currency_id} ) { # currency was specified
  84       $currency = SL::DB::Manager::Currency->find_by(name => $params{currency}) || SL::DB::Manager::Currency->find_by(id => $params{currency_id});
  85     } else { # use invoice currency
  86       $currency = SL::DB::Manager::Currency->find_by(id => $self->currency_id);
  87     };
  88     die "no currency" unless $currency;
  89     if ($currency->id == $::instance_conf->get_currency_id) {
  90       $exchangerate = 1;
  91     } else {
  92       my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $currency->id,
  93                                                         transdate   => $transdate_obj,
  94                                                        );
  95       if ($rate) {
  96         $exchangerate = $is_sales ? $rate->buy : $rate->sell;
  97       } else {
  98         die "No exchange rate for " . $transdate_obj->to_kivitendo;
  99       };
 100     };
 101   } else { # no currency param given or currency is the same as default_currency
 102     $exchangerate = 1;
 103   };
 104
 105   # options with_skonto_pt and difference_as_skonto don't require the parameter
 106   # amount, but if amount is passed, make sure it matches the expected value
 107   if ( $params{'payment_type'} eq 'difference_as_skonto' ) {
 108     croak "amount $params{amount} doesn't match open amount " . $self->open_amount . ", diff = " . ($params{amount}-$self->open_amount) if $params{amount} && abs($self->open_amount - $params{amount} ) > 0.0000001;
 109   } elsif ( $params{'payment_type'} eq 'with_skonto_pt' ) {
 110     croak "amount $params{amount} doesn't match amount less skonto: " . $self->amount_less_skonto . "\n" if $params{amount} && abs($self->amount_less_skonto - $params{amount} ) > 0.0000001;
 111     croak "payment type with_skonto_pt can't be used if payments have already been made" if $self->paid != 0;
 112   };
 113
 114   # absolute skonto amount for invoice, use as reference sum to see if the
 115   # calculated skontos add up
 116   # only needed for payment_term "with_skonto_pt"
 117
 118   my $skonto_amount_check = $self->skonto_amount; # variable should be zero after calculating all skonto
 119   my $total_open_amount   = $self->open_amount;
 120
 121   # account where money is paid to/from: bank account or cash
 122   my $account_bank = SL::DB::Manager::Chart->find_by(id => $params{chart_id});
 123   croak "can't find bank account with id " . $params{chart_id} unless ref $account_bank;
 124
 125   my $reference_account = $self->reference_account;
 126   croak "can't find reference account (link = AR/AP) for invoice" unless ref $reference_account;
 127
 128   my $memo   = $params{memo}   // '';
 129   my $source = $params{source} // '';
 130
 131   my $rounded_params_amount = _round( $params{amount} ); # / $exchangerate);
 132   my $fx_gain_loss_amount = 0; # for fx_gain and fx_loss
 133
 134   my $db = $self->db;
 135   $db->with_transaction(sub {
 136     my $new_acc_trans;
 137
 138     # all three payment type create 1 AR/AP booking (the paid part)
 139     # difference_as_skonto creates n skonto bookings (1 for each buchungsgruppe type)
 140     # with_skonto_pt creates 1 bank booking and n skonto bookings (1 for each buchungsgruppe type)
 141     # without_skonto creates 1 bank booking
 142
 143     # as long as there is no automatic tax, payments are always booked with
 144     # taxkey 0
 145
 146     unless ( $params{payment_type} eq 'difference_as_skonto' ) {
 147       # cases with_skonto_pt, free_skonto and without_skonto
 148
 149       # for case with_skonto_pt we need to know the corrected amount at this
 150       # stage if we are going to use $params{amount}
 151
 152       my $pay_amount = $rounded_params_amount;
 153       $pay_amount = $self->amount_less_skonto if $params{payment_type} eq 'with_skonto_pt';
 154
 155       # bank account and AR/AP
 156       $paid_amount += $pay_amount * $exchangerate;
 157
 158       my $amount = (-1 * $pay_amount) * $mult;
 159
 160
 161       # total amount against bank, do we already know this by now?
 162       $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 163                                                    chart_id   => $account_bank->id,
 164                                                    chart_link => $account_bank->link,
 165                                                    amount     => $amount,
 166                                                    transdate  => $transdate_obj,
 167                                                    source     => $source,
 168                                                    memo       => $memo,
 169                                                    project_id => $params{project_id} ? $params{project_id} : undef,
 170                                                    taxkey     => 0,
 171                                                    tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 172       $new_acc_trans->save;
 173
 174       push @new_acc_ids, $new_acc_trans->acc_trans_id;
 175       # deal with fxtransaction
 176       if ( $self->currency_id != $::instance_conf->get_currency_id ) {
 177         my $fxamount = _round($amount - ($amount * $exchangerate));
 178         $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 179                                                      chart_id       => $account_bank->id,
 180                                                      chart_link     => $account_bank->link,
 181                                                      amount         => $fxamount * -1,
 182                                                      transdate      => $transdate_obj,
 183                                                      source         => $source,
 184                                                      memo           => $memo,
 185                                                      taxkey         => 0,
 186                                                      fx_transaction => 1,
 187                                                      tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 188         $new_acc_trans->save;
 189         push @new_acc_ids, $new_acc_trans->acc_trans_id;
 190         # if invoice exchangerate differs from exchangerate of payment
 191         # deal with fxloss and fxamount
 192         if ($self->exchangerate and $self->exchangerate != 1 and $self->exchangerate != $exchangerate) {
 193           my $fxgain_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxgain_accno_id) || die "Can't determine fxgain chart";
 194           my $fxloss_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxloss_accno_id) || die "Can't determine fxloss chart";
 195           my $gain_loss_amount = _round($amount * ($exchangerate - $self->exchangerate ) * -1,2);
 196           my $gain_loss_chart = $gain_loss_amount > 0 ? $fxgain_chart : $fxloss_chart;
 197           $fx_gain_loss_amount = $gain_loss_amount;
 198
 199           $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 200                                                        chart_id       => $gain_loss_chart->id,
 201                                                        chart_link     => $gain_loss_chart->link,
 202                                                        amount         => $gain_loss_amount,
 203                                                        transdate      => $transdate_obj,
 204                                                        source         => $source,
 205                                                        memo           => $memo,
 206                                                        taxkey         => 0,
 207                                                        fx_transaction => 0,
 208                                                        tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 209           $new_acc_trans->save;
 210           push @new_acc_ids, $new_acc_trans->acc_trans_id;
 211
 212         }
 213       }
 214     }
 215     # better everything except without_skonto
 216     if ($params{payment_type} eq 'difference_as_skonto' or $params{payment_type} eq 'with_skonto_pt'
 217         or $params{payment_type} eq 'free_skonto' ) {
 218
 219       my $total_skonto_amount;
 220       if ( $params{payment_type} eq 'with_skonto_pt' ) {
 221         $total_skonto_amount = $self->skonto_amount;
 222       } elsif ( $params{payment_type} eq 'difference_as_skonto' ) {
 223         $total_skonto_amount = $self->open_amount;
 224       } elsif ( $params{payment_type} eq 'free_skonto') {
 225         $total_skonto_amount = $params{skonto_amount};
 226       }
 227       my @skonto_bookings = $self->skonto_charts($total_skonto_amount);
 228
 229       # error checking:
 230       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 231         my $calculated_skonto_sum  = sum map { $_->{skonto_amount} } @skonto_bookings;
 232         croak "calculated skonto for difference_as_skonto = $calculated_skonto_sum doesn't add up open amount: " . $self->open_amount unless _round($calculated_skonto_sum) == _round($self->open_amount);
 233       };
 234
 235       my $reference_amount = $total_skonto_amount;
 236
 237       # create an acc_trans entry for each result of $self->skonto_charts
 238       foreach my $skonto_booking ( @skonto_bookings ) {
 239         next unless $skonto_booking->{'chart_id'};
 240         next unless $skonto_booking->{'skonto_amount'} != 0;
 241         my $amount = -1 * $skonto_booking->{skonto_amount};
 242         $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 243                                                      chart_id   => $skonto_booking->{'chart_id'},
 244                                                      chart_link => SL::DB::Manager::Chart->find_by(id => $skonto_booking->{'chart_id'})->link,
 245                                                      amount     => $amount * $mult,
 246                                                      transdate  => $transdate_obj,
 247                                                      source     => $params{source},
 248                                                      taxkey     => 0,
 249                                                      tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 250
 251         # the acc_trans entries are saved individually, not added to $self and then saved all at once
 252         $new_acc_trans->save;
 253         push @new_acc_ids, $new_acc_trans->acc_trans_id;
 254
 255         $reference_amount -= abs($amount);
 256         $paid_amount      += -1 * $amount * $exchangerate;
 257         $skonto_amount_check -= $skonto_booking->{'skonto_amount'};
 258       };
 259       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 260           die "difference_as_skonto calculated incorrectly, sum of calculated payments doesn't add up to open amount $total_open_amount, reference_amount = $reference_amount\n" unless _round($reference_amount) == 0;
 261       }
 262     }
 263
 264     my $arap_amount = 0;
 265
 266     if ( $params{payment_type} eq 'difference_as_skonto' ) {
 267       $arap_amount = $total_open_amount;
 268     } elsif ( $params{payment_type} eq 'without_skonto' ) {
 269       $arap_amount = $rounded_params_amount;
 270     } elsif ( $params{payment_type} eq 'with_skonto_pt' ) {
 271       # this should be amount + sum(amount+skonto), but while we only allow
 272       # with_skonto_pt for completely unpaid invoices we just use the value
 273       # from the invoice
 274       $arap_amount = $total_open_amount;
 275     } elsif ( $params{payment_type} eq 'free_skonto' ) {
 276       # we forced positive values and forced rounding at the beginning
 277       # therefore the above comment can be safely applied for this payment type
 278       $arap_amount = $params{amount} + $params{skonto_amount};
 279     }
 280
 281     # regardless of payment_type there is always only exactly one arap booking
 282     # TODO: compare $arap_amount to running total
 283     my $arap_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 284                                                   chart_id   => $reference_account->id,
 285                                                   chart_link => $reference_account->link,
 286                                                   amount     => _round($arap_amount * $mult * $exchangerate - $fx_gain_loss_amount),
 287                                                   transdate  => $transdate_obj,
 288                                                   source     => '', #$params{source},
 289                                                   taxkey     => 0,
 290                                                   tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 291     $arap_booking->save;
 292     push @new_acc_ids, $arap_booking->acc_trans_id;
 293
 294     # hook for invoice_for_advance_payment DATEV always pairs, acc_trans_id has to be higher than arap_booking ;-)
 295     if ($self->invoice_type eq 'invoice_for_advance_payment') {
 296       my $clearing_chart = SL::DB::Chart->new(id => $::instance_conf->get_advance_payment_clearing_chart_id)->load;
 297       die "No Clearing Chart for Advance Payment" unless ref $clearing_chart eq 'SL::DB::Chart';
 298
 299       # what does ptc say
 300       my %inv_calc = $self->calculate_prices_and_taxes();
 301       my @trans_ids = keys %{ $inv_calc{amounts} };
 302       die "Invalid state for advance payment more than one trans_id" if (scalar @trans_ids > 1);
 303       my $entry = delete $inv_calc{amounts}{$trans_ids[0]};
 304       my $tax;
 305       if ($entry->{tax_id}) {
 306         $tax = SL::DB::Manager::Tax->find_by(id => $entry->{tax_id}); # || die "Can't find tax with id " . $entry->{tax_id};
 307       }
 308       if ($tax and $tax->rate != 0) {
 309         my ($netamount, $taxamount);
 310         my $roundplaces = 2;
 311         # we dont have a clue about skonto, that's why we use $arap_amount as taxincluded
 312         ($netamount, $taxamount) = Form->calculate_tax($arap_amount, $tax->rate, 1, $roundplaces);
 313         # for debugging database set
 314         my $fullmatch = $netamount == $entry->{amount} ? '::netamount total true' : '';
 315         my $tax_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 316                                                      chart_id   => $tax->chart_id,
 317                                                      chart_link => $tax->chart->link,
 318                                                      amount     => _round($taxamount),
 319                                                      transdate  => $transdate_obj,
 320                                                      source     => 'Automatic Tax Booking for Payment in Advance' . $fullmatch,
 321                                                      taxkey     => $tax->taxkey,
 322                                                      tax_id     => $tax->id);
 323         $tax_booking->save;
 324         push @new_acc_ids, $tax_booking->acc_trans_id;
 325         my $arap_tax_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 326                                                      chart_id   => $clearing_chart->id,
 327                                                      chart_link => $clearing_chart->link,
 328                                                      amount     => _round($taxamount * -1),
 329                                                      transdate  => $transdate_obj,
 330                                                      source     => 'Automatic Tax Booking for Payment in Advance' . $fullmatch,
 331                                                      taxkey     => 0,
 332                                                      tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 333         $arap_tax_booking->save;
 334         push @new_acc_ids, $arap_tax_booking->acc_trans_id;
 335       }
 336     }
 337     $fx_gain_loss_amount *= -1 if $self->is_sales;
 338     $self->paid($self->paid + _round($paid_amount) + $fx_gain_loss_amount) if $paid_amount;
 339     $self->datepaid($transdate_obj);
 340     $self->save;
 341
 342     # make sure transactions will be reloaded the next time $self->transactions
 343     # is called, as pay_invoice saves the acc_trans objects individually rather
 344     # than adding them to the transaction relation array.
 345     $self->forget_related('transactions');
 346
 347     my $datev_check = 0;
 348     if ( $is_sales )  {
 349       if ( (  $self->invoice && $::instance_conf->get_datev_check_on_sales_invoice  ) ||
 350            ( !$self->invoice && $::instance_conf->get_datev_check_on_ar_transaction )) {
 351         $datev_check = 1;
 352       }
 353     } else {
 354       if ( (  $self->invoice && $::instance_conf->get_datev_check_on_purchase_invoice ) ||
 355            ( !$self->invoice && $::instance_conf->get_datev_check_on_ap_transaction   )) {
 356         $datev_check = 1;
 357       }
 358     }
 359
 360     if ( $datev_check ) {
 361
 362       my $datev = SL::DATEV->new(
 363         dbh        => $db->dbh,
 364         trans_id   => $self->{id},
 365       );
 366
 367       $datev->generate_datev_data;
 368
 369       if ($datev->errors) {
 370         # this exception should be caught by with_transaction, which handles the rollback
 371         die join "\n", $::locale->text('DATEV check returned errors:'), $datev->errors;
 372       }
 373     }
 374
 375     1;
 376
 377   }) || die t8('error while paying invoice #1 : ', $self->invnumber) . $db->error . "\n";
 378   return wantarray ? @new_acc_ids : 1;
 379 }
 380
 381 sub skonto_date {
 382
 383   my $self = shift;
 384
 385   return undef unless ref $self->payment_terms;
 386   return undef unless $self->payment_terms->terms_skonto > 0;
 387   return DateTime->from_object(object => $self->transdate)->add(days => $self->payment_terms->terms_skonto);
 388 };
 389
 390 sub reference_account {
 391   my $self = shift;
 392
 393   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 394
 395   require SL::DB::Manager::AccTransaction;
 396
 397   my $link_filter = $is_sales ? 'AR' : 'AP';
 398
 399   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 400      trans_id   => $self->id,
 401      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 402   );
 403
 404   return undef unless ref $acc_trans;
 405
 406   my $reference_account = SL::DB::Manager::Chart->find_by(id => $acc_trans->chart_id);
 407
 408   return $reference_account;
 409 };
 410
 411 sub reference_amount {
 412   my $self = shift;
 413
 414   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 415
 416   require SL::DB::Manager::AccTransaction;
 417
 418   my $link_filter = $is_sales ? 'AR' : 'AP';
 419
 420   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 421      trans_id   => $self->id,
 422      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 423   );
 424
 425   return undef unless ref $acc_trans;
 426
 427   # this should be the same as $self->amount
 428   return $acc_trans->amount;
 429 };
 430
 431
 432 sub open_amount {
 433   my $self = shift;
 434
 435   # in the future maybe calculate this from acc_trans
 436
 437   # if the difference is 0.01 Cent this may end up as 0.009999999999998
 438   # numerically, so round this value when checking for cent threshold >= 0.01
 439
 440   return ($self->amount // 0) - ($self->paid // 0);
 441 };
 442
 443 sub open_percent {
 444   my $self = shift;
 445
 446   return 0 if $self->amount == 0;
 447   my $open_percent;
 448   if ( $self->open_amount < 0 ) {
 449     # overpaid, currently treated identically
 450     $open_percent = $self->open_amount * 100 / $self->amount;
 451   } else {
 452     $open_percent = $self->open_amount * 100 / $self->amount;
 453   };
 454
 455   return _round($open_percent) || 0;
 456 };
 457
 458 sub skonto_amount {
 459   my $self = shift;
 460
 461   return $self->amount - $self->amount_less_skonto;
 462 };
 463
 464 sub remaining_skonto_days {
 465   my $self = shift;
 466
 467   return undef unless ref $self->skonto_date;
 468
 469   my $dur = DateTime::Duration->new($self->skonto_date - DateTime->today);
 470   return $dur->delta_days();
 471
 472 };
 473
 474 sub percent_skonto {
 475   my $self = shift;
 476
 477   my $percent_skonto = 0;
 478
 479   return undef unless ref $self->payment_terms;
 480   return undef unless $self->payment_terms->percent_skonto > 0;
 481   $percent_skonto = $self->payment_terms->percent_skonto;
 482
 483   return $percent_skonto;
 484 };
 485
 486 sub amount_less_skonto {
 487   # amount that has to be paid if skonto applies, always return positive rounded values
 488   # no, rare case, but credit_notes and negative ap have negative amounts
 489   # and therefore this comment may be misguiding
 490   # the result is rounded so we can directly compare it with the user input
 491   my $self = shift;
 492
 493   my $percent_skonto = $self->percent_skonto || 0;
 494
 495   return _round($self->amount - ( $self->amount * $percent_skonto) );
 496
 497 };
 498
 499 sub check_skonto_configuration {
 500   my $self = shift;
 501
 502   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 503
 504   my $skonto_configured = 1; # default is assume skonto works
 505
 506   # my $transactions = $self->transactions;
 507   foreach my $transaction (@{ $self->transactions }) {
 508     # find all transactions with an AR_amount or AP_amount link
 509     my $tax = SL::DB::Manager::Tax->get_first( where => [taxkey => $transaction->taxkey, id => $transaction->tax_id ]);
 510
 511     # acc_trans entries for the taxes (chart_link == A[RP]_tax) often
 512     # have combinations of taxkey & tax_id that don't exist in
 513     # tax. Those must be skipped.
 514     next if !$tax && ($transaction->chart_link !~ m{A[RP]_amount});
 515
 516     croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 517
 518     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->chart_link) };
 519     if ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) {
 520       $skonto_configured = 0 unless $tax->skonto_sales_chart_id;
 521     } elsif ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) {
 522       $skonto_configured = 0 unless $tax->skonto_purchase_chart_id;
 523     };
 524   };
 525
 526   return $skonto_configured;
 527 };
 528
 529 sub open_sepa_transfer_amount {
 530   my $self = shift;
 531
 532   my ($vc, $key, $type);
 533   if ( ref($self) eq 'SL::DB::Invoice' ) {
 534     $vc   = 'customer';
 535     $key  = 'ap_id';
 536     $type = 'ar';
 537   } else {
 538     $vc   = 'vendor';
 539     $key  = 'ap_id';
 540     $type = 'ap';
 541   };
 542
 543   my $sql = qq|SELECT SUM(sei.amount) AS amount FROM sepa_export_items sei | .
 544             qq| LEFT JOIN sepa_export se ON (sei.sepa_export_id = se.id)   | .
 545             qq| WHERE $key = ? AND NOT se.closed AND (se.vc = '$vc')       |;
 546
 547   my ($open_sepa_amount) = $self->db->dbh->selectrow_array($sql, undef, $self->id);
 548
 549   return $open_sepa_amount || 0;
 550
 551 };
 552
 553
 554 sub skonto_charts {
 555   my $self = shift;
 556
 557   # TODO: use param for amount, may also want to calculate skonto_amounts by
 558   # passing percentage in the future
 559
 560   my $amount = shift || $self->skonto_amount;
 561
 562   croak "no amount passed to skonto_charts" unless abs(_round($amount)) >= 0.01;
 563
 564   # TODO: check whether there are negative values in invoice / acc_trans ... credited items
 565
 566   # don't check whether skonto applies, because user may want to override this
 567   # return undef unless $self->percent_skonto;
 568
 569   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 570
 571   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign
 572
 573   my @skonto_charts;  # resulting array with all income/expense accounts that have to be corrected
 574
 575   # calculate effective skonto (percentage) in difference_as_skonto mode
 576   # only works if there are no negative acc_trans values
 577   my $effective_skonto_rate = $amount ? $amount / $self->amount : 0;
 578
 579   # checks:
 580   my $total_skonto_amount  = 0;
 581   my $total_rounding_error = 0;
 582
 583   my $reference_ARAP_amount = 0;
 584
 585   # my $transactions = $self->transactions;
 586   foreach my $transaction (@{ $self->transactions }) {
 587     # find all transactions with an AR_amount or AP_amount link
 588     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->{chart_link}) };
 589     # second condition is that we can determine an automatic Skonto account for each AR_amount entry
 590
 591     if ( ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) or ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) ) {
 592         # $reference_ARAP_amount += $transaction->{amount} * $mult;
 593
 594         # quick hack that works around problem of non-unique tax keys in SKR04
 595         # ? use tax_id in acc_trans
 596         my $tax = SL::DB::Manager::Tax->get_first( where => [id => $transaction->{tax_id}]);
 597         croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 598
 599         if ( $is_sales ) {
 600           die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $transaction->{taxkey} , $tax->taxdescription , $tax->rate*100) unless ref $tax->skonto_sales_chart;
 601         } else {
 602           die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $transaction->{taxkey} , $tax->taxdescription , $tax->rate*100) unless ref $tax->skonto_purchase_chart;
 603         };
 604
 605         my $skonto_amount_unrounded;
 606
 607         my $skonto_percent_abs = $self->amount ? abs($transaction->amount * (1 + $tax->rate) * 100 / $self->amount) : 0;
 608
 609         my $transaction_amount = abs($transaction->{amount} * (1 + $tax->rate));
 610         my $transaction_skonto_percent = abs($transaction_amount/$self->amount); # abs($transaction->{amount} * (1 + $tax->rate));
 611
 612
 613         $skonto_amount_unrounded   = abs($amount * $transaction_skonto_percent);
 614         my $skonto_amount_rounded  = _round($skonto_amount_unrounded);
 615         my $rounding_error         = $skonto_amount_unrounded - $skonto_amount_rounded;
 616         my $rounded_rounding_error = _round($rounding_error);
 617
 618         $total_rounding_error += $rounding_error;
 619         $total_skonto_amount  += $skonto_amount_rounded;
 620
 621         my $rec = {
 622           # skonto_percent_abs: relative part of amount + tax to the total invoice amount
 623           'skonto_percent_abs'     => $skonto_percent_abs,
 624           'chart_id'               => $is_sales ? $tax->skonto_sales_chart->id : $tax->skonto_purchase_chart->id,
 625           'skonto_amount'          => $skonto_amount_rounded,
 626           # 'rounding_error'         => $rounding_error,
 627           # 'rounded_rounding_error' => $rounded_rounding_error,
 628         };
 629
 630         push @skonto_charts, $rec;
 631       };
 632   };
 633
 634   # if the rounded sum of all rounding_errors reaches 0.01 this sum is
 635   # subtracted from the largest skonto_amount
 636   my $rounded_total_rounding_error = abs(_round($total_rounding_error));
 637
 638   if ( $rounded_total_rounding_error > 0 ) {
 639     my $highest_amount_pos = 0;
 640     my $highest_amount = 0;
 641     my $i = -1;
 642     foreach my $ref ( @skonto_charts ) {
 643       $i++;
 644       if ( $ref->{skonto_amount} > $highest_amount ) {
 645         $highest_amount     = $ref->{skonto_amount};
 646         $highest_amount_pos = $i;
 647       };
 648     };
 649     $skonto_charts[$i]->{skonto_amount} -= $rounded_total_rounding_error;
 650   };
 651
 652   return @skonto_charts;
 653 };
 654
 655
 656 sub within_skonto_period {
 657   my $self = shift;
 658   my $dateref = shift || DateTime->now->truncate( to => 'day' );
 659
 660   return undef unless ref $dateref eq 'DateTime';
 661   return 0 unless $self->skonto_date;
 662
 663   # return 1 if requested date (or today) is inside skonto period
 664   # this will also return 1 if date is before the invoice date
 665   return $dateref <= $self->skonto_date;
 666 };
 667
 668 sub valid_skonto_amount {
 669   my $self = shift;
 670   my $amount = shift || 0;
 671   my $max_skonto_percent = 0.10;
 672
 673   return 0 unless $amount > 0;
 674
 675   # does this work for other currencies?
 676   return ($self->amount*$max_skonto_percent) > $amount;
 677 };
 678
 679 sub get_payment_select_options_for_bank_transaction {
 680   my ($self, $bt_id, %params) = @_;
 681
 682
 683   # CAVEAT template code expects with_skonto_pt at position 1 for visual help
 684   # due to skonto_charts, we cannot offer skonto for credit notes and neg ap
 685   my $skontoable = $self->amount > 0 ? 1 : 0;
 686   my @options;
 687   if(!$self->skonto_date) {
 688     push(@options, { payment_type => 'without_skonto', display => t8('without skonto'), selected => 1 });
 689     # wrong call to presenter or not implemented? disabled option is ignored
 690     # push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt'), disabled => 1 });
 691     push(@options, { payment_type => 'free_skonto', display => t8('free skonto') }) if $skontoable;
 692     return @options;
 693   }
 694   # valid skonto date, check if skonto is preferred
 695   my $bt = SL::DB::BankTransaction->new(id => $bt_id)->load;
 696   if ($self->skonto_date && $self->within_skonto_period($bt->transdate)) {
 697     push(@options, { payment_type => 'without_skonto', display => t8('without skonto') });
 698     push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt'), selected => 1 }) if $skontoable;
 699   } else {
 700     push(@options, { payment_type => 'without_skonto', display => t8('without skonto') , selected => 1 });
 701     push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt')}) if $skontoable;
 702   }
 703   push(@options, { payment_type => 'free_skonto', display => t8('free skonto') }) if $skontoable;
 704   return @options;
 705 }
 706
 707 sub exchangerate {
 708   my ($self) = @_;
 709
 710   return 1 if $self->currency_id == $::instance_conf->get_currency_id;
 711
 712   die "transdate isn't a DateTime object:" . ref($self->transdate) unless ref($self->transdate) eq 'DateTime';
 713   my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $self->currency_id,
 714                                                     transdate   => $self->transdate,
 715                                                    );
 716   return undef unless $rate;
 717
 718   return $self->is_sales ? $rate->buy : $rate->sell; # also undef if not defined
 719 };
 720
 721 sub get_payment_suggestions {
 722
 723   my ($self, %params) = @_;
 724
 725   my $open_amount = $self->open_amount;
 726   $open_amount   -= $self->open_sepa_transfer_amount if $params{sepa};
 727
 728   $self->{invoice_amount_suggestion} = $open_amount;
 729   undef $self->{payment_select_options};
 730   push(@{$self->{payment_select_options}} , { payment_type => 'without_skonto',  display => t8('without skonto') });
 731   if ( $self->within_skonto_period ) {
 732     # If there have been no payments yet suggest amount_less_skonto, otherwise the open amount
 733     if ( $open_amount &&                   # invoice amount not 0
 734          $open_amount == $self->amount &&  # no payments yet, or sum of payments and sepa export amounts is zero
 735          $self->check_skonto_configuration) {
 736       $self->{invoice_amount_suggestion} = $self->amount_less_skonto;
 737       push(@{$self->{payment_select_options}} , { payment_type => 'with_skonto_pt',  display => t8('with skonto acc. to pt') , selected => 1 });
 738     } else {
 739       if ( ( $self->valid_skonto_amount($self->open_amount) || $self->valid_skonto_amount($open_amount) ) and not $params{sepa} ) {
 740         $self->{invoice_amount_suggestion} = $open_amount;
 741         # only suggest difference_as_skonto if open_amount exactly matches skonto_amount
 742         # AND we aren't in SEPA mode
 743         my $selected = 0;
 744         $selected = 1 if _round($open_amount) == _round($self->skonto_amount);
 745         push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => $selected });
 746       };
 747     };
 748   } else {
 749     # invoice was configured with skonto, but skonto date has passed, or no skonto available
 750     $self->{invoice_amount_suggestion} = $open_amount;
 751     # difference_as_skonto doesn't make any sense for SEPA transfer, as this doesn't cause any actual payment
 752     if ( $self->valid_skonto_amount($self->open_amount) && not $params{sepa} ) {
 753       push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => 0 });
 754     };
 755   };
 756   return 1;
 757 };
 758
 759 # locales for payment type
 760 #
 761 # $main::locale->text('without_skonto')
 762 # $main::locale->text('with_skonto_pt')
 763 # $main::locale->text('difference_as_skonto')
 764 #
 765
 766 sub validate_payment_type {
 767   my $payment_type = shift;
 768
 769   my %allowed_payment_types = map { $_ => 1 } qw(without_skonto with_skonto_pt difference_as_skonto free_skonto);
 770   croak "illegal payment type: $payment_type, must be one of: " . join(' ', keys %allowed_payment_types) unless $allowed_payment_types{ $payment_type };
 771
 772   return 1;
 773 }
 774
 775 sub forex {
 776   my ($self) = @_;
 777   $self->currency_id == $::instance_conf->get_currency_id ? return 0 : return 1;
 778 };
 779
 780 sub _round {
 781   my $value = shift;
 782   my $num_dec = 2;
 783   return $::form->round_amount($value, 2);
 784 }
 785
 786 1;
 787
 788 __END__
 789
 790 =pod
 791
 792 =head1 NAME
 793
 794 SL::DB::Helper::Payment  Mixin providing helper methods for paying C<Invoice>
 795                          and C<PurchaseInvoice> objects and using skonto
 796
 797 =head1 SYNOPSIS
 798
 799 In addition to actually causing a payment via pay_invoice this helper contains
 800 many methods that help in determining information about the status of the
 801 invoice, such as the remaining open amount, whether skonto applies, until which
 802 date skonto applies, the skonto amount and relative percentages, what to do
 803 with skonto, ...
 804
 805 To prevent duplicate code this was all added in this mixin rather than directly
 806 in SL::DB::Invoice and SL::DB::PurchaseInvoice.
 807
 808 =over 4
 809
 810 =item C<pay_invoice %params>
 811
 812 Create a payment booking for an existing invoice object (type ar/ap/is/ir) via
 813 a configured bank account.
 814
 815 This function deals with all the acc_trans entries and also updates paid and datepaid.
 816 The params C<transdate> and C<chart_id> are mandantory.
 817 If the default payment ('without_skonto') is used the param amount is also
 818 mandantory.
 819 If the payment type ('free_skonto') is used the number params skonto_amount and amount
 820 are as well mandantory and need to be positive. Furthermore the skonto amount has
 821 to be lower than the payment or open invoice amount.
 822
 823 Transdate can either be a date object or a date string.
 824 Chart_id is the id of the payment booking chart.
 825 Amount is either a positive or negative number, but never 0.
 826
 827 CAVEAT! The helper tries to get the sign right and all calls from BankTransaction are
 828 positive (abs($value)) values.
 829
 830
 831 Example:
 832
 833   my $ap   = SL::DB::Manager::PurchaseInvoice->find_by( invnumber => '1');
 834   my $bank = SL::DB::Manager::BankAccount->find_by( name => 'Bank');
 835   $ap->pay_invoice(chart_id      => $bank->chart_id,
 836                    amount        => $ap->open_amount,
 837                    transdate     => DateTime->now->to_kivitendo,
 838                    memo          => 'foobar',
 839                    source        => 'barfoo',
 840                    payment_type  => 'without_skonto',  # default if not specified
 841                    project_id    => 25,
 842                   );
 843
 844 or with skonto:
 845   $ap->pay_invoice(chart_id      => $bank->chart_id,
 846                    amount        => $ap->amount,       # doesn't need to be specified
 847                    transdate     => DateTime->now->to_kivitendo,
 848                    memo          => 'foobar',
 849                    source        => 'barfoo',
 850                    payment_type  => 'with_skonto',
 851                   );
 852
 853 or in a certain currency:
 854   $ap->pay_invoice(chart_id      => $bank->chart_id,
 855                    amount        => 500,
 856                    currency      => 'USD',
 857                    transdate     => DateTime->now->to_kivitendo,
 858                    memo          => 'foobar',
 859                    source        => 'barfoo',
 860                    payment_type  => 'with_skonto_pt',
 861                   );
 862
 863 Allowed payment types are:
 864   without_skonto with_skonto_pt difference_as_skonto
 865
 866 The option C<payment_type> allows for a basic skonto mechanism.
 867
 868 C<without_skonto> is the default mode, "amount" is paid to the account in
 869 chart_id. This can also be used for partial payments and corrections via
 870 negative amounts.
 871
 872 C<with_skonto_pt> can't be used for partial payments. When used on unpaid
 873 invoices the whole amount is paid, with the skonto part automatically being
 874 booked according to the skonto chart configured in the tax settings for each
 875 tax key. If an amount is passed it is ignored and the actual configured skonto
 876 amount is used.
 877
 878 C<difference_as_skonto> can only be used after partial payments have been made,
 879 the whole specified amount is booked according to the skonto charts configured
 880 in the tax settings for each tax key.
 881
 882 So passing amount doesn't have any effect for the cases C<with_skonto_pt> and
 883 C<difference_as_skonto>, as all necessary values are taken from the stored
 884 invoice.
 885
 886 The skonto modes automatically calculate the relative amounts for a mix of
 887 taxes, e.g. items with 7% and 19% in one invoice. There is a helper method
 888 skonto_charts, which calculates the relative percentages according to the
 889 amounts in acc_trans (which are grouped by tax).
 890
 891 There is currently no way of excluding certain items in an invoice from having
 892 skonto applied to them.  If this feature was added to parts the calculation
 893 method of relative skonto would have to be completely rewritten using the
 894 invoice items rather than acc_trans.
 895
 896 The skonto modes also still don't automatically correct the tax, this still has
 897 to be done manually. Therefore all payments generated by pay_invoice have
 898 taxkey 0.
 899
 900 There is currently no way to directly pay an invoice via this method if the
 901 effective skonto differs from the skonto according to the payment terms
 902 configured for the invoice/vendor.
 903
 904 In this case one has to pay in two steps: first the actual paid amount via
 905 "without skonto", and then the remainder via "difference_as_skonto". The user
 906 has to there actively decide whether to accept the differing skonto.
 907
 908 Because of the way skonto_charts works the calculation doesn't work if there
 909 are negative values in acc_trans. E.g. one invoice with a positive value for
 910 19% tax and a negative value for the acc_trans line with 7%
 911
 912 Skonto doesn't/shouldn't apply if the invoice contains credited items.
 913
 914 If no amount is given the whole open amout is paid.
 915
 916 If neither currency or currency_id are given as params, the currency of the
 917 invoice is assumed to be the payment currency.
 918
 919 If successful the return value will be 1 in scalar context or in list context
 920 the two ids (acc_trans_id) of the newly created bookings.
 921
 922 =item C<reference_account>
 923
 924 Returns a chart object which is the chart of the invoice with link AR or AP.
 925
 926 Example (1200 is the AR account for SKR04):
 927   my $invoice = invoice(invnumber => '144');
 928   $invoice->reference_account->accno
 929   # 1200
 930
 931 =item C<percent_skonto>
 932
 933 Returns the configured skonto percentage of the payment terms of an invoice,
 934 e.g. 0.02 for 2%. Payment terms come from invoice settingssettings for ap.
 935
 936 =item C<amount_less_skonto>
 937
 938 If the invoice has a payment term,
 939 calculate the amount to be paid in the case of skonto.  This doesn't check,
 940 whether skonto applies (i.e. skonto doesn't wasn't exceeded), it just subtracts
 941 the configured percentage (e.g. 2%) from the total amount.
 942
 943 The returned value is rounded to two decimals.
 944
 945 =item C<skonto_date>
 946
 947 The date up to which skonto may be taken. This is calculated from the invoice
 948 date + the number of days configured in the payment terms.
 949
 950 This method can also be used to determine whether skonto applies for the
 951 invoice, as it returns undef if there is no payment term or skonto days is set
 952 to 0.
 953
 954 =item C<within_skonto_period [DATE]>
 955
 956 Returns 0 or 1.
 957
 958 Checks whether the invoice has payment terms configured, and whether the date
 959 is within the skonto max date. If no date is passed the current date is used.
 960
 961 You can also pass a dateref object as a parameter to check whether skonto
 962 applies for that date rather than the current date.
 963
 964 =item C<valid_skonto_amount>
 965
 966 Takes an amount as an argument and checks whether the amount is less than 10%
 967 of the total amount of the invoice. The value of 10% is currently hardcoded in
 968 the method. This method is currently used to check whether to offer the payment
 969 option "difference as skonto".
 970
 971 Example:
 972  if ( $invoice->valid_skonto_amount($invoice->open_amount) ) {
 973    # ... do something
 974  }
 975
 976 =item C<skonto_charts [$amount]>
 977
 978 Returns a list of chart_ids and some calculated numbers that can be used for
 979 paying the invoice with skonto. This function will automatically calculate the
 980 relative skonto amounts even if the invoice contains several types of taxes
 981 (e.g. 7% and 19%).
 982
 983 Example usage:
 984   my $invoice = SL::DB::Manager::Invoice->find_by(invnumber => '211');
 985   my @skonto_charts = $invoice->skonto_charts;
 986
 987 or with the total skonto amount as an argument:
 988   my @skonto_charts = $invoice->skonto_charts($invoice->open_amount);
 989
 990 The following values are generated for each chart:
 991
 992 =over 2
 993
 994 =item C<chart_id>
 995
 996 The chart id of the skonto amount to be booked.
 997
 998 =item C<skonto_amount>
 999
1000 The total amount to be paid to the account
1001
1002 =item C<skonto_percent>
1003
1004 The relative percentage of that skonto chart. This can be useful if the actual
1005 ekonto that is paid deviates from the granted skonto, e.g. customer effectively
1006 pays 2.6% skonto instead of 2%, and we accept this. Then we can still calculate
1007 the relative skonto amounts for different taxes based on the absolute
1008 percentages. Used for case C<difference_as_skonto>.
1009
1010 =item C<skonto_percent_abs>
1011
1012 The absolute percentage of that skonto chart in relation to the total amount.
1013 Used to calculate skonto_amount for case C<with_skonto_pt>.
1014
1015 =back
1016
1017 If the invoice contains several types of taxes then skonto_charts can be used
1018 to calculate the relative amounts.
1019
1020 Example in console of an invoice with 100 Euro at 7% and 100 Euro at 19% with
1021 tax not included:
1022
1023   my $invoice = invoice(invnumber => '144');
1024   $invoice->amount
1025   226.00000
1026   $invoice->payment_terms->percent_skonto
1027   0.02
1028   $invoice->skonto_charts
1029   pp $invoice->skonto_charts
1030   #             $VAR1 = {
1031   #               'chart_id'       => 128,
1032   #               'skonto_amount'  => '2.14',
1033   #               'skonto_percent' => '47.3451327433627'
1034   #             };
1035   #             $VAR2 = {
1036   #               'chart_id'       => 130,
1037   #               'skonto_amount'  => '2.38',
1038   #               'skonto_percent' => '52.654867256637'
1039   #             };
1040
1041 C<skonto_charts> always returns positive values (abs) for C<skonto_amount> and
1042 C<skonto_percent>.
1043
1044 C<skonto_charts> generates one entry for each acc_trans entry. ar and ap
1045 bookings only have one acc_trans entry for each taxkey (e.g. 7% and 19%).  This
1046 is because all the items are grouped according to the Buchungsgruppen mechanism
1047 and the totals are written to acc_trans.  For is and ir it is possible to have
1048 several acc_trans entries with the same tax. In this case skonto_charts
1049 generates a skonto booking for each acc_trans income/expense entry.
1050
1051 In the future this function may also be used to calculate the corrections for
1052 the income tax.
1053
1054 =item C<open_amount>
1055
1056 Unrounded total open amount of invoice (amount - paid).
1057 Doesn't take into account pending SEPA transfers.
1058
1059 =item C<open_percent>
1060
1061 Percentage of the invoice that is still unpaid, e.g. 100,00 if no payments have
1062 been made yet, 0,00 if fully paid.
1063
1064 =item C<remaining_skonto_days>
1065
1066 How many days skonto can still be taken, calculated from current day. Returns 0
1067 if current day is the max skonto date, and negative number if skonto date has
1068 already passed.
1069
1070 Returns undef if skonto is not configured for that invoice.
1071
1072 =item C<get_payment_suggestions %params>
1073
1074 Creates data intended for an L.select_tag dropdown that can be used in a
1075 template. Depending on the rules it will choose from the options
1076 without_skonto, with_skonto_pt and difference_as_skonto, and select the most
1077 likely one.
1078
1079 If the parameter "sepa" is passed, the SEPA export payments that haven't been
1080 executed yet are considered when determining the open amount of the invoice.
1081
1082 The current rules are:
1083
1084 =over 2
1085
1086 =item * without_skonto is always an option
1087
1088 =item * with_skonto_pt is only offered if there haven't been any payments yet and the current date is within the skonto period.
1089
1090 =item * difference_as_skonto is only offered if there have already been payments made and the open amount is smaller than 10% of the total amount.
1091
1092 with_skonto_pt will only be offered, if all the AR_amount/AP_amount have a
1093 taxkey with a configured skonto chart
1094
1095 =back
1096
1097 It will also fill $self->{invoice_amount_suggestion} with either the open
1098 amount, or if with_skonto_pt is selected, with amount_less_skonto, so the
1099 template can fill the input with the likely amount.
1100
1101 Example in console:
1102   my $ar = invoice( invnumber => '257');
1103   $ar->get_payment_suggestions;
1104   print $ar->{invoice_amount_suggestion} . "\n";
1105   # 97.23
1106   pp $ar->{payment_select_options}
1107   # $VAR1 = [
1108   #         {
1109   #           'display' => 'ohne Skonto',
1110   #           'payment_type' => 'without_skonto'
1111   #         },
1112   #         {
1113   #           'display' => 'mit Skonto nach ZB',
1114   #           'payment_type' => 'with_skonto_pt',
1115   #           'selected' => 1
1116   #         }
1117   #       ];
1118
1119 The resulting array $ar->{payment_select_options} can be used in a template
1120 select_tag using value_key and title_key:
1121
1122 [% L.select_tag('payment_type_' _ loop.count, invoice.payment_select_options, value_key => 'payment_type', title_key => 'display', id => 'payment_type_' _ loop.count) %]
1123
1124 It would probably make sense to have different rules for the pre-selected items
1125 for sales and purchase, and to also make these rules configurable in the
1126 defaults. E.g. when creating a SEPA bank transfer for vendor invoices a company
1127 might always want to pay quickly making use of skonto, while another company
1128 might always want to pay as late as possible.
1129
1130 =item C<get_payment_select_options_for_bank_transaction $banktransaction_id %params>
1131
1132 Make suggestion for a skonto payment type by returning an HTML blob of the options
1133 of a HTML drop-down select with the most likely option preselected.
1134
1135 This is a helper function for BankTransaction/ajax_payment_suggestion and
1136 template/webpages/bank_transactions/invoices.html
1137
1138 We are working with an existing payment, so difference_as_skonto never makes sense.
1139
1140 If skonto is not possible (skonto_date does not exists) simply return
1141 the single 'no skonto' option as a visual hint.
1142
1143 If skonto is possible (skonto_date exists), add two possibilities:
1144 without_skonto and with_skonto_pt if payment date is within skonto_date,
1145 preselect with_skonto_pt, otherwise preselect without skonto.
1146
1147 =item C<exchangerate>
1148
1149 Returns 1 immediately if the record uses the default currency.
1150
1151 Returns the exchangerate in database format for the invoice according to that
1152 invoice's transdate, returning 'buy' for sales, 'sell' for purchases.
1153
1154 If no exchangerate can be found for that day undef is returned.
1155
1156 =item C<forex>
1157
1158 Returns 1 if record uses a different currency, 0 if the default currency is used.
1159
1160 =back
1161
1162 =head1 TODO AND CAVEATS
1163
1164 =over 4
1165
1166 =item *
1167
1168 when looking at open amount, maybe consider that there may already be queued
1169 amounts in SEPA Export
1170
1171 =item * C<skonto_charts>
1172
1173 Cannot handle negative skonto amounts, will always calculate the skonto amount
1174 for credit notes or negative ap transactions with a positive sign.
1175
1176
1177 =back
1178
1179 =head1 AUTHOR
1180
1181 G. Richardson E<lt>grichardson@kivitendo-premium.de<gt>
1182
1183 =cut