SL/DB/Helper/Payment.pm

   1 package SL::DB::Helper::Payment;
   2
   3 use strict;
   4
   5 use parent qw(Exporter);
   6 our @EXPORT = qw(pay_invoice);
   7 our @EXPORT_OK = qw(skonto_date amount_less_skonto within_skonto_period percent_skonto reference_account reference_amount open_amount open_percent remaining_skonto_days skonto_amount check_skonto_configuration valid_skonto_amount get_payment_suggestions validate_payment_type open_sepa_transfer_amount get_payment_select_options_for_bank_transaction exchangerate forex _skonto_charts_and_tax_correction);
   8 our %EXPORT_TAGS = (
   9   "ALL" => [@EXPORT, @EXPORT_OK],
  10 );
  11
  12 require SL::DB::Chart;
  13
  14 use Carp;
  15 use Data::Dumper;
  16 use DateTime;
  17 use List::Util qw(sum);
  18
  19 use SL::DATEV qw(:CONSTANTS);
  20 use SL::DB::Exchangerate;
  21 use SL::DB::Currency;
  22 use SL::HTML::Util;
  23 use SL::Locale::String qw(t8);
  24
  25 #
  26 # Public functions not exported by default
  27 #
  28
  29 sub pay_invoice {
  30   my ($self, %params) = @_;
  31
  32   require SL::DB::Tax;
  33
  34   my $is_sales = ref($self) eq 'SL::DB::Invoice';
  35   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign depending on ar/ap
  36   my @new_acc_ids;
  37   my $paid_amount = 0; # the amount that will be later added to $self->paid, should be in default currency
  38
  39   # default values if not set
  40   $params{payment_type} = 'without_skonto' unless $params{payment_type};
  41   validate_payment_type($params{payment_type});
  42
  43   # check for required parameters and optional params depending on payment_type
  44   Common::check_params(\%params, qw(chart_id transdate));
  45   Common::check_params(\%params, qw(bt_id)) unless $params{payment_type} eq 'without_skonto';
  46   if ( $params{'payment_type'} eq 'without_skonto' && abs($params{'amount'}) < 0) {
  47     croak "invalid amount for payment_type 'without_skonto': $params{'amount'}\n";
  48   }
  49   if ($params{'payment_type'} eq 'free_skonto') {
  50     # we dont like too much automagic for this payment type.
  51     # we force caller input for amount and skonto amount
  52     Common::check_params(\%params, qw(amount skonto_amount));
  53     # secondly we dont want to handle credit notes and purchase credit notes
  54     croak("Cannot use 'free skonto' for credit or debit notes") if ($params{amount} <= 0 || $params{skonto_amount} <= 0);
  55     # both amount have to be rounded
  56     $params{skonto_amount} = _round($params{skonto_amount});
  57     $params{amount}        = _round($params{amount});
  58     # lastly skonto_amount has to be smaller than the open invoice amount or payment amount ;-)
  59     if ($params{skonto_amount} > abs($self->open_amount) || $params{skonto_amount} > $params{amount}) {
  60       croak("Skonto amount higher than the payment or invoice amount");
  61     }
  62   }
  63
  64   my $transdate_obj;
  65   if (ref($params{transdate}) eq 'DateTime') {
  66     $transdate_obj = $params{transdate};
  67   } else {
  68     $transdate_obj = $::locale->parse_date_to_object($params{transdate});
  69   };
  70   croak t8('Illegal date') unless ref $transdate_obj;
  71
  72   # check for closed period
  73   my $closedto = $::locale->parse_date_to_object($::instance_conf->get_closedto);
  74   if ( ref $closedto && $transdate_obj < $closedto ) {
  75     croak t8('Cannot post payment for a closed period!');
  76   };
  77
  78   # check for maximum number of future days
  79   if ( $::instance_conf->get_max_future_booking_interval > 0 ) {
  80     croak t8('Cannot post transaction above the maximum future booking date!') if $transdate_obj > DateTime->now->add( days => $::instance_conf->get_max_future_booking_interval );
  81   };
  82
  83   # currency is either passed or use the invoice currency if it differs from the default currency
  84   # TODO remove
  85   my ($exchangerate,$currency);
  86   if ($params{currency} || $params{currency_id}) {
  87     if ($params{currency} || $params{currency_id} ) { # currency was specified
  88       $currency = SL::DB::Manager::Currency->find_by(name => $params{currency}) || SL::DB::Manager::Currency->find_by(id => $params{currency_id});
  89     } else { # use invoice currency
  90       $currency = SL::DB::Manager::Currency->find_by(id => $self->currency_id);
  91     };
  92     die "no currency" unless $currency;
  93     if ($currency->id == $::instance_conf->get_currency_id) {
  94       $exchangerate = 1;
  95     } else {
  96       my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $currency->id,
  97                                                         transdate   => $transdate_obj,
  98                                                        );
  99       if ($rate) {
 100         $exchangerate = $is_sales ? $rate->buy : $rate->sell;
 101       } else {
 102         die "No exchange rate for " . $transdate_obj->to_kivitendo;
 103       };
 104     };
 105   } else { # no currency param given or currency is the same as default_currency
 106     $exchangerate = 1;
 107   };
 108
 109   # options with_skonto_pt and difference_as_skonto don't require the parameter
 110   # amount, but if amount is passed, make sure it matches the expected value
 111   if ( $params{'payment_type'} eq 'difference_as_skonto' ) {
 112     croak "amount $params{amount} doesn't match open amount " . $self->open_amount . ", diff = " . ($params{amount}-$self->open_amount) if $params{amount} && abs($self->open_amount - $params{amount} ) > 0.0000001;
 113   } elsif ( $params{'payment_type'} eq 'with_skonto_pt' ) {
 114     croak "amount $params{amount} doesn't match amount less skonto: " . $self->amount_less_skonto . "\n" if $params{amount} && abs($self->amount_less_skonto - $params{amount} ) > 0.0000001;
 115     croak "payment type with_skonto_pt can't be used if payments have already been made" if $self->paid != 0;
 116   };
 117
 118   # absolute skonto amount for invoice, use as reference sum to see if the
 119   # calculated skontos add up
 120   # only needed for payment_term "with_skonto_pt"
 121
 122   my $skonto_amount_check = $self->skonto_amount; # variable should be zero after calculating all skonto
 123   my $total_open_amount   = $self->open_amount;
 124
 125   # account where money is paid to/from: bank account or cash
 126   my $account_bank = SL::DB::Manager::Chart->find_by(id => $params{chart_id});
 127   croak "can't find bank account with id " . $params{chart_id} unless ref $account_bank;
 128
 129   my $reference_account = $self->reference_account;
 130   croak "can't find reference account (link = AR/AP) for invoice" unless ref $reference_account;
 131
 132   my $memo   = $params{memo}   // '';
 133   my $source = $params{source} // '';
 134
 135   my $rounded_params_amount = _round( $params{amount} ); # / $exchangerate);
 136   my $fx_gain_loss_amount = 0; # for fx_gain and fx_loss
 137
 138   my $db = $self->db;
 139   $db->with_transaction(sub {
 140     my $new_acc_trans;
 141
 142     # all three payment type create 1 AR/AP booking (the paid part)
 143     # difference_as_skonto creates n skonto bookings (1 for each buchungsgruppe type)
 144     # with_skonto_pt creates 1 bank booking and n skonto bookings (1 for each buchungsgruppe type)
 145     # without_skonto creates 1 bank booking
 146
 147     # as long as there is no automatic tax, payments are always booked with
 148     # taxkey 0
 149
 150     unless ( $params{payment_type} eq 'difference_as_skonto' ) {
 151       # cases with_skonto_pt, free_skonto and without_skonto
 152
 153       # for case with_skonto_pt we need to know the corrected amount at this
 154       # stage if we are going to use $params{amount}
 155
 156       my $pay_amount = $rounded_params_amount;
 157       $pay_amount = $self->amount_less_skonto if $params{payment_type} eq 'with_skonto_pt';
 158
 159       # bank account and AR/AP
 160       $paid_amount += $pay_amount * $exchangerate;
 161
 162       my $amount = (-1 * $pay_amount) * $mult;
 163
 164
 165       # total amount against bank, do we already know this by now?
 166       $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 167                                                    chart_id   => $account_bank->id,
 168                                                    chart_link => $account_bank->link,
 169                                                    amount     => $amount,
 170                                                    transdate  => $transdate_obj,
 171                                                    source     => $source,
 172                                                    memo       => $memo,
 173                                                    project_id => $params{project_id} ? $params{project_id} : undef,
 174                                                    taxkey     => 0,
 175                                                    tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 176       $new_acc_trans->save;
 177
 178       push @new_acc_ids, $new_acc_trans->acc_trans_id;
 179       # deal with fxtransaction
 180       if ( $self->currency_id != $::instance_conf->get_currency_id ) {
 181         my $fxamount = _round($amount - ($amount * $exchangerate));
 182         $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 183                                                      chart_id       => $account_bank->id,
 184                                                      chart_link     => $account_bank->link,
 185                                                      amount         => $fxamount * -1,
 186                                                      transdate      => $transdate_obj,
 187                                                      source         => $source,
 188                                                      memo           => $memo,
 189                                                      taxkey         => 0,
 190                                                      fx_transaction => 1,
 191                                                      tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 192         $new_acc_trans->save;
 193         push @new_acc_ids, $new_acc_trans->acc_trans_id;
 194         # if invoice exchangerate differs from exchangerate of payment
 195         # deal with fxloss and fxamount
 196         if ($self->exchangerate and $self->exchangerate != 1 and $self->exchangerate != $exchangerate) {
 197           my $fxgain_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxgain_accno_id) || die "Can't determine fxgain chart";
 198           my $fxloss_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxloss_accno_id) || die "Can't determine fxloss chart";
 199           my $gain_loss_amount = _round($amount * ($exchangerate - $self->exchangerate ) * -1,2);
 200           my $gain_loss_chart = $gain_loss_amount > 0 ? $fxgain_chart : $fxloss_chart;
 201           $fx_gain_loss_amount = $gain_loss_amount;
 202
 203           $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 204                                                        chart_id       => $gain_loss_chart->id,
 205                                                        chart_link     => $gain_loss_chart->link,
 206                                                        amount         => $gain_loss_amount,
 207                                                        transdate      => $transdate_obj,
 208                                                        source         => $source,
 209                                                        memo           => $memo,
 210                                                        taxkey         => 0,
 211                                                        fx_transaction => 0,
 212                                                        tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 213           $new_acc_trans->save;
 214           push @new_acc_ids, $new_acc_trans->acc_trans_id;
 215
 216         }
 217       }
 218     }
 219     # better everything except without_skonto
 220     if ($params{payment_type} eq 'difference_as_skonto' or $params{payment_type} eq 'with_skonto_pt'
 221         or $params{payment_type} eq 'free_skonto' ) {
 222
 223       my $total_skonto_amount;
 224       if ( $params{payment_type} eq 'with_skonto_pt' ) {
 225         $total_skonto_amount = $self->skonto_amount;
 226       } elsif ( $params{payment_type} eq 'difference_as_skonto' ) {
 227         # only used for tests. no real code calls this payment_type!
 228         $total_skonto_amount = $self->open_amount;
 229       } elsif ( $params{payment_type} eq 'free_skonto') {
 230         $total_skonto_amount = $params{skonto_amount};
 231       }
 232       my @skonto_bookings = $self->_skonto_charts_and_tax_correction(amount => $total_skonto_amount, bt_id => $params{bt_id},
 233                                                                      transdate_obj => $transdate_obj, memo => $params{memo},
 234                                                                      source => $params{source});
 235       # error checking:
 236       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 237         my $calculated_skonto_sum  = sum map { $_->{skonto_amount} } @skonto_bookings;
 238         croak "calculated skonto for difference_as_skonto = $calculated_skonto_sum doesn't add up open amount: " . $self->open_amount unless _round($calculated_skonto_sum) == _round($self->open_amount);
 239       };
 240
 241       my $reference_amount = $total_skonto_amount;
 242
 243       # create an acc_trans entry for each result of $self->skonto_charts
 244       # TODO create internal sub _skonto_bookings
 245       foreach my $skonto_booking ( @skonto_bookings ) {
 246         next unless $skonto_booking->{'chart_id'};
 247         next unless $skonto_booking->{'skonto_amount'} != 0;
 248         my $amount = -1 * $skonto_booking->{skonto_amount};
 249         $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 250                                                      chart_id   => $skonto_booking->{'chart_id'},
 251                                                      chart_link => SL::DB::Manager::Chart->find_by(id => $skonto_booking->{'chart_id'})->link,
 252                                                      amount     => $amount * $mult,
 253                                                      transdate  => $transdate_obj,
 254                                                      source     => $params{source},
 255                                                      taxkey     => 0,
 256                                                      tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 257
 258         # the acc_trans entries are saved individually, not added to $self and then saved all at once
 259         $new_acc_trans->save;
 260         push @new_acc_ids, $new_acc_trans->acc_trans_id;
 261
 262         $reference_amount -= abs($amount);
 263         $paid_amount      += -1 * $amount * $exchangerate;
 264         $skonto_amount_check -= $skonto_booking->{'skonto_amount'};
 265       }
 266       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 267           die "difference_as_skonto calculated incorrectly, sum of calculated payments doesn't add up to open amount $total_open_amount, reference_amount = $reference_amount\n" unless _round($reference_amount) == 0;
 268       }
 269     }
 270
 271     my $arap_amount = 0;
 272
 273     if ( $params{payment_type} eq 'difference_as_skonto' ) {
 274       $arap_amount = $total_open_amount;
 275     } elsif ( $params{payment_type} eq 'without_skonto' ) {
 276       $arap_amount = $rounded_params_amount;
 277     } elsif ( $params{payment_type} eq 'with_skonto_pt' ) {
 278       # this should be amount + sum(amount+skonto), but while we only allow
 279       # with_skonto_pt for completely unpaid invoices we just use the value
 280       # from the invoice
 281       $arap_amount = $total_open_amount;
 282     } elsif ( $params{payment_type} eq 'free_skonto' ) {
 283       # we forced positive values and forced rounding at the beginning
 284       # therefore the above comment can be safely applied for this payment type
 285       $arap_amount = $params{amount} + $params{skonto_amount};
 286     }
 287
 288     # regardless of payment_type there is always only exactly one arap booking
 289     # TODO: compare $arap_amount to running total
 290     my $arap_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 291                                                   chart_id   => $reference_account->id,
 292                                                   chart_link => $reference_account->link,
 293                                                   amount     => _round($arap_amount * $mult * $exchangerate - $fx_gain_loss_amount),
 294                                                   transdate  => $transdate_obj,
 295                                                   source     => '', #$params{source},
 296                                                   taxkey     => 0,
 297                                                   tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 298     $arap_booking->save;
 299     push @new_acc_ids, $arap_booking->acc_trans_id;
 300
 301     # hook for invoice_for_advance_payment DATEV always pairs, acc_trans_id has to be higher than arap_booking ;-)
 302     if ($self->invoice_type eq 'invoice_for_advance_payment') {
 303       my $clearing_chart = SL::DB::Chart->new(id => $::instance_conf->get_advance_payment_clearing_chart_id)->load;
 304       die "No Clearing Chart for Advance Payment" unless ref $clearing_chart eq 'SL::DB::Chart';
 305
 306       # what does ptc say
 307       my %inv_calc = $self->calculate_prices_and_taxes();
 308       my @trans_ids = keys %{ $inv_calc{amounts} };
 309       die "Invalid state for advance payment more than one trans_id" if (scalar @trans_ids > 1);
 310       my $entry = delete $inv_calc{amounts}{$trans_ids[0]};
 311       my $tax;
 312       if ($entry->{tax_id}) {
 313         $tax = SL::DB::Manager::Tax->find_by(id => $entry->{tax_id}); # || die "Can't find tax with id " . $entry->{tax_id};
 314       }
 315       if ($tax and $tax->rate != 0) {
 316         my ($netamount, $taxamount);
 317         my $roundplaces = 2;
 318         # we dont have a clue about skonto, that's why we use $arap_amount as taxincluded
 319         ($netamount, $taxamount) = Form->calculate_tax($arap_amount, $tax->rate, 1, $roundplaces);
 320         # for debugging database set
 321         my $fullmatch = $netamount == $entry->{amount} ? '::netamount total true' : '';
 322         my $transfer_chart = $tax->taxkey == 2 ? SL::DB::Chart->new(id => $::instance_conf->get_advance_payment_taxable_7_id)->load
 323                           :  $tax->taxkey == 3 ? SL::DB::Chart->new(id => $::instance_conf->get_advance_payment_taxable_19_id)->load
 324                           :  undef;
 325         die "No Transfer Chart for Advance Payment" unless ref $transfer_chart eq 'SL::DB::Chart';
 326
 327         my $arap_full_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 328                                                            chart_id   => $clearing_chart->id,
 329                                                            chart_link => $clearing_chart->link,
 330                                                            amount     => $arap_amount * -1, # full amount
 331                                                            transdate  => $transdate_obj,
 332                                                            source     => 'Automatic Tax Booking for Payment in Advance' . $fullmatch,
 333                                                            taxkey     => 0,
 334                                                            tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 335         $arap_full_booking->save;
 336         push @new_acc_ids, $arap_full_booking->acc_trans_id;
 337
 338         my $arap_tax_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 339                                                           chart_id   => $transfer_chart->id,
 340                                                           chart_link => $transfer_chart->link,
 341                                                           amount     => _round($netamount), # full amount
 342                                                           transdate  => $transdate_obj,
 343                                                           source     => 'Automatic Tax Booking for Payment in Advance' . $fullmatch,
 344                                                           taxkey     => $tax->taxkey,
 345                                                           tax_id     => $tax->id);
 346         $arap_tax_booking->save;
 347         push @new_acc_ids, $arap_tax_booking->acc_trans_id;
 348
 349         my $tax_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 350                                                      chart_id   => $tax->chart_id,
 351                                                      chart_link => $tax->chart->link,
 352                                                      amount     => _round($taxamount),
 353                                                      transdate  => $transdate_obj,
 354                                                      source     => 'Automatic Tax Booking for Payment in Advance' . $fullmatch,
 355                                                      taxkey     => 0,
 356                                                      tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 357
 358         $tax_booking->save;
 359         push @new_acc_ids, $tax_booking->acc_trans_id;
 360       }
 361     }
 362     $fx_gain_loss_amount *= -1 if $self->is_sales;
 363     $self->paid($self->paid + _round($paid_amount) + $fx_gain_loss_amount) if $paid_amount;
 364     $self->datepaid($transdate_obj);
 365     $self->save;
 366
 367     # make sure transactions will be reloaded the next time $self->transactions
 368     # is called, as pay_invoice saves the acc_trans objects individually rather
 369     # than adding them to the transaction relation array.
 370     $self->forget_related('transactions');
 371
 372     my $datev_check = 0;
 373     if ( $is_sales )  {
 374       if ( (  $self->invoice && $::instance_conf->get_datev_check_on_sales_invoice  ) ||
 375            ( !$self->invoice && $::instance_conf->get_datev_check_on_ar_transaction )) {
 376         $datev_check = 1;
 377       }
 378     } else {
 379       if ( (  $self->invoice && $::instance_conf->get_datev_check_on_purchase_invoice ) ||
 380            ( !$self->invoice && $::instance_conf->get_datev_check_on_ap_transaction   )) {
 381         $datev_check = 1;
 382       }
 383     }
 384
 385     if ( $datev_check ) {
 386
 387       my $datev = SL::DATEV->new(
 388         dbh        => $db->dbh,
 389         trans_id   => $self->{id},
 390       );
 391
 392       $datev->generate_datev_data;
 393
 394       if ($datev->errors) {
 395         # this exception should be caught by with_transaction, which handles the rollback
 396         die join "\n", $::locale->text('DATEV check returned errors:'), $datev->errors;
 397       }
 398     }
 399
 400     1;
 401
 402   }) || die t8('error while paying invoice #1 : ', $self->invnumber) . $db->error . "\n";
 403   return wantarray ? @new_acc_ids : 1;
 404 }
 405
 406 sub skonto_date {
 407
 408   my $self = shift;
 409
 410   return undef unless ref $self->payment_terms;
 411   return undef unless $self->payment_terms->terms_skonto > 0;
 412   return DateTime->from_object(object => $self->transdate)->add(days => $self->payment_terms->terms_skonto);
 413 };
 414
 415 sub reference_account {
 416   my $self = shift;
 417
 418   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 419
 420   require SL::DB::Manager::AccTransaction;
 421
 422   my $link_filter = $is_sales ? 'AR' : 'AP';
 423
 424   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 425      trans_id   => $self->id,
 426      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 427   );
 428
 429   return undef unless ref $acc_trans;
 430
 431   my $reference_account = SL::DB::Manager::Chart->find_by(id => $acc_trans->chart_id);
 432
 433   return $reference_account;
 434 };
 435
 436 sub reference_amount {
 437   my $self = shift;
 438
 439   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 440
 441   require SL::DB::Manager::AccTransaction;
 442
 443   my $link_filter = $is_sales ? 'AR' : 'AP';
 444
 445   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 446      trans_id   => $self->id,
 447      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 448   );
 449
 450   return undef unless ref $acc_trans;
 451
 452   # this should be the same as $self->amount
 453   return $acc_trans->amount;
 454 };
 455
 456
 457 sub open_amount {
 458   my $self = shift;
 459
 460   # in the future maybe calculate this from acc_trans
 461
 462   # if the difference is 0.01 Cent this may end up as 0.009999999999998
 463   # numerically, so round this value when checking for cent threshold >= 0.01
 464
 465   return ($self->amount // 0) - ($self->paid // 0);
 466 };
 467
 468 sub open_percent {
 469   my $self = shift;
 470
 471   return 0 if $self->amount == 0;
 472   my $open_percent;
 473   if ( $self->open_amount < 0 ) {
 474     # overpaid, currently treated identically
 475     $open_percent = $self->open_amount * 100 / $self->amount;
 476   } else {
 477     $open_percent = $self->open_amount * 100 / $self->amount;
 478   };
 479
 480   return _round($open_percent) || 0;
 481 };
 482
 483 sub skonto_amount {
 484   my $self = shift;
 485
 486   return $self->amount - $self->amount_less_skonto;
 487 };
 488
 489 sub remaining_skonto_days {
 490   my $self = shift;
 491
 492   return undef unless ref $self->skonto_date;
 493
 494   my $dur = DateTime::Duration->new($self->skonto_date - DateTime->today);
 495   return $dur->delta_days();
 496
 497 };
 498
 499 sub percent_skonto {
 500   my $self = shift;
 501
 502   my $percent_skonto = 0;
 503
 504   return undef unless ref $self->payment_terms;
 505   return undef unless $self->payment_terms->percent_skonto > 0;
 506   $percent_skonto = $self->payment_terms->percent_skonto;
 507
 508   return $percent_skonto;
 509 };
 510
 511 sub amount_less_skonto {
 512   # amount that has to be paid if skonto applies, always return positive rounded values
 513   # no, rare case, but credit_notes and negative ap have negative amounts
 514   # and therefore this comment may be misguiding
 515   # the result is rounded so we can directly compare it with the user input
 516   my $self = shift;
 517
 518   my $percent_skonto = $self->percent_skonto || 0;
 519
 520   return _round($self->amount - ( $self->amount * $percent_skonto) );
 521
 522 };
 523
 524 sub check_skonto_configuration {
 525   my $self = shift;
 526
 527   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 528
 529   my $skonto_configured = 1; # default is assume skonto works
 530
 531   # my $transactions = $self->transactions;
 532   foreach my $transaction (@{ $self->transactions }) {
 533     # find all transactions with an AR_amount or AP_amount link
 534     my $tax = SL::DB::Manager::Tax->get_first( where => [taxkey => $transaction->taxkey, id => $transaction->tax_id ]);
 535
 536     # acc_trans entries for the taxes (chart_link == A[RP]_tax) often
 537     # have combinations of taxkey & tax_id that don't exist in
 538     # tax. Those must be skipped.
 539     next if !$tax && ($transaction->chart_link !~ m{A[RP]_amount});
 540
 541     croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 542
 543     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->chart_link) };
 544     if ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) {
 545       $skonto_configured = 0 unless $tax->skonto_sales_chart_id;
 546     } elsif ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) {
 547       $skonto_configured = 0 unless $tax->skonto_purchase_chart_id;
 548     };
 549   };
 550
 551   return $skonto_configured;
 552 };
 553
 554 sub open_sepa_transfer_amount {
 555   my $self = shift;
 556
 557   my ($vc, $key, $type);
 558   if ( ref($self) eq 'SL::DB::Invoice' ) {
 559     $vc   = 'customer';
 560     $key  = 'ap_id';
 561     $type = 'ar';
 562   } else {
 563     $vc   = 'vendor';
 564     $key  = 'ap_id';
 565     $type = 'ap';
 566   };
 567
 568   my $sql = qq|SELECT SUM(sei.amount) AS amount FROM sepa_export_items sei | .
 569             qq| LEFT JOIN sepa_export se ON (sei.sepa_export_id = se.id)   | .
 570             qq| WHERE $key = ? AND NOT se.closed AND (se.vc = '$vc')       |;
 571
 572   my ($open_sepa_amount) = $self->db->dbh->selectrow_array($sql, undef, $self->id);
 573
 574   return $open_sepa_amount || 0;
 575
 576 }
 577
 578 sub _skonto_charts_and_tax_correction {
 579   my ($self, %params)   = @_;
 580   my $amount = $params{amount} || $self->skonto_amount;
 581
 582   croak "no amount passed to skonto_charts"                    unless abs(_round($amount)) >= 0.01;
 583   croak "no banktransaction.id passed to skonto_charts"        unless $params{bt_id};
 584   croak "no banktransaction.transdate passed to skonto_charts" unless ref $params{transdate_obj} eq 'DateTime';
 585
 586   my $is_sales = $self->is_sales;
 587   my (@skonto_charts, $inv_calc, $total_skonto_rounded);
 588
 589   $inv_calc = $self->get_tax_and_amount_by_tax_chart_id();
 590
 591   # foreach tax.chart_id || $entry->{ta..id}
 592   while (my ($tax_chart_id, $entry) = each %{ $inv_calc } ) {
 593     my $tax = SL::DB::Manager::Tax->find_by(id => $entry->{tax_id}) || die "Can't find tax with id " . $tax_chart_id;
 594     die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $tax->taxkey, $tax->taxdescription , $tax->rate * 100)
 595       unless $is_sales ? ref $tax->skonto_sales_chart : ref $tax->skonto_purchase_chart;
 596
 597     # percent net amount
 598     my $transaction_net_skonto_percent = abs($entry->{netamount} / $self->amount);
 599     my $skonto_netamount_unrounded     = abs($amount * $transaction_net_skonto_percent);
 600
 601     # percent tax amount
 602     my $transaction_tax_skonto_percent = abs($entry->{tax} / $self->amount);
 603     my $skonto_taxamount_unrounded     = abs($amount * $transaction_tax_skonto_percent);
 604
 605     my $skonto_taxamount_rounded   = _round($skonto_taxamount_unrounded);
 606     my $skonto_netamount_rounded   = _round($skonto_netamount_unrounded);
 607     my $chart_id                   = $is_sales ? $tax->skonto_sales_chart->id : $tax->skonto_purchase_chart->id;
 608
 609     # entry net + tax for caller
 610     my $rec_net = {
 611       chart_id               => $chart_id,
 612       skonto_amount          => _round($skonto_netamount_unrounded + $skonto_taxamount_unrounded),
 613     };
 614     push @skonto_charts, $rec_net;
 615     $total_skonto_rounded += $rec_net->{skonto_amount};
 616
 617     # add-on: correct tax with one linked gl booking
 618
 619     # no skonto tax correction for dual tax (reverse charge) or rate = 0
 620     next if ($tax->rate == 0 || $tax->reverse_charge_chart_id);
 621
 622     my ($credit, $debit);
 623     $credit = SL::DB::Manager::Chart->find_by(id => $chart_id);
 624     $debit  = SL::DB::Manager::Chart->find_by(id => $tax_chart_id);
 625     croak("No such Chart ID")  unless ref $credit eq 'SL::DB::Chart' && ref $debit eq 'SL::DB::Chart';
 626     my $notes = SL::HTML::Util->strip($self->notes);
 627
 628     my $current_transaction = SL::DB::GLTransaction->new(
 629          employee_id    => $self->employee_id,
 630          transdate      => $params{transdate_obj},
 631          notes          => $params{source} . ' ' . $params{memo},
 632          description    => $notes || $self->invnumber,
 633          reference      => t8('Skonto Tax Correction for') . " " . $tax->rate * 100 . '% ' . $self->invnumber,
 634          department_id  => $self->department_id ? $self->department_id : undef,
 635          imported       => 0, # not imported
 636          taxincluded    => 0,
 637       )->add_chart_booking(
 638          chart  => $is_sales ? $debit : $credit,
 639          debit  => abs($skonto_taxamount_rounded),
 640          source => t8('Skonto Tax Correction for') . " " . $self->invnumber,
 641          memo   => $params{memo},
 642          tax_id => 0,
 643       )->add_chart_booking(
 644          chart  => $is_sales ? $credit : $debit,
 645          credit => abs($skonto_taxamount_rounded),
 646          source => t8('Skonto Tax Correction for') . " " . $self->invnumber,
 647          memo   => $params{memo},
 648          tax_id => 0,
 649       )->post;
 650
 651     # add a stable link acc_trans_id to bank_transactions.id
 652     foreach my $transaction (@{ $current_transaction->transactions }) {
 653       my %props_acc = (
 654            acc_trans_id        => $transaction->acc_trans_id,
 655            bank_transaction_id => $params{bt_id},
 656            gl                  => $current_transaction->id,
 657       );
 658       SL::DB::BankTransactionAccTrans->new(%props_acc)->save;
 659     }
 660     # Record a record link from banktransactions to gl
 661     my %props_rl = (
 662          from_table => 'bank_transactions',
 663          from_id    => $params{bt_id},
 664          to_table   => 'gl',
 665          to_id      => $current_transaction->id,
 666     );
 667     SL::DB::RecordLink->new(%props_rl)->save;
 668     # Record a record link from arap to gl
 669     # linked gl booking will appear in tab linked records
 670     # this is just a link for convenience
 671     %props_rl = (
 672          from_table => $is_sales ? 'ar' : 'ap',
 673          from_id    => $self->id,
 674          to_table   => 'gl',
 675          to_id      => $current_transaction->id,
 676     );
 677     SL::DB::RecordLink->new(%props_rl)->save;
 678
 679   }
 680   # check for rounding errors, at least for the payment chart
 681   # we ignore tax rounding errors as long as the amount (user input or calculated)
 682   # is fully assigned.
 683   # we simply alter one cent for the first skonto booking entry
 684   # should be correct for most of the cases (no invoices with mixed taxes)
 685   if ($total_skonto_rounded - $amount > 0.01) {
 686     # add one cent
 687     $skonto_charts[0]->{skonto_amount} -= 0.01;
 688   } elsif ($amount - $total_skonto_rounded > 0.01) {
 689     # subtract one cent
 690     $skonto_charts[0]->{skonto_amount} += 0.01;
 691   }
 692
 693   # return same array of skonto charts as sub skonto_charts
 694   return @skonto_charts;
 695 }
 696
 697 sub within_skonto_period {
 698   my $self = shift;
 699   my $dateref = shift || DateTime->now->truncate( to => 'day' );
 700
 701   return undef unless ref $dateref eq 'DateTime';
 702   return 0 unless $self->skonto_date;
 703
 704   # return 1 if requested date (or today) is inside skonto period
 705   # this will also return 1 if date is before the invoice date
 706   return $dateref <= $self->skonto_date;
 707 };
 708
 709 sub valid_skonto_amount {
 710   my $self = shift;
 711   my $amount = shift || 0;
 712   my $max_skonto_percent = 0.10;
 713
 714   return 0 unless $amount > 0;
 715
 716   # does this work for other currencies?
 717   return ($self->amount*$max_skonto_percent) > $amount;
 718 };
 719
 720 sub get_payment_select_options_for_bank_transaction {
 721   my ($self, $bt_id, %params) = @_;
 722
 723
 724   # CAVEAT template code expects with_skonto_pt at position 1 for visual help
 725   # due to skonto_charts, we cannot offer skonto for credit notes and neg ap
 726   my $skontoable = $self->amount > 0 ? 1 : 0;
 727   my @options;
 728   if(!$self->skonto_date) {
 729     push(@options, { payment_type => 'without_skonto', display => t8('without skonto'), selected => 1 });
 730     # wrong call to presenter or not implemented? disabled option is ignored
 731     # push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt'), disabled => 1 });
 732     push(@options, { payment_type => 'free_skonto', display => t8('free skonto') }) if $skontoable;
 733     return @options;
 734   }
 735   # valid skonto date, check if skonto is preferred
 736   my $bt = SL::DB::BankTransaction->new(id => $bt_id)->load;
 737   if ($self->skonto_date && $self->within_skonto_period($bt->transdate)) {
 738     push(@options, { payment_type => 'without_skonto', display => t8('without skonto') });
 739     push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt'), selected => 1 }) if $skontoable;
 740   } else {
 741     push(@options, { payment_type => 'without_skonto', display => t8('without skonto') , selected => 1 });
 742     push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt')}) if $skontoable;
 743   }
 744   push(@options, { payment_type => 'free_skonto', display => t8('free skonto') }) if $skontoable;
 745   return @options;
 746 }
 747
 748 sub exchangerate {
 749   my ($self) = @_;
 750
 751   return 1 if $self->currency_id == $::instance_conf->get_currency_id;
 752
 753   die "transdate isn't a DateTime object:" . ref($self->transdate) unless ref($self->transdate) eq 'DateTime';
 754   my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $self->currency_id,
 755                                                     transdate   => $self->transdate,
 756                                                    );
 757   return undef unless $rate;
 758
 759   return $self->is_sales ? $rate->buy : $rate->sell; # also undef if not defined
 760 };
 761
 762 sub get_payment_suggestions {
 763
 764   my ($self, %params) = @_;
 765
 766   my $open_amount = $self->open_amount;
 767   $open_amount   -= $self->open_sepa_transfer_amount if $params{sepa};
 768
 769   $self->{invoice_amount_suggestion} = $open_amount;
 770   undef $self->{payment_select_options};
 771   push(@{$self->{payment_select_options}} , { payment_type => 'without_skonto',  display => t8('without skonto') });
 772   if ( $self->within_skonto_period ) {
 773     # If there have been no payments yet suggest amount_less_skonto, otherwise the open amount
 774     if ( $open_amount &&                   # invoice amount not 0
 775          $open_amount == $self->amount &&  # no payments yet, or sum of payments and sepa export amounts is zero
 776          $self->check_skonto_configuration) {
 777       $self->{invoice_amount_suggestion} = $self->amount_less_skonto;
 778       push(@{$self->{payment_select_options}} , { payment_type => 'with_skonto_pt',  display => t8('with skonto acc. to pt') , selected => 1 });
 779     } else {
 780       if ( ( $self->valid_skonto_amount($self->open_amount) || $self->valid_skonto_amount($open_amount) ) and not $params{sepa} ) {
 781         # Will never be reached
 782         die "This case is as dead as the dead cat. Go to start, don't pick 2,000 \$";
 783         $self->{invoice_amount_suggestion} = $open_amount;
 784         # only suggest difference_as_skonto if open_amount exactly matches skonto_amount
 785         # AND we aren't in SEPA mode
 786         my $selected = 0;
 787         $selected = 1 if _round($open_amount) == _round($self->skonto_amount);
 788         push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => $selected });
 789       };
 790     };
 791   } else {
 792     # invoice was configured with skonto, but skonto date has passed, or no skonto available
 793     $self->{invoice_amount_suggestion} = $open_amount;
 794     # difference_as_skonto doesn't make any sense for SEPA transfer, as this doesn't cause any actual payment
 795     if ( $self->valid_skonto_amount($self->open_amount) && not $params{sepa} ) {
 796       push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => 0 });
 797     };
 798   };
 799   return 1;
 800 };
 801
 802 # locales for payment type
 803 #
 804 # $main::locale->text('without_skonto')
 805 # $main::locale->text('with_skonto_pt')
 806 # $main::locale->text('difference_as_skonto')
 807 #
 808
 809 sub validate_payment_type {
 810   my $payment_type = shift;
 811
 812   my %allowed_payment_types = map { $_ => 1 } qw(without_skonto with_skonto_pt difference_as_skonto free_skonto);
 813   croak "illegal payment type: $payment_type, must be one of: " . join(' ', keys %allowed_payment_types) unless $allowed_payment_types{ $payment_type };
 814
 815   return 1;
 816 }
 817
 818 sub forex {
 819   my ($self) = @_;
 820   $self->currency_id == $::instance_conf->get_currency_id ? return 0 : return 1;
 821 };
 822
 823 sub _round {
 824   my $value = shift;
 825   my $num_dec = 2;
 826   return $::form->round_amount($value, 2);
 827 }
 828
 829 1;
 830
 831 __END__
 832
 833 =pod
 834
 835 =head1 NAME
 836
 837 SL::DB::Helper::Payment  Mixin providing helper methods for paying C<Invoice>
 838                          and C<PurchaseInvoice> objects and using skonto
 839
 840 =head1 SYNOPSIS
 841
 842 In addition to actually causing a payment via pay_invoice this helper contains
 843 many methods that help in determining information about the status of the
 844 invoice, such as the remaining open amount, whether skonto applies, until which
 845 date skonto applies, the skonto amount and relative percentages, what to do
 846 with skonto, ...
 847
 848 To prevent duplicate code this was all added in this mixin rather than directly
 849 in SL::DB::Invoice and SL::DB::PurchaseInvoice.
 850
 851 =over 4
 852
 853 =item C<pay_invoice %params>
 854
 855 Create a payment booking for an existing invoice object (type ar/ap/is/ir) via
 856 a configured bank account.
 857
 858 This function deals with all the acc_trans entries and also updates paid and datepaid.
 859 The params C<transdate> and C<chart_id> are mandantory.
 860 If the default payment ('without_skonto') is used the param amount is also
 861 mandantory.
 862 If the payment type ('free_skonto') is used the number params skonto_amount and amount
 863 are as well mandantory and need to be positive. Furthermore the skonto amount has
 864 to be lower than the payment or open invoice amount.
 865
 866 Transdate can either be a date object or a date string.
 867 Chart_id is the id of the payment booking chart.
 868 Amount is either a positive or negative number, but never 0.
 869
 870 CAVEAT! The helper tries to get the sign right and all calls from BankTransaction are
 871 positive (abs($value)) values.
 872
 873
 874 Example:
 875
 876   my $ap   = SL::DB::Manager::PurchaseInvoice->find_by( invnumber => '1');
 877   my $bank = SL::DB::Manager::BankAccount->find_by( name => 'Bank');
 878   $ap->pay_invoice(chart_id      => $bank->chart_id,
 879                    amount        => $ap->open_amount,
 880                    transdate     => DateTime->now->to_kivitendo,
 881                    memo          => 'foobar',
 882                    source        => 'barfoo',
 883                    payment_type  => 'without_skonto',  # default if not specified
 884                    project_id    => 25,
 885                   );
 886
 887 or with skonto:
 888   $ap->pay_invoice(chart_id      => $bank->chart_id,
 889                    amount        => $ap->amount,       # doesn't need to be specified
 890                    transdate     => DateTime->now->to_kivitendo,
 891                    memo          => 'foobar',
 892                    source        => 'barfoo',
 893                    payment_type  => 'with_skonto',
 894                   );
 895
 896 or in a certain currency:
 897   $ap->pay_invoice(chart_id      => $bank->chart_id,
 898                    amount        => 500,
 899                    currency      => 'USD',
 900                    transdate     => DateTime->now->to_kivitendo,
 901                    memo          => 'foobar',
 902                    source        => 'barfoo',
 903                    payment_type  => 'with_skonto_pt',
 904                   );
 905
 906 Allowed payment types are:
 907   without_skonto with_skonto_pt difference_as_skonto
 908
 909 The option C<payment_type> allows for a basic skonto mechanism.
 910
 911 C<without_skonto> is the default mode, "amount" is paid to the account in
 912 chart_id. This can also be used for partial payments and corrections via
 913 negative amounts.
 914
 915 C<with_skonto_pt> can't be used for partial payments. When used on unpaid
 916 invoices the whole amount is paid, with the skonto part automatically being
 917 booked according to the skonto chart configured in the tax settings for each
 918 tax key. If an amount is passed it is ignored and the actual configured skonto
 919 amount is used.
 920
 921 C<difference_as_skonto> can only be used after partial payments have been made,
 922 the whole specified amount is booked according to the skonto charts configured
 923 in the tax settings for each tax key.
 924
 925 So passing amount doesn't have any effect for the cases C<with_skonto_pt> and
 926 C<difference_as_skonto>, as all necessary values are taken from the stored
 927 invoice.
 928
 929 The skonto modes automatically calculate the relative amounts for a mix of
 930 taxes, e.g. items with 7% and 19% in one invoice. There is a helper method
 931 skonto_charts, which calculates the relative percentages according to the
 932 amounts in acc_trans (which are grouped by tax).
 933
 934 There is currently no way of excluding certain items in an invoice from having
 935 skonto applied to them.  If this feature was added to parts the calculation
 936 method of relative skonto would have to be completely rewritten using the
 937 invoice items rather than acc_trans.
 938
 939 The skonto modes also still don't automatically correct the tax, this still has
 940 to be done manually. Therefore all payments generated by pay_invoice have
 941 taxkey 0.
 942
 943 There is currently no way to directly pay an invoice via this method if the
 944 effective skonto differs from the skonto according to the payment terms
 945 configured for the invoice/vendor.
 946
 947 In this case one has to pay in two steps: first the actual paid amount via
 948 "without skonto", and then the remainder via "difference_as_skonto". The user
 949 has to there actively decide whether to accept the differing skonto.
 950
 951 Because of the way skonto_charts works the calculation doesn't work if there
 952 are negative values in acc_trans. E.g. one invoice with a positive value for
 953 19% tax and a negative value for the acc_trans line with 7%
 954
 955 Skonto doesn't/shouldn't apply if the invoice contains credited items.
 956
 957 If no amount is given the whole open amout is paid.
 958
 959 If neither currency or currency_id are given as params, the currency of the
 960 invoice is assumed to be the payment currency.
 961
 962 If successful the return value will be 1 in scalar context or in list context
 963 the two ids (acc_trans_id) of the newly created bookings.
 964
 965 =item C<reference_account>
 966
 967 Returns a chart object which is the chart of the invoice with link AR or AP.
 968
 969 Example (1200 is the AR account for SKR04):
 970   my $invoice = invoice(invnumber => '144');
 971   $invoice->reference_account->accno
 972   # 1200
 973
 974 =item C<percent_skonto>
 975
 976 Returns the configured skonto percentage of the payment terms of an invoice,
 977 e.g. 0.02 for 2%. Payment terms come from invoice settingssettings for ap.
 978
 979 =item C<amount_less_skonto>
 980
 981 If the invoice has a payment term,
 982 calculate the amount to be paid in the case of skonto.  This doesn't check,
 983 whether skonto applies (i.e. skonto doesn't wasn't exceeded), it just subtracts
 984 the configured percentage (e.g. 2%) from the total amount.
 985
 986 The returned value is rounded to two decimals.
 987
 988 =item C<skonto_date>
 989
 990 The date up to which skonto may be taken. This is calculated from the invoice
 991 date + the number of days configured in the payment terms.
 992
 993 This method can also be used to determine whether skonto applies for the
 994 invoice, as it returns undef if there is no payment term or skonto days is set
 995 to 0.
 996
 997 =item C<within_skonto_period [DATE]>
 998
 999 Returns 0 or 1.
