SL/DB/Helper/Payment.pm

   1 package SL::DB::Helper::Payment;
   2
   3 use strict;
   4
   5 use parent qw(Exporter);
   6 our @EXPORT = qw(pay_invoice);
   7 our @EXPORT_OK = qw(skonto_date skonto_charts amount_less_skonto within_skonto_period percent_skonto reference_account reference_amount open_amount open_percent remaining_skonto_days skonto_amount check_skonto_configuration valid_skonto_amount get_payment_suggestions validate_payment_type open_sepa_transfer_amount get_payment_select_options_for_bank_transaction create_bank_transaction exchangerate);
   8 our %EXPORT_TAGS = (
   9   "ALL" => [@EXPORT, @EXPORT_OK],
  10 );
  11
  12 require SL::DB::Chart;
  13 use Data::Dumper;
  14 use DateTime;
  15 use SL::DATEV qw(:CONSTANTS);
  16 use SL::Locale::String qw(t8);
  17 use List::Util qw(sum);
  18 use SL::DB::Exchangerate;
  19 use SL::DB::Currency;
  20 use Carp;
  21
  22 #
  23 # Public functions not exported by default
  24 #
  25
  26 sub pay_invoice {
  27   my ($self, %params) = @_;
  28
  29   require SL::DB::Tax;
  30
  31   my $is_sales = ref($self) eq 'SL::DB::Invoice';
  32   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign depending on ar/ap
  33
  34   my $paid_amount = 0; # the amount that will be later added to $self->paid, should be in default currency
  35
  36   # default values if not set
  37   $params{payment_type} = 'without_skonto' unless $params{payment_type};
  38   validate_payment_type($params{payment_type});
  39
  40   # check for required parameters
  41   Common::check_params(\%params, qw(chart_id transdate));
  42
  43   my $transdate_obj;
  44   if (ref($params{transdate} eq 'DateTime')) {
  45     $transdate_obj = $params{transdate};
  46   } else {
  47    $transdate_obj = $::locale->parse_date_to_object($params{transdate});
  48   };
  49   croak t8('Illegal date') unless ref $transdate_obj;
  50
  51   # check for closed period
  52   my $closedto = $::locale->parse_date_to_object($::instance_conf->get_closedto);
  53   if ( ref $closedto && $transdate_obj < $closedto ) {
  54     croak t8('Cannot post payment for a closed period!');
  55   };
  56
  57   # check for maximum number of future days
  58   if ( $::instance_conf->get_max_future_booking_interval > 0 ) {
  59     croak t8('Cannot post transaction above the maximum future booking date!') if $transdate_obj > DateTime->now->add( days => $::instance_conf->get_max_future_booking_interval );
  60   };
  61
  62   # currency is either passed or use the invoice currency if it differs from the default currency
  63   my ($exchangerate,$currency);
  64   if ($params{currency} || $params{currency_id} || $self->currency_id != $::instance_conf->get_currency_id) {
  65     if ($params{currency} || $params{currency_id} ) { # currency was specified
  66       $currency = SL::DB::Manager::Currency->find_by(name => $params{currency}) || SL::DB::Manager::Currency->find_by(id => $params{currency_id});
  67     } else { # use invoice currency
  68       $currency = SL::DB::Manager::Currency->find_by(id => $self->currency_id);
  69     };
  70     die "no currency" unless $currency;
  71     if ($currency->id == $::instance_conf->get_currency_id) {
  72       $exchangerate = 1;
  73     } else {
  74       my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $currency->id,
  75                                                         transdate   => $transdate_obj,
  76                                                        );
  77       if ($rate) {
  78         $exchangerate = $is_sales ? $rate->buy : $rate->sell;
  79       } else {
  80         die "No exchange rate for " . $transdate_obj->to_kivitendo;
  81       };
  82     };
  83   } else { # no currency param given or currency is the same as default_currency
  84     $exchangerate = 1;
  85   };
  86
  87   # input checks:
  88   if ( $params{'payment_type'} eq 'without_skonto' ) {
  89     croak "invalid amount for payment_type 'without_skonto': $params{'amount'}\n" unless abs($params{'amount'}) > 0;
  90   };
  91
  92   # options with_skonto_pt and difference_as_skonto don't require the parameter
  93   # amount, but if amount is passed, make sure it matches the expected value
  94   if ( $params{'payment_type'} eq 'difference_as_skonto' ) {
  95     croak "amount $params{amount} doesn't match open amount " . $self->open_amount . ", diff = " . ($params{amount}-$self->open_amount) if $params{amount} && abs($self->open_amount - $params{amount} ) > 0.0000001;
  96   } elsif ( $params{'payment_type'} eq 'with_skonto_pt' ) {
  97     croak "amount $params{amount} doesn't match amount less skonto: " . $self->open_amount . "\n" if $params{amount} && abs($self->amount_less_skonto - $params{amount} ) > 0.0000001;
  98     croak "payment type with_skonto_pt can't be used if payments have already been made" if $self->paid != 0;
  99   };
 100
 101   # absolute skonto amount for invoice, use as reference sum to see if the
 102   # calculated skontos add up
 103   # only needed for payment_term "with_skonto_pt"
 104
 105   my $skonto_amount_check = $self->skonto_amount; # variable should be zero after calculating all skonto
 106   my $total_open_amount   = $self->open_amount;
 107
 108   # account where money is paid to/from: bank account or cash
 109   my $account_bank = SL::DB::Manager::Chart->find_by(id => $params{chart_id});
 110   croak "can't find bank account" unless ref $account_bank;
 111
 112   my $reference_account = $self->reference_account;
 113   croak "can't find reference account (link = AR/AP) for invoice" unless ref $reference_account;
 114
 115   my $memo   = $params{'memo'}   || '';
 116   my $source = $params{'source'} || '';
 117
 118   my $rounded_params_amount = _round( $params{amount} ); # / $exchangerate);
 119   my $fx_gain_loss_amount = 0; # for fx_gain and fx_loss
 120
 121   my $db = $self->db;
 122   $db->do_transaction(sub {
 123     my $new_acc_trans;
 124
 125     # all three payment type create 1 AR/AP booking (the paid part)
 126     # difference_as_skonto creates n skonto bookings (1 for each tax type)
 127     # with_skonto_pt creates 1 bank booking and n skonto bookings (1 for each tax type)
 128     # without_skonto creates 1 bank booking
 129
 130     # as long as there is no automatic tax, payments are always booked with
 131     # taxkey 0
 132
 133     unless ( $params{payment_type} eq 'difference_as_skonto' ) {
 134       # cases with_skonto_pt and without_skonto
 135
 136       # for case with_skonto_pt we need to know the corrected amount at this
 137       # stage if we are going to use $params{amount}
 138
 139       my $pay_amount = $rounded_params_amount;
 140       $pay_amount = $self->amount_less_skonto if $params{payment_type} eq 'with_skonto_pt';
 141
 142       # bank account and AR/AP
 143       $paid_amount += $pay_amount * $exchangerate;
 144
 145       my $amount = (-1 * $pay_amount) * $mult;
 146
 147
 148       # total amount against bank, do we already know this by now?
 149       $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 150                                                    chart_id   => $account_bank->id,
 151                                                    chart_link => $account_bank->link,
 152                                                    amount     => $amount,
 153                                                    transdate  => $transdate_obj,
 154                                                    source     => $source,
 155                                                    memo       => $memo,
 156                                                    project_id => $params{project_id} ? $params{project_id} : undef,
 157                                                    taxkey     => 0,
 158                                                    tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 159       $new_acc_trans->save;
 160
 161       # deal with fxtransaction
 162       if ( $self->currency_id != $::instance_conf->get_currency_id ) {
 163         my $fxamount = _round($amount - ($amount * $exchangerate));
 164         $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 165                                                      chart_id       => $account_bank->id,
 166                                                      chart_link     => $account_bank->link,
 167                                                      amount         => $fxamount * -1,
 168                                                      transdate      => $transdate_obj,
 169                                                      source         => $source,
 170                                                      memo           => $memo,
 171                                                      taxkey         => 0,
 172                                                      fx_transaction => 1,
 173                                                      tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 174         $new_acc_trans->save;
 175         # if invoice exchangerate differs from exchangerate of payment
 176         # deal with fxloss and fxamount
 177         if ($self->exchangerate and $self->exchangerate != 1 and $self->exchangerate != $exchangerate) {
 178           my $fxgain_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxgain_accno_id) || die "Can't determine fxgain chart";
 179           my $fxloss_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxloss_accno_id) || die "Can't determine fxloss chart";
 180           my $gain_loss_amount = _round($amount * ($exchangerate - $self->exchangerate ) * -1,2);
 181           my $gain_loss_chart = $gain_loss_amount > 0 ? $fxgain_chart : $fxloss_chart;
 182           $fx_gain_loss_amount = $gain_loss_amount;
 183
 184           $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 185                                                        chart_id       => $gain_loss_chart->id,
 186                                                        chart_link     => $gain_loss_chart->link,
 187                                                        amount         => $gain_loss_amount,
 188                                                        transdate      => $transdate_obj,
 189                                                        source         => $source,
 190                                                        memo           => $memo,
 191                                                        taxkey         => 0,
 192                                                        fx_transaction => 0,
 193                                                        tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 194           $new_acc_trans->save;
 195
 196         };
 197       };
 198     };
 199
 200     if ( $params{payment_type} eq 'difference_as_skonto' or $params{payment_type} eq 'with_skonto_pt' ) {
 201
 202       my $total_skonto_amount;
 203       if ( $params{payment_type} eq 'with_skonto_pt' ) {
 204         $total_skonto_amount = $self->skonto_amount;
 205       } elsif ( $params{payment_type} eq 'difference_as_skonto' ) {
 206         $total_skonto_amount = $self->open_amount;
 207       };
 208
 209       my @skonto_bookings = $self->skonto_charts($total_skonto_amount);
 210
 211       # error checking:
 212       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 213         my $calculated_skonto_sum  = sum map { $_->{skonto_amount} } @skonto_bookings;
 214         croak "calculated skonto for difference_as_skonto = $calculated_skonto_sum doesn't add up open amount: " . $self->open_amount unless _round($calculated_skonto_sum) == _round($self->open_amount);
 215       };
 216
 217       my $reference_amount = $total_skonto_amount;
 218
 219       # create an acc_trans entry for each result of $self->skonto_charts
 220       foreach my $skonto_booking ( @skonto_bookings ) {
 221         next unless $skonto_booking->{'chart_id'};
 222         next unless $skonto_booking->{'skonto_amount'} != 0;
 223         my $amount = -1 * $skonto_booking->{skonto_amount};
 224         $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 225                                                      chart_id   => $skonto_booking->{'chart_id'},
 226                                                      chart_link => SL::DB::Manager::Chart->find_by(id => $skonto_booking->{'chart_id'})->link,
 227                                                      amount     => $amount * $mult,
 228                                                      transdate  => $transdate_obj,
 229                                                      source     => $params{source},
 230                                                      taxkey     => 0,
 231                                                      tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 232
 233         # the acc_trans entries are saved individually, not added to $self and then saved all at once
 234         $new_acc_trans->save;
 235
 236         $reference_amount -= abs($amount);
 237         $paid_amount      += -1 * $amount * $exchangerate;
 238         $skonto_amount_check -= $skonto_booking->{'skonto_amount'};
 239       };
 240       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 241           die "difference_as_skonto calculated incorrectly, sum of calculated payments doesn't add up to open amount $total_open_amount, reference_amount = $reference_amount\n" unless _round($reference_amount) == 0;
 242       }
 243
 244     };
 245
 246     my $arap_amount = 0;
 247
 248     if ( $params{payment_type} eq 'difference_as_skonto' ) {
 249       $arap_amount = $total_open_amount;
 250     } elsif ( $params{payment_type} eq 'without_skonto' ) {
 251       $arap_amount = $rounded_params_amount;
 252     } elsif ( $params{payment_type} eq 'with_skonto_pt' ) {
 253       # this should be amount + sum(amount+skonto), but while we only allow
 254       # with_skonto_pt for completely unpaid invoices we just use the value
 255       # from the invoice
 256       $arap_amount = $total_open_amount;
 257     };
 258
 259     # regardless of payment_type there is always only exactly one arap booking
 260     # TODO: compare $arap_amount to running total
 261     my $arap_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 262                                                   chart_id   => $reference_account->id,
 263                                                   chart_link => $reference_account->link,
 264                                                   amount     => _round($arap_amount * $mult * $exchangerate - $fx_gain_loss_amount),
 265                                                   transdate  => $transdate_obj,
 266                                                   source     => '', #$params{source},
 267                                                   taxkey     => 0,
 268                                                   tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 269     $arap_booking->save;
 270
 271     $fx_gain_loss_amount *= -1 if $self->is_sales;
 272     $self->paid($self->paid + _round($paid_amount) + $fx_gain_loss_amount) if $paid_amount;
 273     $self->datepaid($transdate_obj);
 274     $self->save;
 275
 276     # make sure transactions will be reloaded the next time $self->transactions
 277     # is called, as pay_invoice saves the acc_trans objects individually rather
 278     # than adding them to the transaction relation array.
 279     $self->forget_related('transactions');
 280
 281   my $datev_check = 0;
 282   if ( $is_sales )  {
 283     if ( (  $self->invoice && $::instance_conf->get_datev_check_on_sales_invoice  ) ||
 284          ( !$self->invoice && $::instance_conf->get_datev_check_on_ar_transaction )) {
 285       $datev_check = 1;
 286     };
 287   } else {
 288     if ( (  $self->invoice && $::instance_conf->get_datev_check_on_purchase_invoice ) ||
 289          ( !$self->invoice && $::instance_conf->get_datev_check_on_ap_transaction   )) {
 290       $datev_check = 1;
 291     };
 292   };
 293
 294   if ( $datev_check ) {
 295
 296     my $datev = SL::DATEV->new(
 297       exporttype => DATEV_ET_BUCHUNGEN,
 298       format     => DATEV_FORMAT_KNE,
 299       dbh        => $db->dbh,
 300       trans_id   => $self->{id},
 301     );
 302
 303     $datev->clean_temporary_directories;
 304     $datev->export;
 305
 306     if ($datev->errors) {
 307       # this exception should be caught by do_transaction, which handles the rollback
 308       die join "\n", $::locale->text('DATEV check returned errors:'), $datev->errors;
 309     }
 310   };
 311
 312   }) || die t8('error while paying invoice #1 : ', $self->invnumber) . $db->error . "\n";
 313
 314   return 1;
 315 };
 316
 317 sub skonto_date {
 318
 319   my $self = shift;
 320
 321   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 322
 323   my $skonto_date;
 324
 325   if ( $is_sales ) {
 326     return undef unless ref $self->payment_terms;
 327     return undef unless $self->payment_terms->terms_skonto > 0;
 328     $skonto_date = DateTime->from_object(object => $self->transdate)->add(days => $self->payment_terms->terms_skonto);
 329   } else {
 330     return undef unless ref $self->vendor->payment_terms;
 331     return undef unless $self->vendor->payment_terms->terms_skonto > 0;
 332     $skonto_date = DateTime->from_object(object => $self->transdate)->add(days => $self->vendor->payment_terms->terms_skonto);
 333   };
 334
 335   return $skonto_date;
 336 };
 337
 338 sub reference_account {
 339   my $self = shift;
 340
 341   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 342
 343   require SL::DB::Manager::AccTransaction;
 344
 345   my $link_filter = $is_sales ? 'AR' : 'AP';
 346
 347   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 348      trans_id   => $self->id,
 349      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 350   );
 351
 352   return undef unless ref $acc_trans;
 353
 354   my $reference_account = SL::DB::Manager::Chart->find_by(id => $acc_trans->chart_id);
 355
 356   return $reference_account;
 357 };
 358
 359 sub reference_amount {
 360   my $self = shift;
 361
 362   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 363
 364   require SL::DB::Manager::AccTransaction;
 365
 366   my $link_filter = $is_sales ? 'AR' : 'AP';
 367
 368   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 369      trans_id   => $self->id,
 370      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 371   );
 372
 373   return undef unless ref $acc_trans;
 374
 375   # this should be the same as $self->amount
 376   return $acc_trans->amount;
 377 };
 378
 379
 380 sub open_amount {
 381   my $self = shift;
 382
 383   # in the future maybe calculate this from acc_trans
 384
 385   # if the difference is 0.01 Cent this may end up as 0.009999999999998
 386   # numerically, so round this value when checking for cent threshold >= 0.01
 387
 388   return $self->amount - $self->paid;
 389 };
 390
 391 sub open_percent {
 392   my $self = shift;
 393
 394   return 0 if $self->amount == 0;
 395   my $open_percent;
 396   if ( $self->open_amount < 0 ) {
 397     # overpaid, currently treated identically
 398     $open_percent = $self->open_amount * 100 / $self->amount;
 399   } else {
 400     $open_percent = $self->open_amount * 100 / $self->amount;
 401   };
 402
 403   return _round($open_percent) || 0;
 404 };
 405
 406 sub skonto_amount {
 407   my $self = shift;
 408
 409   return $self->amount - $self->amount_less_skonto;
 410 };
 411
 412 sub remaining_skonto_days {
 413   my $self = shift;
 414
 415   return undef unless ref $self->skonto_date;
 416
 417   my $dur = DateTime::Duration->new($self->skonto_date - DateTime->today);
 418   return $dur->delta_days();
 419
 420 };
 421
 422 sub percent_skonto {
 423   my $self = shift;
 424
 425   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 426
 427   my $percent_skonto = 0;
 428
 429   if ( $is_sales ) {
 430     return undef unless ref $self->payment_terms;
 431     return undef unless $self->payment_terms->percent_skonto > 0;
 432     $percent_skonto = $self->payment_terms->percent_skonto;
 433   } else {
 434     return undef unless ref $self->vendor->payment_terms;
 435     return undef unless $self->vendor->payment_terms->terms_skonto > 0;
 436     $percent_skonto = $self->vendor->payment_terms->percent_skonto;
 437   };
 438
 439   return $percent_skonto;
 440 };
 441
 442 sub amount_less_skonto {
 443   # amount that has to be paid if skonto applies, always return positive rounded values
 444   # the result is rounded so we can directly compare it with the user input
 445   my $self = shift;
 446
 447   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 448
 449   my $percent_skonto = $self->percent_skonto || 0;
 450
 451   return _round($self->amount - ( $self->amount * $percent_skonto) );
 452
 453 };
 454
 455 sub check_skonto_configuration {
 456   my $self = shift;
 457
 458   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 459
 460   my $skonto_configured = 1; # default is assume skonto works
 461
 462   # my $transactions = $self->transactions;
 463   foreach my $transaction (@{ $self->transactions }) {
 464     # find all transactions with an AR_amount or AP_amount link
 465     my $tax = SL::DB::Manager::Tax->get_first( where => [taxkey => $transaction->taxkey]);
 466     croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 467
 468     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->chart_link) };
 469     if ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) {
 470       $skonto_configured = 0 unless $tax->skonto_sales_chart_id;
 471     } elsif ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) {
 472       $skonto_configured = 0 unless $tax->skonto_purchase_chart_id;
 473     };
 474   };
 475
 476   return $skonto_configured;
 477 };
 478
 479 sub open_sepa_transfer_amount {
 480   my $self = shift;
 481
 482   my ($vc, $key, $type);
 483   if ( ref($self) eq 'SL::DB::Invoice' ) {
 484     $vc   = 'customer';
 485     $key  = 'ap_id';
 486     $type = 'ar';
 487   } else {
 488     $vc   = 'vendor';
 489     $key  = 'ap_id';
 490     $type = 'ap';
 491   };
 492
 493   my $sql = qq|SELECT SUM(sei.amount) AS amount FROM sepa_export_items sei | .
 494             qq| LEFT JOIN sepa_export se ON (sei.sepa_export_id = se.id)   | .
 495             qq| WHERE $key = ? AND NOT se.closed AND (se.vc = '$vc')       |;
 496
 497   my ($open_sepa_amount) = $self->db->dbh->selectrow_array($sql, undef, $self->id);
 498
 499   return $open_sepa_amount || 0;
 500
 501 };
 502
 503
 504 sub skonto_charts {
 505   my $self = shift;
 506
 507   # TODO: use param for amount, may also want to calculate skonto_amounts by
 508   # passing percentage in the future
 509
 510   my $amount = shift || $self->skonto_amount;
 511
 512   croak "no amount passed to skonto_charts" unless abs(_round($amount)) >= 0.01;
 513
 514   # TODO: check whether there are negative values in invoice / acc_trans ... credited items
 515
 516   # don't check whether skonto applies, because user may want to override this
 517   # return undef unless $self->percent_skonto;  # for is_sales
 518   # return undef unless $self->vendor->payment_terms->percent_skonto;  # for purchase
 519
 520   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 521
 522   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign
 523
 524   my @skonto_charts;  # resulting array with all income/expense accounts that have to be corrected
 525
 526   # calculate effective skonto (percentage) in difference_as_skonto mode
 527   # only works if there are no negative acc_trans values
 528   my $effective_skonto_rate = $amount ? $amount / $self->amount : 0;
 529
 530   # checks:
 531   my $total_skonto_amount  = 0;
 532   my $total_rounding_error = 0;
 533
 534   my $reference_ARAP_amount = 0;
 535
 536   # my $transactions = $self->transactions;
 537   foreach my $transaction (@{ $self->transactions }) {
 538     # find all transactions with an AR_amount or AP_amount link
 539     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->{chart_link}) };
 540     # second condition is that we can determine an automatic Skonto account for each AR_amount entry
 541
 542     if ( ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) or ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) ) {
 543         # $reference_ARAP_amount += $transaction->{amount} * $mult;
 544
 545         # quick hack that works around problem of non-unique tax keys in SKR04
 546         my $tax = SL::DB::Manager::Tax->get_first( where => [taxkey => $transaction->{taxkey}]);
 547         croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 548
 549         if ( $is_sales ) {
 550           die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $transaction->{taxkey} , $tax->taxdescription , $tax->rate*100) unless ref $tax->skonto_sales_chart;
 551         } else {
 552           die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $transaction->{taxkey} , $tax->taxdescription , $tax->rate*100) unless ref $tax->skonto_purchase_chart;
 553         };
 554
 555         my $skonto_amount_unrounded;
 556
 557         my $skonto_percent_abs = $self->amount ? abs($transaction->amount * (1 + $tax->rate) * 100 / $self->amount) : 0;
 558
 559         my $transaction_amount = abs($transaction->{amount} * (1 + $tax->rate));
 560         my $transaction_skonto_percent = abs($transaction_amount/$self->amount); # abs($transaction->{amount} * (1 + $tax->rate));
 561
 562
 563         $skonto_amount_unrounded   = abs($amount * $transaction_skonto_percent);
 564         my $skonto_amount_rounded  = _round($skonto_amount_unrounded);
 565         my $rounding_error         = $skonto_amount_unrounded - $skonto_amount_rounded;
 566         my $rounded_rounding_error = _round($rounding_error);
 567
 568         $total_rounding_error += $rounding_error;
 569         $total_skonto_amount  += $skonto_amount_rounded;
 570
 571         my $rec = {
 572           # skonto_percent_abs: relative part of amount + tax to the total invoice amount
 573           'skonto_percent_abs'     => $skonto_percent_abs,
 574           'chart_id'               => $is_sales ? $tax->skonto_sales_chart->id : $tax->skonto_purchase_chart->id,
 575           'skonto_amount'          => $skonto_amount_rounded,
 576           # 'rounding_error'         => $rounding_error,
 577           # 'rounded_rounding_error' => $rounded_rounding_error,
 578         };
 579
 580         push @skonto_charts, $rec;
 581       };
 582   };
 583
 584   # if the rounded sum of all rounding_errors reaches 0.01 this sum is
 585   # subtracted from the largest skonto_amount
 586   my $rounded_total_rounding_error = abs(_round($total_rounding_error));
 587
 588   if ( $rounded_total_rounding_error > 0 ) {
 589     my $highest_amount_pos = 0;
 590     my $highest_amount = 0;
 591     my $i = -1;
 592     foreach my $ref ( @skonto_charts ) {
 593       $i++;
 594       if ( $ref->{skonto_amount} > $highest_amount ) {
 595         $highest_amount     = $ref->{skonto_amount};
 596         $highest_amount_pos = $i;
 597       };
 598     };
 599     $skonto_charts[$i]->{skonto_amount} -= $rounded_total_rounding_error;
 600   };
 601
 602   return @skonto_charts;
 603 };
 604
 605
 606 sub within_skonto_period {
 607   my $self = shift;
 608   my $dateref = shift || DateTime->now->truncate( to => 'day' );
 609
 610   return undef unless ref $dateref eq 'DateTime';
 611   return 0 unless $self->skonto_date;
 612
 613   # return 1 if requested date (or today) is inside skonto period
 614   # this will also return 1 if date is before the invoice date
 615   return $dateref <= $self->skonto_date;
 616 };
 617
 618 sub valid_skonto_amount {
 619   my $self = shift;
 620   my $amount = shift || 0;
 621   my $max_skonto_percent = 0.10;
 622
 623   return 0 unless $amount > 0;
 624
 625   # does this work for other currencies?
 626   return ($self->amount*$max_skonto_percent) > $amount;
 627 };
 628
 629 sub get_payment_select_options_for_bank_transaction {
 630   my ($self, $bt_id, %params) = @_;
 631
 632   my $bt = SL::DB::Manager::BankTransaction->find_by( id => $bt_id );
 633   die unless $bt;
 634
 635   my $open_amount = $self->open_amount;
 636
 637   my @options;
 638   if ( $open_amount &&                   # invoice amount not 0
 639        $self->skonto_date &&             # check whether skonto applies
 640        abs(abs($self->amount_less_skonto) - abs($bt->amount)) < 0.01 &&
 641        $self->check_skonto_configuration) {
 642          if ( $self->within_skonto_period($bt->transdate) ) {
 643            push(@options, { payment_type => 'without_skonto', display => t8('without skonto') });
 644            push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt'), selected => 1 });
 645          } else {
 646            push(@options, { payment_type => 'without_skonto', display => t8('without skonto') , selected => 1 });
 647            push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt')});
 648          };
 649   };
 650
 651   return @options;
 652
 653 };
 654
 655 sub exchangerate {
 656   my ($self) = @_;
 657
 658   return 1 if $self->currency_id == $::instance_conf->get_currency_id;
 659
 660   my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $self->currency_id,
 661                                                     transdate   => $self->transdate,
 662                                                    );
 663   return undef unless $rate;
 664   $self->is_sales ? return $rate->sell : return $rate->buy;
 665 };
 666
 667 sub get_payment_suggestions {
 668
 669   my ($self, %params) = @_;
 670
 671   my $open_amount = $self->open_amount;
 672   $open_amount   -= $self->open_sepa_transfer_amount if $params{sepa};
 673
 674   $self->{invoice_amount_suggestion} = $open_amount;
 675   undef $self->{payment_select_options};
 676   push(@{$self->{payment_select_options}} , { payment_type => 'without_skonto',  display => t8('without skonto') });
 677   if ( $self->within_skonto_period ) {
 678     # If there have been no payments yet suggest amount_less_skonto, otherwise the open amount
 679     if ( $open_amount &&                   # invoice amount not 0
 680          $open_amount == $self->amount &&  # no payments yet, or sum of payments and sepa export amounts is zero
 681          $self->check_skonto_configuration) {
 682       $self->{invoice_amount_suggestion} = $self->amount_less_skonto;
 683       push(@{$self->{payment_select_options}} , { payment_type => 'with_skonto_pt',  display => t8('with skonto acc. to pt') , selected => 1 });
 684     } else {
 685       if ( ( $self->valid_skonto_amount($self->open_amount) || $self->valid_skonto_amount($open_amount) ) and not $params{sepa} ) {
 686         $self->{invoice_amount_suggestion} = $open_amount;
 687         # only suggest difference_as_skonto if open_amount exactly matches skonto_amount
 688         # AND we aren't in SEPA mode
 689         my $selected = 0;
 690         $selected = 1 if _round($open_amount) == _round($self->skonto_amount);
 691         push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => $selected });
 692       };
 693     };
 694   } else {
 695     # invoice was configured with skonto, but skonto date has passed, or no skonto available
 696     $self->{invoice_amount_suggestion} = $open_amount;
 697     # difference_as_skonto doesn't make any sense for SEPA transfer, as this doesn't cause any actual payment
 698     if ( $self->valid_skonto_amount($self->open_amount) && not $params{sepa} ) {
 699       push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => 0 });
 700     };
 701   };
 702   return 1;
 703 };
 704
 705 sub validate_payment_type {
 706   my $payment_type = shift;
 707
 708   my %allowed_payment_types = map { $_ => 1 } qw(without_skonto with_skonto_pt difference_as_skonto);
 709   croak "illegal payment type: $payment_type, must be one of: " . join(' ', keys %allowed_payment_types) unless $allowed_payment_types{ $payment_type };
 710
 711   return 1;
 712 }
 713
 714 sub create_bank_transaction {
 715   my ($self, %params) = @_;
 716
 717   require SL::DB::Chart;
 718   require SL::DB::BankAccount;
 719
 720   my $bank_chart;
 721   if ( $params{chart_id} ) {
 722     $bank_chart = SL::DB::Manager::Chart->find_by(chart_id => $params{chart_id}) or die "Can't find bank chart";
 723   } elsif ( $::instance_conf->get_ar_paid_accno_id ) {
 724     $bank_chart   = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_ar_paid_accno_id);
 725   } else {
 726     $bank_chart = SL::DB::Manager::Chart->find_by(description => 'Bank') or die "Can't find bank chart";
 727   };
 728   my $bank_account = SL::DB::Manager::BankAccount->find_by(chart_id => $bank_chart->id) or die "Can't find bank account for chart";
 729
 730   my $multiplier = $self->is_sales ? 1 : -1;
 731   my $amount = ($params{amount} || $self->amount) * $multiplier;
 732
 733   my $transdate = $params{transdate} || DateTime->today;
 734
 735   my $bt = SL::DB::BankTransaction->new(
 736     local_bank_account_id => $bank_account->id,
 737     remote_bank_code      => $self->customervendor->bank_code,
 738     remote_account_number => $self->customervendor->account_number,
 739     transdate             => $transdate,
 740     valutadate            => $transdate,
 741     amount                => $::form->round_amount($amount, 2),
 742     currency              => $self->currency->id,
 743     remote_name           => $self->customervendor->depositor,
 744     purpose               => $self->invnumber
 745   )->save;
 746 };
 747
 748
 749 sub _round {
 750   my $value = shift;
 751   my $num_dec = 2;
 752   return $::form->round_amount($value, 2);
 753 }
 754
 755 1;
 756
 757 __END__
 758
 759 =pod
 760
 761 =head1 NAME
 762
 763 SL::DB::Helper::Payment  Mixin providing helper methods for paying C<Invoice>
 764                          and C<PurchaseInvoice> objects and using skonto
 765
 766 =head1 SYNOPSIS
 767
 768 In addition to actually causing a payment via pay_invoice this helper contains
 769 many methods that help in determining information about the status of the
 770 invoice, such as the remaining open amount, whether skonto applies, until which
 771 date skonto applies, the skonto amount and relative percentages, what to do
 772 with skonto, ...
 773
 774 To prevent duplicate code this was all added in this mixin rather than directly
 775 in SL::DB::Invoice and SL::DB::PurchaseInvoice.
 776
 777 =over 4
 778
 779 =item C<pay_invoice %params>
 780
 781 Create a payment booking for an existing invoice object (type ar/ap/is/ir) via
 782 a configured bank account.
 783
 784 This function deals with all the acc_trans entries and also updates paid and datepaid.
 785
 786 Example:
 787
 788   my $ap   = SL::DB::Manager::PurchaseInvoice->find_by( invnumber => '1');
 789   my $bank = SL::DB::Manager::BankAccount->find_by( name => 'Bank');
 790   $ap->pay_invoice(chart_id      => $bank->chart_id,
 791                    amount        => $ap->open_amount,
 792                    transdate     => DateTime->now->to_kivitendo,
 793                    memo          => 'foobar',
 794                    source        => 'barfoo',
 795                    payment_type  => 'without_skonto',  # default if not specified
 796                    project_id    => 25,
 797                   );
 798
 799 or with skonto:
 800   $ap->pay_invoice(chart_id      => $bank->chart_id,
 801                    amount        => $ap->amount,       # doesn't need to be specified
 802                    transdate     => DateTime->now->to_kivitendo,
 803                    memo          => 'foobar',
 804                    source        => 'barfoo',
 805                    payment_type  => 'with_skonto',
 806                   );
 807
 808 or in a certain currency:
 809   $ap->pay_invoice(chart_id      => $bank->chart_id,
 810                    amount        => 500,
 811                    currency      => 'USD',
 812                    transdate     => DateTime->now->to_kivitendo,
 813                    memo          => 'foobar',
 814                    source        => 'barfoo',
 815                    payment_type  => 'with_skonto',
 816                   );
 817
 818 Allowed payment types are:
 819   without_skonto with_skonto_pt difference_as_skonto
 820
 821 The option C<payment_type> allows for a basic skonto mechanism.
 822
 823 C<without_skonto> is the default mode, "amount" is paid to the account in
 824 chart_id. This can also be used for partial payments and corrections via
 825 negative amounts.
 826
 827 C<with_skonto_pt> can't be used for partial payments. When used on unpaid
 828 invoices the whole amount is paid, with the skonto part automatically being
 829 booked according to the skonto chart configured in the tax settings for each
 830 tax key. If an amount is passed it is ignored and the actual configured skonto
 831 amount is used.
 832
 833 C<difference_as_skonto> can only be used after partial payments have been made,
 834 the whole specified amount is booked according to the skonto charts configured
 835 in the tax settings for each tax key.
 836
 837 So passing amount doesn't have any effect for the cases C<with_skonto_pt> and
 838 C<difference_as_skonto>, as all necessary values are taken from the stored
 839 invoice.
 840
 841 The skonto modes automatically calculate the relative amounts for a mix of
 842 taxes, e.g. items with 7% and 19% in one invoice. There is a helper method
 843 skonto_charts, which calculates the relative percentages according to the
 844 amounts in acc_trans (which are grouped by tax).
 845
 846 There is currently no way of excluding certain items in an invoice from having
 847 skonto applied to them.  If this feature was added to parts the calculation
 848 method of relative skonto would have to be completely rewritten using the
 849 invoice items rather than acc_trans.
 850
 851 The skonto modes also still don't automatically correct the tax, this still has
 852 to be done manually. Therefore all payments generated by pay_invoice have
 853 taxkey 0.
 854
 855 There is currently no way to directly pay an invoice via this method if the
 856 effective skonto differs from the skonto according to the payment terms
 857 configured for the invoice/vendor.
 858
 859 In this case one has to pay in two steps: first the actual paid amount via
 860 "without skonto", and then the remainder via "difference_as_skonto". The user
 861 has to there actively decide whether to accept the differing skonto.
 862
 863 Because of the way skonto_charts works the calculation doesn't work if there
 864 are negative values in acc_trans. E.g. one invoice with a positive value for
 865 19% tax and a negative value for the acc_trans line with 7%
 866
 867 Skonto doesn't/shouldn't apply if the invoice contains credited items.
 868
 869 If no amount is given the whole open amout is paid.
 870
 871 If neither currency or currency_id are given as params, the currency of the
 872 invoice is assumed to be the payment currency.
 873
 874 =item C<reference_account>
 875
 876 Returns a chart object which is the chart of the invoice with link AR or AP.
 877
 878 Example (1200 is the AR account for SKR04):
 879   my $invoice = invoice(invnumber => '144');
 880   $invoice->reference_account->accno
 881   # 1200
 882
 883 =item C<percent_skonto>
 884
 885 Returns the configured skonto percentage of the payment terms of an invoice,
 886 e.g. 0.02 for 2%. Payment terms come from invoice settings for ar, from vendor
 887 settings for ap.
 888
 889 =item C<amount_less_skonto>
 890
 891 If the invoice has a payment term (via ar for sales, via vendor for purchase),
 892 calculate the amount to be paid in the case of skonto.  This doesn't check,
 893 whether skonto applies (i.e. skonto doesn't wasn't exceeded), it just subtracts
 894 the configured percentage (e.g. 2%) from the total amount.
 895
 896 The returned value is rounded to two decimals.
 897
 898 =item C<skonto_date>
 899
 900 The date up to which skonto may be taken. This is calculated from the invoice
 901 date + the number of days configured in the payment terms.
 902
 903 This method can also be used to determine whether skonto applies for the
 904 invoice, as it returns undef if there is no payment term or skonto days is set
 905 to 0.
 906
 907 =item C<within_skonto_period [DATE]>
 908
 909 Returns 0 or 1.
 910
 911 Checks whether the invoice has payment terms configured, and whether the date
 912 is within the skonto max date. If no date is passed the current date is used.
 913
 914 You can also pass a dateref object as a parameter to check whether skonto
 915 applies for that date rather than the current date.
 916
 917 =item C<valid_skonto_amount>
 918
 919 Takes an amount as an argument and checks whether the amount is less than 10%
 920 of the total amount of the invoice. The value of 10% is currently hardcoded in
 921 the method. This method is currently used to check whether to offer the payment
 922 option "difference as skonto".
 923
 924 Example:
 925  if ( $invoice->valid_skonto_amount($invoice->open_amount) ) {
 926    # ... do something
 927  }
 928
 929 =item C<skonto_charts [$amount]>
 930
 931 Returns a list of chart_ids and some calculated numbers that can be used for
 932 paying the invoice with skonto. This function will automatically calculate the
 933 relative skonto amounts even if the invoice contains several types of taxes
 934 (e.g. 7% and 19%).
 935
 936 Example usage:
 937   my $invoice = SL::DB::Manager::Invoice->find_by(invnumber => '211');
 938   my @skonto_charts = $invoice->skonto_charts;
 939
 940 or with the total skonto amount as an argument:
 941   my @skonto_charts = $invoice->skonto_charts($invoice->open_amount);
 942
 943 The following values are generated for each chart:
 944
 945 =over 2
 946
 947 =item C<chart_id>
 948
 949 The chart id of the skonto amount to be booked.
 950
 951 =item C<skonto_amount>
 952
 953 The total amount to be paid to the account
 954
 955 =item C<skonto_percent>
 956
 957 The relative percentage of that skonto chart. This can be useful if the actual
 958 ekonto that is paid deviates from the granted skonto, e.g. customer effectively
 959 pays 2.6% skonto instead of 2%, and we accept this. Then we can still calculate
 960 the relative skonto amounts for different taxes based on the absolute
 961 percentages. Used for case C<difference_as_skonto>.
 962
 963 =item C<skonto_percent_abs>
 964
 965 The absolute percentage of that skonto chart in relation to the total amount.
 966 Used to calculate skonto_amount for case C<with_skonto_pt>.
 967
 968 =back
 969
 970 If the invoice contains several types of taxes then skonto_charts can be used
 971 to calculate the relative amounts.
 972
 973 Example in console of an invoice with 100 Euro at 7% and 100 Euro at 19% with
 974 tax not included:
 975
 976   my $invoice = invoice(invnumber => '144');
 977   $invoice->amount
 978   226.00000
 979   $invoice->payment_terms->percent_skonto
 980   0.02
 981   $invoice->skonto_charts
 982   pp $invoice->skonto_charts
 983   #             $VAR1 = {
 984   #               'chart_id'       => 128,
 985   #               'skonto_amount'  => '2.14',
 986   #               'skonto_percent' => '47.3451327433627'
 987   #             };
 988   #             $VAR2 = {
 989   #               'chart_id'       => 130,
 990   #               'skonto_amount'  => '2.38',
 991   #               'skonto_percent' => '52.654867256637'
 992   #             };
 993
 994 C<skonto_charts> always returns positive values (abs) for C<skonto_amount> and
 995 C<skonto_percent>.
 996
 997 C<skonto_charts> generates one entry for each acc_trans entry. ar and ap
 998 bookings only have one acc_trans entry for each taxkey (e.g. 7% and 19%).  This
 999 is because all the items are grouped according to the Buchungsgruppen mechanism
