SL/DB/Helper/Payment.pm

   1 package SL::DB::Helper::Payment;
   2
   3 use strict;
   4
   5 use parent qw(Exporter);
   6 our @EXPORT = qw(pay_invoice);
   7 our @EXPORT_OK = qw(skonto_date skonto_charts amount_less_skonto within_skonto_period percent_skonto reference_account reference_amount open_amount open_percent remaining_skonto_days skonto_amount check_skonto_configuration valid_skonto_amount get_payment_suggestions validate_payment_type open_sepa_transfer_amount get_payment_select_options_for_bank_transaction exchangerate forex);
   8 our %EXPORT_TAGS = (
   9   "ALL" => [@EXPORT, @EXPORT_OK],
  10 );
  11
  12 require SL::DB::Chart;
  13 use Data::Dumper;
  14 use DateTime;
  15 use SL::DATEV qw(:CONSTANTS);
  16 use SL::Locale::String qw(t8);
  17 use List::Util qw(sum);
  18 use SL::DB::Exchangerate;
  19 use SL::DB::Currency;
  20 use Carp;
  21
  22 #
  23 # Public functions not exported by default
  24 #
  25
  26 sub pay_invoice {
  27   my ($self, %params) = @_;
  28
  29   require SL::DB::Tax;
  30
  31   my $is_sales = ref($self) eq 'SL::DB::Invoice';
  32   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign depending on ar/ap
  33
  34   my $paid_amount = 0; # the amount that will be later added to $self->paid, should be in default currency
  35
  36   # default values if not set
  37   $params{payment_type} = 'without_skonto' unless $params{payment_type};
  38   validate_payment_type($params{payment_type});
  39
  40   # check for required parameters
  41   Common::check_params(\%params, qw(chart_id transdate));
  42
  43   my $transdate_obj;
  44   if (ref($params{transdate} eq 'DateTime')) {
  45     $transdate_obj = $params{transdate};
  46   } else {
  47    $transdate_obj = $::locale->parse_date_to_object($params{transdate});
  48   };
  49   croak t8('Illegal date') unless ref $transdate_obj;
  50
  51   # check for closed period
  52   my $closedto = $::locale->parse_date_to_object($::instance_conf->get_closedto);
  53   if ( ref $closedto && $transdate_obj < $closedto ) {
  54     croak t8('Cannot post payment for a closed period!');
  55   };
  56
  57   # check for maximum number of future days
  58   if ( $::instance_conf->get_max_future_booking_interval > 0 ) {
  59     croak t8('Cannot post transaction above the maximum future booking date!') if $transdate_obj > DateTime->now->add( days => $::instance_conf->get_max_future_booking_interval );
  60   };
  61
  62   # currency is either passed or use the invoice currency if it differs from the default currency
  63   my ($exchangerate,$currency);
  64   if ($params{currency} || $params{currency_id} || $self->currency_id != $::instance_conf->get_currency_id) {
  65     if ($params{currency} || $params{currency_id} ) { # currency was specified
  66       $currency = SL::DB::Manager::Currency->find_by(name => $params{currency}) || SL::DB::Manager::Currency->find_by(id => $params{currency_id});
  67     } else { # use invoice currency
  68       $currency = SL::DB::Manager::Currency->find_by(id => $self->currency_id);
  69     };
  70     die "no currency" unless $currency;
  71     if ($currency->id == $::instance_conf->get_currency_id) {
  72       $exchangerate = 1;
  73     } else {
  74       my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $currency->id,
  75                                                         transdate   => $transdate_obj,
  76                                                        );
  77       if ($rate) {
  78         $exchangerate = $is_sales ? $rate->buy : $rate->sell;
  79       } else {
  80         die "No exchange rate for " . $transdate_obj->to_kivitendo;
  81       };
  82     };
  83   } else { # no currency param given or currency is the same as default_currency
  84     $exchangerate = 1;
  85   };
  86
  87   # input checks:
  88   if ( $params{'payment_type'} eq 'without_skonto' ) {
  89     croak "invalid amount for payment_type 'without_skonto': $params{'amount'}\n" unless abs($params{'amount'}) > 0;
  90   };
  91
  92   # options with_skonto_pt and difference_as_skonto don't require the parameter
  93   # amount, but if amount is passed, make sure it matches the expected value
  94   if ( $params{'payment_type'} eq 'difference_as_skonto' ) {
  95     croak "amount $params{amount} doesn't match open amount " . $self->open_amount . ", diff = " . ($params{amount}-$self->open_amount) if $params{amount} && abs($self->open_amount - $params{amount} ) > 0.0000001;
  96   } elsif ( $params{'payment_type'} eq 'with_skonto_pt' ) {
  97     croak "amount $params{amount} doesn't match amount less skonto: " . $self->amount_less_skonto . "\n" if $params{amount} && abs($self->amount_less_skonto - $params{amount} ) > 0.0000001;
  98     croak "payment type with_skonto_pt can't be used if payments have already been made" if $self->paid != 0;
  99   };
 100
 101   # absolute skonto amount for invoice, use as reference sum to see if the
 102   # calculated skontos add up
 103   # only needed for payment_term "with_skonto_pt"
 104
 105   my $skonto_amount_check = $self->skonto_amount; # variable should be zero after calculating all skonto
 106   my $total_open_amount   = $self->open_amount;
 107
 108   # account where money is paid to/from: bank account or cash
 109   my $account_bank = SL::DB::Manager::Chart->find_by(id => $params{chart_id});
 110   croak "can't find bank account" unless ref $account_bank;
 111
 112   my $reference_account = $self->reference_account;
 113   croak "can't find reference account (link = AR/AP) for invoice" unless ref $reference_account;
 114
 115   my $memo   = $params{memo}   // '';
 116   my $source = $params{source} // '';
 117
 118   my $rounded_params_amount = _round( $params{amount} ); # / $exchangerate);
 119   my $fx_gain_loss_amount = 0; # for fx_gain and fx_loss
 120
 121   my $db = $self->db;
 122   $db->with_transaction(sub {
 123     my $new_acc_trans;
 124
 125     # all three payment type create 1 AR/AP booking (the paid part)
 126     # difference_as_skonto creates n skonto bookings (1 for each tax type)
 127     # with_skonto_pt creates 1 bank booking and n skonto bookings (1 for each tax type)
 128     # without_skonto creates 1 bank booking
 129
 130     # as long as there is no automatic tax, payments are always booked with
 131     # taxkey 0
 132
 133     unless ( $params{payment_type} eq 'difference_as_skonto' ) {
 134       # cases with_skonto_pt and without_skonto
 135
 136       # for case with_skonto_pt we need to know the corrected amount at this
 137       # stage if we are going to use $params{amount}
 138
 139       my $pay_amount = $rounded_params_amount;
 140       $pay_amount = $self->amount_less_skonto if $params{payment_type} eq 'with_skonto_pt';
 141
 142       # bank account and AR/AP
 143       $paid_amount += $pay_amount * $exchangerate;
 144
 145       my $amount = (-1 * $pay_amount) * $mult;
 146
 147
 148       # total amount against bank, do we already know this by now?
 149       $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 150                                                    chart_id   => $account_bank->id,
 151                                                    chart_link => $account_bank->link,
 152                                                    amount     => $amount,
 153                                                    transdate  => $transdate_obj,
 154                                                    source     => $source,
 155                                                    memo       => $memo,
 156                                                    project_id => $params{project_id} ? $params{project_id} : undef,
 157                                                    taxkey     => 0,
 158                                                    tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 159       $new_acc_trans->save;
 160
 161       # deal with fxtransaction
 162       if ( $self->currency_id != $::instance_conf->get_currency_id ) {
 163         my $fxamount = _round($amount - ($amount * $exchangerate));
 164         $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 165                                                      chart_id       => $account_bank->id,
 166                                                      chart_link     => $account_bank->link,
 167                                                      amount         => $fxamount * -1,
 168                                                      transdate      => $transdate_obj,
 169                                                      source         => $source,
 170                                                      memo           => $memo,
 171                                                      taxkey         => 0,
 172                                                      fx_transaction => 1,
 173                                                      tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 174         $new_acc_trans->save;
 175         # if invoice exchangerate differs from exchangerate of payment
 176         # deal with fxloss and fxamount
 177         if ($self->exchangerate and $self->exchangerate != 1 and $self->exchangerate != $exchangerate) {
 178           my $fxgain_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxgain_accno_id) || die "Can't determine fxgain chart";
 179           my $fxloss_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxloss_accno_id) || die "Can't determine fxloss chart";
 180           my $gain_loss_amount = _round($amount * ($exchangerate - $self->exchangerate ) * -1,2);
 181           my $gain_loss_chart = $gain_loss_amount > 0 ? $fxgain_chart : $fxloss_chart;
 182           $fx_gain_loss_amount = $gain_loss_amount;
 183
 184           $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 185                                                        chart_id       => $gain_loss_chart->id,
 186                                                        chart_link     => $gain_loss_chart->link,
 187                                                        amount         => $gain_loss_amount,
 188                                                        transdate      => $transdate_obj,
 189                                                        source         => $source,
 190                                                        memo           => $memo,
 191                                                        taxkey         => 0,
 192                                                        fx_transaction => 0,
 193                                                        tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 194           $new_acc_trans->save;
 195
 196         };
 197       };
 198     };
 199
 200     if ( $params{payment_type} eq 'difference_as_skonto' or $params{payment_type} eq 'with_skonto_pt' ) {
 201
 202       my $total_skonto_amount;
 203       if ( $params{payment_type} eq 'with_skonto_pt' ) {
 204         $total_skonto_amount = $self->skonto_amount;
 205       } elsif ( $params{payment_type} eq 'difference_as_skonto' ) {
 206         $total_skonto_amount = $self->open_amount;
 207       };
 208
 209       my @skonto_bookings = $self->skonto_charts($total_skonto_amount);
 210
 211       # error checking:
 212       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 213         my $calculated_skonto_sum  = sum map { $_->{skonto_amount} } @skonto_bookings;
 214         croak "calculated skonto for difference_as_skonto = $calculated_skonto_sum doesn't add up open amount: " . $self->open_amount unless _round($calculated_skonto_sum) == _round($self->open_amount);
 215       };
 216
 217       my $reference_amount = $total_skonto_amount;
 218
 219       # create an acc_trans entry for each result of $self->skonto_charts
 220       foreach my $skonto_booking ( @skonto_bookings ) {
 221         next unless $skonto_booking->{'chart_id'};
 222         next unless $skonto_booking->{'skonto_amount'} != 0;
 223         my $amount = -1 * $skonto_booking->{skonto_amount};
 224         $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 225                                                      chart_id   => $skonto_booking->{'chart_id'},
 226                                                      chart_link => SL::DB::Manager::Chart->find_by(id => $skonto_booking->{'chart_id'})->link,
 227                                                      amount     => $amount * $mult,
 228                                                      transdate  => $transdate_obj,
 229                                                      source     => $params{source},
 230                                                      taxkey     => 0,
 231                                                      tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 232
 233         # the acc_trans entries are saved individually, not added to $self and then saved all at once
 234         $new_acc_trans->save;
 235
 236         $reference_amount -= abs($amount);
 237         $paid_amount      += -1 * $amount * $exchangerate;
 238         $skonto_amount_check -= $skonto_booking->{'skonto_amount'};
 239       };
 240       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 241           die "difference_as_skonto calculated incorrectly, sum of calculated payments doesn't add up to open amount $total_open_amount, reference_amount = $reference_amount\n" unless _round($reference_amount) == 0;
 242       }
 243
 244     };
 245
 246     my $arap_amount = 0;
 247
 248     if ( $params{payment_type} eq 'difference_as_skonto' ) {
 249       $arap_amount = $total_open_amount;
 250     } elsif ( $params{payment_type} eq 'without_skonto' ) {
 251       $arap_amount = $rounded_params_amount;
 252     } elsif ( $params{payment_type} eq 'with_skonto_pt' ) {
 253       # this should be amount + sum(amount+skonto), but while we only allow
 254       # with_skonto_pt for completely unpaid invoices we just use the value
 255       # from the invoice
 256       $arap_amount = $total_open_amount;
 257     };
 258
 259     # regardless of payment_type there is always only exactly one arap booking
 260     # TODO: compare $arap_amount to running total
 261     my $arap_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 262                                                   chart_id   => $reference_account->id,
 263                                                   chart_link => $reference_account->link,
 264                                                   amount     => _round($arap_amount * $mult * $exchangerate - $fx_gain_loss_amount),
 265                                                   transdate  => $transdate_obj,
 266                                                   source     => '', #$params{source},
 267                                                   taxkey     => 0,
 268                                                   tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 269     $arap_booking->save;
 270
 271     $fx_gain_loss_amount *= -1 if $self->is_sales;
 272     $self->paid($self->paid + _round($paid_amount) + $fx_gain_loss_amount) if $paid_amount;
 273     $self->datepaid($transdate_obj);
 274     $self->save;
 275
 276     # make sure transactions will be reloaded the next time $self->transactions
 277     # is called, as pay_invoice saves the acc_trans objects individually rather
 278     # than adding them to the transaction relation array.
 279     $self->forget_related('transactions');
 280
 281     my $datev_check = 0;
 282     if ( $is_sales )  {
 283       if ( (  $self->invoice && $::instance_conf->get_datev_check_on_sales_invoice  ) ||
 284            ( !$self->invoice && $::instance_conf->get_datev_check_on_ar_transaction )) {
 285         $datev_check = 1;
 286       }
 287     } else {
 288       if ( (  $self->invoice && $::instance_conf->get_datev_check_on_purchase_invoice ) ||
 289            ( !$self->invoice && $::instance_conf->get_datev_check_on_ap_transaction   )) {
 290         $datev_check = 1;
 291       }
 292     }
 293
 294     if ( $datev_check ) {
 295
 296       my $datev = SL::DATEV->new(
 297         dbh        => $db->dbh,
 298         trans_id   => $self->{id},
 299       );
 300
 301       $datev->generate_datev_data;
 302
 303       if ($datev->errors) {
 304         # this exception should be caught by with_transaction, which handles the rollback
 305         die join "\n", $::locale->text('DATEV check returned errors:'), $datev->errors;
 306       }
 307     }
 308
 309     1;
 310
 311   }) || die t8('error while paying invoice #1 : ', $self->invnumber) . $db->error . "\n";
 312
 313   return 1;
 314 };
 315
 316 sub skonto_date {
 317
 318   my $self = shift;
 319
 320   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 321
 322   my $skonto_date;
 323
 324   if ( $is_sales ) {
 325     return undef unless ref $self->payment_terms;
 326     return undef unless $self->payment_terms->terms_skonto > 0;
 327     $skonto_date = DateTime->from_object(object => $self->transdate)->add(days => $self->payment_terms->terms_skonto);
 328   } else {
 329     return undef unless ref $self->vendor->payment_terms;
 330     return undef unless $self->vendor->payment_terms->terms_skonto > 0;
 331     $skonto_date = DateTime->from_object(object => $self->transdate)->add(days => $self->vendor->payment_terms->terms_skonto);
 332   };
 333
 334   return $skonto_date;
 335 };
 336
 337 sub reference_account {
 338   my $self = shift;
 339
 340   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 341
 342   require SL::DB::Manager::AccTransaction;
 343
 344   my $link_filter = $is_sales ? 'AR' : 'AP';
 345
 346   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 347      trans_id   => $self->id,
 348      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 349   );
 350
 351   return undef unless ref $acc_trans;
 352
 353   my $reference_account = SL::DB::Manager::Chart->find_by(id => $acc_trans->chart_id);
 354
 355   return $reference_account;
 356 };
 357
 358 sub reference_amount {
 359   my $self = shift;
 360
 361   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 362
 363   require SL::DB::Manager::AccTransaction;
 364
 365   my $link_filter = $is_sales ? 'AR' : 'AP';
 366
 367   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 368      trans_id   => $self->id,
 369      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 370   );
 371
 372   return undef unless ref $acc_trans;
 373
 374   # this should be the same as $self->amount
 375   return $acc_trans->amount;
 376 };
 377
 378
 379 sub open_amount {
 380   my $self = shift;
 381
 382   # in the future maybe calculate this from acc_trans
 383
 384   # if the difference is 0.01 Cent this may end up as 0.009999999999998
 385   # numerically, so round this value when checking for cent threshold >= 0.01
 386
 387   return ($self->amount // 0) - ($self->paid // 0);
 388 };
 389
 390 sub open_percent {
 391   my $self = shift;
 392
 393   return 0 if $self->amount == 0;
 394   my $open_percent;
 395   if ( $self->open_amount < 0 ) {
 396     # overpaid, currently treated identically
 397     $open_percent = $self->open_amount * 100 / $self->amount;
 398   } else {
 399     $open_percent = $self->open_amount * 100 / $self->amount;
 400   };
 401
 402   return _round($open_percent) || 0;
 403 };
 404
 405 sub skonto_amount {
 406   my $self = shift;
 407
 408   return $self->amount - $self->amount_less_skonto;
 409 };
 410
 411 sub remaining_skonto_days {
 412   my $self = shift;
 413
 414   return undef unless ref $self->skonto_date;
 415
 416   my $dur = DateTime::Duration->new($self->skonto_date - DateTime->today);
 417   return $dur->delta_days();
 418
 419 };
 420
 421 sub percent_skonto {
 422   my $self = shift;
 423
 424   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 425
 426   my $percent_skonto = 0;
 427
 428   if ( $is_sales ) {
 429     return undef unless ref $self->payment_terms;
 430     return undef unless $self->payment_terms->percent_skonto > 0;
 431     $percent_skonto = $self->payment_terms->percent_skonto;
 432   } else {
 433     return undef unless ref $self->vendor->payment_terms;
 434     return undef unless $self->vendor->payment_terms->terms_skonto > 0;
 435     $percent_skonto = $self->vendor->payment_terms->percent_skonto;
 436   };
 437
 438   return $percent_skonto;
 439 };
 440
 441 sub amount_less_skonto {
 442   # amount that has to be paid if skonto applies, always return positive rounded values
 443   # the result is rounded so we can directly compare it with the user input
 444   my $self = shift;
 445
 446   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 447
 448   my $percent_skonto = $self->percent_skonto || 0;
 449
 450   return _round($self->amount - ( $self->amount * $percent_skonto) );
 451
 452 };
 453
 454 sub check_skonto_configuration {
 455   my $self = shift;
 456
 457   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 458
 459   my $skonto_configured = 1; # default is assume skonto works
 460
 461   # my $transactions = $self->transactions;
 462   foreach my $transaction (@{ $self->transactions }) {
 463     # find all transactions with an AR_amount or AP_amount link
 464     my $tax = SL::DB::Manager::Tax->get_first( where => [taxkey => $transaction->taxkey]);
 465     croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 466
 467     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->chart_link) };
 468     if ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) {
 469       $skonto_configured = 0 unless $tax->skonto_sales_chart_id;
 470     } elsif ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) {
 471       $skonto_configured = 0 unless $tax->skonto_purchase_chart_id;
 472     };
 473   };
 474
 475   return $skonto_configured;
 476 };
 477
 478 sub open_sepa_transfer_amount {
 479   my $self = shift;
 480
 481   my ($vc, $key, $type);
 482   if ( ref($self) eq 'SL::DB::Invoice' ) {
 483     $vc   = 'customer';
 484     $key  = 'ap_id';
 485     $type = 'ar';
 486   } else {
 487     $vc   = 'vendor';
 488     $key  = 'ap_id';
 489     $type = 'ap';
 490   };
 491
 492   my $sql = qq|SELECT SUM(sei.amount) AS amount FROM sepa_export_items sei | .
 493             qq| LEFT JOIN sepa_export se ON (sei.sepa_export_id = se.id)   | .
 494             qq| WHERE $key = ? AND NOT se.closed AND (se.vc = '$vc')       |;
 495
 496   my ($open_sepa_amount) = $self->db->dbh->selectrow_array($sql, undef, $self->id);
 497
 498   return $open_sepa_amount || 0;
 499
 500 };
 501
 502
 503 sub skonto_charts {
 504   my $self = shift;
 505
 506   # TODO: use param for amount, may also want to calculate skonto_amounts by
 507   # passing percentage in the future
 508
 509   my $amount = shift || $self->skonto_amount;
 510
 511   croak "no amount passed to skonto_charts" unless abs(_round($amount)) >= 0.01;
 512
 513   # TODO: check whether there are negative values in invoice / acc_trans ... credited items
 514
 515   # don't check whether skonto applies, because user may want to override this
 516   # return undef unless $self->percent_skonto;  # for is_sales
 517   # return undef unless $self->vendor->payment_terms->percent_skonto;  # for purchase
 518
 519   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 520
 521   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign
 522
 523   my @skonto_charts;  # resulting array with all income/expense accounts that have to be corrected
 524
 525   # calculate effective skonto (percentage) in difference_as_skonto mode
 526   # only works if there are no negative acc_trans values
 527   my $effective_skonto_rate = $amount ? $amount / $self->amount : 0;
 528
 529   # checks:
 530   my $total_skonto_amount  = 0;
 531   my $total_rounding_error = 0;
 532
 533   my $reference_ARAP_amount = 0;
 534
 535   # my $transactions = $self->transactions;
 536   foreach my $transaction (@{ $self->transactions }) {
 537     # find all transactions with an AR_amount or AP_amount link
 538     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->{chart_link}) };
 539     # second condition is that we can determine an automatic Skonto account for each AR_amount entry
 540
 541     if ( ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) or ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) ) {
 542         # $reference_ARAP_amount += $transaction->{amount} * $mult;
 543
 544         # quick hack that works around problem of non-unique tax keys in SKR04
 545         my $tax = SL::DB::Manager::Tax->get_first( where => [taxkey => $transaction->{taxkey}]);
 546         croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 547
 548         if ( $is_sales ) {
 549           die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $transaction->{taxkey} , $tax->taxdescription , $tax->rate*100) unless ref $tax->skonto_sales_chart;
 550         } else {
 551           die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $transaction->{taxkey} , $tax->taxdescription , $tax->rate*100) unless ref $tax->skonto_purchase_chart;
 552         };
 553
 554         my $skonto_amount_unrounded;
 555
 556         my $skonto_percent_abs = $self->amount ? abs($transaction->amount * (1 + $tax->rate) * 100 / $self->amount) : 0;
 557
 558         my $transaction_amount = abs($transaction->{amount} * (1 + $tax->rate));
 559         my $transaction_skonto_percent = abs($transaction_amount/$self->amount); # abs($transaction->{amount} * (1 + $tax->rate));
 560
 561
 562         $skonto_amount_unrounded   = abs($amount * $transaction_skonto_percent);
 563         my $skonto_amount_rounded  = _round($skonto_amount_unrounded);
 564         my $rounding_error         = $skonto_amount_unrounded - $skonto_amount_rounded;
 565         my $rounded_rounding_error = _round($rounding_error);
 566
 567         $total_rounding_error += $rounding_error;
 568         $total_skonto_amount  += $skonto_amount_rounded;
 569
 570         my $rec = {
 571           # skonto_percent_abs: relative part of amount + tax to the total invoice amount
 572           'skonto_percent_abs'     => $skonto_percent_abs,
 573           'chart_id'               => $is_sales ? $tax->skonto_sales_chart->id : $tax->skonto_purchase_chart->id,
 574           'skonto_amount'          => $skonto_amount_rounded,
 575           # 'rounding_error'         => $rounding_error,
 576           # 'rounded_rounding_error' => $rounded_rounding_error,
 577         };
 578
 579         push @skonto_charts, $rec;
 580       };
 581   };
 582
 583   # if the rounded sum of all rounding_errors reaches 0.01 this sum is
 584   # subtracted from the largest skonto_amount
 585   my $rounded_total_rounding_error = abs(_round($total_rounding_error));
 586
 587   if ( $rounded_total_rounding_error > 0 ) {
 588     my $highest_amount_pos = 0;
 589     my $highest_amount = 0;
 590     my $i = -1;
 591     foreach my $ref ( @skonto_charts ) {
 592       $i++;
 593       if ( $ref->{skonto_amount} > $highest_amount ) {
 594         $highest_amount     = $ref->{skonto_amount};
 595         $highest_amount_pos = $i;
 596       };
 597     };
 598     $skonto_charts[$i]->{skonto_amount} -= $rounded_total_rounding_error;
 599   };
 600
 601   return @skonto_charts;
 602 };
 603
 604
 605 sub within_skonto_period {
 606   my $self = shift;
 607   my $dateref = shift || DateTime->now->truncate( to => 'day' );
 608
 609   return undef unless ref $dateref eq 'DateTime';
 610   return 0 unless $self->skonto_date;
 611
 612   # return 1 if requested date (or today) is inside skonto period
 613   # this will also return 1 if date is before the invoice date
 614   return $dateref <= $self->skonto_date;
 615 };
 616
 617 sub valid_skonto_amount {
 618   my $self = shift;
 619   my $amount = shift || 0;
 620   my $max_skonto_percent = 0.10;
 621
 622   return 0 unless $amount > 0;
 623
 624   # does this work for other currencies?
 625   return ($self->amount*$max_skonto_percent) > $amount;
 626 };
 627
 628 sub get_payment_select_options_for_bank_transaction {
 629   my ($self, $bt_id, %params) = @_;
 630
 631   my $bt = SL::DB::Manager::BankTransaction->find_by( id => $bt_id );
 632   die unless $bt;
 633
 634   my $open_amount = $self->open_amount;
 635   #$main::lxdebug->message(LXDebug->DEBUG2(),"skonto_date=".$self->skonto_date." open amount=".$open_amount);
 636   my @options;
 637   if ( $open_amount &&                   # invoice amount not 0
 638        $self->skonto_date &&             # check whether skonto applies
 639        ( abs(abs($self->amount_less_skonto) - abs($bt->amount)) < 0.01 ||
 640         ( $bt->transaction_code eq "191" && abs($self->amount_less_skonto) < abs($bt->amount) )) &&
 641        $self->check_skonto_configuration) {
 642          if ( $self->within_skonto_period($bt->transdate) ) {
 643            push(@options, { payment_type => 'without_skonto', display => t8('without skonto') });
 644            push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt'), selected => 1 });
 645          } else {
 646            push(@options, { payment_type => 'without_skonto', display => t8('without skonto') , selected => 1 });
 647            push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt')});
 648          };
 649   };
 650
 651   return @options;
 652
 653 };
 654
 655 sub exchangerate {
 656   my ($self) = @_;
 657
 658   return 1 if $self->currency_id == $::instance_conf->get_currency_id;
 659
 660   die "transdate isn't a DateTime object:" . ref($self->transdate) unless ref($self->transdate) eq 'DateTime';
 661   my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $self->currency_id,
 662                                                     transdate   => $self->transdate,
 663                                                    );
 664   return undef unless $rate;
 665
 666   return $self->is_sales ? $rate->buy : $rate->sell; # also undef if not defined
 667 };
 668
 669 sub get_payment_suggestions {
 670
 671   my ($self, %params) = @_;
 672
 673   my $open_amount = $self->open_amount;
 674   $open_amount   -= $self->open_sepa_transfer_amount if $params{sepa};
 675
 676   $self->{invoice_amount_suggestion} = $open_amount;
 677   undef $self->{payment_select_options};
 678   push(@{$self->{payment_select_options}} , { payment_type => 'without_skonto',  display => t8('without skonto') });
 679   if ( $self->within_skonto_period ) {
 680     # If there have been no payments yet suggest amount_less_skonto, otherwise the open amount
 681     if ( $open_amount &&                   # invoice amount not 0
 682          $open_amount == $self->amount &&  # no payments yet, or sum of payments and sepa export amounts is zero
 683          $self->check_skonto_configuration) {
 684       $self->{invoice_amount_suggestion} = $self->amount_less_skonto;
 685       push(@{$self->{payment_select_options}} , { payment_type => 'with_skonto_pt',  display => t8('with skonto acc. to pt') , selected => 1 });
 686     } else {
 687       if ( ( $self->valid_skonto_amount($self->open_amount) || $self->valid_skonto_amount($open_amount) ) and not $params{sepa} ) {
 688         $self->{invoice_amount_suggestion} = $open_amount;
 689         # only suggest difference_as_skonto if open_amount exactly matches skonto_amount
 690         # AND we aren't in SEPA mode
 691         my $selected = 0;
 692         $selected = 1 if _round($open_amount) == _round($self->skonto_amount);
 693         push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => $selected });
 694       };
 695     };
 696   } else {
 697     # invoice was configured with skonto, but skonto date has passed, or no skonto available
 698     $self->{invoice_amount_suggestion} = $open_amount;
 699     # difference_as_skonto doesn't make any sense for SEPA transfer, as this doesn't cause any actual payment
 700     if ( $self->valid_skonto_amount($self->open_amount) && not $params{sepa} ) {
 701       push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => 0 });
 702     };
 703   };
 704   return 1;
 705 };
 706
 707 # locales for payment type
 708 #
 709 # $main::locale->text('without_skonto')
 710 # $main::locale->text('with_skonto_pt')
 711 # $main::locale->text('difference_as_skonto')
 712 #
 713
 714 sub validate_payment_type {
 715   my $payment_type = shift;
 716
 717   my %allowed_payment_types = map { $_ => 1 } qw(without_skonto with_skonto_pt difference_as_skonto);
 718   croak "illegal payment type: $payment_type, must be one of: " . join(' ', keys %allowed_payment_types) unless $allowed_payment_types{ $payment_type };
 719
 720   return 1;
 721 }
 722
 723 sub forex {
 724   my ($self) = @_;
 725   $self->currency_id == $::instance_conf->get_currency_id ? return 0 : return 1;
 726 };
 727
 728 sub _round {
 729   my $value = shift;
 730   my $num_dec = 2;
 731   return $::form->round_amount($value, 2);
 732 }
 733
 734 1;
 735
 736 __END__
 737
 738 =pod
 739
 740 =head1 NAME
 741
 742 SL::DB::Helper::Payment  Mixin providing helper methods for paying C<Invoice>
 743                          and C<PurchaseInvoice> objects and using skonto
 744
 745 =head1 SYNOPSIS
 746
 747 In addition to actually causing a payment via pay_invoice this helper contains
 748 many methods that help in determining information about the status of the
 749 invoice, such as the remaining open amount, whether skonto applies, until which
 750 date skonto applies, the skonto amount and relative percentages, what to do
 751 with skonto, ...
 752
 753 To prevent duplicate code this was all added in this mixin rather than directly
 754 in SL::DB::Invoice and SL::DB::PurchaseInvoice.
 755
 756 =over 4
 757
 758 =item C<pay_invoice %params>
 759
 760 Create a payment booking for an existing invoice object (type ar/ap/is/ir) via
 761 a configured bank account.
 762
 763 This function deals with all the acc_trans entries and also updates paid and datepaid.
 764
 765 Example:
 766
 767   my $ap   = SL::DB::Manager::PurchaseInvoice->find_by( invnumber => '1');
 768   my $bank = SL::DB::Manager::BankAccount->find_by( name => 'Bank');
 769   $ap->pay_invoice(chart_id      => $bank->chart_id,
 770                    amount        => $ap->open_amount,
 771                    transdate     => DateTime->now->to_kivitendo,
 772                    memo          => 'foobar',
 773                    source        => 'barfoo',
 774                    payment_type  => 'without_skonto',  # default if not specified
 775                    project_id    => 25,
 776                   );
 777
 778 or with skonto:
 779   $ap->pay_invoice(chart_id      => $bank->chart_id,
 780                    amount        => $ap->amount,       # doesn't need to be specified
 781                    transdate     => DateTime->now->to_kivitendo,
 782                    memo          => 'foobar',
 783                    source        => 'barfoo',
 784                    payment_type  => 'with_skonto',
 785                   );
 786
 787 or in a certain currency:
 788   $ap->pay_invoice(chart_id      => $bank->chart_id,
 789                    amount        => 500,
 790                    currency      => 'USD',
 791                    transdate     => DateTime->now->to_kivitendo,
 792                    memo          => 'foobar',
 793                    source        => 'barfoo',
 794                    payment_type  => 'with_skonto',
 795                   );
 796
 797 Allowed payment types are:
 798   without_skonto with_skonto_pt difference_as_skonto
 799
 800 The option C<payment_type> allows for a basic skonto mechanism.
 801
 802 C<without_skonto> is the default mode, "amount" is paid to the account in
 803 chart_id. This can also be used for partial payments and corrections via
 804 negative amounts.
 805
 806 C<with_skonto_pt> can't be used for partial payments. When used on unpaid
 807 invoices the whole amount is paid, with the skonto part automatically being
 808 booked according to the skonto chart configured in the tax settings for each
 809 tax key. If an amount is passed it is ignored and the actual configured skonto
 810 amount is used.
 811
 812 C<difference_as_skonto> can only be used after partial payments have been made,
 813 the whole specified amount is booked according to the skonto charts configured
 814 in the tax settings for each tax key.
 815
 816 So passing amount doesn't have any effect for the cases C<with_skonto_pt> and
 817 C<difference_as_skonto>, as all necessary values are taken from the stored
 818 invoice.
 819
 820 The skonto modes automatically calculate the relative amounts for a mix of
 821 taxes, e.g. items with 7% and 19% in one invoice. There is a helper method
 822 skonto_charts, which calculates the relative percentages according to the
 823 amounts in acc_trans (which are grouped by tax).
 824
 825 There is currently no way of excluding certain items in an invoice from having
 826 skonto applied to them.  If this feature was added to parts the calculation
 827 method of relative skonto would have to be completely rewritten using the
 828 invoice items rather than acc_trans.
 829
 830 The skonto modes also still don't automatically correct the tax, this still has
 831 to be done manually. Therefore all payments generated by pay_invoice have
 832 taxkey 0.
 833
 834 There is currently no way to directly pay an invoice via this method if the
 835 effective skonto differs from the skonto according to the payment terms
 836 configured for the invoice/vendor.
 837
 838 In this case one has to pay in two steps: first the actual paid amount via
 839 "without skonto", and then the remainder via "difference_as_skonto". The user
 840 has to there actively decide whether to accept the differing skonto.
 841
 842 Because of the way skonto_charts works the calculation doesn't work if there
 843 are negative values in acc_trans. E.g. one invoice with a positive value for
 844 19% tax and a negative value for the acc_trans line with 7%
 845
 846 Skonto doesn't/shouldn't apply if the invoice contains credited items.
 847
 848 If no amount is given the whole open amout is paid.
 849
 850 If neither currency or currency_id are given as params, the currency of the
 851 invoice is assumed to be the payment currency.
 852
 853 =item C<reference_account>
 854
 855 Returns a chart object which is the chart of the invoice with link AR or AP.
 856
 857 Example (1200 is the AR account for SKR04):
 858   my $invoice = invoice(invnumber => '144');
 859   $invoice->reference_account->accno
 860   # 1200
 861
 862 =item C<percent_skonto>
 863
 864 Returns the configured skonto percentage of the payment terms of an invoice,
 865 e.g. 0.02 for 2%. Payment terms come from invoice settings for ar, from vendor
 866 settings for ap.
 867
 868 =item C<amount_less_skonto>
 869
 870 If the invoice has a payment term (via ar for sales, via vendor for purchase),
 871 calculate the amount to be paid in the case of skonto.  This doesn't check,
 872 whether skonto applies (i.e. skonto doesn't wasn't exceeded), it just subtracts
 873 the configured percentage (e.g. 2%) from the total amount.
 874
 875 The returned value is rounded to two decimals.
 876
 877 =item C<skonto_date>
 878
 879 The date up to which skonto may be taken. This is calculated from the invoice
 880 date + the number of days configured in the payment terms.
 881
 882 This method can also be used to determine whether skonto applies for the
 883 invoice, as it returns undef if there is no payment term or skonto days is set
 884 to 0.
 885
 886 =item C<within_skonto_period [DATE]>
 887
 888 Returns 0 or 1.
 889
 890 Checks whether the invoice has payment terms configured, and whether the date
 891 is within the skonto max date. If no date is passed the current date is used.
 892
 893 You can also pass a dateref object as a parameter to check whether skonto
 894 applies for that date rather than the current date.
 895
 896 =item C<valid_skonto_amount>
 897
 898 Takes an amount as an argument and checks whether the amount is less than 10%
 899 of the total amount of the invoice. The value of 10% is currently hardcoded in
 900 the method. This method is currently used to check whether to offer the payment
 901 option "difference as skonto".
 902
 903 Example:
 904  if ( $invoice->valid_skonto_amount($invoice->open_amount) ) {
 905    # ... do something
 906  }
 907
 908 =item C<skonto_charts [$amount]>
 909
 910 Returns a list of chart_ids and some calculated numbers that can be used for
 911 paying the invoice with skonto. This function will automatically calculate the
 912 relative skonto amounts even if the invoice contains several types of taxes
 913 (e.g. 7% and 19%).
 914
 915 Example usage:
 916   my $invoice = SL::DB::Manager::Invoice->find_by(invnumber => '211');
 917   my @skonto_charts = $invoice->skonto_charts;
 918
 919 or with the total skonto amount as an argument:
 920   my @skonto_charts = $invoice->skonto_charts($invoice->open_amount);
 921
 922 The following values are generated for each chart:
 923
 924 =over 2
 925
 926 =item C<chart_id>
 927
 928 The chart id of the skonto amount to be booked.
 929
 930 =item C<skonto_amount>
 931
 932 The total amount to be paid to the account
 933
 934 =item C<skonto_percent>
 935
 936 The relative percentage of that skonto chart. This can be useful if the actual
 937 ekonto that is paid deviates from the granted skonto, e.g. customer effectively
 938 pays 2.6% skonto instead of 2%, and we accept this. Then we can still calculate
 939 the relative skonto amounts for different taxes based on the absolute
 940 percentages. Used for case C<difference_as_skonto>.
 941
 942 =item C<skonto_percent_abs>
 943
 944 The absolute percentage of that skonto chart in relation to the total amount.
 945 Used to calculate skonto_amount for case C<with_skonto_pt>.
 946
 947 =back
 948
 949 If the invoice contains several types of taxes then skonto_charts can be used
 950 to calculate the relative amounts.
 951
 952 Example in console of an invoice with 100 Euro at 7% and 100 Euro at 19% with
 953 tax not included:
 954
 955   my $invoice = invoice(invnumber => '144');
 956   $invoice->amount
 957   226.00000
 958   $invoice->payment_terms->percent_skonto
 959   0.02
 960   $invoice->skonto_charts
 961   pp $invoice->skonto_charts
 962   #             $VAR1 = {
 963   #               'chart_id'       => 128,
 964   #               'skonto_amount'  => '2.14',
 965   #               'skonto_percent' => '47.3451327433627'
 966   #             };
 967   #             $VAR2 = {
 968   #               'chart_id'       => 130,
 969   #               'skonto_amount'  => '2.38',
 970   #               'skonto_percent' => '52.654867256637'
 971   #             };
 972
 973 C<skonto_charts> always returns positive values (abs) for C<skonto_amount> and
 974 C<skonto_percent>.
 975
 976 C<skonto_charts> generates one entry for each acc_trans entry. ar and ap
 977 bookings only have one acc_trans entry for each taxkey (e.g. 7% and 19%).  This
 978 is because all the items are grouped according to the Buchungsgruppen mechanism
 979 and the totals are written to acc_trans.  For is and ir it is possible to have
 980 several acc_trans entries with the same tax. In this case skonto_charts
 981 generates a skonto booking for each acc_trans income/expense entry.
 982
 983 In the future this function may also be used to calculate the corrections for
 984 the income tax.
 985
 986 =item C<open_amount>
 987
 988 Unrounded total open amount of invoice (amount - paid).
 989 Doesn't take into account pending SEPA transfers.
 990
 991 =item C<open_percent>
 992
 993 Percentage of the invoice that is still unpaid, e.g. 100,00 if no payments have
 994 been made yet, 0,00 if fully paid.
 995
 996 =item C<remaining_skonto_days>
 997
 998 How many days skonto can still be taken, calculated from current day. Returns 0
 999 if current day is the max skonto date, and negative number if skonto date has
