SL/DB/Helper/Payment.pm

   1 package SL::DB::Helper::Payment;
   2
   3 use strict;
   4
   5 use parent qw(Exporter);
   6 our @EXPORT = qw(pay_invoice);
   7 our @EXPORT_OK = qw(skonto_date skonto_charts amount_less_skonto within_skonto_period percent_skonto reference_account reference_amount open_amount open_percent remaining_skonto_days skonto_amount check_skonto_configuration valid_skonto_amount get_payment_suggestions validate_payment_type open_sepa_transfer_amount get_payment_select_options_for_bank_transaction create_bank_transaction exchangerate);
   8 our %EXPORT_TAGS = (
   9   "ALL" => [@EXPORT, @EXPORT_OK],
  10 );
  11
  12 require SL::DB::Chart;
  13 use Data::Dumper;
  14 use DateTime;
  15 use SL::DATEV qw(:CONSTANTS);
  16 use SL::Locale::String qw(t8);
  17 use List::Util qw(sum);
  18 use SL::DB::Exchangerate;
  19 use SL::DB::Currency;
  20 use Carp;
  21
  22 #
  23 # Public functions not exported by default
  24 #
  25
  26 sub pay_invoice {
  27   my ($self, %params) = @_;
  28
  29   require SL::DB::Tax;
  30
  31   my $is_sales = ref($self) eq 'SL::DB::Invoice';
  32   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign depending on ar/ap
  33
  34   my $paid_amount = 0; # the amount that will be later added to $self->paid, should be in default currency
  35
  36   # default values if not set
  37   $params{payment_type} = 'without_skonto' unless $params{payment_type};
  38   validate_payment_type($params{payment_type});
  39
  40   # check for required parameters
  41   Common::check_params(\%params, qw(chart_id transdate));
  42
  43   my $transdate_obj;
  44   if (ref($params{transdate} eq 'DateTime')) {
  45     $transdate_obj = $params{transdate};
  46   } else {
  47    $transdate_obj = $::locale->parse_date_to_object($params{transdate});
  48   };
  49   croak t8('Illegal date') unless ref $transdate_obj;
  50
  51   # check for closed period
  52   my $closedto = $::locale->parse_date_to_object($::instance_conf->get_closedto);
  53   if ( ref $closedto && $transdate_obj < $closedto ) {
  54     croak t8('Cannot post payment for a closed period!');
  55   };
  56
  57   # check for maximum number of future days
  58   if ( $::instance_conf->get_max_future_booking_interval > 0 ) {
  59     croak t8('Cannot post transaction above the maximum future booking date!') if $transdate_obj > DateTime->now->add( days => $::instance_conf->get_max_future_booking_interval );
  60   };
  61
  62   # currency is either passed or use the invoice currency if it differs from the default currency
  63   my ($exchangerate,$currency);
  64   if ($params{currency} || $params{currency_id} || $self->currency_id != $::instance_conf->get_currency_id) {
  65     if ($params{currency} || $params{currency_id} ) { # currency was specified
  66       $currency = SL::DB::Manager::Currency->find_by(name => $params{currency}) || SL::DB::Manager::Currency->find_by(id => $params{currency_id});
  67     } else { # use invoice currency
  68       $currency = SL::DB::Manager::Currency->find_by(id => $self->currency_id);
  69     };
  70     die "no currency" unless $currency;
  71     if ($currency->id == $::instance_conf->get_currency_id) {
  72       $exchangerate = 1;
  73     } else {
  74       my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $currency->id,
  75                                                         transdate   => $transdate_obj,
  76                                                        );
  77       if ($rate) {
  78         $exchangerate = $is_sales ? $rate->buy : $rate->sell;
  79       } else {
  80         die "No exchange rate for " . $transdate_obj->to_kivitendo;
  81       };
  82     };
  83   } else { # no currency param given or currency is the same as default_currency
  84     $exchangerate = 1;
  85   };
  86
  87   # input checks:
  88   if ( $params{'payment_type'} eq 'without_skonto' ) {
  89     croak "invalid amount for payment_type 'without_skonto': $params{'amount'}\n" unless abs($params{'amount'}) > 0;
  90   };
  91
  92   # options with_skonto_pt and difference_as_skonto don't require the parameter
  93   # amount, but if amount is passed, make sure it matches the expected value
  94   if ( $params{'payment_type'} eq 'difference_as_skonto' ) {
  95     croak "amount $params{amount} doesn't match open amount " . $self->open_amount . ", diff = " . ($params{amount}-$self->open_amount) if $params{amount} && abs($self->open_amount - $params{amount} ) > 0.0000001;
  96   } elsif ( $params{'payment_type'} eq 'with_skonto_pt' ) {
  97     croak "amount $params{amount} doesn't match amount less skonto: " . $self->open_amount . "\n" if $params{amount} && abs($self->amount_less_skonto - $params{amount} ) > 0.0000001;
  98     croak "payment type with_skonto_pt can't be used if payments have already been made" if $self->paid != 0;
  99   };
 100
 101   # absolute skonto amount for invoice, use as reference sum to see if the
 102   # calculated skontos add up
 103   # only needed for payment_term "with_skonto_pt"
 104
 105   my $skonto_amount_check = $self->skonto_amount; # variable should be zero after calculating all skonto
 106   my $total_open_amount   = $self->open_amount;
 107
 108   # account where money is paid to/from: bank account or cash
 109   my $account_bank = SL::DB::Manager::Chart->find_by(id => $params{chart_id});
 110   croak "can't find bank account" unless ref $account_bank;
 111
 112   my $reference_account = $self->reference_account;
 113   croak "can't find reference account (link = AR/AP) for invoice" unless ref $reference_account;
 114
 115   my $memo   = $params{'memo'}   || '';
 116   my $source = $params{'source'} || '';
 117
 118   my $rounded_params_amount = _round( $params{amount} ); # / $exchangerate);
 119   my $fx_gain_loss_amount = 0; # for fx_gain and fx_loss
 120
 121   my $db = $self->db;
 122   $db->do_transaction(sub {
 123     my $new_acc_trans;
 124
 125     # all three payment type create 1 AR/AP booking (the paid part)
 126     # difference_as_skonto creates n skonto bookings (1 for each tax type)
 127     # with_skonto_pt creates 1 bank booking and n skonto bookings (1 for each tax type)
 128     # without_skonto creates 1 bank booking
 129
 130     # as long as there is no automatic tax, payments are always booked with
 131     # taxkey 0
 132
 133     unless ( $params{payment_type} eq 'difference_as_skonto' ) {
 134       # cases with_skonto_pt and without_skonto
 135
 136       # for case with_skonto_pt we need to know the corrected amount at this
 137       # stage if we are going to use $params{amount}
 138
 139       my $pay_amount = $rounded_params_amount;
 140       $pay_amount = $self->amount_less_skonto if $params{payment_type} eq 'with_skonto_pt';
 141
 142       # bank account and AR/AP
 143       $paid_amount += $pay_amount * $exchangerate;
 144
 145       my $amount = (-1 * $pay_amount) * $mult;
 146
 147
 148       # total amount against bank, do we already know this by now?
 149       $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 150                                                    chart_id   => $account_bank->id,
 151                                                    chart_link => $account_bank->link,
 152                                                    amount     => $amount,
 153                                                    transdate  => $transdate_obj,
 154                                                    source     => $source,
 155                                                    memo       => $memo,
 156                                                    taxkey     => 0,
 157                                                    tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 158       $new_acc_trans->save;
 159
 160       # deal with fxtransaction
 161       if ( $self->currency_id != $::instance_conf->get_currency_id ) {
 162         my $fxamount = _round($amount - ($amount * $exchangerate));
 163         $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 164                                                      chart_id       => $account_bank->id,
 165                                                      chart_link     => $account_bank->link,
 166                                                      amount         => $fxamount * -1,
 167                                                      transdate      => $transdate_obj,
 168                                                      source         => $source,
 169                                                      memo           => $memo,
 170                                                      taxkey         => 0,
 171                                                      fx_transaction => 1,
 172                                                      tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 173         $new_acc_trans->save;
 174         # if invoice exchangerate differs from exchangerate of payment
 175         # deal with fxloss and fxamount
 176         if ($self->exchangerate and $self->exchangerate != 1 and $self->exchangerate != $exchangerate) {
 177           my $fxgain_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxgain_accno_id) || die "Can't determine fxgain chart";
 178           my $fxloss_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxloss_accno_id) || die "Can't determine fxloss chart";
 179           my $gain_loss_amount = _round($amount * ($exchangerate - $self->exchangerate ) * -1,2);
 180           my $gain_loss_chart = $gain_loss_amount > 0 ? $fxgain_chart : $fxloss_chart;
 181           $fx_gain_loss_amount = $gain_loss_amount;
 182
 183           $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 184                                                        chart_id       => $gain_loss_chart->id,
 185                                                        chart_link     => $gain_loss_chart->link,
 186                                                        amount         => $gain_loss_amount,
 187                                                        transdate      => $transdate_obj,
 188                                                        source         => $source,
 189                                                        memo           => $memo,
 190                                                        taxkey         => 0,
 191                                                        fx_transaction => 0,
 192                                                        tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 193           $new_acc_trans->save;
 194
 195         };
 196       };
 197     };
 198
 199     if ( $params{payment_type} eq 'difference_as_skonto' or $params{payment_type} eq 'with_skonto_pt' ) {
 200
 201       my $total_skonto_amount;
 202       if ( $params{payment_type} eq 'with_skonto_pt' ) {
 203         $total_skonto_amount = $self->skonto_amount;
 204       } elsif ( $params{payment_type} eq 'difference_as_skonto' ) {
 205         $total_skonto_amount = $self->open_amount;
 206       };
 207
 208       my @skonto_bookings = $self->skonto_charts($total_skonto_amount);
 209
 210       # error checking:
 211       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 212         my $calculated_skonto_sum  = sum map { $_->{skonto_amount} } @skonto_bookings;
 213         croak "calculated skonto for difference_as_skonto = $calculated_skonto_sum doesn't add up open amount: " . $self->open_amount unless _round($calculated_skonto_sum) == _round($self->open_amount);
 214       };
 215
 216       my $reference_amount = $total_skonto_amount;
 217
 218       # create an acc_trans entry for each result of $self->skonto_charts
 219       foreach my $skonto_booking ( @skonto_bookings ) {
 220         next unless $skonto_booking->{'chart_id'};
 221         next unless $skonto_booking->{'skonto_amount'} != 0;
 222         my $amount = -1 * $skonto_booking->{skonto_amount};
 223         $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 224                                                      chart_id   => $skonto_booking->{'chart_id'},
 225                                                      chart_link => SL::DB::Manager::Chart->find_by(id => $skonto_booking->{'chart_id'})->link,
 226                                                      amount     => $amount * $mult,
 227                                                      transdate  => $transdate_obj,
 228                                                      source     => $params{source},
 229                                                      taxkey     => 0,
 230                                                      tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 231
 232         # the acc_trans entries are saved individually, not added to $self and then saved all at once
 233         $new_acc_trans->save;
 234
 235         $reference_amount -= abs($amount);
 236         $paid_amount      += -1 * $amount * $exchangerate;
 237         $skonto_amount_check -= $skonto_booking->{'skonto_amount'};
 238       };
 239       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 240           die "difference_as_skonto calculated incorrectly, sum of calculated payments doesn't add up to open amount $total_open_amount, reference_amount = $reference_amount\n" unless _round($reference_amount) == 0;
 241       }
 242
 243     };
 244
 245     my $arap_amount = 0;
 246
 247     if ( $params{payment_type} eq 'difference_as_skonto' ) {
 248       $arap_amount = $total_open_amount;
 249     } elsif ( $params{payment_type} eq 'without_skonto' ) {
 250       $arap_amount = $rounded_params_amount;
 251     } elsif ( $params{payment_type} eq 'with_skonto_pt' ) {
 252       # this should be amount + sum(amount+skonto), but while we only allow
 253       # with_skonto_pt for completely unpaid invoices we just use the value
 254       # from the invoice
 255       $arap_amount = $total_open_amount;
 256     };
 257
 258     # regardless of payment_type there is always only exactly one arap booking
 259     # TODO: compare $arap_amount to running total
 260     my $arap_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 261                                                   chart_id   => $reference_account->id,
 262                                                   chart_link => $reference_account->link,
 263                                                   amount     => _round($arap_amount * $mult * $exchangerate - $fx_gain_loss_amount),
 264                                                   transdate  => $transdate_obj,
 265                                                   source     => '', #$params{source},
 266                                                   taxkey     => 0,
 267                                                   tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 268     $arap_booking->save;
 269
 270     $fx_gain_loss_amount *= -1 if $self->is_sales;
 271     $self->paid($self->paid + _round($paid_amount) + $fx_gain_loss_amount) if $paid_amount;
 272     $self->datepaid($transdate_obj);
 273     $self->save;
 274
 275     # make sure transactions will be reloaded the next time $self->transactions
 276     # is called, as pay_invoice saves the acc_trans objects individually rather
 277     # than adding them to the transaction relation array.
 278     $self->forget_related('transactions');
 279
 280   my $datev_check = 0;
 281   if ( $is_sales )  {
 282     if ( (  $self->invoice && $::instance_conf->get_datev_check_on_sales_invoice  ) ||
 283          ( !$self->invoice && $::instance_conf->get_datev_check_on_ar_transaction )) {
 284       $datev_check = 1;
 285     };
 286   } else {
 287     if ( (  $self->invoice && $::instance_conf->get_datev_check_on_purchase_invoice ) ||
 288          ( !$self->invoice && $::instance_conf->get_datev_check_on_ap_transaction   )) {
 289       $datev_check = 1;
 290     };
 291   };
 292
 293   if ( $datev_check ) {
 294
 295     my $datev = SL::DATEV->new(
 296       exporttype => DATEV_ET_BUCHUNGEN,
 297       format     => DATEV_FORMAT_KNE,
 298       dbh        => $db->dbh,
 299       trans_id   => $self->{id},
 300     );
 301
 302     $datev->clean_temporary_directories;
 303     $datev->export;
 304
 305     if ($datev->errors) {
 306       # this exception should be caught by do_transaction, which handles the rollback
 307       die join "\n", $::locale->text('DATEV check returned errors:'), $datev->errors;
 308     }
 309   };
 310
 311   }) || die t8('error while paying invoice #1 : ', $self->invnumber) . $db->error . "\n";
 312
 313   return 1;
 314 };
 315
 316 sub skonto_date {
 317
 318   my $self = shift;
 319
 320   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 321
 322   my $skonto_date;
 323
 324   if ( $is_sales ) {
 325     return undef unless ref $self->payment_terms;
 326     return undef unless $self->payment_terms->terms_skonto > 0;
 327     $skonto_date = DateTime->from_object(object => $self->transdate)->add(days => $self->payment_terms->terms_skonto);
 328   } else {
 329     return undef unless ref $self->vendor->payment_terms;
 330     return undef unless $self->vendor->payment_terms->terms_skonto > 0;
 331     $skonto_date = DateTime->from_object(object => $self->transdate)->add(days => $self->vendor->payment_terms->terms_skonto);
 332   };
 333
 334   return $skonto_date;
 335 };
 336
 337 sub reference_account {
 338   my $self = shift;
 339
 340   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 341
 342   require SL::DB::Manager::AccTransaction;
 343
 344   my $link_filter = $is_sales ? 'AR' : 'AP';
 345
 346   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 347      trans_id   => $self->id,
 348      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 349   );
 350
 351   return undef unless ref $acc_trans;
 352
 353   my $reference_account = SL::DB::Manager::Chart->find_by(id => $acc_trans->chart_id);
 354
 355   return $reference_account;
 356 };
 357
 358 sub reference_amount {
 359   my $self = shift;
 360
 361   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 362
 363   require SL::DB::Manager::AccTransaction;
 364
 365   my $link_filter = $is_sales ? 'AR' : 'AP';
 366
 367   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 368      trans_id   => $self->id,
 369      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 370   );
 371
 372   return undef unless ref $acc_trans;
 373
 374   # this should be the same as $self->amount
 375   return $acc_trans->amount;
 376 };
 377
 378
 379 sub open_amount {
 380   my $self = shift;
 381
 382   # in the future maybe calculate this from acc_trans
 383
 384   # if the difference is 0.01 Cent this may end up as 0.009999999999998
 385   # numerically, so round this value when checking for cent threshold >= 0.01
 386
 387   return $self->amount - $self->paid;
 388 };
 389
 390 sub open_percent {
 391   my $self = shift;
 392
 393   return 0 if $self->amount == 0;
 394   my $open_percent;
 395   if ( $self->open_amount < 0 ) {
 396     # overpaid, currently treated identically
 397     $open_percent = $self->open_amount * 100 / $self->amount;
 398   } else {
 399     $open_percent = $self->open_amount * 100 / $self->amount;
 400   };
 401
 402   return _round($open_percent) || 0;
 403 };
 404
 405 sub skonto_amount {
 406   my $self = shift;
 407
 408   return $self->amount - $self->amount_less_skonto;
 409 };
 410
 411 sub remaining_skonto_days {
 412   my $self = shift;
 413
 414   return undef unless ref $self->skonto_date;
 415
 416   my $dur = DateTime::Duration->new($self->skonto_date - DateTime->today);
 417   return $dur->delta_days();
 418
 419 };
 420
 421 sub percent_skonto {
 422   my $self = shift;
 423
 424   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 425
 426   my $percent_skonto = 0;
 427
 428   if ( $is_sales ) {
 429     return undef unless ref $self->payment_terms;
 430     return undef unless $self->payment_terms->percent_skonto > 0;
 431     $percent_skonto = $self->payment_terms->percent_skonto;
 432   } else {
 433     return undef unless ref $self->vendor->payment_terms;
 434     return undef unless $self->vendor->payment_terms->terms_skonto > 0;
 435     $percent_skonto = $self->vendor->payment_terms->percent_skonto;
 436   };
 437
 438   return $percent_skonto;
 439 };
 440
 441 sub amount_less_skonto {
 442   # amount that has to be paid if skonto applies, always return positive rounded values
 443   # the result is rounded so we can directly compare it with the user input
 444   my $self = shift;
 445
 446   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 447
 448   my $percent_skonto = $self->percent_skonto || 0;
 449
 450   return _round($self->amount - ( $self->amount * $percent_skonto) );
 451
 452 };
 453
 454 sub check_skonto_configuration {
 455   my $self = shift;
 456
 457   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 458
 459   my $skonto_configured = 1; # default is assume skonto works
 460
 461   # my $transactions = $self->transactions;
 462   foreach my $transaction (@{ $self->transactions }) {
 463     # find all transactions with an AR_amount or AP_amount link
 464     my $tax = SL::DB::Manager::Tax->get_first( where => [taxkey => $transaction->taxkey]);
 465     croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 466
 467     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->chart_link) };
 468     if ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) {
 469       $skonto_configured = 0 unless $tax->skonto_sales_chart_id;
 470     } elsif ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) {
 471       $skonto_configured = 0 unless $tax->skonto_purchase_chart_id;
 472     };
 473   };
 474
 475   return $skonto_configured;
 476 };
 477
 478 sub open_sepa_transfer_amount {
 479   my $self = shift;
 480
 481   my ($vc, $key, $type);
 482   if ( ref($self) eq 'SL::DB::Invoice' ) {
 483     $vc   = 'customer';
 484     $key  = 'ap_id';
 485     $type = 'ar';
 486   } else {
 487     $vc   = 'vendor';
 488     $key  = 'ap_id';
 489     $type = 'ap';
 490   };
 491
 492   my $sql = qq|SELECT SUM(sei.amount) AS amount FROM sepa_export_items sei | .
 493             qq| LEFT JOIN sepa_export se ON (sei.sepa_export_id = se.id)   | .
 494             qq| WHERE $key = ? AND NOT se.closed AND (se.vc = '$vc')       |;
 495
 496   my ($open_sepa_amount) = $self->db->dbh->selectrow_array($sql, undef, $self->id);
 497
 498   return $open_sepa_amount || 0;
 499
 500 };
 501
 502
 503 sub skonto_charts {
 504   my $self = shift;
 505
 506   # TODO: use param for amount, may also want to calculate skonto_amounts by
 507   # passing percentage in the future
 508
 509   my $amount = shift || $self->skonto_amount;
 510
 511   croak "no amount passed to skonto_charts" unless abs(_round($amount)) >= 0.01;
 512
 513   # TODO: check whether there are negative values in invoice / acc_trans ... credited items
 514
 515   # don't check whether skonto applies, because user may want to override this
 516   # return undef unless $self->percent_skonto;  # for is_sales
 517   # return undef unless $self->vendor->payment_terms->percent_skonto;  # for purchase
 518
 519   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 520
 521   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign
 522
 523   my @skonto_charts;  # resulting array with all income/expense accounts that have to be corrected
 524
 525   # calculate effective skonto (percentage) in difference_as_skonto mode
 526   # only works if there are no negative acc_trans values
 527   my $effective_skonto_rate = $amount ? $amount / $self->amount : 0;
 528
 529   # checks:
 530   my $total_skonto_amount  = 0;
 531   my $total_rounding_error = 0;
 532
 533   my $reference_ARAP_amount = 0;
 534
 535   # my $transactions = $self->transactions;
 536   foreach my $transaction (@{ $self->transactions }) {
 537     # find all transactions with an AR_amount or AP_amount link
 538     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->{chart_link}) };
 539     # second condition is that we can determine an automatic Skonto account for each AR_amount entry
 540
 541     if ( ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) or ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) ) {
 542         # $reference_ARAP_amount += $transaction->{amount} * $mult;
 543
 544         # quick hack that works around problem of non-unique tax keys in SKR04
 545         my $tax = SL::DB::Manager::Tax->get_first( where => [taxkey => $transaction->{taxkey}]);
 546         croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 547
 548         if ( $is_sales ) {
 549           die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $transaction->{taxkey} , $tax->taxdescription , $tax->rate*100) unless ref $tax->skonto_sales_chart;
 550         } else {
 551           die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $transaction->{taxkey} , $tax->taxdescription , $tax->rate*100) unless ref $tax->skonto_purchase_chart;
 552         };
 553
 554         my $skonto_amount_unrounded;
 555
 556         my $skonto_percent_abs = $self->amount ? abs($transaction->amount * (1 + $tax->rate) * 100 / $self->amount) : 0;
 557
 558         my $transaction_amount = abs($transaction->{amount} * (1 + $tax->rate));
 559         my $transaction_skonto_percent = abs($transaction_amount/$self->amount); # abs($transaction->{amount} * (1 + $tax->rate));
 560
 561
 562         $skonto_amount_unrounded   = abs($amount * $transaction_skonto_percent);
 563         my $skonto_amount_rounded  = _round($skonto_amount_unrounded);
 564         my $rounding_error         = $skonto_amount_unrounded - $skonto_amount_rounded;
 565         my $rounded_rounding_error = _round($rounding_error);
 566
 567         $total_rounding_error += $rounding_error;
 568         $total_skonto_amount  += $skonto_amount_rounded;
 569
 570         my $rec = {
 571           # skonto_percent_abs: relative part of amount + tax to the total invoice amount
 572           'skonto_percent_abs'     => $skonto_percent_abs,
 573           'chart_id'               => $is_sales ? $tax->skonto_sales_chart->id : $tax->skonto_purchase_chart->id,
 574           'skonto_amount'          => $skonto_amount_rounded,
 575           # 'rounding_error'         => $rounding_error,
 576           # 'rounded_rounding_error' => $rounded_rounding_error,
 577         };
 578
 579         push @skonto_charts, $rec;
 580       };
 581   };
 582
 583   # if the rounded sum of all rounding_errors reaches 0.01 this sum is
 584   # subtracted from the largest skonto_amount
 585   my $rounded_total_rounding_error = abs(_round($total_rounding_error));
 586
 587   if ( $rounded_total_rounding_error > 0 ) {
 588     my $highest_amount_pos = 0;
 589     my $highest_amount = 0;
 590     my $i = -1;
 591     foreach my $ref ( @skonto_charts ) {
 592       $i++;
 593       if ( $ref->{skonto_amount} > $highest_amount ) {
 594         $highest_amount     = $ref->{skonto_amount};
 595         $highest_amount_pos = $i;
 596       };
 597     };
 598     $skonto_charts[$i]->{skonto_amount} -= $rounded_total_rounding_error;
 599   };
 600
 601   return @skonto_charts;
 602 };
 603
 604
 605 sub within_skonto_period {
 606   my $self = shift;
 607   my $dateref = shift || DateTime->now->truncate( to => 'day' );
 608
 609   return undef unless ref $dateref eq 'DateTime';
 610   return 0 unless $self->skonto_date;
 611
 612   # return 1 if requested date (or today) is inside skonto period
 613   # this will also return 1 if date is before the invoice date
 614   return $dateref <= $self->skonto_date;
 615 };
 616
 617 sub valid_skonto_amount {
 618   my $self = shift;
 619   my $amount = shift || 0;
 620   my $max_skonto_percent = 0.10;
 621
 622   return 0 unless $amount > 0;
 623
 624   # does this work for other currencies?
 625   return ($self->amount*$max_skonto_percent) > $amount;
 626 };
 627
 628 sub get_payment_select_options_for_bank_transaction {
 629   my ($self, $bt_id, %params) = @_;
 630
 631   my $bt = SL::DB::Manager::BankTransaction->find_by( id => $bt_id );
 632   die unless $bt;
 633
 634   my $open_amount = $self->open_amount;
 635
 636   my @options;
 637   if ( $open_amount &&                   # invoice amount not 0
 638        $self->skonto_date &&             # check whether skonto applies
 639        abs(abs($self->amount_less_skonto) - abs($bt->amount)) < 0.01 &&
 640        $self->check_skonto_configuration) {
 641          if ( $self->within_skonto_period($bt->transdate) ) {
 642            push(@options, { payment_type => 'without_skonto', display => t8('without skonto') });
 643            push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt'), selected => 1 });
 644          } else {
 645            push(@options, { payment_type => 'without_skonto', display => t8('without skonto') , selected => 1 });
 646            push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt')});
 647          };
 648   };
 649
 650   return @options;
 651
 652 };
 653
 654 sub exchangerate {
 655   my ($self) = @_;
 656
 657   return 1 if $self->currency_id == $::instance_conf->get_currency_id;
 658
 659   my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $self->currency_id,
 660                                                     transdate   => $self->transdate,
 661                                                    );
 662   return undef unless $rate;
 663   $self->is_sales ? return $rate->sell : return $rate->buy;
 664 };
 665
 666 sub get_payment_suggestions {
 667
 668   my ($self, %params) = @_;
 669
 670   my $open_amount = $self->open_amount;
 671   $open_amount   -= $self->open_sepa_transfer_amount if $params{sepa};
 672
 673   $self->{invoice_amount_suggestion} = $open_amount;
 674   undef $self->{payment_select_options};
 675   push(@{$self->{payment_select_options}} , { payment_type => 'without_skonto',  display => t8('without skonto') });
 676   if ( $self->within_skonto_period ) {
 677     # If there have been no payments yet suggest amount_less_skonto, otherwise the open amount
 678     if ( $open_amount &&                   # invoice amount not 0
 679          $open_amount == $self->amount &&  # no payments yet, or sum of payments and sepa export amounts is zero
 680          $self->check_skonto_configuration) {
 681       $self->{invoice_amount_suggestion} = $self->amount_less_skonto;
 682       push(@{$self->{payment_select_options}} , { payment_type => 'with_skonto_pt',  display => t8('with skonto acc. to pt') , selected => 1 });
 683     } else {
 684       if ( ( $self->valid_skonto_amount($self->open_amount) || $self->valid_skonto_amount($open_amount) ) and not $params{sepa} ) {
 685         $self->{invoice_amount_suggestion} = $open_amount;
 686         # only suggest difference_as_skonto if open_amount exactly matches skonto_amount
 687         # AND we aren't in SEPA mode
 688         my $selected = 0;
 689         $selected = 1 if _round($open_amount) == _round($self->skonto_amount);
 690         push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => $selected });
 691       };
 692     };
 693   } else {
 694     # invoice was configured with skonto, but skonto date has passed, or no skonto available
 695     $self->{invoice_amount_suggestion} = $open_amount;
 696     # difference_as_skonto doesn't make any sense for SEPA transfer, as this doesn't cause any actual payment
 697     if ( $self->valid_skonto_amount($self->open_amount) && not $params{sepa} ) {
 698       push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => 0 });
 699     };
 700   };
 701   return 1;
 702 };
 703
 704 sub validate_payment_type {
 705   my $payment_type = shift;
 706
 707   my %allowed_payment_types = map { $_ => 1 } qw(without_skonto with_skonto_pt difference_as_skonto);
 708   croak "illegal payment type: $payment_type, must be one of: " . join(' ', keys %allowed_payment_types) unless $allowed_payment_types{ $payment_type };
 709
 710   return 1;
 711 }
 712
 713 sub create_bank_transaction {
 714   my ($self, %params) = @_;
 715
 716   require SL::DB::Chart;
 717   require SL::DB::BankAccount;
 718
 719   my $bank_chart;
 720   if ( $params{chart_id} ) {
 721     $bank_chart = SL::DB::Manager::Chart->find_by(chart_id => $params{chart_id}) or die "Can't find bank chart";
 722   } elsif ( $::instance_conf->get_ar_paid_accno_id ) {
 723     $bank_chart   = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_ar_paid_accno_id);
 724   } else {
 725     $bank_chart = SL::DB::Manager::Chart->find_by(description => 'Bank') or die "Can't find bank chart";
 726   };
 727   my $bank_account = SL::DB::Manager::BankAccount->find_by(chart_id => $bank_chart->id) or die "Can't find bank account for chart";
 728
 729   my $multiplier = $self->is_sales ? 1 : -1;
 730   my $amount = ($params{amount} || $self->amount) * $multiplier;
 731
 732   my $transdate = $params{transdate} || DateTime->today;
 733
 734   my $bt = SL::DB::BankTransaction->new(
 735     local_bank_account_id => $bank_account->id,
 736     remote_bank_code      => $self->customervendor->bank_code,
 737     remote_account_number => $self->customervendor->account_number,
 738     transdate             => $transdate,
 739     valutadate            => $transdate,
 740     amount                => $::form->round_amount($amount, 2),
 741     currency              => $self->currency->id,
 742     remote_name           => $self->customervendor->depositor,
 743     purpose               => $self->invnumber
 744   )->save;
 745 };
 746
 747
 748 sub _round {
 749   my $value = shift;
 750   my $num_dec = 2;
 751   return $::form->round_amount($value, 2);
 752 }
 753
 754 1;
 755
 756 __END__
 757
 758 =pod
 759
 760 =head1 NAME
 761
 762 SL::DB::Helper::Payment  Mixin providing helper methods for paying C<Invoice>
 763                          and C<PurchaseInvoice> objects and using skonto
 764
 765 =head1 SYNOPSIS
 766
 767 In addition to actually causing a payment via pay_invoice this helper contains
 768 many methods that help in determining information about the status of the
 769 invoice, such as the remaining open amount, whether skonto applies, until which
 770 date skonto applies, the skonto amount and relative percentages, what to do
 771 with skonto, ...
 772
 773 To prevent duplicate code this was all added in this mixin rather than directly
 774 in SL::DB::Invoice and SL::DB::PurchaseInvoice.
 775
 776 =over 4
 777
 778 =item C<pay_invoice %params>
 779
 780 Create a payment booking for an existing invoice object (type ar/ap/is/ir) via
 781 a configured bank account.
 782
 783 This function deals with all the acc_trans entries and also updates paid and datepaid.
 784
 785 Example:
 786
 787   my $ap   = SL::DB::Manager::PurchaseInvoice->find_by( invnumber => '1');
 788   my $bank = SL::DB::Manager::BankAccount->find_by( name => 'Bank');
 789   $ap->pay_invoice(chart_id      => $bank->chart_id,
 790                    amount        => $ap->open_amount,
 791                    transdate     => DateTime->now->to_kivitendo,
 792                    memo          => 'foobar',
 793                    source        => 'barfoo',
 794                    payment_type  => 'without_skonto',  # default if not specified
 795                   );
 796
 797 or with skonto:
 798   $ap->pay_invoice(chart_id      => $bank->chart_id,
 799                    amount        => $ap->amount,       # doesn't need to be specified
 800                    transdate     => DateTime->now->to_kivitendo,
 801                    memo          => 'foobar',
 802                    source        => 'barfoo',
 803                    payment_type  => 'with_skonto',
 804                   );
 805
 806 or in a certain currency:
 807   $ap->pay_invoice(chart_id      => $bank->chart_id,
 808                    amount        => 500,
 809                    currency      => 'USD',
 810                    transdate     => DateTime->now->to_kivitendo,
 811                    memo          => 'foobar',
 812                    source        => 'barfoo',
 813                    payment_type  => 'with_skonto',
 814                   );
 815
 816 Allowed payment types are:
 817   without_skonto with_skonto_pt difference_as_skonto
 818
 819 The option C<payment_type> allows for a basic skonto mechanism.
 820
 821 C<without_skonto> is the default mode, "amount" is paid to the account in
 822 chart_id. This can also be used for partial payments and corrections via
 823 negative amounts.
 824
 825 C<with_skonto_pt> can't be used for partial payments. When used on unpaid
 826 invoices the whole amount is paid, with the skonto part automatically being
 827 booked according to the skonto chart configured in the tax settings for each
 828 tax key. If an amount is passed it is ignored and the actual configured skonto
 829 amount is used.
 830
 831 C<difference_as_skonto> can only be used after partial payments have been made,
 832 the whole specified amount is booked according to the skonto charts configured
 833 in the tax settings for each tax key.
 834
 835 So passing amount doesn't have any effect for the cases C<with_skonto_pt> and
 836 C<difference_as_skonto>, as all necessary values are taken from the stored
 837 invoice.
 838
 839 The skonto modes automatically calculate the relative amounts for a mix of
 840 taxes, e.g. items with 7% and 19% in one invoice. There is a helper method
 841 skonto_charts, which calculates the relative percentages according to the
 842 amounts in acc_trans (which are grouped by tax).
 843
 844 There is currently no way of excluding certain items in an invoice from having
 845 skonto applied to them.  If this feature was added to parts the calculation
 846 method of relative skonto would have to be completely rewritten using the
 847 invoice items rather than acc_trans.
 848
 849 The skonto modes also still don't automatically correct the tax, this still has
 850 to be done manually. Therefore all payments generated by pay_invoice have
 851 taxkey 0.
 852
 853 There is currently no way to directly pay an invoice via this method if the
 854 effective skonto differs from the skonto according to the payment terms
 855 configured for the invoice/vendor.
 856
 857 In this case one has to pay in two steps: first the actual paid amount via
 858 "without skonto", and then the remainder via "difference_as_skonto". The user
 859 has to there actively decide whether to accept the differing skonto.
 860
 861 Because of the way skonto_charts works the calculation doesn't work if there
 862 are negative values in acc_trans. E.g. one invoice with a positive value for
 863 19% tax and a negative value for the acc_trans line with 7%
 864
 865 Skonto doesn't/shouldn't apply if the invoice contains credited items.
 866
 867 If no amount is given the whole open amout is paid.
 868
 869 If neither currency or currency_id are given as params, the currency of the
 870 invoice is assumed to be the payment currency.
 871
 872 =item C<reference_account>
 873
 874 Returns a chart object which is the chart of the invoice with link AR or AP.
 875
 876 Example (1200 is the AR account for SKR04):
 877   my $invoice = invoice(invnumber => '144');
 878   $invoice->reference_account->accno
 879   # 1200
 880
 881 =item C<percent_skonto>
 882
 883 Returns the configured skonto percentage of the payment terms of an invoice,
 884 e.g. 0.02 for 2%. Payment terms come from invoice settings for ar, from vendor
 885 settings for ap.
 886
 887 =item C<amount_less_skonto>
 888
 889 If the invoice has a payment term (via ar for sales, via vendor for purchase),
 890 calculate the amount to be paid in the case of skonto.  This doesn't check,
 891 whether skonto applies (i.e. skonto doesn't wasn't exceeded), it just subtracts
 892 the configured percentage (e.g. 2%) from the total amount.
 893
 894 The returned value is rounded to two decimals.
 895
 896 =item C<skonto_date>
 897
 898 The date up to which skonto may be taken. This is calculated from the invoice
 899 date + the number of days configured in the payment terms.
 900
 901 This method can also be used to determine whether skonto applies for the
 902 invoice, as it returns undef if there is no payment term or skonto days is set
 903 to 0.
 904
 905 =item C<within_skonto_period [DATE]>
 906
 907 Returns 0 or 1.
 908
 909 Checks whether the invoice has payment terms configured, and whether the date
 910 is within the skonto max date. If no date is passed the current date is used.
 911
 912 You can also pass a dateref object as a parameter to check whether skonto
 913 applies for that date rather than the current date.
 914
 915 =item C<valid_skonto_amount>
 916
 917 Takes an amount as an argument and checks whether the amount is less than 10%
 918 of the total amount of the invoice. The value of 10% is currently hardcoded in
 919 the method. This method is currently used to check whether to offer the payment
 920 option "difference as skonto".
 921
 922 Example:
 923  if ( $invoice->valid_skonto_amount($invoice->open_amount) ) {
 924    # ... do something
 925  }
 926
 927 =item C<skonto_charts [$amount]>
 928
 929 Returns a list of chart_ids and some calculated numbers that can be used for
 930 paying the invoice with skonto. This function will automatically calculate the
 931 relative skonto amounts even if the invoice contains several types of taxes
 932 (e.g. 7% and 19%).
 933
 934 Example usage:
 935   my $invoice = SL::DB::Manager::Invoice->find_by(invnumber => '211');
 936   my @skonto_charts = $invoice->skonto_charts;
 937
 938 or with the total skonto amount as an argument:
 939   my @skonto_charts = $invoice->skonto_charts($invoice->open_amount);
 940
 941 The following values are generated for each chart:
 942
 943 =over 2
 944
 945 =item C<chart_id>
 946
 947 The chart id of the skonto amount to be booked.
 948
 949 =item C<skonto_amount>
 950
 951 The total amount to be paid to the account
 952
 953 =item C<skonto_percent>
 954
 955 The relative percentage of that skonto chart. This can be useful if the actual
 956 ekonto that is paid deviates from the granted skonto, e.g. customer effectively
 957 pays 2.6% skonto instead of 2%, and we accept this. Then we can still calculate
 958 the relative skonto amounts for different taxes based on the absolute
 959 percentages. Used for case C<difference_as_skonto>.
 960
 961 =item C<skonto_percent_abs>
 962
 963 The absolute percentage of that skonto chart in relation to the total amount.
 964 Used to calculate skonto_amount for case C<with_skonto_pt>.
 965
 966 =back
 967
 968 If the invoice contains several types of taxes then skonto_charts can be used
 969 to calculate the relative amounts.
 970
 971 Example in console of an invoice with 100 Euro at 7% and 100 Euro at 19% with
 972 tax not included:
 973
 974   my $invoice = invoice(invnumber => '144');
 975   $invoice->amount
 976   226.00000
 977   $invoice->payment_terms->percent_skonto
 978   0.02
 979   $invoice->skonto_charts
 980   pp $invoice->skonto_charts
 981   #             $VAR1 = {
 982   #               'chart_id'       => 128,
 983   #               'skonto_amount'  => '2.14',
 984   #               'skonto_percent' => '47.3451327433627'
 985   #             };
 986   #             $VAR2 = {
 987   #               'chart_id'       => 130,
 988   #               'skonto_amount'  => '2.38',
 989   #               'skonto_percent' => '52.654867256637'
 990   #             };
 991
 992 C<skonto_charts> always returns positive values (abs) for C<skonto_amount> and
 993 C<skonto_percent>.
 994
 995 C<skonto_charts> generates one entry for each acc_trans entry. ar and ap
 996 bookings only have one acc_trans entry for each taxkey (e.g. 7% and 19%).  This
 997 is because all the items are grouped according to the Buchungsgruppen mechanism
 998 and the totals are written to acc_trans.  For is and ir it is possible to have
 999 several acc_trans entries with the same tax. In this case skonto_charts