1000
1001 Checks whether the invoice has payment terms configured, and whether the date
1002 is within the skonto max date. If no date is passed the current date is used.
1003
1004 You can also pass a dateref object as a parameter to check whether skonto
1005 applies for that date rather than the current date.
1006
1007 =item C<valid_skonto_amount>
1008
1009 Takes an amount as an argument and checks whether the amount is less than 10%
1010 of the total amount of the invoice. The value of 10% is currently hardcoded in
1011 the method. This method is currently used to check whether to offer the payment
1012 option "difference as skonto".
1013
1014 Example:
1015  if ( $invoice->valid_skonto_amount($invoice->open_amount) ) {
1016    # ... do something
1017  }
1018
1019 =item C<skonto_charts [$amount]>
1020
1021 Returns a list of chart_ids and some calculated numbers that can be used for
1022 paying the invoice with skonto. This function will automatically calculate the
1023 relative skonto amounts even if the invoice contains several types of taxes
1024 (e.g. 7% and 19%).
1025
1026 Example usage:
1027   my $invoice = SL::DB::Manager::Invoice->find_by(invnumber => '211');
1028   my @skonto_charts = $invoice->skonto_charts;
1029
1030 or with the total skonto amount as an argument:
1031   my @skonto_charts = $invoice->skonto_charts($invoice->open_amount);
1032
1033 The following values are generated for each chart:
1034
1035 =over 2
1036
1037 =item C<chart_id>
1038
1039 The chart id of the skonto amount to be booked.
1040
1041 =item C<skonto_amount>
1042
1043 The total amount to be paid to the account
1044
1045 =item C<skonto_percent>
1046
1047 The relative percentage of that skonto chart. This can be useful if the actual
1048 ekonto that is paid deviates from the granted skonto, e.g. customer effectively
1049 pays 2.6% skonto instead of 2%, and we accept this. Then we can still calculate
1050 the relative skonto amounts for different taxes based on the absolute
1051 percentages. Used for case C<difference_as_skonto>.
1052
1053 =item C<skonto_percent_abs>
1054
1055 The absolute percentage of that skonto chart in relation to the total amount.
1056 Used to calculate skonto_amount for case C<with_skonto_pt>.
1057
1058 =back
1059
1060 If the invoice contains several types of taxes then skonto_charts can be used
1061 to calculate the relative amounts.
1062
1063 Example in console of an invoice with 100 Euro at 7% and 100 Euro at 19% with
1064 tax not included:
1065
1066   my $invoice = invoice(invnumber => '144');
1067   $invoice->amount
1068   226.00000
1069   $invoice->payment_terms->percent_skonto
1070   0.02
1071   $invoice->skonto_charts
1072   pp $invoice->skonto_charts
1073   #             $VAR1 = {
1074   #               'chart_id'       => 128,
1075   #               'skonto_amount'  => '2.14',
1076   #               'skonto_percent' => '47.3451327433627'
1077   #             };
1078   #             $VAR2 = {
1079   #               'chart_id'       => 130,
1080   #               'skonto_amount'  => '2.38',
1081   #               'skonto_percent' => '52.654867256637'
1082   #             };
1083
1084 C<skonto_charts> always returns positive values (abs) for C<skonto_amount> and
1085 C<skonto_percent>.
1086
1087 C<skonto_charts> generates one entry for each acc_trans entry. ar and ap
1088 bookings only have one acc_trans entry for each taxkey (e.g. 7% and 19%).  This
1089 is because all the items are grouped according to the Buchungsgruppen mechanism
1090 and the totals are written to acc_trans.  For is and ir it is possible to have
1091 several acc_trans entries with the same tax. In this case skonto_charts
1092 generates a skonto booking for each acc_trans income/expense entry.
1093
1094 In the future this function may also be used to calculate the corrections for
1095 the income tax.
1096
1097 =item C<open_amount>
1098
1099 Unrounded total open amount of invoice (amount - paid).
1100 Doesn't take into account pending SEPA transfers.
1101
1102 =item C<open_percent>
1103
1104 Percentage of the invoice that is still unpaid, e.g. 100,00 if no payments have
1105 been made yet, 0,00 if fully paid.
1106
1107 =item C<remaining_skonto_days>
1108
1109 How many days skonto can still be taken, calculated from current day. Returns 0
1110 if current day is the max skonto date, and negative number if skonto date has
1111 already passed.
1112
1113 Returns undef if skonto is not configured for that invoice.
1114
1115 =item C<get_payment_suggestions %params>
1116
1117 Creates data intended for an L.select_tag dropdown that can be used in a
1118 template. Depending on the rules it will choose from the options
1119 without_skonto, with_skonto_pt and difference_as_skonto, and select the most
1120 likely one.
1121
1122 If the parameter "sepa" is passed, the SEPA export payments that haven't been
1123 executed yet are considered when determining the open amount of the invoice.
1124
1125 The current rules are:
1126
1127 =over 2
1128
1129 =item * without_skonto is always an option
1130
1131 =item * with_skonto_pt is only offered if there haven't been any payments yet and the current date is within the skonto period.
1132
1133 =item * difference_as_skonto is only offered if there have already been payments made and the open amount is smaller than 10% of the total amount.
1134
1135 with_skonto_pt will only be offered, if all the AR_amount/AP_amount have a
1136 taxkey with a configured skonto chart
1137
1138 =back
1139
1140 It will also fill $self->{invoice_amount_suggestion} with either the open
1141 amount, or if with_skonto_pt is selected, with amount_less_skonto, so the
1142 template can fill the input with the likely amount.
1143
1144 Example in console:
1145   my $ar = invoice( invnumber => '257');
1146   $ar->get_payment_suggestions;
1147   print $ar->{invoice_amount_suggestion} . "\n";
1148   # 97.23
1149   pp $ar->{payment_select_options}
1150   # $VAR1 = [
1151   #         {
1152   #           'display' => 'ohne Skonto',
1153   #           'payment_type' => 'without_skonto'
1154   #         },
1155   #         {
1156   #           'display' => 'mit Skonto nach ZB',
1157   #           'payment_type' => 'with_skonto_pt',
1158   #           'selected' => 1
1159   #         }
1160   #       ];
1161
1162 The resulting array $ar->{payment_select_options} can be used in a template
1163 select_tag using value_key and title_key:
1164
1165 [% L.select_tag('payment_type_' _ loop.count, invoice.payment_select_options, value_key => 'payment_type', title_key => 'display', id => 'payment_type_' _ loop.count) %]
1166
1167 It would probably make sense to have different rules for the pre-selected items
1168 for sales and purchase, and to also make these rules configurable in the
1169 defaults. E.g. when creating a SEPA bank transfer for vendor invoices a company
1170 might always want to pay quickly making use of skonto, while another company
1171 might always want to pay as late as possible.
1172
1173 =item C<get_payment_select_options_for_bank_transaction $banktransaction_id %params>
1174
1175 Make suggestion for a skonto payment type by returning an HTML blob of the options
1176 of a HTML drop-down select with the most likely option preselected.
1177
1178 This is a helper function for BankTransaction/ajax_payment_suggestion and
1179 template/webpages/bank_transactions/invoices.html
1180
1181 We are working with an existing payment, so difference_as_skonto never makes sense.
1182
1183 If skonto is not possible (skonto_date does not exists) simply return
1184 the single 'no skonto' option as a visual hint.
1185
1186 If skonto is possible (skonto_date exists), add two possibilities:
1187 without_skonto and with_skonto_pt if payment date is within skonto_date,
1188 preselect with_skonto_pt, otherwise preselect without skonto.
1189
1190 =item C<exchangerate>
1191
1192 Returns 1 immediately if the record uses the default currency.
1193
1194 Returns the exchangerate in database format for the invoice according to that
1195 invoice's transdate, returning 'buy' for sales, 'sell' for purchases.
1196
1197 If no exchangerate can be found for that day undef is returned.
1198
1199 =item C<forex>
1200
1201 Returns 1 if record uses a different currency, 0 if the default currency is used.
1202
1203 =back
1204
1205 =head1 TODO AND CAVEATS
1206
1207 =over 4
1208
1209 =item *
1210
1211 when looking at open amount, maybe consider that there may already be queued
1212 amounts in SEPA Export
1213
1214 =item * C<skonto_charts>
1215
1216 Cannot handle negative skonto amounts, will always calculate the skonto amount
1217 for credit notes or negative ap transactions with a positive sign.
1218
1219
1220 =back
1221
1222 =head1 AUTHOR
1223
1224 G. Richardson E<lt>grichardson@kivitendo-premium.de<gt>
1225
1226 =cut