SL/DB/Helper/Payment.pm

   1 package SL::DB::Helper::Payment;
   2
   3 use strict;
   4
   5 use parent qw(Exporter);
   6 our @EXPORT = qw(pay_invoice);
   7 our @EXPORT_OK = qw(skonto_date skonto_charts amount_less_skonto within_skonto_period percent_skonto reference_account reference_amount open_amount open_percent remaining_skonto_days skonto_amount check_skonto_configuration valid_skonto_amount get_payment_suggestions validate_payment_type open_sepa_transfer_amount get_payment_select_options_for_bank_transaction exchangerate forex);
   8 our %EXPORT_TAGS = (
   9   "ALL" => [@EXPORT, @EXPORT_OK],
  10 );
  11
  12 require SL::DB::Chart;
  13 use Data::Dumper;
  14 use DateTime;
  15 use SL::DATEV qw(:CONSTANTS);
  16 use SL::Locale::String qw(t8);
  17 use List::Util qw(sum);
  18 use SL::DB::Exchangerate;
  19 use SL::DB::Currency;
  20 use Carp;
  21
  22 #
  23 # Public functions not exported by default
  24 #
  25
  26 sub pay_invoice {
  27   my ($self, %params) = @_;
  28
  29   require SL::DB::Tax;
  30
  31   my $is_sales = ref($self) eq 'SL::DB::Invoice';
  32   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign depending on ar/ap
  33
  34   my $paid_amount = 0; # the amount that will be later added to $self->paid, should be in default currency
  35
  36   # default values if not set
  37   $params{payment_type} = 'without_skonto' unless $params{payment_type};
  38   validate_payment_type($params{payment_type});
  39
  40   # check for required parameters
  41   Common::check_params(\%params, qw(chart_id transdate));
  42
  43   my $transdate_obj;
  44   if (ref($params{transdate} eq 'DateTime')) {
  45     $transdate_obj = $params{transdate};
  46   } else {
  47    $transdate_obj = $::locale->parse_date_to_object($params{transdate});
  48   };
  49   croak t8('Illegal date') unless ref $transdate_obj;
  50
  51   # check for closed period
  52   my $closedto = $::locale->parse_date_to_object($::instance_conf->get_closedto);
  53   if ( ref $closedto && $transdate_obj < $closedto ) {
  54     croak t8('Cannot post payment for a closed period!');
  55   };
  56
  57   # check for maximum number of future days
  58   if ( $::instance_conf->get_max_future_booking_interval > 0 ) {
  59     croak t8('Cannot post transaction above the maximum future booking date!') if $transdate_obj > DateTime->now->add( days => $::instance_conf->get_max_future_booking_interval );
  60   };
  61
  62   # currency is either passed or use the invoice currency if it differs from the default currency
  63   my ($exchangerate,$currency);
  64   if ($params{currency} || $params{currency_id} || $self->currency_id != $::instance_conf->get_currency_id) {
  65     if ($params{currency} || $params{currency_id} ) { # currency was specified
  66       $currency = SL::DB::Manager::Currency->find_by(name => $params{currency}) || SL::DB::Manager::Currency->find_by(id => $params{currency_id});
  67     } else { # use invoice currency
  68       $currency = SL::DB::Manager::Currency->find_by(id => $self->currency_id);
  69     };
  70     die "no currency" unless $currency;
  71     if ($currency->id == $::instance_conf->get_currency_id) {
  72       $exchangerate = 1;
  73     } else {
  74       my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $currency->id,
  75                                                         transdate   => $transdate_obj,
  76                                                        );
  77       if ($rate) {
  78         $exchangerate = $is_sales ? $rate->buy : $rate->sell;
  79       } else {
  80         die "No exchange rate for " . $transdate_obj->to_kivitendo;
  81       };
  82     };
  83   } else { # no currency param given or currency is the same as default_currency
  84     $exchangerate = 1;
  85   };
  86
  87   # input checks:
  88   if ( $params{'payment_type'} eq 'without_skonto' ) {
  89     croak "invalid amount for payment_type 'without_skonto': $params{'amount'}\n" unless abs($params{'amount'}) > 0;
  90   };
  91
  92   # options with_skonto_pt and difference_as_skonto don't require the parameter
  93   # amount, but if amount is passed, make sure it matches the expected value
  94   if ( $params{'payment_type'} eq 'difference_as_skonto' ) {
  95     croak "amount $params{amount} doesn't match open amount " . $self->open_amount . ", diff = " . ($params{amount}-$self->open_amount) if $params{amount} && abs($self->open_amount - $params{amount} ) > 0.0000001;
  96   } elsif ( $params{'payment_type'} eq 'with_skonto_pt' ) {
  97     croak "amount $params{amount} doesn't match amount less skonto: " . $self->amount_less_skonto . "\n" if $params{amount} && abs($self->amount_less_skonto - $params{amount} ) > 0.0000001;
  98     croak "payment type with_skonto_pt can't be used if payments have already been made" if $self->paid != 0;
  99   };
 100
 101   # absolute skonto amount for invoice, use as reference sum to see if the
 102   # calculated skontos add up
 103   # only needed for payment_term "with_skonto_pt"
 104
 105   my $skonto_amount_check = $self->skonto_amount; # variable should be zero after calculating all skonto
 106   my $total_open_amount   = $self->open_amount;
 107
 108   # account where money is paid to/from: bank account or cash
 109   my $account_bank = SL::DB::Manager::Chart->find_by(id => $params{chart_id});
 110   croak "can't find bank account" unless ref $account_bank;
 111
 112   my $reference_account = $self->reference_account;
 113   croak "can't find reference account (link = AR/AP) for invoice" unless ref $reference_account;
 114
 115   my $memo   = $params{'memo'}   || '';
 116   my $source = $params{'source'} || '';
 117
 118   my $rounded_params_amount = _round( $params{amount} ); # / $exchangerate);
 119   my $fx_gain_loss_amount = 0; # for fx_gain and fx_loss
 120
 121   my $db = $self->db;
 122   $db->with_transaction(sub {
 123     my $new_acc_trans;
 124
 125     # all three payment type create 1 AR/AP booking (the paid part)
 126     # difference_as_skonto creates n skonto bookings (1 for each tax type)
 127     # with_skonto_pt creates 1 bank booking and n skonto bookings (1 for each tax type)
 128     # without_skonto creates 1 bank booking
 129
 130     # as long as there is no automatic tax, payments are always booked with
 131     # taxkey 0
 132
 133     unless ( $params{payment_type} eq 'difference_as_skonto' ) {
 134       # cases with_skonto_pt and without_skonto
 135
 136       # for case with_skonto_pt we need to know the corrected amount at this
 137       # stage if we are going to use $params{amount}
 138
 139       my $pay_amount = $rounded_params_amount;
 140       $pay_amount = $self->amount_less_skonto if $params{payment_type} eq 'with_skonto_pt';
 141
 142       # bank account and AR/AP
 143       $paid_amount += $pay_amount * $exchangerate;
 144
 145       my $amount = (-1 * $pay_amount) * $mult;
 146
 147
 148       # total amount against bank, do we already know this by now?
 149       $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 150                                                    chart_id   => $account_bank->id,
 151                                                    chart_link => $account_bank->link,
 152                                                    amount     => $amount,
 153                                                    transdate  => $transdate_obj,
 154                                                    source     => $source,
 155                                                    memo       => $memo,
 156                                                    project_id => $params{project_id} ? $params{project_id} : undef,
 157                                                    taxkey     => 0,
 158                                                    tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 159       $new_acc_trans->save;
 160
 161       # deal with fxtransaction
 162       if ( $self->currency_id != $::instance_conf->get_currency_id ) {
 163         my $fxamount = _round($amount - ($amount * $exchangerate));
 164         $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 165                                                      chart_id       => $account_bank->id,
 166                                                      chart_link     => $account_bank->link,
 167                                                      amount         => $fxamount * -1,
 168                                                      transdate      => $transdate_obj,
 169                                                      source         => $source,
 170                                                      memo           => $memo,
 171                                                      taxkey         => 0,
 172                                                      fx_transaction => 1,
 173                                                      tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 174         $new_acc_trans->save;
 175         # if invoice exchangerate differs from exchangerate of payment
 176         # deal with fxloss and fxamount
 177         if ($self->exchangerate and $self->exchangerate != 1 and $self->exchangerate != $exchangerate) {
 178           my $fxgain_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxgain_accno_id) || die "Can't determine fxgain chart";
 179           my $fxloss_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxloss_accno_id) || die "Can't determine fxloss chart";
 180           my $gain_loss_amount = _round($amount * ($exchangerate - $self->exchangerate ) * -1,2);
 181           my $gain_loss_chart = $gain_loss_amount > 0 ? $fxgain_chart : $fxloss_chart;
 182           $fx_gain_loss_amount = $gain_loss_amount;
 183
 184           $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 185                                                        chart_id       => $gain_loss_chart->id,
 186                                                        chart_link     => $gain_loss_chart->link,
 187                                                        amount         => $gain_loss_amount,
 188                                                        transdate      => $transdate_obj,
 189                                                        source         => $source,
 190                                                        memo           => $memo,
 191                                                        taxkey         => 0,
 192                                                        fx_transaction => 0,
 193                                                        tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 194           $new_acc_trans->save;
 195
 196         };
 197       };
 198     };
 199
 200     if ( $params{payment_type} eq 'difference_as_skonto' or $params{payment_type} eq 'with_skonto_pt' ) {
 201
 202       my $total_skonto_amount;
 203       if ( $params{payment_type} eq 'with_skonto_pt' ) {
 204         $total_skonto_amount = $self->skonto_amount;
 205       } elsif ( $params{payment_type} eq 'difference_as_skonto' ) {
 206         $total_skonto_amount = $self->open_amount;
 207       };
 208
 209       my @skonto_bookings = $self->skonto_charts($total_skonto_amount);
 210
 211       # error checking:
 212       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 213         my $calculated_skonto_sum  = sum map { $_->{skonto_amount} } @skonto_bookings;
 214         croak "calculated skonto for difference_as_skonto = $calculated_skonto_sum doesn't add up open amount: " . $self->open_amount unless _round($calculated_skonto_sum) == _round($self->open_amount);
 215       };
 216
 217       my $reference_amount = $total_skonto_amount;
 218
 219       # create an acc_trans entry for each result of $self->skonto_charts
 220       foreach my $skonto_booking ( @skonto_bookings ) {
 221         next unless $skonto_booking->{'chart_id'};
 222         next unless $skonto_booking->{'skonto_amount'} != 0;
 223         my $amount = -1 * $skonto_booking->{skonto_amount};
 224         $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 225                                                      chart_id   => $skonto_booking->{'chart_id'},
 226                                                      chart_link => SL::DB::Manager::Chart->find_by(id => $skonto_booking->{'chart_id'})->link,
 227                                                      amount     => $amount * $mult,
 228                                                      transdate  => $transdate_obj,
 229                                                      source     => $params{source},
 230                                                      taxkey     => 0,
 231                                                      tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 232
 233         # the acc_trans entries are saved individually, not added to $self and then saved all at once
 234         $new_acc_trans->save;
 235
 236         $reference_amount -= abs($amount);
 237         $paid_amount      += -1 * $amount * $exchangerate;
 238         $skonto_amount_check -= $skonto_booking->{'skonto_amount'};
 239       };
 240       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 241           die "difference_as_skonto calculated incorrectly, sum of calculated payments doesn't add up to open amount $total_open_amount, reference_amount = $reference_amount\n" unless _round($reference_amount) == 0;
 242       }
 243
 244     };
 245
 246     my $arap_amount = 0;
 247
 248     if ( $params{payment_type} eq 'difference_as_skonto' ) {
 249       $arap_amount = $total_open_amount;
 250     } elsif ( $params{payment_type} eq 'without_skonto' ) {
 251       $arap_amount = $rounded_params_amount;
 252     } elsif ( $params{payment_type} eq 'with_skonto_pt' ) {
 253       # this should be amount + sum(amount+skonto), but while we only allow
 254       # with_skonto_pt for completely unpaid invoices we just use the value
 255       # from the invoice
 256       $arap_amount = $total_open_amount;
 257     };
 258
 259     # regardless of payment_type there is always only exactly one arap booking
 260     # TODO: compare $arap_amount to running total
 261     my $arap_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 262                                                   chart_id   => $reference_account->id,
 263                                                   chart_link => $reference_account->link,
 264                                                   amount     => _round($arap_amount * $mult * $exchangerate - $fx_gain_loss_amount),
 265                                                   transdate  => $transdate_obj,
 266                                                   source     => '', #$params{source},
 267                                                   taxkey     => 0,
 268                                                   tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 269     $arap_booking->save;
 270
 271     $fx_gain_loss_amount *= -1 if $self->is_sales;
 272     $self->paid($self->paid + _round($paid_amount) + $fx_gain_loss_amount) if $paid_amount;
 273     $self->datepaid($transdate_obj);
 274     $self->save;
 275
 276     # make sure transactions will be reloaded the next time $self->transactions
 277     # is called, as pay_invoice saves the acc_trans objects individually rather
 278     # than adding them to the transaction relation array.
 279     $self->forget_related('transactions');
 280
 281     my $datev_check = 0;
 282     if ( $is_sales )  {
 283       if ( (  $self->invoice && $::instance_conf->get_datev_check_on_sales_invoice  ) ||
 284            ( !$self->invoice && $::instance_conf->get_datev_check_on_ar_transaction )) {
 285         $datev_check = 1;
 286       }
 287     } else {
 288       if ( (  $self->invoice && $::instance_conf->get_datev_check_on_purchase_invoice ) ||
 289            ( !$self->invoice && $::instance_conf->get_datev_check_on_ap_transaction   )) {
 290         $datev_check = 1;
 291       }
 292     }
 293
 294     if ( $datev_check ) {
 295
 296       my $datev = SL::DATEV->new(
 297         exporttype => DATEV_ET_BUCHUNGEN,
 298         format     => DATEV_FORMAT_KNE,
 299         dbh        => $db->dbh,
 300         trans_id   => $self->{id},
 301       );
 302
 303       $datev->clean_temporary_directories;
 304       $datev->export;
 305
 306       if ($datev->errors) {
 307         # this exception should be caught by with_transaction, which handles the rollback
 308         die join "\n", $::locale->text('DATEV check returned errors:'), $datev->errors;
 309       }
 310     }
 311
 312     1;
 313
 314   }) || die t8('error while paying invoice #1 : ', $self->invnumber) . $db->error . "\n";
 315
 316   return 1;
 317 };
 318
 319 sub skonto_date {
 320
 321   my $self = shift;
 322
 323   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 324
 325   my $skonto_date;
 326
 327   if ( $is_sales ) {
 328     return undef unless ref $self->payment_terms;
 329     return undef unless $self->payment_terms->terms_skonto > 0;
 330     $skonto_date = DateTime->from_object(object => $self->transdate)->add(days => $self->payment_terms->terms_skonto);
 331   } else {
 332     return undef unless ref $self->vendor->payment_terms;
 333     return undef unless $self->vendor->payment_terms->terms_skonto > 0;
 334     $skonto_date = DateTime->from_object(object => $self->transdate)->add(days => $self->vendor->payment_terms->terms_skonto);
 335   };
 336
 337   return $skonto_date;
 338 };
 339
 340 sub reference_account {
 341   my $self = shift;
 342
 343   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 344
 345   require SL::DB::Manager::AccTransaction;
 346
 347   my $link_filter = $is_sales ? 'AR' : 'AP';
 348
 349   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 350      trans_id   => $self->id,
 351      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 352   );
 353
 354   return undef unless ref $acc_trans;
 355
 356   my $reference_account = SL::DB::Manager::Chart->find_by(id => $acc_trans->chart_id);
 357
 358   return $reference_account;
 359 };
 360
 361 sub reference_amount {
 362   my $self = shift;
 363
 364   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 365
 366   require SL::DB::Manager::AccTransaction;
 367
 368   my $link_filter = $is_sales ? 'AR' : 'AP';
 369
 370   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 371      trans_id   => $self->id,
 372      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 373   );
 374
 375   return undef unless ref $acc_trans;
 376
 377   # this should be the same as $self->amount
 378   return $acc_trans->amount;
 379 };
 380
 381
 382 sub open_amount {
 383   my $self = shift;
 384
 385   # in the future maybe calculate this from acc_trans
 386
 387   # if the difference is 0.01 Cent this may end up as 0.009999999999998
 388   # numerically, so round this value when checking for cent threshold >= 0.01
 389
 390   return ($self->amount // 0) - ($self->paid // 0);
 391 };
 392
 393 sub open_percent {
 394   my $self = shift;
 395
 396   return 0 if $self->amount == 0;
 397   my $open_percent;
 398   if ( $self->open_amount < 0 ) {
 399     # overpaid, currently treated identically
 400     $open_percent = $self->open_amount * 100 / $self->amount;
 401   } else {
 402     $open_percent = $self->open_amount * 100 / $self->amount;
 403   };
 404
 405   return _round($open_percent) || 0;
 406 };
 407
 408 sub skonto_amount {
 409   my $self = shift;
 410
 411   return $self->amount - $self->amount_less_skonto;
 412 };
 413
 414 sub remaining_skonto_days {
 415   my $self = shift;
 416
 417   return undef unless ref $self->skonto_date;
 418
 419   my $dur = DateTime::Duration->new($self->skonto_date - DateTime->today);
 420   return $dur->delta_days();
 421
 422 };
 423
 424 sub percent_skonto {
 425   my $self = shift;
 426
 427   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 428
 429   my $percent_skonto = 0;
 430
 431   if ( $is_sales ) {
 432     return undef unless ref $self->payment_terms;
 433     return undef unless $self->payment_terms->percent_skonto > 0;
 434     $percent_skonto = $self->payment_terms->percent_skonto;
 435   } else {
 436     return undef unless ref $self->vendor->payment_terms;
 437     return undef unless $self->vendor->payment_terms->terms_skonto > 0;
 438     $percent_skonto = $self->vendor->payment_terms->percent_skonto;
 439   };
 440
 441   return $percent_skonto;
 442 };
 443
 444 sub amount_less_skonto {
 445   # amount that has to be paid if skonto applies, always return positive rounded values
 446   # the result is rounded so we can directly compare it with the user input
 447   my $self = shift;
 448
 449   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 450
 451   my $percent_skonto = $self->percent_skonto || 0;
 452
 453   return _round($self->amount - ( $self->amount * $percent_skonto) );
 454
 455 };
 456
 457 sub check_skonto_configuration {
 458   my $self = shift;
 459
 460   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 461
 462   my $skonto_configured = 1; # default is assume skonto works
 463
 464   # my $transactions = $self->transactions;
 465   foreach my $transaction (@{ $self->transactions }) {
 466     # find all transactions with an AR_amount or AP_amount link
 467     my $tax = SL::DB::Manager::Tax->get_first( where => [taxkey => $transaction->taxkey]);
 468     croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 469
 470     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->chart_link) };
 471     if ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) {
 472       $skonto_configured = 0 unless $tax->skonto_sales_chart_id;
 473     } elsif ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) {
 474       $skonto_configured = 0 unless $tax->skonto_purchase_chart_id;
 475     };
 476   };
 477
 478   return $skonto_configured;
 479 };
 480
 481 sub open_sepa_transfer_amount {
 482   my $self = shift;
 483
 484   my ($vc, $key, $type);
 485   if ( ref($self) eq 'SL::DB::Invoice' ) {
 486     $vc   = 'customer';
 487     $key  = 'ap_id';
 488     $type = 'ar';
 489   } else {
 490     $vc   = 'vendor';
 491     $key  = 'ap_id';
 492     $type = 'ap';
 493   };
 494
 495   my $sql = qq|SELECT SUM(sei.amount) AS amount FROM sepa_export_items sei | .
 496             qq| LEFT JOIN sepa_export se ON (sei.sepa_export_id = se.id)   | .
 497             qq| WHERE $key = ? AND NOT se.closed AND (se.vc = '$vc')       |;
 498
 499   my ($open_sepa_amount) = $self->db->dbh->selectrow_array($sql, undef, $self->id);
 500
 501   return $open_sepa_amount || 0;
 502
 503 };
 504
 505
 506 sub skonto_charts {
 507   my $self = shift;
 508
 509   # TODO: use param for amount, may also want to calculate skonto_amounts by
 510   # passing percentage in the future
 511
 512   my $amount = shift || $self->skonto_amount;
 513
 514   croak "no amount passed to skonto_charts" unless abs(_round($amount)) >= 0.01;
 515
 516   # TODO: check whether there are negative values in invoice / acc_trans ... credited items
 517
 518   # don't check whether skonto applies, because user may want to override this
 519   # return undef unless $self->percent_skonto;  # for is_sales
 520   # return undef unless $self->vendor->payment_terms->percent_skonto;  # for purchase
 521
 522   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 523
 524   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign
 525
 526   my @skonto_charts;  # resulting array with all income/expense accounts that have to be corrected
 527
 528   # calculate effective skonto (percentage) in difference_as_skonto mode
 529   # only works if there are no negative acc_trans values
 530   my $effective_skonto_rate = $amount ? $amount / $self->amount : 0;
 531
 532   # checks:
 533   my $total_skonto_amount  = 0;
 534   my $total_rounding_error = 0;
 535
 536   my $reference_ARAP_amount = 0;
 537
 538   # my $transactions = $self->transactions;
 539   foreach my $transaction (@{ $self->transactions }) {
 540     # find all transactions with an AR_amount or AP_amount link
 541     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->{chart_link}) };
 542     # second condition is that we can determine an automatic Skonto account for each AR_amount entry
 543
 544     if ( ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) or ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) ) {
 545         # $reference_ARAP_amount += $transaction->{amount} * $mult;
 546
 547         # quick hack that works around problem of non-unique tax keys in SKR04
 548         my $tax = SL::DB::Manager::Tax->get_first( where => [taxkey => $transaction->{taxkey}]);
 549         croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 550
 551         if ( $is_sales ) {
 552           die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $transaction->{taxkey} , $tax->taxdescription , $tax->rate*100) unless ref $tax->skonto_sales_chart;
 553         } else {
 554           die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $transaction->{taxkey} , $tax->taxdescription , $tax->rate*100) unless ref $tax->skonto_purchase_chart;
 555         };
 556
 557         my $skonto_amount_unrounded;
 558
 559         my $skonto_percent_abs = $self->amount ? abs($transaction->amount * (1 + $tax->rate) * 100 / $self->amount) : 0;
 560
 561         my $transaction_amount = abs($transaction->{amount} * (1 + $tax->rate));
 562         my $transaction_skonto_percent = abs($transaction_amount/$self->amount); # abs($transaction->{amount} * (1 + $tax->rate));
 563
 564
 565         $skonto_amount_unrounded   = abs($amount * $transaction_skonto_percent);
 566         my $skonto_amount_rounded  = _round($skonto_amount_unrounded);
 567         my $rounding_error         = $skonto_amount_unrounded - $skonto_amount_rounded;
 568         my $rounded_rounding_error = _round($rounding_error);
 569
 570         $total_rounding_error += $rounding_error;
 571         $total_skonto_amount  += $skonto_amount_rounded;
 572
 573         my $rec = {
 574           # skonto_percent_abs: relative part of amount + tax to the total invoice amount
 575           'skonto_percent_abs'     => $skonto_percent_abs,
 576           'chart_id'               => $is_sales ? $tax->skonto_sales_chart->id : $tax->skonto_purchase_chart->id,
 577           'skonto_amount'          => $skonto_amount_rounded,
 578           # 'rounding_error'         => $rounding_error,
 579           # 'rounded_rounding_error' => $rounded_rounding_error,
 580         };
 581
 582         push @skonto_charts, $rec;
 583       };
 584   };
 585
 586   # if the rounded sum of all rounding_errors reaches 0.01 this sum is
 587   # subtracted from the largest skonto_amount
 588   my $rounded_total_rounding_error = abs(_round($total_rounding_error));
 589
 590   if ( $rounded_total_rounding_error > 0 ) {
 591     my $highest_amount_pos = 0;
 592     my $highest_amount = 0;
 593     my $i = -1;
 594     foreach my $ref ( @skonto_charts ) {
 595       $i++;
 596       if ( $ref->{skonto_amount} > $highest_amount ) {
 597         $highest_amount     = $ref->{skonto_amount};
 598         $highest_amount_pos = $i;
 599       };
 600     };
 601     $skonto_charts[$i]->{skonto_amount} -= $rounded_total_rounding_error;
 602   };
 603
 604   return @skonto_charts;
 605 };
 606
 607
 608 sub within_skonto_period {
 609   my $self = shift;
 610   my $dateref = shift || DateTime->now->truncate( to => 'day' );
 611
 612   return undef unless ref $dateref eq 'DateTime';
 613   return 0 unless $self->skonto_date;
 614
 615   # return 1 if requested date (or today) is inside skonto period
 616   # this will also return 1 if date is before the invoice date
 617   return $dateref <= $self->skonto_date;
 618 };
 619
 620 sub valid_skonto_amount {
 621   my $self = shift;
 622   my $amount = shift || 0;
 623   my $max_skonto_percent = 0.10;
 624
 625   return 0 unless $amount > 0;
 626
 627   # does this work for other currencies?
 628   return ($self->amount*$max_skonto_percent) > $amount;
 629 };
 630
 631 sub get_payment_select_options_for_bank_transaction {
 632   my ($self, $bt_id, %params) = @_;
 633
 634   my $bt = SL::DB::Manager::BankTransaction->find_by( id => $bt_id );
 635   die unless $bt;
 636
 637   my $open_amount = $self->open_amount;
 638   #$main::lxdebug->message(LXDebug->DEBUG2(),"skonto_date=".$self->skonto_date." open amount=".$open_amount);
 639   my @options;
 640   if ( $open_amount &&                   # invoice amount not 0
 641        $self->skonto_date &&             # check whether skonto applies
 642        ( abs(abs($self->amount_less_skonto) - abs($bt->amount)) < 0.01 ||
 643         ( $bt->transaction_code eq "191" && abs($self->amount_less_skonto) < abs($bt->amount) )) &&
 644        $self->check_skonto_configuration) {
 645          if ( $self->within_skonto_period($bt->transdate) ) {
 646            push(@options, { payment_type => 'without_skonto', display => t8('without skonto') });
 647            push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt'), selected => 1 });
 648          } else {
 649            push(@options, { payment_type => 'without_skonto', display => t8('without skonto') , selected => 1 });
 650            push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt')});
 651          };
 652   };
 653
 654   return @options;
 655
 656 };
 657
 658 sub exchangerate {
 659   my ($self) = @_;
 660
 661   return 1 if $self->currency_id == $::instance_conf->get_currency_id;
 662
 663   die "transdate isn't a DateTime object:" . ref($self->transdate) unless ref($self->transdate) eq 'DateTime';
 664   my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $self->currency_id,
 665                                                     transdate   => $self->transdate,
 666                                                    );
 667   return undef unless $rate;
 668
 669   return $self->is_sales ? $rate->buy : $rate->sell; # also undef if not defined
 670 };
 671
 672 sub get_payment_suggestions {
 673
 674   my ($self, %params) = @_;
 675
 676   my $open_amount = $self->open_amount;
 677   $open_amount   -= $self->open_sepa_transfer_amount if $params{sepa};
 678
 679   $self->{invoice_amount_suggestion} = $open_amount;
 680   undef $self->{payment_select_options};
 681   push(@{$self->{payment_select_options}} , { payment_type => 'without_skonto',  display => t8('without skonto') });
 682   if ( $self->within_skonto_period ) {
 683     # If there have been no payments yet suggest amount_less_skonto, otherwise the open amount
 684     if ( $open_amount &&                   # invoice amount not 0
 685          $open_amount == $self->amount &&  # no payments yet, or sum of payments and sepa export amounts is zero
 686          $self->check_skonto_configuration) {
 687       $self->{invoice_amount_suggestion} = $self->amount_less_skonto;
 688       push(@{$self->{payment_select_options}} , { payment_type => 'with_skonto_pt',  display => t8('with skonto acc. to pt') , selected => 1 });
 689     } else {
 690       if ( ( $self->valid_skonto_amount($self->open_amount) || $self->valid_skonto_amount($open_amount) ) and not $params{sepa} ) {
 691         $self->{invoice_amount_suggestion} = $open_amount;
 692         # only suggest difference_as_skonto if open_amount exactly matches skonto_amount
 693         # AND we aren't in SEPA mode
 694         my $selected = 0;
 695         $selected = 1 if _round($open_amount) == _round($self->skonto_amount);
 696         push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => $selected });
 697       };
 698     };
 699   } else {
 700     # invoice was configured with skonto, but skonto date has passed, or no skonto available
 701     $self->{invoice_amount_suggestion} = $open_amount;
 702     # difference_as_skonto doesn't make any sense for SEPA transfer, as this doesn't cause any actual payment
 703     if ( $self->valid_skonto_amount($self->open_amount) && not $params{sepa} ) {
 704       push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => 0 });
 705     };
 706   };
 707   return 1;
 708 };
 709
 710 # locales for payment type
 711 #
 712 # $main::locale->text('without_skonto')
 713 # $main::locale->text('with_skonto_pt')
 714 # $main::locale->text('difference_as_skonto')
 715 #
 716
 717 sub validate_payment_type {
 718   my $payment_type = shift;
 719
 720   my %allowed_payment_types = map { $_ => 1 } qw(without_skonto with_skonto_pt difference_as_skonto);
 721   croak "illegal payment type: $payment_type, must be one of: " . join(' ', keys %allowed_payment_types) unless $allowed_payment_types{ $payment_type };
 722
 723   return 1;
 724 }
 725
 726 sub forex {
 727   my ($self) = @_;
 728   $self->currency_id == $::instance_conf->get_currency_id ? return 0 : return 1;
 729 };
 730
 731 sub _round {
 732   my $value = shift;
 733   my $num_dec = 2;
 734   return $::form->round_amount($value, 2);
 735 }
 736
 737 1;
 738
 739 __END__
 740
 741 =pod
 742
 743 =head1 NAME
 744
 745 SL::DB::Helper::Payment  Mixin providing helper methods for paying C<Invoice>
 746                          and C<PurchaseInvoice> objects and using skonto
 747
 748 =head1 SYNOPSIS
 749
 750 In addition to actually causing a payment via pay_invoice this helper contains
 751 many methods that help in determining information about the status of the
 752 invoice, such as the remaining open amount, whether skonto applies, until which
 753 date skonto applies, the skonto amount and relative percentages, what to do
 754 with skonto, ...
 755
 756 To prevent duplicate code this was all added in this mixin rather than directly
 757 in SL::DB::Invoice and SL::DB::PurchaseInvoice.
 758
 759 =over 4
 760
 761 =item C<pay_invoice %params>
 762
 763 Create a payment booking for an existing invoice object (type ar/ap/is/ir) via
 764 a configured bank account.
 765
 766 This function deals with all the acc_trans entries and also updates paid and datepaid.
 767
 768 Example:
 769
 770   my $ap   = SL::DB::Manager::PurchaseInvoice->find_by( invnumber => '1');
 771   my $bank = SL::DB::Manager::BankAccount->find_by( name => 'Bank');
 772   $ap->pay_invoice(chart_id      => $bank->chart_id,
 773                    amount        => $ap->open_amount,
 774                    transdate     => DateTime->now->to_kivitendo,
 775                    memo          => 'foobar',
 776                    source        => 'barfoo',
 777                    payment_type  => 'without_skonto',  # default if not specified
 778                    project_id    => 25,
 779                   );
 780
 781 or with skonto:
 782   $ap->pay_invoice(chart_id      => $bank->chart_id,
 783                    amount        => $ap->amount,       # doesn't need to be specified
 784                    transdate     => DateTime->now->to_kivitendo,
 785                    memo          => 'foobar',
 786                    source        => 'barfoo',
 787                    payment_type  => 'with_skonto',
 788                   );
 789
 790 or in a certain currency:
 791   $ap->pay_invoice(chart_id      => $bank->chart_id,
 792                    amount        => 500,
 793                    currency      => 'USD',
 794                    transdate     => DateTime->now->to_kivitendo,
 795                    memo          => 'foobar',
 796                    source        => 'barfoo',
 797                    payment_type  => 'with_skonto',
 798                   );
 799
 800 Allowed payment types are:
 801   without_skonto with_skonto_pt difference_as_skonto
 802
 803 The option C<payment_type> allows for a basic skonto mechanism.
 804
 805 C<without_skonto> is the default mode, "amount" is paid to the account in
 806 chart_id. This can also be used for partial payments and corrections via
 807 negative amounts.
 808
 809 C<with_skonto_pt> can't be used for partial payments. When used on unpaid
 810 invoices the whole amount is paid, with the skonto part automatically being
 811 booked according to the skonto chart configured in the tax settings for each
 812 tax key. If an amount is passed it is ignored and the actual configured skonto
 813 amount is used.
 814
 815 C<difference_as_skonto> can only be used after partial payments have been made,
 816 the whole specified amount is booked according to the skonto charts configured
 817 in the tax settings for each tax key.
 818
 819 So passing amount doesn't have any effect for the cases C<with_skonto_pt> and
 820 C<difference_as_skonto>, as all necessary values are taken from the stored
 821 invoice.
 822
 823 The skonto modes automatically calculate the relative amounts for a mix of
 824 taxes, e.g. items with 7% and 19% in one invoice. There is a helper method
 825 skonto_charts, which calculates the relative percentages according to the
 826 amounts in acc_trans (which are grouped by tax).
 827
 828 There is currently no way of excluding certain items in an invoice from having
 829 skonto applied to them.  If this feature was added to parts the calculation
 830 method of relative skonto would have to be completely rewritten using the
 831 invoice items rather than acc_trans.
 832
 833 The skonto modes also still don't automatically correct the tax, this still has
 834 to be done manually. Therefore all payments generated by pay_invoice have
 835 taxkey 0.
 836
 837 There is currently no way to directly pay an invoice via this method if the
 838 effective skonto differs from the skonto according to the payment terms
 839 configured for the invoice/vendor.
 840
 841 In this case one has to pay in two steps: first the actual paid amount via
 842 "without skonto", and then the remainder via "difference_as_skonto". The user
 843 has to there actively decide whether to accept the differing skonto.
 844
 845 Because of the way skonto_charts works the calculation doesn't work if there
 846 are negative values in acc_trans. E.g. one invoice with a positive value for
 847 19% tax and a negative value for the acc_trans line with 7%
 848
 849 Skonto doesn't/shouldn't apply if the invoice contains credited items.
 850
 851 If no amount is given the whole open amout is paid.
 852
 853 If neither currency or currency_id are given as params, the currency of the
 854 invoice is assumed to be the payment currency.
 855
 856 =item C<reference_account>
 857
 858 Returns a chart object which is the chart of the invoice with link AR or AP.
 859
 860 Example (1200 is the AR account for SKR04):
 861   my $invoice = invoice(invnumber => '144');
 862   $invoice->reference_account->accno
 863   # 1200
 864
 865 =item C<percent_skonto>
 866
 867 Returns the configured skonto percentage of the payment terms of an invoice,
 868 e.g. 0.02 for 2%. Payment terms come from invoice settings for ar, from vendor
 869 settings for ap.
 870
 871 =item C<amount_less_skonto>
 872
 873 If the invoice has a payment term (via ar for sales, via vendor for purchase),
 874 calculate the amount to be paid in the case of skonto.  This doesn't check,
 875 whether skonto applies (i.e. skonto doesn't wasn't exceeded), it just subtracts
 876 the configured percentage (e.g. 2%) from the total amount.
 877
 878 The returned value is rounded to two decimals.
 879
 880 =item C<skonto_date>
 881
 882 The date up to which skonto may be taken. This is calculated from the invoice
 883 date + the number of days configured in the payment terms.
 884
 885 This method can also be used to determine whether skonto applies for the
 886 invoice, as it returns undef if there is no payment term or skonto days is set
 887 to 0.
 888
 889 =item C<within_skonto_period [DATE]>
 890
 891 Returns 0 or 1.
 892
 893 Checks whether the invoice has payment terms configured, and whether the date
 894 is within the skonto max date. If no date is passed the current date is used.
 895
 896 You can also pass a dateref object as a parameter to check whether skonto
 897 applies for that date rather than the current date.
 898
 899 =item C<valid_skonto_amount>
 900
 901 Takes an amount as an argument and checks whether the amount is less than 10%
 902 of the total amount of the invoice. The value of 10% is currently hardcoded in
 903 the method. This method is currently used to check whether to offer the payment
 904 option "difference as skonto".
 905
 906 Example:
 907  if ( $invoice->valid_skonto_amount($invoice->open_amount) ) {
 908    # ... do something
 909  }
 910
 911 =item C<skonto_charts [$amount]>
 912
 913 Returns a list of chart_ids and some calculated numbers that can be used for
 914 paying the invoice with skonto. This function will automatically calculate the
 915 relative skonto amounts even if the invoice contains several types of taxes
 916 (e.g. 7% and 19%).
 917
 918 Example usage:
 919   my $invoice = SL::DB::Manager::Invoice->find_by(invnumber => '211');
 920   my @skonto_charts = $invoice->skonto_charts;
 921
 922 or with the total skonto amount as an argument:
 923   my @skonto_charts = $invoice->skonto_charts($invoice->open_amount);
 924
 925 The following values are generated for each chart:
 926
 927 =over 2
 928
 929 =item C<chart_id>
 930
 931 The chart id of the skonto amount to be booked.
 932
 933 =item C<skonto_amount>
 934
 935 The total amount to be paid to the account
 936
 937 =item C<skonto_percent>
 938
 939 The relative percentage of that skonto chart. This can be useful if the actual
 940 ekonto that is paid deviates from the granted skonto, e.g. customer effectively
 941 pays 2.6% skonto instead of 2%, and we accept this. Then we can still calculate
 942 the relative skonto amounts for different taxes based on the absolute
 943 percentages. Used for case C<difference_as_skonto>.
 944
 945 =item C<skonto_percent_abs>
 946
 947 The absolute percentage of that skonto chart in relation to the total amount.
 948 Used to calculate skonto_amount for case C<with_skonto_pt>.
 949
 950 =back
 951
 952 If the invoice contains several types of taxes then skonto_charts can be used
 953 to calculate the relative amounts.
 954
 955 Example in console of an invoice with 100 Euro at 7% and 100 Euro at 19% with
 956 tax not included:
 957
 958   my $invoice = invoice(invnumber => '144');
 959   $invoice->amount
 960   226.00000
 961   $invoice->payment_terms->percent_skonto
 962   0.02
 963   $invoice->skonto_charts
 964   pp $invoice->skonto_charts
 965   #             $VAR1 = {
 966   #               'chart_id'       => 128,
 967   #               'skonto_amount'  => '2.14',
 968   #               'skonto_percent' => '47.3451327433627'
 969   #             };
 970   #             $VAR2 = {
 971   #               'chart_id'       => 130,
 972   #               'skonto_amount'  => '2.38',
 973   #               'skonto_percent' => '52.654867256637'
 974   #             };
 975
 976 C<skonto_charts> always returns positive values (abs) for C<skonto_amount> and
 977 C<skonto_percent>.
 978
 979 C<skonto_charts> generates one entry for each acc_trans entry. ar and ap
 980 bookings only have one acc_trans entry for each taxkey (e.g. 7% and 19%).  This
 981 is because all the items are grouped according to the Buchungsgruppen mechanism
 982 and the totals are written to acc_trans.  For is and ir it is possible to have
 983 several acc_trans entries with the same tax. In this case skonto_charts
 984 generates a skonto booking for each acc_trans income/expense entry.
 985
 986 In the future this function may also be used to calculate the corrections for
 987 the income tax.
 988
 989 =item C<open_amount>
 990
 991 Unrounded total open amount of invoice (amount - paid).
 992 Doesn't take into account pending SEPA transfers.
 993
 994 =item C<open_percent>
 995
 996 Percentage of the invoice that is still unpaid, e.g. 100,00 if no payments have
 997 been made yet, 0,00 if fully paid.
 998
 999 =item C<remaining_skonto_days>