1000 generates a skonto booking for each acc_trans income/expense entry.
1001
1002 In the future this function may also be used to calculate the corrections for
1003 the income tax.
1004
1005 =item C<open_amount>
1006
1007 Unrounded total open amount of invoice (amount - paid).
1008 Doesn't take into account pending SEPA transfers.
1009
1010 =item C<open_percent>
1011
1012 Percentage of the invoice that is still unpaid, e.g. 100,00 if no payments have
1013 been made yet, 0,00 if fully paid.
1014
1015 =item C<remaining_skonto_days>
1016
1017 How many days skonto can still be taken, calculated from current day. Returns 0
1018 if current day is the max skonto date, and negative number if skonto date has
1019 already passed.
1020
1021 Returns undef if skonto is not configured for that invoice.
1022
1023 =item C<get_payment_suggestions %params>
1024
1025 Creates data intended for an L.select_tag dropdown that can be used in a
1026 template. Depending on the rules it will choose from the options
1027 without_skonto, with_skonto_pt and difference_as_skonto, and select the most
1028 likely one.
1029
1030 If the parameter "sepa" is passed, the SEPA export payments that haven't been
1031 executed yet are considered when determining the open amount of the invoice.
1032
1033 The current rules are:
1034
1035 =over 2
1036
1037 =item * without_skonto is always an option
1038
1039 =item * with_skonto_pt is only offered if there haven't been any payments yet and the current date is within the skonto period.
1040
1041 =item * difference_as_skonto is only offered if there have already been payments made and the open amount is smaller than 10% of the total amount.
1042
1043 with_skonto_pt will only be offered, if all the AR_amount/AP_amount have a
1044 taxkey with a configured skonto chart
1045
1046 =back
1047
1048 It will also fill $self->{invoice_amount_suggestion} with either the open
1049 amount, or if with_skonto_pt is selected, with amount_less_skonto, so the
1050 template can fill the input with the likely amount.
1051
1052 Example in console:
1053   my $ar = invoice( invnumber => '257');
1054   $ar->get_payment_suggestions;
1055   print $ar->{invoice_amount_suggestion} . "\n";
1056   # 97.23
1057   pp $ar->{payment_select_options}
1058   # $VAR1 = [
1059   #         {
1060   #           'display' => 'ohne Skonto',
1061   #           'payment_type' => 'without_skonto'
1062   #         },
1063   #         {
1064   #           'display' => 'mit Skonto nach ZB',
1065   #           'payment_type' => 'with_skonto_pt',
1066   #           'selected' => 1
1067   #         }
1068   #       ];
1069
1070 The resulting array $ar->{payment_select_options} can be used in a template
1071 select_tag using value_key and title_key:
1072
1073 [% L.select_tag('payment_type_' _ loop.count, invoice.payment_select_options, value_key => 'payment_type', title_key => 'display', id => 'payment_type_' _ loop.count) %]
1074
1075 It would probably make sense to have different rules for the pre-selected items
1076 for sales and purchase, and to also make these rules configurable in the
1077 defaults. E.g. when creating a SEPA bank transfer for vendor invoices a company
1078 might always want to pay quickly making use of skonto, while another company
1079 might always want to pay as late as possible.
1080
1081 =item C<get_payment_select_options_for_bank_transaction $banktransaction_id %params>
1082
1083 Make suggestion for a skonto payment type by returning an HTML blob of the options
1084 of a HTML drop-down select with the most likely option preselected.
1085
1086 This is a helper function for BankTransaction/ajax_payment_suggestion.
1087
1088 We are working with an existing payment, so difference_as_skonto never makes sense.
1089
1090 If skonto is possible (skonto_date exists), add two possibilities:
1091 without_skonto and with_skonto_pt if payment date is within skonto_date,
1092 preselect with_skonto_pt, otherwise preselect without skonto.
1093
1094 =item C<create_bank_transaction %params>
1095
1096 Method used for testing purposes, allows you to quickly create bank
1097 transactions from invoices to have something to test payments against.
1098
1099  my $ap = SL::DB::Manager::Invoice->find_by(id => 41);
1100  $ap->create_bank_transaction(amount => $ap->amount/2, transdate => DateTime->today->add(days => 5));
1101
1102 Amount is always relative to the absolute amount of the invoice, use positive
1103 values for sales and purchases.
1104
1105 =item C<exchangerate>
1106
1107 Returns the exchangerate in database format for the invoice according to that invoice's transdate.
1108 Returns 'sell' for sales, 'buy' for purchases.
1109
1110 =back
1111
1112 =head1 TODO AND CAVEATS
1113
1114 =over 4
1115
1116 =item *
1117
1118 when looking at open amount, maybe consider that there may already be queued
1119 amounts in SEPA Export
1120
1121 =back
1122
1123 =head1 AUTHOR
1124
1125 G. Richardson E<lt>grichardson@kivitendo-premium.de<gt>
1126
1127 =cut