SL/DB/Helper/Payment.pm

   1 package SL::DB::Helper::Payment;
   2
   3 use strict;
   4
   5 use parent qw(Exporter);
   6 our @EXPORT = qw(pay_invoice);
   7 our @EXPORT_OK = qw(skonto_date amount_less_skonto within_skonto_period percent_skonto reference_account reference_amount open_amount open_percent remaining_skonto_days skonto_amount check_skonto_configuration valid_skonto_amount get_payment_suggestions validate_payment_type open_sepa_transfer_amount get_payment_select_options_for_bank_transaction exchangerate forex _skonto_charts_and_tax_correction);
   8 our %EXPORT_TAGS = (
   9   "ALL" => [@EXPORT, @EXPORT_OK],
  10 );
  11
  12 require SL::DB::Chart;
  13
  14 use Carp;
  15 use Data::Dumper;
  16 use DateTime;
  17 use List::Util qw(sum);
  18
  19 use SL::DATEV qw(:CONSTANTS);
  20 use SL::DB::Exchangerate;
  21 use SL::DB::Currency;
  22 use SL::Locale::String qw(t8);
  23
  24 #
  25 # Public functions not exported by default
  26 #
  27
  28 sub pay_invoice {
  29   my ($self, %params) = @_;
  30
  31   require SL::DB::Tax;
  32
  33   my $is_sales = ref($self) eq 'SL::DB::Invoice';
  34   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign depending on ar/ap
  35   my @new_acc_ids;
  36   my $paid_amount = 0; # the amount that will be later added to $self->paid, should be in default currency
  37
  38   # default values if not set
  39   $params{payment_type} = 'without_skonto' unless $params{payment_type};
  40   validate_payment_type($params{payment_type});
  41
  42   # check for required parameters and optional params depending on payment_type
  43   Common::check_params(\%params, qw(chart_id transdate));
  44   Common::check_params(\%params, qw(bt_id)) unless $params{payment_type} eq 'without_skonto';
  45   if ( $params{'payment_type'} eq 'without_skonto' && abs($params{'amount'}) < 0) {
  46     croak "invalid amount for payment_type 'without_skonto': $params{'amount'}\n";
  47   }
  48   if ($params{'payment_type'} eq 'free_skonto') {
  49     # we dont like too much automagic for this payment type.
  50     # we force caller input for amount and skonto amount
  51     Common::check_params(\%params, qw(amount skonto_amount));
  52     # secondly we dont want to handle credit notes and purchase credit notes
  53     croak("Cannot use 'free skonto' for credit or debit notes") if ($params{amount} <= 0 || $params{skonto_amount} <= 0);
  54     # both amount have to be rounded
  55     $params{skonto_amount} = _round($params{skonto_amount});
  56     $params{amount}        = _round($params{amount});
  57     # lastly skonto_amount has to be smaller than the open invoice amount or payment amount ;-)
  58     if ($params{skonto_amount} > abs($self->open_amount) || $params{skonto_amount} > $params{amount}) {
  59       croak("Skonto amount higher than the payment or invoice amount");
  60     }
  61   }
  62
  63   my $transdate_obj;
  64   if (ref($params{transdate}) eq 'DateTime') {
  65     $transdate_obj = $params{transdate};
  66   } else {
  67     $transdate_obj = $::locale->parse_date_to_object($params{transdate});
  68   };
  69   croak t8('Illegal date') unless ref $transdate_obj;
  70
  71   # check for closed period
  72   my $closedto = $::locale->parse_date_to_object($::instance_conf->get_closedto);
  73   if ( ref $closedto && $transdate_obj < $closedto ) {
  74     croak t8('Cannot post payment for a closed period!');
  75   };
  76
  77   # check for maximum number of future days
  78   if ( $::instance_conf->get_max_future_booking_interval > 0 ) {
  79     croak t8('Cannot post transaction above the maximum future booking date!') if $transdate_obj > DateTime->now->add( days => $::instance_conf->get_max_future_booking_interval );
  80   };
  81
  82   # currency is either passed or use the invoice currency if it differs from the default currency
  83   # TODO remove
  84   my ($exchangerate,$currency);
  85   if ($params{currency} || $params{currency_id}) {
  86     if ($params{currency} || $params{currency_id} ) { # currency was specified
  87       $currency = SL::DB::Manager::Currency->find_by(name => $params{currency}) || SL::DB::Manager::Currency->find_by(id => $params{currency_id});
  88     } else { # use invoice currency
  89       $currency = SL::DB::Manager::Currency->find_by(id => $self->currency_id);
  90     };
  91     die "no currency" unless $currency;
  92     if ($currency->id == $::instance_conf->get_currency_id) {
  93       $exchangerate = 1;
  94     } else {
  95       my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $currency->id,
  96                                                         transdate   => $transdate_obj,
  97                                                        );
  98       if ($rate) {
  99         $exchangerate = $is_sales ? $rate->buy : $rate->sell;
 100       } else {
 101         die "No exchange rate for " . $transdate_obj->to_kivitendo;
 102       };
 103     };
 104   } else { # no currency param given or currency is the same as default_currency
 105     $exchangerate = 1;
 106   };
 107
 108   # options with_skonto_pt and difference_as_skonto don't require the parameter
 109   # amount, but if amount is passed, make sure it matches the expected value
 110   if ( $params{'payment_type'} eq 'difference_as_skonto' ) {
 111     croak "amount $params{amount} doesn't match open amount " . $self->open_amount . ", diff = " . ($params{amount}-$self->open_amount) if $params{amount} && abs($self->open_amount - $params{amount} ) > 0.0000001;
 112   } elsif ( $params{'payment_type'} eq 'with_skonto_pt' ) {
 113     croak "amount $params{amount} doesn't match amount less skonto: " . $self->amount_less_skonto . "\n" if $params{amount} && abs($self->amount_less_skonto - $params{amount} ) > 0.0000001;
 114     croak "payment type with_skonto_pt can't be used if payments have already been made" if $self->paid != 0;
 115   };
 116
 117   # absolute skonto amount for invoice, use as reference sum to see if the
 118   # calculated skontos add up
 119   # only needed for payment_term "with_skonto_pt"
 120
 121   my $skonto_amount_check = $self->skonto_amount; # variable should be zero after calculating all skonto
 122   my $total_open_amount   = $self->open_amount;
 123
 124   # account where money is paid to/from: bank account or cash
 125   my $account_bank = SL::DB::Manager::Chart->find_by(id => $params{chart_id});
 126   croak "can't find bank account with id " . $params{chart_id} unless ref $account_bank;
 127
 128   my $reference_account = $self->reference_account;
 129   croak "can't find reference account (link = AR/AP) for invoice" unless ref $reference_account;
 130
 131   my $memo   = $params{memo}   // '';
 132   my $source = $params{source} // '';
 133
 134   my $rounded_params_amount = _round( $params{amount} ); # / $exchangerate);
 135   my $fx_gain_loss_amount = 0; # for fx_gain and fx_loss
 136
 137   my $db = $self->db;
 138   $db->with_transaction(sub {
 139     my $new_acc_trans;
 140
 141     # all three payment type create 1 AR/AP booking (the paid part)
 142     # difference_as_skonto creates n skonto bookings (1 for each buchungsgruppe type)
 143     # with_skonto_pt creates 1 bank booking and n skonto bookings (1 for each buchungsgruppe type)
 144     # without_skonto creates 1 bank booking
 145
 146     # as long as there is no automatic tax, payments are always booked with
 147     # taxkey 0
 148
 149     unless ( $params{payment_type} eq 'difference_as_skonto' ) {
 150       # cases with_skonto_pt, free_skonto and without_skonto
 151
 152       # for case with_skonto_pt we need to know the corrected amount at this
 153       # stage if we are going to use $params{amount}
 154
 155       my $pay_amount = $rounded_params_amount;
 156       $pay_amount = $self->amount_less_skonto if $params{payment_type} eq 'with_skonto_pt';
 157
 158       # bank account and AR/AP
 159       $paid_amount += $pay_amount * $exchangerate;
 160
 161       my $amount = (-1 * $pay_amount) * $mult;
 162
 163
 164       # total amount against bank, do we already know this by now?
 165       $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 166                                                    chart_id   => $account_bank->id,
 167                                                    chart_link => $account_bank->link,
 168                                                    amount     => $amount,
 169                                                    transdate  => $transdate_obj,
 170                                                    source     => $source,
 171                                                    memo       => $memo,
 172                                                    project_id => $params{project_id} ? $params{project_id} : undef,
 173                                                    taxkey     => 0,
 174                                                    tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 175       $new_acc_trans->save;
 176
 177       push @new_acc_ids, $new_acc_trans->acc_trans_id;
 178       # deal with fxtransaction
 179       if ( $self->currency_id != $::instance_conf->get_currency_id ) {
 180         my $fxamount = _round($amount - ($amount * $exchangerate));
 181         $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 182                                                      chart_id       => $account_bank->id,
 183                                                      chart_link     => $account_bank->link,
 184                                                      amount         => $fxamount * -1,
 185                                                      transdate      => $transdate_obj,
 186                                                      source         => $source,
 187                                                      memo           => $memo,
 188                                                      taxkey         => 0,
 189                                                      fx_transaction => 1,
 190                                                      tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 191         $new_acc_trans->save;
 192         push @new_acc_ids, $new_acc_trans->acc_trans_id;
 193         # if invoice exchangerate differs from exchangerate of payment
 194         # deal with fxloss and fxamount
 195         if ($self->exchangerate and $self->exchangerate != 1 and $self->exchangerate != $exchangerate) {
 196           my $fxgain_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxgain_accno_id) || die "Can't determine fxgain chart";
 197           my $fxloss_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxloss_accno_id) || die "Can't determine fxloss chart";
 198           my $gain_loss_amount = _round($amount * ($exchangerate - $self->exchangerate ) * -1,2);
 199           my $gain_loss_chart = $gain_loss_amount > 0 ? $fxgain_chart : $fxloss_chart;
 200           $fx_gain_loss_amount = $gain_loss_amount;
 201
 202           $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 203                                                        chart_id       => $gain_loss_chart->id,
 204                                                        chart_link     => $gain_loss_chart->link,
 205                                                        amount         => $gain_loss_amount,
 206                                                        transdate      => $transdate_obj,
 207                                                        source         => $source,
 208                                                        memo           => $memo,
 209                                                        taxkey         => 0,
 210                                                        fx_transaction => 0,
 211                                                        tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 212           $new_acc_trans->save;
 213           push @new_acc_ids, $new_acc_trans->acc_trans_id;
 214
 215         }
 216       }
 217     }
 218     # better everything except without_skonto
 219     if ($params{payment_type} eq 'difference_as_skonto' or $params{payment_type} eq 'with_skonto_pt'
 220         or $params{payment_type} eq 'free_skonto' ) {
 221
 222       my $total_skonto_amount;
 223       if ( $params{payment_type} eq 'with_skonto_pt' ) {
 224         $total_skonto_amount = $self->skonto_amount;
 225       } elsif ( $params{payment_type} eq 'difference_as_skonto' ) {
 226         # only used for tests. no real code calls this payment_type!
 227         $total_skonto_amount = $self->open_amount;
 228       } elsif ( $params{payment_type} eq 'free_skonto') {
 229         $total_skonto_amount = $params{skonto_amount};
 230       }
 231       my @skonto_bookings = $self->_skonto_charts_and_tax_correction(amount => $total_skonto_amount, bt_id => $params{bt_id},
 232                                                                      transdate_obj => $transdate_obj, memo => $params{memo},
 233                                                                      source => $params{source});
 234       # error checking:
 235       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 236         my $calculated_skonto_sum  = sum map { $_->{skonto_amount} } @skonto_bookings;
 237         croak "calculated skonto for difference_as_skonto = $calculated_skonto_sum doesn't add up open amount: " . $self->open_amount unless _round($calculated_skonto_sum) == _round($self->open_amount);
 238       };
 239
 240       my $reference_amount = $total_skonto_amount;
 241
 242       # create an acc_trans entry for each result of $self->skonto_charts
 243       # TODO create internal sub _skonto_bookings
 244       foreach my $skonto_booking ( @skonto_bookings ) {
 245         next unless $skonto_booking->{'chart_id'};
 246         next unless $skonto_booking->{'skonto_amount'} != 0;
 247         my $amount = -1 * $skonto_booking->{skonto_amount};
 248         $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 249                                                      chart_id   => $skonto_booking->{'chart_id'},
 250                                                      chart_link => SL::DB::Manager::Chart->find_by(id => $skonto_booking->{'chart_id'})->link,
 251                                                      amount     => $amount * $mult,
 252                                                      transdate  => $transdate_obj,
 253                                                      source     => $params{source},
 254                                                      taxkey     => 0,
 255                                                      tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 256
 257         # the acc_trans entries are saved individually, not added to $self and then saved all at once
 258         $new_acc_trans->save;
 259         push @new_acc_ids, $new_acc_trans->acc_trans_id;
 260
 261         $reference_amount -= abs($amount);
 262         $paid_amount      += -1 * $amount * $exchangerate;
 263         $skonto_amount_check -= $skonto_booking->{'skonto_amount'};
 264       }
 265       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 266           die "difference_as_skonto calculated incorrectly, sum of calculated payments doesn't add up to open amount $total_open_amount, reference_amount = $reference_amount\n" unless _round($reference_amount) == 0;
 267       }
 268     }
 269
 270     my $arap_amount = 0;
 271
 272     if ( $params{payment_type} eq 'difference_as_skonto' ) {
 273       $arap_amount = $total_open_amount;
 274     } elsif ( $params{payment_type} eq 'without_skonto' ) {
 275       $arap_amount = $rounded_params_amount;
 276     } elsif ( $params{payment_type} eq 'with_skonto_pt' ) {
 277       # this should be amount + sum(amount+skonto), but while we only allow
 278       # with_skonto_pt for completely unpaid invoices we just use the value
 279       # from the invoice
 280       $arap_amount = $total_open_amount;
 281     } elsif ( $params{payment_type} eq 'free_skonto' ) {
 282       # we forced positive values and forced rounding at the beginning
 283       # therefore the above comment can be safely applied for this payment type
 284       $arap_amount = $params{amount} + $params{skonto_amount};
 285     }
 286
 287     # regardless of payment_type there is always only exactly one arap booking
 288     # TODO: compare $arap_amount to running total
 289     my $arap_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 290                                                   chart_id   => $reference_account->id,
 291                                                   chart_link => $reference_account->link,
 292                                                   amount     => _round($arap_amount * $mult * $exchangerate - $fx_gain_loss_amount),
 293                                                   transdate  => $transdate_obj,
 294                                                   source     => '', #$params{source},
 295                                                   taxkey     => 0,
 296                                                   tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 297     $arap_booking->save;
 298     push @new_acc_ids, $arap_booking->acc_trans_id;
 299
 300     # hook for invoice_for_advance_payment DATEV always pairs, acc_trans_id has to be higher than arap_booking ;-)
 301     if ($self->invoice_type eq 'invoice_for_advance_payment') {
 302       my $clearing_chart = SL::DB::Chart->new(id => $::instance_conf->get_advance_payment_clearing_chart_id)->load;
 303       die "No Clearing Chart for Advance Payment" unless ref $clearing_chart eq 'SL::DB::Chart';
 304
 305       # what does ptc say
 306       my %inv_calc = $self->calculate_prices_and_taxes();
 307       my @trans_ids = keys %{ $inv_calc{amounts} };
 308       die "Invalid state for advance payment more than one trans_id" if (scalar @trans_ids > 1);
 309       my $entry = delete $inv_calc{amounts}{$trans_ids[0]};
 310       my $tax;
 311       if ($entry->{tax_id}) {
 312         $tax = SL::DB::Manager::Tax->find_by(id => $entry->{tax_id}); # || die "Can't find tax with id " . $entry->{tax_id};
 313       }
 314       if ($tax and $tax->rate != 0) {
 315         my ($netamount, $taxamount);
 316         my $roundplaces = 2;
 317         # we dont have a clue about skonto, that's why we use $arap_amount as taxincluded
 318         ($netamount, $taxamount) = Form->calculate_tax($arap_amount, $tax->rate, 1, $roundplaces);
 319         # for debugging database set
 320         my $fullmatch = $netamount == $entry->{amount} ? '::netamount total true' : '';
 321         my $transfer_chart = $tax->taxkey == 2 ? SL::DB::Chart->new(id => $::instance_conf->get_advance_payment_taxable_7_id)->load
 322                           :  $tax->taxkey == 3 ? SL::DB::Chart->new(id => $::instance_conf->get_advance_payment_taxable_19_id)->load
 323                           :  undef;
 324         die "No Transfer Chart for Advance Payment" unless ref $transfer_chart eq 'SL::DB::Chart';
 325
 326         my $arap_full_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 327                                                            chart_id   => $clearing_chart->id,
 328                                                            chart_link => $clearing_chart->link,
 329                                                            amount     => $arap_amount * -1, # full amount
 330                                                            transdate  => $transdate_obj,
 331                                                            source     => 'Automatic Tax Booking for Payment in Advance' . $fullmatch,
 332                                                            taxkey     => 0,
 333                                                            tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 334         $arap_full_booking->save;
 335         push @new_acc_ids, $arap_full_booking->acc_trans_id;
 336
 337         my $arap_tax_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 338                                                           chart_id   => $transfer_chart->id,
 339                                                           chart_link => $transfer_chart->link,
 340                                                           amount     => _round($netamount), # full amount
 341                                                           transdate  => $transdate_obj,
 342                                                           source     => 'Automatic Tax Booking for Payment in Advance' . $fullmatch,
 343                                                           taxkey     => $tax->taxkey,
 344                                                           tax_id     => $tax->id);
 345         $arap_tax_booking->save;
 346         push @new_acc_ids, $arap_tax_booking->acc_trans_id;
 347
 348         my $tax_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 349                                                      chart_id   => $tax->chart_id,
 350                                                      chart_link => $tax->chart->link,
 351                                                      amount     => _round($taxamount),
 352                                                      transdate  => $transdate_obj,
 353                                                      source     => 'Automatic Tax Booking for Payment in Advance' . $fullmatch,
 354                                                      taxkey     => 0,
 355                                                      tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 356
 357         $tax_booking->save;
 358         push @new_acc_ids, $tax_booking->acc_trans_id;
 359       }
 360     }
 361     $fx_gain_loss_amount *= -1 if $self->is_sales;
 362     $self->paid($self->paid + _round($paid_amount) + $fx_gain_loss_amount) if $paid_amount;
 363     $self->datepaid($transdate_obj);
 364     $self->save;
 365
 366     # make sure transactions will be reloaded the next time $self->transactions
 367     # is called, as pay_invoice saves the acc_trans objects individually rather
 368     # than adding them to the transaction relation array.
 369     $self->forget_related('transactions');
 370
 371     my $datev_check = 0;
 372     if ( $is_sales )  {
 373       if ( (  $self->invoice && $::instance_conf->get_datev_check_on_sales_invoice  ) ||
 374            ( !$self->invoice && $::instance_conf->get_datev_check_on_ar_transaction )) {
 375         $datev_check = 1;
 376       }
 377     } else {
 378       if ( (  $self->invoice && $::instance_conf->get_datev_check_on_purchase_invoice ) ||
 379            ( !$self->invoice && $::instance_conf->get_datev_check_on_ap_transaction   )) {
 380         $datev_check = 1;
 381       }
 382     }
 383
 384     if ( $datev_check ) {
 385
 386       my $datev = SL::DATEV->new(
 387         dbh        => $db->dbh,
 388         trans_id   => $self->{id},
 389       );
 390
 391       $datev->generate_datev_data;
 392
 393       if ($datev->errors) {
 394         # this exception should be caught by with_transaction, which handles the rollback
 395         die join "\n", $::locale->text('DATEV check returned errors:'), $datev->errors;
 396       }
 397     }
 398
 399     1;
 400
 401   }) || die t8('error while paying invoice #1 : ', $self->invnumber) . $db->error . "\n";
 402   return wantarray ? @new_acc_ids : 1;
 403 }
 404
 405 sub skonto_date {
 406
 407   my $self = shift;
 408
 409   return undef unless ref $self->payment_terms;
 410   return undef unless $self->payment_terms->terms_skonto > 0;
 411   return DateTime->from_object(object => $self->transdate)->add(days => $self->payment_terms->terms_skonto);
 412 };
 413
 414 sub reference_account {
 415   my $self = shift;
 416
 417   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 418
 419   require SL::DB::Manager::AccTransaction;
 420
 421   my $link_filter = $is_sales ? 'AR' : 'AP';
 422
 423   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 424      trans_id   => $self->id,
 425      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 426   );
 427
 428   return undef unless ref $acc_trans;
 429
 430   my $reference_account = SL::DB::Manager::Chart->find_by(id => $acc_trans->chart_id);
 431
 432   return $reference_account;
 433 };
 434
 435 sub reference_amount {
 436   my $self = shift;
 437
 438   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 439
 440   require SL::DB::Manager::AccTransaction;
 441
 442   my $link_filter = $is_sales ? 'AR' : 'AP';
 443
 444   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 445      trans_id   => $self->id,
 446      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 447   );
 448
 449   return undef unless ref $acc_trans;
 450
 451   # this should be the same as $self->amount
 452   return $acc_trans->amount;
 453 };
 454
 455
 456 sub open_amount {
 457   my $self = shift;
 458
 459   # in the future maybe calculate this from acc_trans
 460
 461   # if the difference is 0.01 Cent this may end up as 0.009999999999998
 462   # numerically, so round this value when checking for cent threshold >= 0.01
 463
 464   return ($self->amount // 0) - ($self->paid // 0);
 465 };
 466
 467 sub open_percent {
 468   my $self = shift;
 469
 470   return 0 if $self->amount == 0;
 471   my $open_percent;
 472   if ( $self->open_amount < 0 ) {
 473     # overpaid, currently treated identically
 474     $open_percent = $self->open_amount * 100 / $self->amount;
 475   } else {
 476     $open_percent = $self->open_amount * 100 / $self->amount;
 477   };
 478
 479   return _round($open_percent) || 0;
 480 };
 481
 482 sub skonto_amount {
 483   my $self = shift;
 484
 485   return $self->amount - $self->amount_less_skonto;
 486 };
 487
 488 sub remaining_skonto_days {
 489   my $self = shift;
 490
 491   return undef unless ref $self->skonto_date;
 492
 493   my $dur = DateTime::Duration->new($self->skonto_date - DateTime->today);
 494   return $dur->delta_days();
 495
 496 };
 497
 498 sub percent_skonto {
 499   my $self = shift;
 500
 501   my $percent_skonto = 0;
 502
 503   return undef unless ref $self->payment_terms;
 504   return undef unless $self->payment_terms->percent_skonto > 0;
 505   $percent_skonto = $self->payment_terms->percent_skonto;
 506
 507   return $percent_skonto;
 508 };
 509
 510 sub amount_less_skonto {
 511   # amount that has to be paid if skonto applies, always return positive rounded values
 512   # no, rare case, but credit_notes and negative ap have negative amounts
 513   # and therefore this comment may be misguiding
 514   # the result is rounded so we can directly compare it with the user input
 515   my $self = shift;
 516
 517   my $percent_skonto = $self->percent_skonto || 0;
 518
 519   return _round($self->amount - ( $self->amount * $percent_skonto) );
 520
 521 };
 522
 523 sub check_skonto_configuration {
 524   my $self = shift;
 525
 526   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 527
 528   my $skonto_configured = 1; # default is assume skonto works
 529
 530   # my $transactions = $self->transactions;
 531   foreach my $transaction (@{ $self->transactions }) {
 532     # find all transactions with an AR_amount or AP_amount link
 533     my $tax = SL::DB::Manager::Tax->get_first( where => [taxkey => $transaction->taxkey, id => $transaction->tax_id ]);
 534
 535     # acc_trans entries for the taxes (chart_link == A[RP]_tax) often
 536     # have combinations of taxkey & tax_id that don't exist in
 537     # tax. Those must be skipped.
 538     next if !$tax && ($transaction->chart_link !~ m{A[RP]_amount});
 539
 540     croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 541
 542     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->chart_link) };
 543     if ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) {
 544       $skonto_configured = 0 unless $tax->skonto_sales_chart_id;
 545     } elsif ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) {
 546       $skonto_configured = 0 unless $tax->skonto_purchase_chart_id;
 547     };
 548   };
 549
 550   return $skonto_configured;
 551 };
 552
 553 sub open_sepa_transfer_amount {
 554   my $self = shift;
 555
 556   my ($vc, $key, $type);
 557   if ( ref($self) eq 'SL::DB::Invoice' ) {
 558     $vc   = 'customer';
 559     $key  = 'ap_id';
 560     $type = 'ar';
 561   } else {
 562     $vc   = 'vendor';
 563     $key  = 'ap_id';
 564     $type = 'ap';
 565   };
 566
 567   my $sql = qq|SELECT SUM(sei.amount) AS amount FROM sepa_export_items sei | .
 568             qq| LEFT JOIN sepa_export se ON (sei.sepa_export_id = se.id)   | .
 569             qq| WHERE $key = ? AND NOT se.closed AND (se.vc = '$vc')       |;
 570
 571   my ($open_sepa_amount) = $self->db->dbh->selectrow_array($sql, undef, $self->id);
 572
 573   return $open_sepa_amount || 0;
 574
 575 }
 576
 577 sub _skonto_charts_and_tax_correction {
 578   my ($self, %params)   = @_;
 579   my $amount = $params{amount} || $self->skonto_amount;
 580
 581   croak "no amount passed to skonto_charts"                    unless abs(_round($amount)) >= 0.01;
 582   croak "no banktransaction.id passed to skonto_charts"        unless $params{bt_id};
 583   croak "no banktransaction.transdate passed to skonto_charts" unless ref $params{transdate_obj} eq 'DateTime';
 584   #$main::lxdebug->message(0, 'id der transaktion' . $params{bt_id});
 585   #$main::lxdebug->message(0, 'wert des skontos:' . $amount);
 586   my $is_sales = $self->is_sales;
 587   my (@skonto_charts, $inv_calc, $total_skonto_rounded);
 588   $inv_calc = $self->get_tax_and_amount_by_tax_chart_id();
 589   #$main::lxdebug->message(0, 'lulu' . Dumper($inv_calc));
 590   while (my ($tax_chart_id, $entry) = each %{ $inv_calc } ) {  # foreach tax key = tax.id
 591     #$main::lxdebug->message(0, 'was hier:' . $tax_chart_id);
 592     my $tax = SL::DB::Manager::Tax->find_by(id => $entry->{tax_id}) || die "Can't find tax with id " . $tax_chart_id;
 593     die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $tax->taxkey, $tax->taxdescription , $tax->rate * 100)
 594       unless $is_sales ? ref $tax->skonto_sales_chart : ref $tax->skonto_purchase_chart;
 595     #$main::lxdebug->message(0, 'was dort:' . $tax->id);
 596     my $transaction_net_skonto_percent = abs($entry->{netamount} / $self->amount);
 597     my $skonto_netamount_unrounded     = abs($amount * $transaction_net_skonto_percent);
 598     #$main::lxdebug->message(0, 'ungerundet netto:' . $skonto_netamount_unrounded);
 599     # divide for tax
 600     my $transaction_tax_skonto_percent = abs($entry->{tax} / $self->amount);
 601     my $skonto_taxamount_unrounded     = abs($amount * $transaction_tax_skonto_percent);
 602     #$main::lxdebug->message(0, 'ungerundet steuer:' . $skonto_taxamount_unrounded);
 603     my $skonto_taxamount_rounded   = _round($skonto_taxamount_unrounded);
 604     my $skonto_netamount_rounded   = _round($skonto_netamount_unrounded);
 605     my $chart_id                   = $is_sales ? $tax->skonto_sales_chart->id : $tax->skonto_purchase_chart->id;
 606
 607     my $rec_net = {
 608       chart_id               => $chart_id,
 609       skonto_amount          => _round($skonto_netamount_unrounded + $skonto_taxamount_unrounded),
 610       # skonto_amount          => _round($skonto_netamount_unrounded) + _round($skonto_taxamount_unrounded),
 611     };
 612     push @skonto_charts, $rec_net;
 613     $total_skonto_rounded += $rec_net->{skonto_amount};
 614
 615     # add-on: correct tax with one linked gl booking
 616
 617     # no skonto tax correction for dual tax (reverse charge) or rate = 0
 618     next if ($tax->rate == 0 || $tax->reverse_charge_chart_id);
 619
 620     my ($credit, $debit);
 621     $credit = SL::DB::Manager::Chart->find_by(id => $chart_id);
 622     $debit  = SL::DB::Manager::Chart->find_by(id => $tax_chart_id);
 623     croak("No such Chart ID")  unless ref $credit eq 'SL::DB::Chart' && ref $debit eq 'SL::DB::Chart';
 624
 625     my $current_transaction = SL::DB::GLTransaction->new(
 626          employee_id    => $self->employee_id,
 627          transdate      => $params{transdate_obj},
 628          notes          => $params{source} . ' ' . $params{memo},
 629          description    => $self->notes || $self->invnumber,
 630          reference      => t8('Skonto Tax Correction for') . " " . $tax->rate * 100 . '% ' . $self->invnumber,
 631          department_id  => $self->department_id ? $self->department_id : undef,
 632          imported       => 0, # not imported
 633          taxincluded    => 0,
 634       )->add_chart_booking(
 635          chart  => $is_sales ? $debit : $credit,
 636          debit  => abs($skonto_taxamount_rounded),
 637          source => t8('Skonto Tax Correction for') . " " . $self->invnumber,
 638          memo   => $params{memo},
 639          tax_id => 0,
 640       )->add_chart_booking(
 641          chart  => $is_sales ? $credit : $debit,
 642          credit => abs($skonto_taxamount_rounded),
 643          source => t8('Skonto Tax Correction for') . " " . $self->invnumber,
 644          memo   => $params{memo},
 645          tax_id => 0,
 646       )->post;
 647
 648     ## add a stable link from ap to gl
 649     # not needed, BankTransactionAccTrans is already stable
 650     # furthermore the origin of the booking is the bank_transaction
 651     #my $arap = $self->is_sales ? 'ar' : 'ap';
 652     #my %props_gl = (
 653     #  $arap . _id => $self->id,
 654     #  gl_id => $current_transaction->id,
 655     #  datev_export => 1,
 656     #);
 657     #if ($arap eq 'ap') {
 658     #  require SL::DB::ApGl;
 659     #  SL::DB::ApGl->new(%props_gl)->save;
 660     #} elsif ($arap eq 'ar') {
 661     #  require SL::DB::ArGl;
 662     #  SL::DB::ArGl->new(%props_gl)->save;
 663     #} else { die "Invalid state"; }
 664     #push @new_acc_ids, map { $_->acc_trans_id } @{ $current_transaction->transactions };
 665
 666     foreach my $transaction (@{ $current_transaction->transactions }) {
 667       my %props_acc = (
 668            acc_trans_id        => $transaction->acc_trans_id,
 669            bank_transaction_id => $params{bt_id},
 670            gl                  => $current_transaction->id,
 671       );
 672       SL::DB::BankTransactionAccTrans->new(%props_acc)->save;
 673     }
 674     # Record a record link from banktransactions to gl
 675     # caller has to assign param bt_id
 676     my %props_rl = (
 677          from_table => 'bank_transactions',
 678          from_id    => $params{bt_id},
 679          to_table   => 'gl',
 680          to_id      => $current_transaction->id,
 681     );
 682     SL::DB::RecordLink->new(%props_rl)->save;
 683     # Record a record link from arap to gl
 684     # linked gl booking will appear in tab linked records
 685     # this is just a link for convenience
 686     %props_rl = (
 687          from_table => $is_sales ? 'ar' : 'ap',
 688          from_id    => $self->id,
 689          to_table   => 'gl',
 690          to_id      => $current_transaction->id,
 691     );
 692     SL::DB::RecordLink->new(%props_rl)->save;
 693
 694   }
 695   # check for rounding errors, at least for the payment chart
 696   # we ignore tax rounding errors as long as the user or calculated
 697   # amount of skonto is fully assigned
 698   # we simply alter one cent for the first skonto booking entry
 699   # should be correct for most of the cases (no invoices with mixed taxes)
 700   if ($total_skonto_rounded - $amount > 0.01) {
 701     # add one cent
 702     $main::lxdebug->message(0, 'Una mas!' . $total_skonto_rounded);
 703     $skonto_charts[0]->{skonto_amount} -= 0.01;
 704   } elsif ($amount - $total_skonto_rounded > 0.01) {
 705     # subtract one cent
 706     $main::lxdebug->message(0, 'Una menos!' . $total_skonto_rounded);
 707     $skonto_charts[0]->{skonto_amount} += 0.01;
 708   } else { $main::lxdebug->message(0, 'No rounding error');  }
 709
 710   # return same array of skonto charts as sub skonto_charts
 711   return @skonto_charts;
 712 }
 713
 714 sub within_skonto_period {
 715   my $self = shift;
 716   my $dateref = shift || DateTime->now->truncate( to => 'day' );
 717
 718   return undef unless ref $dateref eq 'DateTime';
 719   return 0 unless $self->skonto_date;
 720
 721   # return 1 if requested date (or today) is inside skonto period
 722   # this will also return 1 if date is before the invoice date
 723   return $dateref <= $self->skonto_date;
 724 };
 725
 726 sub valid_skonto_amount {
 727   my $self = shift;
 728   my $amount = shift || 0;
 729   my $max_skonto_percent = 0.10;
 730
 731   return 0 unless $amount > 0;
 732
 733   # does this work for other currencies?
 734   return ($self->amount*$max_skonto_percent) > $amount;
 735 };
 736
 737 sub get_payment_select_options_for_bank_transaction {
 738   my ($self, $bt_id, %params) = @_;
 739
 740
 741   # CAVEAT template code expects with_skonto_pt at position 1 for visual help
 742   # due to skonto_charts, we cannot offer skonto for credit notes and neg ap
 743   my $skontoable = $self->amount > 0 ? 1 : 0;
 744   my @options;
 745   if(!$self->skonto_date) {
 746     push(@options, { payment_type => 'without_skonto', display => t8('without skonto'), selected => 1 });
 747     # wrong call to presenter or not implemented? disabled option is ignored
 748     # push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt'), disabled => 1 });
 749     push(@options, { payment_type => 'free_skonto', display => t8('free skonto') }) if $skontoable;
 750     return @options;
 751   }
 752   # valid skonto date, check if skonto is preferred
 753   my $bt = SL::DB::BankTransaction->new(id => $bt_id)->load;
 754   if ($self->skonto_date && $self->within_skonto_period($bt->transdate)) {
 755     push(@options, { payment_type => 'without_skonto', display => t8('without skonto') });
 756     push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt'), selected => 1 }) if $skontoable;
 757   } else {
 758     push(@options, { payment_type => 'without_skonto', display => t8('without skonto') , selected => 1 });
 759     push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt')}) if $skontoable;
 760   }
 761   push(@options, { payment_type => 'free_skonto', display => t8('free skonto') }) if $skontoable;
 762   return @options;
 763 }
 764
 765 sub exchangerate {
 766   my ($self) = @_;
 767
 768   return 1 if $self->currency_id == $::instance_conf->get_currency_id;
 769
 770   die "transdate isn't a DateTime object:" . ref($self->transdate) unless ref($self->transdate) eq 'DateTime';
 771   my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $self->currency_id,
 772                                                     transdate   => $self->transdate,
 773                                                    );
 774   return undef unless $rate;
 775
 776   return $self->is_sales ? $rate->buy : $rate->sell; # also undef if not defined
 777 };
 778
 779 sub get_payment_suggestions {
 780
 781   my ($self, %params) = @_;
 782
 783   my $open_amount = $self->open_amount;
 784   $open_amount   -= $self->open_sepa_transfer_amount if $params{sepa};
 785
 786   $self->{invoice_amount_suggestion} = $open_amount;
 787   undef $self->{payment_select_options};
 788   push(@{$self->{payment_select_options}} , { payment_type => 'without_skonto',  display => t8('without skonto') });
 789   if ( $self->within_skonto_period ) {
 790     # If there have been no payments yet suggest amount_less_skonto, otherwise the open amount
 791     if ( $open_amount &&                   # invoice amount not 0
 792          $open_amount == $self->amount &&  # no payments yet, or sum of payments and sepa export amounts is zero
 793          $self->check_skonto_configuration) {
 794       $self->{invoice_amount_suggestion} = $self->amount_less_skonto;
 795       push(@{$self->{payment_select_options}} , { payment_type => 'with_skonto_pt',  display => t8('with skonto acc. to pt') , selected => 1 });
 796     } else {
 797       if ( ( $self->valid_skonto_amount($self->open_amount) || $self->valid_skonto_amount($open_amount) ) and not $params{sepa} ) {
 798         # Will never be reached
 799         die "This case is as dead as the dead cat. Go to start, don't pick 2,000 \$";
 800         $self->{invoice_amount_suggestion} = $open_amount;
 801         # only suggest difference_as_skonto if open_amount exactly matches skonto_amount
 802         # AND we aren't in SEPA mode
 803         my $selected = 0;
 804         $selected = 1 if _round($open_amount) == _round($self->skonto_amount);
 805         push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => $selected });
 806       };
 807     };
 808   } else {
 809     # invoice was configured with skonto, but skonto date has passed, or no skonto available
 810     $self->{invoice_amount_suggestion} = $open_amount;
 811     # difference_as_skonto doesn't make any sense for SEPA transfer, as this doesn't cause any actual payment
 812     if ( $self->valid_skonto_amount($self->open_amount) && not $params{sepa} ) {
 813       push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => 0 });
 814     };
 815   };
 816   return 1;
 817 };
 818
 819 # locales for payment type
 820 #
 821 # $main::locale->text('without_skonto')
 822 # $main::locale->text('with_skonto_pt')
 823 # $main::locale->text('difference_as_skonto')
 824 #
 825
 826 sub validate_payment_type {
 827   my $payment_type = shift;
 828
 829   my %allowed_payment_types = map { $_ => 1 } qw(without_skonto with_skonto_pt difference_as_skonto free_skonto);
 830   croak "illegal payment type: $payment_type, must be one of: " . join(' ', keys %allowed_payment_types) unless $allowed_payment_types{ $payment_type };
 831
 832   return 1;
 833 }
 834
 835 sub forex {
 836   my ($self) = @_;
 837   $self->currency_id == $::instance_conf->get_currency_id ? return 0 : return 1;
 838 };
 839
 840 sub _round {
 841   my $value = shift;
 842   my $num_dec = 2;
 843   return $::form->round_amount($value, 2);
 844 }
 845
 846 1;
 847
 848 __END__
 849
 850 =pod
 851
 852 =head1 NAME
 853
 854 SL::DB::Helper::Payment  Mixin providing helper methods for paying C<Invoice>
 855                          and C<PurchaseInvoice> objects and using skonto
 856
 857 =head1 SYNOPSIS
 858
 859 In addition to actually causing a payment via pay_invoice this helper contains
 860 many methods that help in determining information about the status of the
 861 invoice, such as the remaining open amount, whether skonto applies, until which
 862 date skonto applies, the skonto amount and relative percentages, what to do
 863 with skonto, ...
 864
 865 To prevent duplicate code this was all added in this mixin rather than directly
 866 in SL::DB::Invoice and SL::DB::PurchaseInvoice.
 867
 868 =over 4
 869
 870 =item C<pay_invoice %params>
 871
 872 Create a payment booking for an existing invoice object (type ar/ap/is/ir) via
 873 a configured bank account.
 874
 875 This function deals with all the acc_trans entries and also updates paid and datepaid.
 876 The params C<transdate> and C<chart_id> are mandantory.
 877 If the default payment ('without_skonto') is used the param amount is also
 878 mandantory.
 879 If the payment type ('free_skonto') is used the number params skonto_amount and amount
 880 are as well mandantory and need to be positive. Furthermore the skonto amount has
 881 to be lower than the payment or open invoice amount.
 882
 883 Transdate can either be a date object or a date string.
 884 Chart_id is the id of the payment booking chart.
 885 Amount is either a positive or negative number, but never 0.
 886
 887 CAVEAT! The helper tries to get the sign right and all calls from BankTransaction are
 888 positive (abs($value)) values.
 889
 890
 891 Example:
 892
 893   my $ap   = SL::DB::Manager::PurchaseInvoice->find_by( invnumber => '1');
 894   my $bank = SL::DB::Manager::BankAccount->find_by( name => 'Bank');
 895   $ap->pay_invoice(chart_id      => $bank->chart_id,
 896                    amount        => $ap->open_amount,
 897                    transdate     => DateTime->now->to_kivitendo,
 898                    memo          => 'foobar',
 899                    source        => 'barfoo',
 900                    payment_type  => 'without_skonto',  # default if not specified
 901                    project_id    => 25,
 902                   );
 903
 904 or with skonto:
 905   $ap->pay_invoice(chart_id      => $bank->chart_id,
 906                    amount        => $ap->amount,       # doesn't need to be specified
 907                    transdate     => DateTime->now->to_kivitendo,
 908                    memo          => 'foobar',
 909                    source        => 'barfoo',
 910                    payment_type  => 'with_skonto',
 911                   );
 912
 913 or in a certain currency:
 914   $ap->pay_invoice(chart_id      => $bank->chart_id,
 915                    amount        => 500,
 916                    currency      => 'USD',
 917                    transdate     => DateTime->now->to_kivitendo,
 918                    memo          => 'foobar',
 919                    source        => 'barfoo',
 920                    payment_type  => 'with_skonto_pt',
 921                   );
 922
 923 Allowed payment types are:
 924   without_skonto with_skonto_pt difference_as_skonto
 925
 926 The option C<payment_type> allows for a basic skonto mechanism.
 927
 928 C<without_skonto> is the default mode, "amount" is paid to the account in
 929 chart_id. This can also be used for partial payments and corrections via
 930 negative amounts.
 931
 932 C<with_skonto_pt> can't be used for partial payments. When used on unpaid
 933 invoices the whole amount is paid, with the skonto part automatically being
 934 booked according to the skonto chart configured in the tax settings for each
 935 tax key. If an amount is passed it is ignored and the actual configured skonto
 936 amount is used.
 937
 938 C<difference_as_skonto> can only be used after partial payments have been made,
 939 the whole specified amount is booked according to the skonto charts configured
 940 in the tax settings for each tax key.
 941
 942 So passing amount doesn't have any effect for the cases C<with_skonto_pt> and
 943 C<difference_as_skonto>, as all necessary values are taken from the stored
 944 invoice.
 945
 946 The skonto modes automatically calculate the relative amounts for a mix of
 947 taxes, e.g. items with 7% and 19% in one invoice. There is a helper method
 948 skonto_charts, which calculates the relative percentages according to the
 949 amounts in acc_trans (which are grouped by tax).
 950
 951 There is currently no way of excluding certain items in an invoice from having
 952 skonto applied to them.  If this feature was added to parts the calculation
 953 method of relative skonto would have to be completely rewritten using the
 954 invoice items rather than acc_trans.
 955
 956 The skonto modes also still don't automatically correct the tax, this still has
 957 to be done manually. Therefore all payments generated by pay_invoice have
 958 taxkey 0.
 959
 960 There is currently no way to directly pay an invoice via this method if the
 961 effective skonto differs from the skonto according to the payment terms
 962 configured for the invoice/vendor.
 963
 964 In this case one has to pay in two steps: first the actual paid amount via
 965 "without skonto", and then the remainder via "difference_as_skonto". The user
 966 has to there actively decide whether to accept the differing skonto.
 967
 968 Because of the way skonto_charts works the calculation doesn't work if there
 969 are negative values in acc_trans. E.g. one invoice with a positive value for
 970 19% tax and a negative value for the acc_trans line with 7%
 971
 972 Skonto doesn't/shouldn't apply if the invoice contains credited items.
 973
 974 If no amount is given the whole open amout is paid.
 975
 976 If neither currency or currency_id are given as params, the currency of the
 977 invoice is assumed to be the payment currency.
 978
 979 If successful the return value will be 1 in scalar context or in list context
 980 the two ids (acc_trans_id) of the newly created bookings.
 981
 982 =item C<reference_account>
 983
 984 Returns a chart object which is the chart of the invoice with link AR or AP.
 985
 986 Example (1200 is the AR account for SKR04):
 987   my $invoice = invoice(invnumber => '144');
 988   $invoice->reference_account->accno
 989   # 1200
 990
 991 =item C<percent_skonto>
 992
 993 Returns the configured skonto percentage of the payment terms of an invoice,
 994 e.g. 0.02 for 2%. Payment terms come from invoice settingssettings for ap.
 995
 996 =item C<amount_less_skonto>
 997
 998 If the invoice has a payment term,
 999 calculate the amount to be paid in the case of skonto.  This doesn't check,