1000
1001 How many days skonto can still be taken, calculated from current day. Returns 0
1002 if current day is the max skonto date, and negative number if skonto date has
1003 already passed.
1004
1005 Returns undef if skonto is not configured for that invoice.
1006
1007 =item C<get_payment_suggestions %params>
1008
1009 Creates data intended for an L.select_tag dropdown that can be used in a
1010 template. Depending on the rules it will choose from the options
1011 without_skonto, with_skonto_pt and difference_as_skonto, and select the most
1012 likely one.
1013
1014 If the parameter "sepa" is passed, the SEPA export payments that haven't been
1015 executed yet are considered when determining the open amount of the invoice.
1016
1017 The current rules are:
1018
1019 =over 2
1020
1021 =item * without_skonto is always an option
1022
1023 =item * with_skonto_pt is only offered if there haven't been any payments yet and the current date is within the skonto period.
1024
1025 =item * difference_as_skonto is only offered if there have already been payments made and the open amount is smaller than 10% of the total amount.
1026
1027 with_skonto_pt will only be offered, if all the AR_amount/AP_amount have a
1028 taxkey with a configured skonto chart
1029
1030 =back
1031
1032 It will also fill $self->{invoice_amount_suggestion} with either the open
1033 amount, or if with_skonto_pt is selected, with amount_less_skonto, so the
1034 template can fill the input with the likely amount.
1035
1036 Example in console:
1037   my $ar = invoice( invnumber => '257');
1038   $ar->get_payment_suggestions;
1039   print $ar->{invoice_amount_suggestion} . "\n";
1040   # 97.23
1041   pp $ar->{payment_select_options}
1042   # $VAR1 = [
1043   #         {
1044   #           'display' => 'ohne Skonto',
1045   #           'payment_type' => 'without_skonto'
1046   #         },
1047   #         {
1048   #           'display' => 'mit Skonto nach ZB',
1049   #           'payment_type' => 'with_skonto_pt',
1050   #           'selected' => 1
1051   #         }
1052   #       ];
1053
1054 The resulting array $ar->{payment_select_options} can be used in a template
1055 select_tag using value_key and title_key:
1056
1057 [% L.select_tag('payment_type_' _ loop.count, invoice.payment_select_options, value_key => 'payment_type', title_key => 'display', id => 'payment_type_' _ loop.count) %]
1058
1059 It would probably make sense to have different rules for the pre-selected items
1060 for sales and purchase, and to also make these rules configurable in the
1061 defaults. E.g. when creating a SEPA bank transfer for vendor invoices a company
1062 might always want to pay quickly making use of skonto, while another company
1063 might always want to pay as late as possible.
1064
1065 =item C<get_payment_select_options_for_bank_transaction $banktransaction_id %params>
1066
1067 Make suggestion for a skonto payment type by returning an HTML blob of the options
1068 of a HTML drop-down select with the most likely option preselected.
1069
1070 This is a helper function for BankTransaction/ajax_payment_suggestion.
1071
1072 We are working with an existing payment, so difference_as_skonto never makes sense.
1073
1074 If skonto is possible (skonto_date exists), add two possibilities:
1075 without_skonto and with_skonto_pt if payment date is within skonto_date,
1076 preselect with_skonto_pt, otherwise preselect without skonto.
1077
1078 =item C<exchangerate>
1079
1080 Returns 1 immediately if the record uses the default currency.
1081
1082 Returns the exchangerate in database format for the invoice according to that
1083 invoice's transdate, returning 'buy' for sales, 'sell' for purchases.
1084
1085 If no exchangerate can be found for that day undef is returned.
1086
1087 =item C<forex>
1088
1089 Returns 1 if record uses a different currency, 0 if the default currency is used.
1090
1091 =back
1092
1093 =head1 TODO AND CAVEATS
1094
1095 =over 4
1096
1097 =item *
1098
1099 when looking at open amount, maybe consider that there may already be queued
1100 amounts in SEPA Export
1101
1102 =back
1103
1104 =head1 AUTHOR
1105
1106 G. Richardson E<lt>grichardson@kivitendo-premium.de<gt>
1107
1108 =cut