1000 already passed.
1001
1002 Returns undef if skonto is not configured for that invoice.
1003
1004 =item C<get_payment_suggestions %params>
1005
1006 Creates data intended for an L.select_tag dropdown that can be used in a
1007 template. Depending on the rules it will choose from the options
1008 without_skonto, with_skonto_pt and difference_as_skonto, and select the most
1009 likely one.
1010
1011 If the parameter "sepa" is passed, the SEPA export payments that haven't been
1012 executed yet are considered when determining the open amount of the invoice.
1013
1014 The current rules are:
1015
1016 =over 2
1017
1018 =item * without_skonto is always an option
1019
1020 =item * with_skonto_pt is only offered if there haven't been any payments yet and the current date is within the skonto period.
1021
1022 =item * difference_as_skonto is only offered if there have already been payments made and the open amount is smaller than 10% of the total amount.
1023
1024 with_skonto_pt will only be offered, if all the AR_amount/AP_amount have a
1025 taxkey with a configured skonto chart
1026
1027 =back
1028
1029 It will also fill $self->{invoice_amount_suggestion} with either the open
1030 amount, or if with_skonto_pt is selected, with amount_less_skonto, so the
1031 template can fill the input with the likely amount.
1032
1033 Example in console:
1034   my $ar = invoice( invnumber => '257');
1035   $ar->get_payment_suggestions;
1036   print $ar->{invoice_amount_suggestion} . "\n";
1037   # 97.23
1038   pp $ar->{payment_select_options}
1039   # $VAR1 = [
1040   #         {
1041   #           'display' => 'ohne Skonto',
1042   #           'payment_type' => 'without_skonto'
1043   #         },
1044   #         {
1045   #           'display' => 'mit Skonto nach ZB',
1046   #           'payment_type' => 'with_skonto_pt',
1047   #           'selected' => 1
1048   #         }
1049   #       ];
1050
1051 The resulting array $ar->{payment_select_options} can be used in a template
1052 select_tag using value_key and title_key:
1053
1054 [% L.select_tag('payment_type_' _ loop.count, invoice.payment_select_options, value_key => 'payment_type', title_key => 'display', id => 'payment_type_' _ loop.count) %]
1055
1056 It would probably make sense to have different rules for the pre-selected items
1057 for sales and purchase, and to also make these rules configurable in the
1058 defaults. E.g. when creating a SEPA bank transfer for vendor invoices a company
1059 might always want to pay quickly making use of skonto, while another company
1060 might always want to pay as late as possible.
1061
1062 =item C<get_payment_select_options_for_bank_transaction $banktransaction_id %params>
1063
1064 Make suggestion for a skonto payment type by returning an HTML blob of the options
1065 of a HTML drop-down select with the most likely option preselected.
1066
1067 This is a helper function for BankTransaction/ajax_payment_suggestion.
1068
1069 We are working with an existing payment, so difference_as_skonto never makes sense.
1070
1071 If skonto is possible (skonto_date exists), add two possibilities:
1072 without_skonto and with_skonto_pt if payment date is within skonto_date,
1073 preselect with_skonto_pt, otherwise preselect without skonto.
1074
1075 =item C<exchangerate>
1076
1077 Returns 1 immediately if the record uses the default currency.
1078
1079 Returns the exchangerate in database format for the invoice according to that
1080 invoice's transdate, returning 'buy' for sales, 'sell' for purchases.
1081
1082 If no exchangerate can be found for that day undef is returned.
1083
1084 =item C<forex>
1085
1086 Returns 1 if record uses a different currency, 0 if the default currency is used.
1087
1088 =back
1089
1090 =head1 TODO AND CAVEATS
1091
1092 =over 4
1093
1094 =item *
1095
1096 when looking at open amount, maybe consider that there may already be queued
1097 amounts in SEPA Export
1098
1099 =back
1100
1101 =head1 AUTHOR
1102
1103 G. Richardson E<lt>grichardson@kivitendo-premium.de<gt>
1104
1105 =cut