1000 whether skonto applies (i.e. skonto doesn't wasn't exceeded), it just subtracts
1001 the configured percentage (e.g. 2%) from the total amount.
1002
1003 The returned value is rounded to two decimals.
1004
1005 =item C<skonto_date>
1006
1007 The date up to which skonto may be taken. This is calculated from the invoice
1008 date + the number of days configured in the payment terms.
1009
1010 This method can also be used to determine whether skonto applies for the
1011 invoice, as it returns undef if there is no payment term or skonto days is set
1012 to 0.
1013
1014 =item C<within_skonto_period [DATE]>
1015
1016 Returns 0 or 1.
1017
1018 Checks whether the invoice has payment terms configured, and whether the date
1019 is within the skonto max date. If no date is passed the current date is used.
1020
1021 You can also pass a dateref object as a parameter to check whether skonto
1022 applies for that date rather than the current date.
1023
1024 =item C<valid_skonto_amount>
1025
1026 Takes an amount as an argument and checks whether the amount is less than 10%
1027 of the total amount of the invoice. The value of 10% is currently hardcoded in
1028 the method. This method is currently used to check whether to offer the payment
1029 option "difference as skonto".
1030
1031 Example:
1032  if ( $invoice->valid_skonto_amount($invoice->open_amount) ) {
1033    # ... do something
1034  }
1035
1036 =item C<skonto_charts [$amount]>
1037
1038 Returns a list of chart_ids and some calculated numbers that can be used for
1039 paying the invoice with skonto. This function will automatically calculate the
1040 relative skonto amounts even if the invoice contains several types of taxes
1041 (e.g. 7% and 19%).
1042
1043 Example usage:
1044   my $invoice = SL::DB::Manager::Invoice->find_by(invnumber => '211');
1045   my @skonto_charts = $invoice->skonto_charts;
1046
1047 or with the total skonto amount as an argument:
1048   my @skonto_charts = $invoice->skonto_charts($invoice->open_amount);
1049
1050 The following values are generated for each chart:
1051
1052 =over 2
1053
1054 =item C<chart_id>
1055
1056 The chart id of the skonto amount to be booked.
1057
1058 =item C<skonto_amount>
1059
1060 The total amount to be paid to the account
1061
1062 =item C<skonto_percent>
1063
1064 The relative percentage of that skonto chart. This can be useful if the actual
1065 ekonto that is paid deviates from the granted skonto, e.g. customer effectively
1066 pays 2.6% skonto instead of 2%, and we accept this. Then we can still calculate
1067 the relative skonto amounts for different taxes based on the absolute
1068 percentages. Used for case C<difference_as_skonto>.
1069
1070 =item C<skonto_percent_abs>
1071
1072 The absolute percentage of that skonto chart in relation to the total amount.
1073 Used to calculate skonto_amount for case C<with_skonto_pt>.
1074
1075 =back
1076
1077 If the invoice contains several types of taxes then skonto_charts can be used
1078 to calculate the relative amounts.
1079
1080 Example in console of an invoice with 100 Euro at 7% and 100 Euro at 19% with
1081 tax not included:
1082
1083   my $invoice = invoice(invnumber => '144');
1084   $invoice->amount
1085   226.00000
1086   $invoice->payment_terms->percent_skonto
1087   0.02
1088   $invoice->skonto_charts
1089   pp $invoice->skonto_charts
1090   #             $VAR1 = {
1091   #               'chart_id'       => 128,
1092   #               'skonto_amount'  => '2.14',
1093   #               'skonto_percent' => '47.3451327433627'
1094   #             };
1095   #             $VAR2 = {
1096   #               'chart_id'       => 130,
1097   #               'skonto_amount'  => '2.38',
1098   #               'skonto_percent' => '52.654867256637'
1099   #             };
1100
1101 C<skonto_charts> always returns positive values (abs) for C<skonto_amount> and
1102 C<skonto_percent>.
1103
1104 C<skonto_charts> generates one entry for each acc_trans entry. ar and ap
1105 bookings only have one acc_trans entry for each taxkey (e.g. 7% and 19%).  This
1106 is because all the items are grouped according to the Buchungsgruppen mechanism
1107 and the totals are written to acc_trans.  For is and ir it is possible to have
1108 several acc_trans entries with the same tax. In this case skonto_charts
1109 generates a skonto booking for each acc_trans income/expense entry.
1110
1111 In the future this function may also be used to calculate the corrections for
1112 the income tax.
1113
1114 =item C<open_amount>
1115
1116 Unrounded total open amount of invoice (amount - paid).
1117 Doesn't take into account pending SEPA transfers.
1118
1119 =item C<open_percent>
1120
1121 Percentage of the invoice that is still unpaid, e.g. 100,00 if no payments have
1122 been made yet, 0,00 if fully paid.
1123
1124 =item C<remaining_skonto_days>
1125
1126 How many days skonto can still be taken, calculated from current day. Returns 0
1127 if current day is the max skonto date, and negative number if skonto date has
1128 already passed.
1129
1130 Returns undef if skonto is not configured for that invoice.
1131
1132 =item C<get_payment_suggestions %params>
1133
1134 Creates data intended for an L.select_tag dropdown that can be used in a
1135 template. Depending on the rules it will choose from the options
1136 without_skonto, with_skonto_pt and difference_as_skonto, and select the most
1137 likely one.
1138
1139 If the parameter "sepa" is passed, the SEPA export payments that haven't been
1140 executed yet are considered when determining the open amount of the invoice.
1141
1142 The current rules are:
1143
1144 =over 2
1145
1146 =item * without_skonto is always an option
1147
1148 =item * with_skonto_pt is only offered if there haven't been any payments yet and the current date is within the skonto period.
1149
1150 =item * difference_as_skonto is only offered if there have already been payments made and the open amount is smaller than 10% of the total amount.
1151
1152 with_skonto_pt will only be offered, if all the AR_amount/AP_amount have a
1153 taxkey with a configured skonto chart
1154
1155 =back
1156
1157 It will also fill $self->{invoice_amount_suggestion} with either the open
1158 amount, or if with_skonto_pt is selected, with amount_less_skonto, so the
1159 template can fill the input with the likely amount.
1160
1161 Example in console:
1162   my $ar = invoice( invnumber => '257');
1163   $ar->get_payment_suggestions;
1164   print $ar->{invoice_amount_suggestion} . "\n";
1165   # 97.23
1166   pp $ar->{payment_select_options}
1167   # $VAR1 = [
1168   #         {
1169   #           'display' => 'ohne Skonto',
1170   #           'payment_type' => 'without_skonto'
1171   #         },
1172   #         {
1173   #           'display' => 'mit Skonto nach ZB',
1174   #           'payment_type' => 'with_skonto_pt',
1175   #           'selected' => 1
1176   #         }
1177   #       ];
1178
1179 The resulting array $ar->{payment_select_options} can be used in a template
1180 select_tag using value_key and title_key:
1181
1182 [% L.select_tag('payment_type_' _ loop.count, invoice.payment_select_options, value_key => 'payment_type', title_key => 'display', id => 'payment_type_' _ loop.count) %]
1183
1184 It would probably make sense to have different rules for the pre-selected items
1185 for sales and purchase, and to also make these rules configurable in the
1186 defaults. E.g. when creating a SEPA bank transfer for vendor invoices a company
1187 might always want to pay quickly making use of skonto, while another company
1188 might always want to pay as late as possible.
1189
1190 =item C<get_payment_select_options_for_bank_transaction $banktransaction_id %params>
1191
1192 Make suggestion for a skonto payment type by returning an HTML blob of the options
1193 of a HTML drop-down select with the most likely option preselected.
1194
1195 This is a helper function for BankTransaction/ajax_payment_suggestion and
1196 template/webpages/bank_transactions/invoices.html
1197
1198 We are working with an existing payment, so difference_as_skonto never makes sense.
1199
1200 If skonto is not possible (skonto_date does not exists) simply return
1201 the single 'no skonto' option as a visual hint.
1202
1203 If skonto is possible (skonto_date exists), add two possibilities:
1204 without_skonto and with_skonto_pt if payment date is within skonto_date,
1205 preselect with_skonto_pt, otherwise preselect without skonto.
1206
1207 =item C<exchangerate>
1208
1209 Returns 1 immediately if the record uses the default currency.
1210
1211 Returns the exchangerate in database format for the invoice according to that
1212 invoice's transdate, returning 'buy' for sales, 'sell' for purchases.
1213
1214 If no exchangerate can be found for that day undef is returned.
1215
1216 =item C<forex>
1217
1218 Returns 1 if record uses a different currency, 0 if the default currency is used.
1219
1220 =back
1221
1222 =head1 TODO AND CAVEATS
1223
1224 =over 4
1225
1226 =item *
1227
1228 when looking at open amount, maybe consider that there may already be queued
1229 amounts in SEPA Export
1230
1231 =item * C<skonto_charts>
1232
1233 Cannot handle negative skonto amounts, will always calculate the skonto amount
1234 for credit notes or negative ap transactions with a positive sign.
1235
1236
1237 =back
1238
1239 =head1 AUTHOR
1240
1241 G. Richardson E<lt>grichardson@kivitendo-premium.de<gt>
1242
1243 =cut