SL/DB/Helper/Payment.pm

   1 package SL::DB::Helper::Payment;
   2
   3 use strict;
   4
   5 use parent qw(Exporter);
   6 our @EXPORT = qw(pay_invoice);
   7 our @EXPORT_OK = qw(skonto_date skonto_charts amount_less_skonto within_skonto_period percent_skonto reference_account reference_amount open_amount open_percent remaining_skonto_days skonto_amount check_skonto_configuration valid_skonto_amount get_payment_suggestions validate_payment_type open_sepa_transfer_amount get_payment_select_options_for_bank_transaction exchangerate forex);
   8 our %EXPORT_TAGS = (
   9   "ALL" => [@EXPORT, @EXPORT_OK],
  10 );
  11
  12 require SL::DB::Chart;
  13 use Data::Dumper;
  14 use DateTime;
  15 use SL::DATEV qw(:CONSTANTS);
  16 use SL::Locale::String qw(t8);
  17 use List::Util qw(sum);
  18 use SL::DB::Exchangerate;
  19 use SL::DB::Currency;
  20 use Carp;
  21
  22 #
  23 # Public functions not exported by default
  24 #
  25
  26 sub pay_invoice {
  27   my ($self, %params) = @_;
  28
  29   require SL::DB::Tax;
  30
  31   my $is_sales = ref($self) eq 'SL::DB::Invoice';
  32   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign depending on ar/ap
  33   my @new_acc_ids;
  34   my $paid_amount = 0; # the amount that will be later added to $self->paid, should be in default currency
  35
  36   # default values if not set
  37   $params{payment_type} = 'without_skonto' unless $params{payment_type};
  38   validate_payment_type($params{payment_type});
  39
  40   # check for required parameters and optional params depending on payment_type
  41   Common::check_params(\%params, qw(chart_id transdate));
  42   if ( $params{'payment_type'} eq 'without_skonto' && abs($params{'amount'}) < 0) {
  43     croak "invalid amount for payment_type 'without_skonto': $params{'amount'}\n";
  44   }
  45   if ($params{'payment_type'} eq 'free_skonto') {
  46     # we dont like too much automagic for this payment type.
  47     # we force caller input for amount and skonto amount
  48     Common::check_params(\%params, qw(amount skonto_amount));
  49     # secondly we dont want to handle credit notes and purchase credit notes
  50     croak("Cannot use 'free skonto' for credit or debit notes") if ($params{amount} <= 0 || $params{skonto_amount} <= 0);
  51     # both amount have to be rounded
  52     $params{skonto_amount} = _round($params{skonto_amount});
  53     $params{amount}        = _round($params{amount});
  54     # lastly skonto_amount has to be smaller than the open invoice amount or payment amount ;-)
  55     if ($params{skonto_amount} > abs($self->open_amount) || $params{skonto_amount} > $params{amount}) {
  56       croak("Skonto amount higher than the payment or invoice amount");
  57     }
  58   }
  59
  60   my $transdate_obj;
  61   if (ref($params{transdate}) eq 'DateTime') {
  62     $transdate_obj = $params{transdate};
  63   } else {
  64     $transdate_obj = $::locale->parse_date_to_object($params{transdate});
  65   };
  66   croak t8('Illegal date') unless ref $transdate_obj;
  67
  68   # check for closed period
  69   my $closedto = $::locale->parse_date_to_object($::instance_conf->get_closedto);
  70   if ( ref $closedto && $transdate_obj < $closedto ) {
  71     croak t8('Cannot post payment for a closed period!');
  72   };
  73
  74   # check for maximum number of future days
  75   if ( $::instance_conf->get_max_future_booking_interval > 0 ) {
  76     croak t8('Cannot post transaction above the maximum future booking date!') if $transdate_obj > DateTime->now->add( days => $::instance_conf->get_max_future_booking_interval );
  77   };
  78
  79   # currency is either passed or use the invoice currency if it differs from the default currency
  80   my ($exchangerate,$currency);
  81   if ($params{currency} || $params{currency_id} || $self->currency_id != $::instance_conf->get_currency_id) {
  82     if ($params{currency} || $params{currency_id} ) { # currency was specified
  83       $currency = SL::DB::Manager::Currency->find_by(name => $params{currency}) || SL::DB::Manager::Currency->find_by(id => $params{currency_id});
  84     } else { # use invoice currency
  85       $currency = SL::DB::Manager::Currency->find_by(id => $self->currency_id);
  86     };
  87     die "no currency" unless $currency;
  88     if ($currency->id == $::instance_conf->get_currency_id) {
  89       $exchangerate = 1;
  90     } else {
  91       my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $currency->id,
  92                                                         transdate   => $transdate_obj,
  93                                                        );
  94       if ($rate) {
  95         $exchangerate = $is_sales ? $rate->buy : $rate->sell;
  96       } else {
  97         die "No exchange rate for " . $transdate_obj->to_kivitendo;
  98       };
  99     };
 100   } else { # no currency param given or currency is the same as default_currency
 101     $exchangerate = 1;
 102   };
 103
 104   # options with_skonto_pt and difference_as_skonto don't require the parameter
 105   # amount, but if amount is passed, make sure it matches the expected value
 106   if ( $params{'payment_type'} eq 'difference_as_skonto' ) {
 107     croak "amount $params{amount} doesn't match open amount " . $self->open_amount . ", diff = " . ($params{amount}-$self->open_amount) if $params{amount} && abs($self->open_amount - $params{amount} ) > 0.0000001;
 108   } elsif ( $params{'payment_type'} eq 'with_skonto_pt' ) {
 109     croak "amount $params{amount} doesn't match amount less skonto: " . $self->amount_less_skonto . "\n" if $params{amount} && abs($self->amount_less_skonto - $params{amount} ) > 0.0000001;
 110     croak "payment type with_skonto_pt can't be used if payments have already been made" if $self->paid != 0;
 111   };
 112
 113   # absolute skonto amount for invoice, use as reference sum to see if the
 114   # calculated skontos add up
 115   # only needed for payment_term "with_skonto_pt"
 116
 117   my $skonto_amount_check = $self->skonto_amount; # variable should be zero after calculating all skonto
 118   my $total_open_amount   = $self->open_amount;
 119
 120   # account where money is paid to/from: bank account or cash
 121   my $account_bank = SL::DB::Manager::Chart->find_by(id => $params{chart_id});
 122   croak "can't find bank account with id " . $params{chart_id} unless ref $account_bank;
 123
 124   my $reference_account = $self->reference_account;
 125   croak "can't find reference account (link = AR/AP) for invoice" unless ref $reference_account;
 126
 127   my $memo   = $params{memo}   // '';
 128   my $source = $params{source} // '';
 129
 130   my $rounded_params_amount = _round( $params{amount} ); # / $exchangerate);
 131   my $fx_gain_loss_amount = 0; # for fx_gain and fx_loss
 132
 133   my $db = $self->db;
 134   $db->with_transaction(sub {
 135     my $new_acc_trans;
 136
 137     # all three payment type create 1 AR/AP booking (the paid part)
 138     # difference_as_skonto creates n skonto bookings (1 for each buchungsgruppe type)
 139     # with_skonto_pt creates 1 bank booking and n skonto bookings (1 for each buchungsgruppe type)
 140     # without_skonto creates 1 bank booking
 141
 142     # as long as there is no automatic tax, payments are always booked with
 143     # taxkey 0
 144
 145     unless ( $params{payment_type} eq 'difference_as_skonto' ) {
 146       # cases with_skonto_pt, free_skonto and without_skonto
 147
 148       # for case with_skonto_pt we need to know the corrected amount at this
 149       # stage if we are going to use $params{amount}
 150
 151       my $pay_amount = $rounded_params_amount;
 152       $pay_amount = $self->amount_less_skonto if $params{payment_type} eq 'with_skonto_pt';
 153
 154       # bank account and AR/AP
 155       $paid_amount += $pay_amount * $exchangerate;
 156
 157       my $amount = (-1 * $pay_amount) * $mult;
 158
 159
 160       # total amount against bank, do we already know this by now?
 161       $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 162                                                    chart_id   => $account_bank->id,
 163                                                    chart_link => $account_bank->link,
 164                                                    amount     => $amount,
 165                                                    transdate  => $transdate_obj,
 166                                                    source     => $source,
 167                                                    memo       => $memo,
 168                                                    project_id => $params{project_id} ? $params{project_id} : undef,
 169                                                    taxkey     => 0,
 170                                                    tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 171       $new_acc_trans->save;
 172
 173       push @new_acc_ids, $new_acc_trans->acc_trans_id;
 174       # deal with fxtransaction
 175       if ( $self->currency_id != $::instance_conf->get_currency_id ) {
 176         my $fxamount = _round($amount - ($amount * $exchangerate));
 177         $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 178                                                      chart_id       => $account_bank->id,
 179                                                      chart_link     => $account_bank->link,
 180                                                      amount         => $fxamount * -1,
 181                                                      transdate      => $transdate_obj,
 182                                                      source         => $source,
 183                                                      memo           => $memo,
 184                                                      taxkey         => 0,
 185                                                      fx_transaction => 1,
 186                                                      tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 187         $new_acc_trans->save;
 188         push @new_acc_ids, $new_acc_trans->acc_trans_id;
 189         # if invoice exchangerate differs from exchangerate of payment
 190         # deal with fxloss and fxamount
 191         if ($self->exchangerate and $self->exchangerate != 1 and $self->exchangerate != $exchangerate) {
 192           my $fxgain_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxgain_accno_id) || die "Can't determine fxgain chart";
 193           my $fxloss_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxloss_accno_id) || die "Can't determine fxloss chart";
 194           my $gain_loss_amount = _round($amount * ($exchangerate - $self->exchangerate ) * -1,2);
 195           my $gain_loss_chart = $gain_loss_amount > 0 ? $fxgain_chart : $fxloss_chart;
 196           $fx_gain_loss_amount = $gain_loss_amount;
 197
 198           $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 199                                                        chart_id       => $gain_loss_chart->id,
 200                                                        chart_link     => $gain_loss_chart->link,
 201                                                        amount         => $gain_loss_amount,
 202                                                        transdate      => $transdate_obj,
 203                                                        source         => $source,
 204                                                        memo           => $memo,
 205                                                        taxkey         => 0,
 206                                                        fx_transaction => 0,
 207                                                        tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 208           $new_acc_trans->save;
 209           push @new_acc_ids, $new_acc_trans->acc_trans_id;
 210
 211         }
 212       }
 213     }
 214     # better everything except without_skonto
 215     if ($params{payment_type} eq 'difference_as_skonto' or $params{payment_type} eq 'with_skonto_pt'
 216         or $params{payment_type} eq 'free_skonto' ) {
 217
 218       my $total_skonto_amount;
 219       if ( $params{payment_type} eq 'with_skonto_pt' ) {
 220         $total_skonto_amount = $self->skonto_amount;
 221       } elsif ( $params{payment_type} eq 'difference_as_skonto' ) {
 222         $total_skonto_amount = $self->open_amount;
 223       } elsif ( $params{payment_type} eq 'free_skonto') {
 224         $total_skonto_amount = $params{skonto_amount};
 225       }
 226       my @skonto_bookings = $self->skonto_charts($total_skonto_amount);
 227
 228       # error checking:
 229       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 230         my $calculated_skonto_sum  = sum map { $_->{skonto_amount} } @skonto_bookings;
 231         croak "calculated skonto for difference_as_skonto = $calculated_skonto_sum doesn't add up open amount: " . $self->open_amount unless _round($calculated_skonto_sum) == _round($self->open_amount);
 232       };
 233
 234       my $reference_amount = $total_skonto_amount;
 235
 236       # create an acc_trans entry for each result of $self->skonto_charts
 237       foreach my $skonto_booking ( @skonto_bookings ) {
 238         next unless $skonto_booking->{'chart_id'};
 239         next unless $skonto_booking->{'skonto_amount'} != 0;
 240         my $amount = -1 * $skonto_booking->{skonto_amount};
 241         $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 242                                                      chart_id   => $skonto_booking->{'chart_id'},
 243                                                      chart_link => SL::DB::Manager::Chart->find_by(id => $skonto_booking->{'chart_id'})->link,
 244                                                      amount     => $amount * $mult,
 245                                                      transdate  => $transdate_obj,
 246                                                      source     => $params{source},
 247                                                      taxkey     => 0,
 248                                                      tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 249
 250         # the acc_trans entries are saved individually, not added to $self and then saved all at once
 251         $new_acc_trans->save;
 252         push @new_acc_ids, $new_acc_trans->acc_trans_id;
 253
 254         $reference_amount -= abs($amount);
 255         $paid_amount      += -1 * $amount * $exchangerate;
 256         $skonto_amount_check -= $skonto_booking->{'skonto_amount'};
 257       };
 258       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 259           die "difference_as_skonto calculated incorrectly, sum of calculated payments doesn't add up to open amount $total_open_amount, reference_amount = $reference_amount\n" unless _round($reference_amount) == 0;
 260       }
 261     }
 262
 263     my $arap_amount = 0;
 264
 265     if ( $params{payment_type} eq 'difference_as_skonto' ) {
 266       $arap_amount = $total_open_amount;
 267     } elsif ( $params{payment_type} eq 'without_skonto' ) {
 268       $arap_amount = $rounded_params_amount;
 269     } elsif ( $params{payment_type} eq 'with_skonto_pt' ) {
 270       # this should be amount + sum(amount+skonto), but while we only allow
 271       # with_skonto_pt for completely unpaid invoices we just use the value
 272       # from the invoice
 273       $arap_amount = $total_open_amount;
 274     } elsif ( $params{payment_type} eq 'free_skonto' ) {
 275       # we forced positive values and forced rounding at the beginning
 276       # therefore the above comment can be safely applied for this payment type
 277       $arap_amount = $params{amount} + $params{skonto_amount};
 278     }
 279
 280     # regardless of payment_type there is always only exactly one arap booking
 281     # TODO: compare $arap_amount to running total
 282     my $arap_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 283                                                   chart_id   => $reference_account->id,
 284                                                   chart_link => $reference_account->link,
 285                                                   amount     => _round($arap_amount * $mult * $exchangerate - $fx_gain_loss_amount),
 286                                                   transdate  => $transdate_obj,
 287                                                   source     => '', #$params{source},
 288                                                   taxkey     => 0,
 289                                                   tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 290     $arap_booking->save;
 291     push @new_acc_ids, $arap_booking->acc_trans_id;
 292
 293     $fx_gain_loss_amount *= -1 if $self->is_sales;
 294     $self->paid($self->paid + _round($paid_amount) + $fx_gain_loss_amount) if $paid_amount;
 295     $self->datepaid($transdate_obj);
 296     $self->save;
 297
 298     # make sure transactions will be reloaded the next time $self->transactions
 299     # is called, as pay_invoice saves the acc_trans objects individually rather
 300     # than adding them to the transaction relation array.
 301     $self->forget_related('transactions');
 302
 303     my $datev_check = 0;
 304     if ( $is_sales )  {
 305       if ( (  $self->invoice && $::instance_conf->get_datev_check_on_sales_invoice  ) ||
 306            ( !$self->invoice && $::instance_conf->get_datev_check_on_ar_transaction )) {
 307         $datev_check = 1;
 308       }
 309     } else {
 310       if ( (  $self->invoice && $::instance_conf->get_datev_check_on_purchase_invoice ) ||
 311            ( !$self->invoice && $::instance_conf->get_datev_check_on_ap_transaction   )) {
 312         $datev_check = 1;
 313       }
 314     }
 315
 316     if ( $datev_check ) {
 317
 318       my $datev = SL::DATEV->new(
 319         dbh        => $db->dbh,
 320         trans_id   => $self->{id},
 321       );
 322
 323       $datev->generate_datev_data;
 324
 325       if ($datev->errors) {
 326         # this exception should be caught by with_transaction, which handles the rollback
 327         die join "\n", $::locale->text('DATEV check returned errors:'), $datev->errors;
 328       }
 329     }
 330
 331     1;
 332
 333   }) || die t8('error while paying invoice #1 : ', $self->invnumber) . $db->error . "\n";
 334   return wantarray ? @new_acc_ids : 1;
 335 }
 336
 337 sub skonto_date {
 338
 339   my $self = shift;
 340
 341   return undef unless ref $self->payment_terms;
 342   return undef unless $self->payment_terms->terms_skonto > 0;
 343   return DateTime->from_object(object => $self->transdate)->add(days => $self->payment_terms->terms_skonto);
 344 };
 345
 346 sub reference_account {
 347   my $self = shift;
 348
 349   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 350
 351   require SL::DB::Manager::AccTransaction;
 352
 353   my $link_filter = $is_sales ? 'AR' : 'AP';
 354
 355   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 356      trans_id   => $self->id,
 357      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 358   );
 359
 360   return undef unless ref $acc_trans;
 361
 362   my $reference_account = SL::DB::Manager::Chart->find_by(id => $acc_trans->chart_id);
 363
 364   return $reference_account;
 365 };
 366
 367 sub reference_amount {
 368   my $self = shift;
 369
 370   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 371
 372   require SL::DB::Manager::AccTransaction;
 373
 374   my $link_filter = $is_sales ? 'AR' : 'AP';
 375
 376   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 377      trans_id   => $self->id,
 378      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 379   );
 380
 381   return undef unless ref $acc_trans;
 382
 383   # this should be the same as $self->amount
 384   return $acc_trans->amount;
 385 };
 386
 387
 388 sub open_amount {
 389   my $self = shift;
 390
 391   # in the future maybe calculate this from acc_trans
 392
 393   # if the difference is 0.01 Cent this may end up as 0.009999999999998
 394   # numerically, so round this value when checking for cent threshold >= 0.01
 395
 396   return ($self->amount // 0) - ($self->paid // 0);
 397 };
 398
 399 sub open_percent {
 400   my $self = shift;
 401
 402   return 0 if $self->amount == 0;
 403   my $open_percent;
 404   if ( $self->open_amount < 0 ) {
 405     # overpaid, currently treated identically
 406     $open_percent = $self->open_amount * 100 / $self->amount;
 407   } else {
 408     $open_percent = $self->open_amount * 100 / $self->amount;
 409   };
 410
 411   return _round($open_percent) || 0;
 412 };
 413
 414 sub skonto_amount {
 415   my $self = shift;
 416
 417   return $self->amount - $self->amount_less_skonto;
 418 };
 419
 420 sub remaining_skonto_days {
 421   my $self = shift;
 422
 423   return undef unless ref $self->skonto_date;
 424
 425   my $dur = DateTime::Duration->new($self->skonto_date - DateTime->today);
 426   return $dur->delta_days();
 427
 428 };
 429
 430 sub percent_skonto {
 431   my $self = shift;
 432
 433   my $percent_skonto = 0;
 434
 435   return undef unless ref $self->payment_terms;
 436   return undef unless $self->payment_terms->percent_skonto > 0;
 437   $percent_skonto = $self->payment_terms->percent_skonto;
 438
 439   return $percent_skonto;
 440 };
 441
 442 sub amount_less_skonto {
 443   # amount that has to be paid if skonto applies, always return positive rounded values
 444   # no, rare case, but credit_notes and negative ap have negative amounts
 445   # and therefore this comment may be misguiding
 446   # the result is rounded so we can directly compare it with the user input
 447   my $self = shift;
 448
 449   my $percent_skonto = $self->percent_skonto || 0;
 450
 451   return _round($self->amount - ( $self->amount * $percent_skonto) );
 452
 453 };
 454
 455 sub check_skonto_configuration {
 456   my $self = shift;
 457
 458   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 459
 460   my $skonto_configured = 1; # default is assume skonto works
 461
 462   # my $transactions = $self->transactions;
 463   foreach my $transaction (@{ $self->transactions }) {
 464     # find all transactions with an AR_amount or AP_amount link
 465     my $tax = SL::DB::Manager::Tax->get_first( where => [taxkey => $transaction->taxkey, id => $transaction->tax_id ]);
 466
 467     # acc_trans entries for the taxes (chart_link == A[RP]_tax) often
 468     # have combinations of taxkey & tax_id that don't exist in
 469     # tax. Those must be skipped.
 470     next if !$tax && ($transaction->chart_link !~ m{A[RP]_amount});
 471
 472     croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 473
 474     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->chart_link) };
 475     if ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) {
 476       $skonto_configured = 0 unless $tax->skonto_sales_chart_id;
 477     } elsif ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) {
 478       $skonto_configured = 0 unless $tax->skonto_purchase_chart_id;
 479     };
 480   };
 481
 482   return $skonto_configured;
 483 };
 484
 485 sub open_sepa_transfer_amount {
 486   my $self = shift;
 487
 488   my ($vc, $key, $type);
 489   if ( ref($self) eq 'SL::DB::Invoice' ) {
 490     $vc   = 'customer';
 491     $key  = 'ap_id';
 492     $type = 'ar';
 493   } else {
 494     $vc   = 'vendor';
 495     $key  = 'ap_id';
 496     $type = 'ap';
 497   };
 498
 499   my $sql = qq|SELECT SUM(sei.amount) AS amount FROM sepa_export_items sei | .
 500             qq| LEFT JOIN sepa_export se ON (sei.sepa_export_id = se.id)   | .
 501             qq| WHERE $key = ? AND NOT se.closed AND (se.vc = '$vc')       |;
 502
 503   my ($open_sepa_amount) = $self->db->dbh->selectrow_array($sql, undef, $self->id);
 504
 505   return $open_sepa_amount || 0;
 506
 507 };
 508
 509
 510 sub skonto_charts {
 511   my $self = shift;
 512
 513   # TODO: use param for amount, may also want to calculate skonto_amounts by
 514   # passing percentage in the future
 515
 516   my $amount = shift || $self->skonto_amount;
 517
 518   croak "no amount passed to skonto_charts" unless abs(_round($amount)) >= 0.01;
 519
 520   # TODO: check whether there are negative values in invoice / acc_trans ... credited items
 521
 522   # don't check whether skonto applies, because user may want to override this
 523   # return undef unless $self->percent_skonto;
 524
 525   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 526
 527   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign
 528
 529   my @skonto_charts;  # resulting array with all income/expense accounts that have to be corrected
 530
 531   # calculate effective skonto (percentage) in difference_as_skonto mode
 532   # only works if there are no negative acc_trans values
 533   my $effective_skonto_rate = $amount ? $amount / $self->amount : 0;
 534
 535   # checks:
 536   my $total_skonto_amount  = 0;
 537   my $total_rounding_error = 0;
 538
 539   my $reference_ARAP_amount = 0;
 540
 541   # my $transactions = $self->transactions;
 542   foreach my $transaction (@{ $self->transactions }) {
 543     # find all transactions with an AR_amount or AP_amount link
 544     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->{chart_link}) };
 545     # second condition is that we can determine an automatic Skonto account for each AR_amount entry
 546
 547     if ( ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) or ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) ) {
 548         # $reference_ARAP_amount += $transaction->{amount} * $mult;
 549
 550         # quick hack that works around problem of non-unique tax keys in SKR04
 551         # ? use tax_id in acc_trans
 552         my $tax = SL::DB::Manager::Tax->get_first( where => [id => $transaction->{tax_id}]);
 553         croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 554
 555         if ( $is_sales ) {
 556           die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $transaction->{taxkey} , $tax->taxdescription , $tax->rate*100) unless ref $tax->skonto_sales_chart;
 557         } else {
 558           die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $transaction->{taxkey} , $tax->taxdescription , $tax->rate*100) unless ref $tax->skonto_purchase_chart;
 559         };
 560
 561         my $skonto_amount_unrounded;
 562
 563         my $skonto_percent_abs = $self->amount ? abs($transaction->amount * (1 + $tax->rate) * 100 / $self->amount) : 0;
 564
 565         my $transaction_amount = abs($transaction->{amount} * (1 + $tax->rate));
 566         my $transaction_skonto_percent = abs($transaction_amount/$self->amount); # abs($transaction->{amount} * (1 + $tax->rate));
 567
 568
 569         $skonto_amount_unrounded   = abs($amount * $transaction_skonto_percent);
 570         my $skonto_amount_rounded  = _round($skonto_amount_unrounded);
 571         my $rounding_error         = $skonto_amount_unrounded - $skonto_amount_rounded;
 572         my $rounded_rounding_error = _round($rounding_error);
 573
 574         $total_rounding_error += $rounding_error;
 575         $total_skonto_amount  += $skonto_amount_rounded;
 576
 577         my $rec = {
 578           # skonto_percent_abs: relative part of amount + tax to the total invoice amount
 579           'skonto_percent_abs'     => $skonto_percent_abs,
 580           'chart_id'               => $is_sales ? $tax->skonto_sales_chart->id : $tax->skonto_purchase_chart->id,
 581           'skonto_amount'          => $skonto_amount_rounded,
 582           # 'rounding_error'         => $rounding_error,
 583           # 'rounded_rounding_error' => $rounded_rounding_error,
 584         };
 585
 586         push @skonto_charts, $rec;
 587       };
 588   };
 589
 590   # if the rounded sum of all rounding_errors reaches 0.01 this sum is
 591   # subtracted from the largest skonto_amount
 592   my $rounded_total_rounding_error = abs(_round($total_rounding_error));
 593
 594   if ( $rounded_total_rounding_error > 0 ) {
 595     my $highest_amount_pos = 0;
 596     my $highest_amount = 0;
 597     my $i = -1;
 598     foreach my $ref ( @skonto_charts ) {
 599       $i++;
 600       if ( $ref->{skonto_amount} > $highest_amount ) {
 601         $highest_amount     = $ref->{skonto_amount};
 602         $highest_amount_pos = $i;
 603       };
 604     };
 605     $skonto_charts[$i]->{skonto_amount} -= $rounded_total_rounding_error;
 606   };
 607
 608   return @skonto_charts;
 609 };
 610
 611
 612 sub within_skonto_period {
 613   my $self = shift;
 614   my $dateref = shift || DateTime->now->truncate( to => 'day' );
 615
 616   return undef unless ref $dateref eq 'DateTime';
 617   return 0 unless $self->skonto_date;
 618
 619   # return 1 if requested date (or today) is inside skonto period
 620   # this will also return 1 if date is before the invoice date
 621   return $dateref <= $self->skonto_date;
 622 };
 623
 624 sub valid_skonto_amount {
 625   my $self = shift;
 626   my $amount = shift || 0;
 627   my $max_skonto_percent = 0.10;
 628
 629   return 0 unless $amount > 0;
 630
 631   # does this work for other currencies?
 632   return ($self->amount*$max_skonto_percent) > $amount;
 633 };
 634
 635 sub get_payment_select_options_for_bank_transaction {
 636   my ($self, $bt_id, %params) = @_;
 637
 638
 639   # CAVEAT template code expects with_skonto_pt at position 1 for visual help
 640   # due to skonto_charts, we cannot offer skonto for credit notes and neg ap
 641   my $skontoable = $self->amount > 0 ? 1 : 0;
 642   my @options;
 643   if(!$self->skonto_date) {
 644     push(@options, { payment_type => 'without_skonto', display => t8('without skonto'), selected => 1 });
 645     # wrong call to presenter or not implemented? disabled option is ignored
 646     # push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt'), disabled => 1 });
 647     push(@options, { payment_type => 'free_skonto', display => t8('free skonto') }) if $skontoable;
 648     return @options;
 649   }
 650   # valid skonto date, check if skonto is preferred
 651   my $bt = SL::DB::BankTransaction->new(id => $bt_id)->load;
 652   if ($self->skonto_date && $self->within_skonto_period($bt->transdate)) {
 653     push(@options, { payment_type => 'without_skonto', display => t8('without skonto') });
 654     push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt'), selected => 1 }) if $skontoable;
 655   } else {
 656     push(@options, { payment_type => 'without_skonto', display => t8('without skonto') , selected => 1 });
 657     push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt')}) if $skontoable;
 658   }
 659   push(@options, { payment_type => 'free_skonto', display => t8('free skonto') }) if $skontoable;
 660   return @options;
 661 }
 662
 663 sub exchangerate {
 664   my ($self) = @_;
 665
 666   return 1 if $self->currency_id == $::instance_conf->get_currency_id;
 667
 668   die "transdate isn't a DateTime object:" . ref($self->transdate) unless ref($self->transdate) eq 'DateTime';
 669   my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $self->currency_id,
 670                                                     transdate   => $self->transdate,
 671                                                    );
 672   return undef unless $rate;
 673
 674   return $self->is_sales ? $rate->buy : $rate->sell; # also undef if not defined
 675 };
 676
 677 sub get_payment_suggestions {
 678
 679   my ($self, %params) = @_;
 680
 681   my $open_amount = $self->open_amount;
 682   $open_amount   -= $self->open_sepa_transfer_amount if $params{sepa};
 683
 684   $self->{invoice_amount_suggestion} = $open_amount;
 685   undef $self->{payment_select_options};
 686   push(@{$self->{payment_select_options}} , { payment_type => 'without_skonto',  display => t8('without skonto') });
 687   if ( $self->within_skonto_period ) {
 688     # If there have been no payments yet suggest amount_less_skonto, otherwise the open amount
 689     if ( $open_amount &&                   # invoice amount not 0
 690          $open_amount == $self->amount &&  # no payments yet, or sum of payments and sepa export amounts is zero
 691          $self->check_skonto_configuration) {
 692       $self->{invoice_amount_suggestion} = $self->amount_less_skonto;
 693       push(@{$self->{payment_select_options}} , { payment_type => 'with_skonto_pt',  display => t8('with skonto acc. to pt') , selected => 1 });
 694     } else {
 695       if ( ( $self->valid_skonto_amount($self->open_amount) || $self->valid_skonto_amount($open_amount) ) and not $params{sepa} ) {
 696         $self->{invoice_amount_suggestion} = $open_amount;
 697         # only suggest difference_as_skonto if open_amount exactly matches skonto_amount
 698         # AND we aren't in SEPA mode
 699         my $selected = 0;
 700         $selected = 1 if _round($open_amount) == _round($self->skonto_amount);
 701         push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => $selected });
 702       };
 703     };
 704   } else {
 705     # invoice was configured with skonto, but skonto date has passed, or no skonto available
 706     $self->{invoice_amount_suggestion} = $open_amount;
 707     # difference_as_skonto doesn't make any sense for SEPA transfer, as this doesn't cause any actual payment
 708     if ( $self->valid_skonto_amount($self->open_amount) && not $params{sepa} ) {
 709       push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => 0 });
 710     };
 711   };
 712   return 1;
 713 };
 714
 715 # locales for payment type
 716 #
 717 # $main::locale->text('without_skonto')
 718 # $main::locale->text('with_skonto_pt')
 719 # $main::locale->text('difference_as_skonto')
 720 #
 721
 722 sub validate_payment_type {
 723   my $payment_type = shift;
 724
 725   my %allowed_payment_types = map { $_ => 1 } qw(without_skonto with_skonto_pt difference_as_skonto free_skonto);
 726   croak "illegal payment type: $payment_type, must be one of: " . join(' ', keys %allowed_payment_types) unless $allowed_payment_types{ $payment_type };
 727
 728   return 1;
 729 }
 730
 731 sub forex {
 732   my ($self) = @_;
 733   $self->currency_id == $::instance_conf->get_currency_id ? return 0 : return 1;
 734 };
 735
 736 sub _round {
 737   my $value = shift;
 738   my $num_dec = 2;
 739   return $::form->round_amount($value, 2);
 740 }
 741
 742 1;
 743
 744 __END__
 745
 746 =pod
 747
 748 =head1 NAME
 749
 750 SL::DB::Helper::Payment  Mixin providing helper methods for paying C<Invoice>
 751                          and C<PurchaseInvoice> objects and using skonto
 752
 753 =head1 SYNOPSIS
 754
 755 In addition to actually causing a payment via pay_invoice this helper contains
 756 many methods that help in determining information about the status of the
 757 invoice, such as the remaining open amount, whether skonto applies, until which
 758 date skonto applies, the skonto amount and relative percentages, what to do
 759 with skonto, ...
 760
 761 To prevent duplicate code this was all added in this mixin rather than directly
 762 in SL::DB::Invoice and SL::DB::PurchaseInvoice.
 763
 764 =over 4
 765
 766 =item C<pay_invoice %params>
 767
 768 Create a payment booking for an existing invoice object (type ar/ap/is/ir) via
 769 a configured bank account.
 770
 771 This function deals with all the acc_trans entries and also updates paid and datepaid.
 772 The params C<transdate> and C<chart_id> are mandantory.
 773 If the default payment ('without_skonto') is used the param amount is also
 774 mandantory.
 775 If the payment type ('free_skonto') is used the number params skonto_amount and amount
 776 are as well mandantory and need to be positive. Furthermore the skonto amount has
 777 to be lower than the payment or open invoice amount.
 778
 779 Transdate can either be a date object or a date string.
 780 Chart_id is the id of the payment booking chart.
 781 Amount is either a postive or negative number, but never 0.
 782
 783
 784 Example:
 785
 786   my $ap   = SL::DB::Manager::PurchaseInvoice->find_by( invnumber => '1');
 787   my $bank = SL::DB::Manager::BankAccount->find_by( name => 'Bank');
 788   $ap->pay_invoice(chart_id      => $bank->chart_id,
 789                    amount        => $ap->open_amount,
 790                    transdate     => DateTime->now->to_kivitendo,
 791                    memo          => 'foobar',
 792                    source        => 'barfoo',
 793                    payment_type  => 'without_skonto',  # default if not specified
 794                    project_id    => 25,
 795                   );
 796
 797 or with skonto:
 798   $ap->pay_invoice(chart_id      => $bank->chart_id,
 799                    amount        => $ap->amount,       # doesn't need to be specified
 800                    transdate     => DateTime->now->to_kivitendo,
 801                    memo          => 'foobar',
 802                    source        => 'barfoo',
 803                    payment_type  => 'with_skonto',
 804                   );
 805
 806 or in a certain currency:
 807   $ap->pay_invoice(chart_id      => $bank->chart_id,
 808                    amount        => 500,
 809                    currency      => 'USD',
 810                    transdate     => DateTime->now->to_kivitendo,
 811                    memo          => 'foobar',
 812                    source        => 'barfoo',
 813                    payment_type  => 'with_skonto_pt',
 814                   );
 815
 816 Allowed payment types are:
 817   without_skonto with_skonto_pt difference_as_skonto
 818
 819 The option C<payment_type> allows for a basic skonto mechanism.
 820
 821 C<without_skonto> is the default mode, "amount" is paid to the account in
 822 chart_id. This can also be used for partial payments and corrections via
 823 negative amounts.
 824
 825 C<with_skonto_pt> can't be used for partial payments. When used on unpaid
 826 invoices the whole amount is paid, with the skonto part automatically being
 827 booked according to the skonto chart configured in the tax settings for each
 828 tax key. If an amount is passed it is ignored and the actual configured skonto
 829 amount is used.
 830
 831 C<difference_as_skonto> can only be used after partial payments have been made,
 832 the whole specified amount is booked according to the skonto charts configured
 833 in the tax settings for each tax key.
 834
 835 So passing amount doesn't have any effect for the cases C<with_skonto_pt> and
 836 C<difference_as_skonto>, as all necessary values are taken from the stored
 837 invoice.
 838
 839 The skonto modes automatically calculate the relative amounts for a mix of
 840 taxes, e.g. items with 7% and 19% in one invoice. There is a helper method
 841 skonto_charts, which calculates the relative percentages according to the
 842 amounts in acc_trans (which are grouped by tax).
 843
 844 There is currently no way of excluding certain items in an invoice from having
 845 skonto applied to them.  If this feature was added to parts the calculation
 846 method of relative skonto would have to be completely rewritten using the
 847 invoice items rather than acc_trans.
 848
 849 The skonto modes also still don't automatically correct the tax, this still has
 850 to be done manually. Therefore all payments generated by pay_invoice have
 851 taxkey 0.
 852
 853 There is currently no way to directly pay an invoice via this method if the
 854 effective skonto differs from the skonto according to the payment terms
 855 configured for the invoice/vendor.
 856
 857 In this case one has to pay in two steps: first the actual paid amount via
 858 "without skonto", and then the remainder via "difference_as_skonto". The user
 859 has to there actively decide whether to accept the differing skonto.
 860
 861 Because of the way skonto_charts works the calculation doesn't work if there
 862 are negative values in acc_trans. E.g. one invoice with a positive value for
 863 19% tax and a negative value for the acc_trans line with 7%
 864
 865 Skonto doesn't/shouldn't apply if the invoice contains credited items.
 866
 867 If no amount is given the whole open amout is paid.
 868
 869 If neither currency or currency_id are given as params, the currency of the
 870 invoice is assumed to be the payment currency.
 871
 872 If successful the return value will be 1 in scalar context or in list context
 873 the two ids (acc_trans_id) of the newly created bookings.
 874
 875 =item C<reference_account>
 876
 877 Returns a chart object which is the chart of the invoice with link AR or AP.
 878
 879 Example (1200 is the AR account for SKR04):
 880   my $invoice = invoice(invnumber => '144');
 881   $invoice->reference_account->accno
 882   # 1200
 883
 884 =item C<percent_skonto>
 885
 886 Returns the configured skonto percentage of the payment terms of an invoice,
 887 e.g. 0.02 for 2%. Payment terms come from invoice settingssettings for ap.
 888
 889 =item C<amount_less_skonto>
 890
 891 If the invoice has a payment term,
 892 calculate the amount to be paid in the case of skonto.  This doesn't check,
 893 whether skonto applies (i.e. skonto doesn't wasn't exceeded), it just subtracts
 894 the configured percentage (e.g. 2%) from the total amount.
 895
 896 The returned value is rounded to two decimals.
 897
 898 =item C<skonto_date>
 899
 900 The date up to which skonto may be taken. This is calculated from the invoice
 901 date + the number of days configured in the payment terms.
 902
 903 This method can also be used to determine whether skonto applies for the
 904 invoice, as it returns undef if there is no payment term or skonto days is set
 905 to 0.
 906
 907 =item C<within_skonto_period [DATE]>
 908
 909 Returns 0 or 1.
 910
 911 Checks whether the invoice has payment terms configured, and whether the date
 912 is within the skonto max date. If no date is passed the current date is used.
 913
 914 You can also pass a dateref object as a parameter to check whether skonto
 915 applies for that date rather than the current date.
 916
 917 =item C<valid_skonto_amount>
 918
 919 Takes an amount as an argument and checks whether the amount is less than 10%
 920 of the total amount of the invoice. The value of 10% is currently hardcoded in
 921 the method. This method is currently used to check whether to offer the payment
 922 option "difference as skonto".
 923
 924 Example:
 925  if ( $invoice->valid_skonto_amount($invoice->open_amount) ) {
 926    # ... do something
 927  }
 928
 929 =item C<skonto_charts [$amount]>
 930
 931 Returns a list of chart_ids and some calculated numbers that can be used for
 932 paying the invoice with skonto. This function will automatically calculate the
 933 relative skonto amounts even if the invoice contains several types of taxes
 934 (e.g. 7% and 19%).
 935
 936 Example usage:
 937   my $invoice = SL::DB::Manager::Invoice->find_by(invnumber => '211');
 938   my @skonto_charts = $invoice->skonto_charts;
 939
 940 or with the total skonto amount as an argument:
 941   my @skonto_charts = $invoice->skonto_charts($invoice->open_amount);
 942
 943 The following values are generated for each chart:
 944
 945 =over 2
 946
 947 =item C<chart_id>
 948
 949 The chart id of the skonto amount to be booked.
 950
 951 =item C<skonto_amount>
 952
 953 The total amount to be paid to the account
 954
 955 =item C<skonto_percent>
 956
 957 The relative percentage of that skonto chart. This can be useful if the actual
 958 ekonto that is paid deviates from the granted skonto, e.g. customer effectively
 959 pays 2.6% skonto instead of 2%, and we accept this. Then we can still calculate
 960 the relative skonto amounts for different taxes based on the absolute
 961 percentages. Used for case C<difference_as_skonto>.
 962
 963 =item C<skonto_percent_abs>
 964
 965 The absolute percentage of that skonto chart in relation to the total amount.
 966 Used to calculate skonto_amount for case C<with_skonto_pt>.
 967
 968 =back
 969
 970 If the invoice contains several types of taxes then skonto_charts can be used
 971 to calculate the relative amounts.
 972
 973 Example in console of an invoice with 100 Euro at 7% and 100 Euro at 19% with
 974 tax not included:
 975
 976   my $invoice = invoice(invnumber => '144');
 977   $invoice->amount
 978   226.00000
 979   $invoice->payment_terms->percent_skonto
 980   0.02
 981   $invoice->skonto_charts
 982   pp $invoice->skonto_charts
 983   #             $VAR1 = {
 984   #               'chart_id'       => 128,
 985   #               'skonto_amount'  => '2.14',
 986   #               'skonto_percent' => '47.3451327433627'
 987   #             };
 988   #             $VAR2 = {
 989   #               'chart_id'       => 130,
 990   #               'skonto_amount'  => '2.38',
 991   #               'skonto_percent' => '52.654867256637'
 992   #             };
 993
 994 C<skonto_charts> always returns positive values (abs) for C<skonto_amount> and
 995 C<skonto_percent>.
 996
 997 C<skonto_charts> generates one entry for each acc_trans entry. ar and ap
 998 bookings only have one acc_trans entry for each taxkey (e.g. 7% and 19%).  This
 999 is because all the items are grouped according to the Buchungsgruppen mechanism