1000 and the totals are written to acc_trans.  For is and ir it is possible to have
1001 several acc_trans entries with the same tax. In this case skonto_charts
1002 generates a skonto booking for each acc_trans income/expense entry.
1003
1004 In the future this function may also be used to calculate the corrections for
1005 the income tax.
1006
1007 =item C<open_amount>
1008
1009 Unrounded total open amount of invoice (amount - paid).
1010 Doesn't take into account pending SEPA transfers.
1011
1012 =item C<open_percent>
1013
1014 Percentage of the invoice that is still unpaid, e.g. 100,00 if no payments have
1015 been made yet, 0,00 if fully paid.
1016
1017 =item C<remaining_skonto_days>
1018
1019 How many days skonto can still be taken, calculated from current day. Returns 0
1020 if current day is the max skonto date, and negative number if skonto date has
1021 already passed.
1022
1023 Returns undef if skonto is not configured for that invoice.
1024
1025 =item C<get_payment_suggestions %params>
1026
1027 Creates data intended for an L.select_tag dropdown that can be used in a
1028 template. Depending on the rules it will choose from the options
1029 without_skonto, with_skonto_pt and difference_as_skonto, and select the most
1030 likely one.
1031
1032 If the parameter "sepa" is passed, the SEPA export payments that haven't been
1033 executed yet are considered when determining the open amount of the invoice.
1034
1035 The current rules are:
1036
1037 =over 2
1038
1039 =item * without_skonto is always an option
1040
1041 =item * with_skonto_pt is only offered if there haven't been any payments yet and the current date is within the skonto period.
1042
1043 =item * difference_as_skonto is only offered if there have already been payments made and the open amount is smaller than 10% of the total amount.
1044
1045 with_skonto_pt will only be offered, if all the AR_amount/AP_amount have a
1046 taxkey with a configured skonto chart
1047
1048 =back
1049
1050 It will also fill $self->{invoice_amount_suggestion} with either the open
1051 amount, or if with_skonto_pt is selected, with amount_less_skonto, so the
1052 template can fill the input with the likely amount.
1053
1054 Example in console:
1055   my $ar = invoice( invnumber => '257');
1056   $ar->get_payment_suggestions;
1057   print $ar->{invoice_amount_suggestion} . "\n";
1058   # 97.23
1059   pp $ar->{payment_select_options}
1060   # $VAR1 = [
1061   #         {
1062   #           'display' => 'ohne Skonto',
1063   #           'payment_type' => 'without_skonto'
1064   #         },
1065   #         {
1066   #           'display' => 'mit Skonto nach ZB',
1067   #           'payment_type' => 'with_skonto_pt',
1068   #           'selected' => 1
1069   #         }
1070   #       ];
1071
1072 The resulting array $ar->{payment_select_options} can be used in a template
1073 select_tag using value_key and title_key:
1074
1075 [% L.select_tag('payment_type_' _ loop.count, invoice.payment_select_options, value_key => 'payment_type', title_key => 'display', id => 'payment_type_' _ loop.count) %]
1076
1077 It would probably make sense to have different rules for the pre-selected items
1078 for sales and purchase, and to also make these rules configurable in the
1079 defaults. E.g. when creating a SEPA bank transfer for vendor invoices a company
1080 might always want to pay quickly making use of skonto, while another company
1081 might always want to pay as late as possible.
1082
1083 =item C<get_payment_select_options_for_bank_transaction $banktransaction_id %params>
1084
1085 Make suggestion for a skonto payment type by returning an HTML blob of the options
1086 of a HTML drop-down select with the most likely option preselected.
1087
1088 This is a helper function for BankTransaction/ajax_payment_suggestion.
1089
1090 We are working with an existing payment, so difference_as_skonto never makes sense.
1091
1092 If skonto is possible (skonto_date exists), add two possibilities:
1093 without_skonto and with_skonto_pt if payment date is within skonto_date,
1094 preselect with_skonto_pt, otherwise preselect without skonto.
1095
1096 =item C<create_bank_transaction %params>
1097
1098 Method used for testing purposes, allows you to quickly create bank
1099 transactions from invoices to have something to test payments against.
1100
1101  my $ap = SL::DB::Manager::Invoice->find_by(id => 41);
1102  $ap->create_bank_transaction(amount => $ap->amount/2, transdate => DateTime->today->add(days => 5));
1103
1104 Amount is always relative to the absolute amount of the invoice, use positive
1105 values for sales and purchases.
1106
1107 =item C<exchangerate>
1108
1109 Returns the exchangerate in database format for the invoice according to that invoice's transdate.
1110 Returns 'sell' for sales, 'buy' for purchases.
1111
1112 =back
1113
1114 =head1 TODO AND CAVEATS
1115
1116 =over 4
1117
1118 =item *
1119
1120 when looking at open amount, maybe consider that there may already be queued
1121 amounts in SEPA Export
1122
1123 =back
1124
1125 =head1 AUTHOR
1126
1127 G. Richardson E<lt>grichardson@kivitendo-premium.de<gt>
1128
1129 =cut