1000 and the totals are written to acc_trans.  For is and ir it is possible to have
1001 several acc_trans entries with the same tax. In this case skonto_charts
1002 generates a skonto booking for each acc_trans income/expense entry.
1003
1004 In the future this function may also be used to calculate the corrections for
1005 the income tax.
1006
1007 =item C<open_amount>
1008
1009 Unrounded total open amount of invoice (amount - paid).
1010 Doesn't take into account pending SEPA transfers.
1011
1012 =item C<open_percent>
1013
1014 Percentage of the invoice that is still unpaid, e.g. 100,00 if no payments have
1015 been made yet, 0,00 if fully paid.
1016
1017 =item C<remaining_skonto_days>
1018
1019 How many days skonto can still be taken, calculated from current day. Returns 0
1020 if current day is the max skonto date, and negative number if skonto date has
1021 already passed.
1022
1023 Returns undef if skonto is not configured for that invoice.
1024
1025 =item C<get_payment_suggestions %params>
1026
1027 Creates data intended for an L.select_tag dropdown that can be used in a
1028 template. Depending on the rules it will choose from the options
1029 without_skonto, with_skonto_pt and difference_as_skonto, and select the most
1030 likely one.
1031
1032 If the parameter "sepa" is passed, the SEPA export payments that haven't been
1033 executed yet are considered when determining the open amount of the invoice.
1034
1035 The current rules are:
1036
1037 =over 2
1038
1039 =item * without_skonto is always an option
1040
1041 =item * with_skonto_pt is only offered if there haven't been any payments yet and the current date is within the skonto period.
1042
1043 =item * difference_as_skonto is only offered if there have already been payments made and the open amount is smaller than 10% of the total amount.
1044
1045 with_skonto_pt will only be offered, if all the AR_amount/AP_amount have a
1046 taxkey with a configured skonto chart
1047
1048 =back
1049
1050 It will also fill $self->{invoice_amount_suggestion} with either the open
1051 amount, or if with_skonto_pt is selected, with amount_less_skonto, so the
1052 template can fill the input with the likely amount.
1053
1054 Example in console:
1055   my $ar = invoice( invnumber => '257');
1056   $ar->get_payment_suggestions;
1057   print $ar->{invoice_amount_suggestion} . "\n";
1058   # 97.23
1059   pp $ar->{payment_select_options}
1060   # $VAR1 = [
1061   #         {
1062   #           'display' => 'ohne Skonto',
1063   #           'payment_type' => 'without_skonto'
1064   #         },
1065   #         {
1066   #           'display' => 'mit Skonto nach ZB',
1067   #           'payment_type' => 'with_skonto_pt',
1068   #           'selected' => 1
1069   #         }
1070   #       ];
1071
1072 The resulting array $ar->{payment_select_options} can be used in a template
1073 select_tag using value_key and title_key:
1074
1075 [% L.select_tag('payment_type_' _ loop.count, invoice.payment_select_options, value_key => 'payment_type', title_key => 'display', id => 'payment_type_' _ loop.count) %]
1076
1077 It would probably make sense to have different rules for the pre-selected items
1078 for sales and purchase, and to also make these rules configurable in the
1079 defaults. E.g. when creating a SEPA bank transfer for vendor invoices a company
1080 might always want to pay quickly making use of skonto, while another company
1081 might always want to pay as late as possible.
1082
1083 =item C<get_payment_select_options_for_bank_transaction $banktransaction_id %params>
1084
1085 Make suggestion for a skonto payment type by returning an HTML blob of the options
1086 of a HTML drop-down select with the most likely option preselected.
1087
1088 This is a helper function for BankTransaction/ajax_payment_suggestion and
1089 template/webpages/bank_transactions/invoices.html
1090
1091 We are working with an existing payment, so difference_as_skonto never makes sense.
1092
1093 If skonto is not possible (skonto_date does not exists) simply return
1094 the single 'no skonto' option as a visual hint.
1095
1096 If skonto is possible (skonto_date exists), add two possibilities:
1097 without_skonto and with_skonto_pt if payment date is within skonto_date,
1098 preselect with_skonto_pt, otherwise preselect without skonto.
1099
1100 =item C<exchangerate>
1101
1102 Returns 1 immediately if the record uses the default currency.
1103
1104 Returns the exchangerate in database format for the invoice according to that
1105 invoice's transdate, returning 'buy' for sales, 'sell' for purchases.
1106
1107 If no exchangerate can be found for that day undef is returned.
1108
1109 =item C<forex>
1110
1111 Returns 1 if record uses a different currency, 0 if the default currency is used.
1112
1113 =back
1114
1115 =head1 TODO AND CAVEATS
1116
1117 =over 4
1118
1119 =item *
1120
1121 when looking at open amount, maybe consider that there may already be queued
1122 amounts in SEPA Export
1123
1124 =item * C<skonto_charts>
1125
1126 Cannot handle negative skonto amounts, will always calculate the skonto amount
1127 for credit notes or negative ap transactions with a positive sign.
1128
1129
1130 =back
1131
1132 =head1 AUTHOR
1133
1134 G. Richardson E<lt>grichardson@kivitendo-premium.de<gt>
1135
1136 =cut