SL/DB/Helper/Payment.pm

   1 package SL::DB::Helper::Payment;
   2
   3 use strict;
   4
   5 use parent qw(Exporter);
   6 our @EXPORT = qw(pay_invoice);
   7 our @EXPORT_OK = qw(skonto_date skonto_charts amount_less_skonto within_skonto_period percent_skonto reference_account reference_amount open_amount open_percent remaining_skonto_days skonto_amount check_skonto_configuration valid_skonto_amount get_payment_suggestions validate_payment_type open_sepa_transfer_amount get_payment_select_options_for_bank_transaction exchangerate forex);
   8 our %EXPORT_TAGS = (
   9   "ALL" => [@EXPORT, @EXPORT_OK],
  10 );
  11
  12 require SL::DB::Chart;
  13 use Data::Dumper;
  14 use DateTime;
  15 use SL::DATEV qw(:CONSTANTS);
  16 use SL::Locale::String qw(t8);
  17 use List::Util qw(sum);
  18 use SL::DB::Exchangerate;
  19 use SL::DB::Currency;
  20 use Carp;
  21
  22 #
  23 # Public functions not exported by default
  24 #
  25
  26 sub pay_invoice {
  27   my ($self, %params) = @_;
  28
  29   require SL::DB::Tax;
  30
  31   my $is_sales = ref($self) eq 'SL::DB::Invoice';
  32   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign depending on ar/ap
  33   my @new_acc_ids;
  34   my $paid_amount = 0; # the amount that will be later added to $self->paid, should be in default currency
  35
  36   # default values if not set
  37   $params{payment_type} = 'without_skonto' unless $params{payment_type};
  38   validate_payment_type($params{payment_type});
  39
  40   # check for required parameters
  41   Common::check_params(\%params, qw(chart_id transdate));
  42
  43   my $transdate_obj;
  44   if (ref($params{transdate} eq 'DateTime')) {
  45     $transdate_obj = $params{transdate};
  46   } else {
  47    $transdate_obj = $::locale->parse_date_to_object($params{transdate});
  48   };
  49   croak t8('Illegal date') unless ref $transdate_obj;
  50
  51   # check for closed period
  52   my $closedto = $::locale->parse_date_to_object($::instance_conf->get_closedto);
  53   if ( ref $closedto && $transdate_obj < $closedto ) {
  54     croak t8('Cannot post payment for a closed period!');
  55   };
  56
  57   # check for maximum number of future days
  58   if ( $::instance_conf->get_max_future_booking_interval > 0 ) {
  59     croak t8('Cannot post transaction above the maximum future booking date!') if $transdate_obj > DateTime->now->add( days => $::instance_conf->get_max_future_booking_interval );
  60   };
  61
  62   # currency is either passed or use the invoice currency if it differs from the default currency
  63   my ($exchangerate,$currency);
  64   if ($params{currency} || $params{currency_id} || $self->currency_id != $::instance_conf->get_currency_id) {
  65     if ($params{currency} || $params{currency_id} ) { # currency was specified
  66       $currency = SL::DB::Manager::Currency->find_by(name => $params{currency}) || SL::DB::Manager::Currency->find_by(id => $params{currency_id});
  67     } else { # use invoice currency
  68       $currency = SL::DB::Manager::Currency->find_by(id => $self->currency_id);
  69     };
  70     die "no currency" unless $currency;
  71     if ($currency->id == $::instance_conf->get_currency_id) {
  72       $exchangerate = 1;
  73     } else {
  74       my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $currency->id,
  75                                                         transdate   => $transdate_obj,
  76                                                        );
  77       if ($rate) {
  78         $exchangerate = $is_sales ? $rate->buy : $rate->sell;
  79       } else {
  80         die "No exchange rate for " . $transdate_obj->to_kivitendo;
  81       };
  82     };
  83   } else { # no currency param given or currency is the same as default_currency
  84     $exchangerate = 1;
  85   };
  86
  87   # input checks:
  88   if ( $params{'payment_type'} eq 'without_skonto' ) {
  89     croak "invalid amount for payment_type 'without_skonto': $params{'amount'}\n" unless abs($params{'amount'}) > 0;
  90   };
  91
  92   # options with_skonto_pt and difference_as_skonto don't require the parameter
  93   # amount, but if amount is passed, make sure it matches the expected value
  94   if ( $params{'payment_type'} eq 'difference_as_skonto' ) {
  95     croak "amount $params{amount} doesn't match open amount " . $self->open_amount . ", diff = " . ($params{amount}-$self->open_amount) if $params{amount} && abs($self->open_amount - $params{amount} ) > 0.0000001;
  96   } elsif ( $params{'payment_type'} eq 'with_skonto_pt' ) {
  97     croak "amount $params{amount} doesn't match amount less skonto: " . $self->amount_less_skonto . "\n" if $params{amount} && abs($self->amount_less_skonto - $params{amount} ) > 0.0000001;
  98     croak "payment type with_skonto_pt can't be used if payments have already been made" if $self->paid != 0;
  99   };
 100
 101   # absolute skonto amount for invoice, use as reference sum to see if the
 102   # calculated skontos add up
 103   # only needed for payment_term "with_skonto_pt"
 104
 105   my $skonto_amount_check = $self->skonto_amount; # variable should be zero after calculating all skonto
 106   my $total_open_amount   = $self->open_amount;
 107
 108   # account where money is paid to/from: bank account or cash
 109   my $account_bank = SL::DB::Manager::Chart->find_by(id => $params{chart_id});
 110   croak "can't find bank account with id " . $params{chart_id} unless ref $account_bank;
 111
 112   my $reference_account = $self->reference_account;
 113   croak "can't find reference account (link = AR/AP) for invoice" unless ref $reference_account;
 114
 115   my $memo   = $params{memo}   // '';
 116   my $source = $params{source} // '';
 117
 118   my $rounded_params_amount = _round( $params{amount} ); # / $exchangerate);
 119   my $fx_gain_loss_amount = 0; # for fx_gain and fx_loss
 120
 121   my $db = $self->db;
 122   $db->with_transaction(sub {
 123     my $new_acc_trans;
 124
 125     # all three payment type create 1 AR/AP booking (the paid part)
 126     # difference_as_skonto creates n skonto bookings (1 for each buchungsgruppe type)
 127     # with_skonto_pt creates 1 bank booking and n skonto bookings (1 for each buchungsgruppe type)
 128     # without_skonto creates 1 bank booking
 129
 130     # as long as there is no automatic tax, payments are always booked with
 131     # taxkey 0
 132
 133     unless ( $params{payment_type} eq 'difference_as_skonto' ) {
 134       # cases with_skonto_pt and without_skonto
 135
 136       # for case with_skonto_pt we need to know the corrected amount at this
 137       # stage if we are going to use $params{amount}
 138
 139       my $pay_amount = $rounded_params_amount;
 140       $pay_amount = $self->amount_less_skonto if $params{payment_type} eq 'with_skonto_pt';
 141
 142       # bank account and AR/AP
 143       $paid_amount += $pay_amount * $exchangerate;
 144
 145       my $amount = (-1 * $pay_amount) * $mult;
 146
 147
 148       # total amount against bank, do we already know this by now?
 149       $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 150                                                    chart_id   => $account_bank->id,
 151                                                    chart_link => $account_bank->link,
 152                                                    amount     => $amount,
 153                                                    transdate  => $transdate_obj,
 154                                                    source     => $source,
 155                                                    memo       => $memo,
 156                                                    project_id => $params{project_id} ? $params{project_id} : undef,
 157                                                    taxkey     => 0,
 158                                                    tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 159       $new_acc_trans->save;
 160
 161       push @new_acc_ids, $new_acc_trans->acc_trans_id;
 162       # deal with fxtransaction
 163       if ( $self->currency_id != $::instance_conf->get_currency_id ) {
 164         my $fxamount = _round($amount - ($amount * $exchangerate));
 165         $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 166                                                      chart_id       => $account_bank->id,
 167                                                      chart_link     => $account_bank->link,
 168                                                      amount         => $fxamount * -1,
 169                                                      transdate      => $transdate_obj,
 170                                                      source         => $source,
 171                                                      memo           => $memo,
 172                                                      taxkey         => 0,
 173                                                      fx_transaction => 1,
 174                                                      tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 175         $new_acc_trans->save;
 176         push @new_acc_ids, $new_acc_trans->acc_trans_id;
 177         # if invoice exchangerate differs from exchangerate of payment
 178         # deal with fxloss and fxamount
 179         if ($self->exchangerate and $self->exchangerate != 1 and $self->exchangerate != $exchangerate) {
 180           my $fxgain_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxgain_accno_id) || die "Can't determine fxgain chart";
 181           my $fxloss_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxloss_accno_id) || die "Can't determine fxloss chart";
 182           my $gain_loss_amount = _round($amount * ($exchangerate - $self->exchangerate ) * -1,2);
 183           my $gain_loss_chart = $gain_loss_amount > 0 ? $fxgain_chart : $fxloss_chart;
 184           $fx_gain_loss_amount = $gain_loss_amount;
 185
 186           $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 187                                                        chart_id       => $gain_loss_chart->id,
 188                                                        chart_link     => $gain_loss_chart->link,
 189                                                        amount         => $gain_loss_amount,
 190                                                        transdate      => $transdate_obj,
 191                                                        source         => $source,
 192                                                        memo           => $memo,
 193                                                        taxkey         => 0,
 194                                                        fx_transaction => 0,
 195                                                        tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 196           $new_acc_trans->save;
 197           push @new_acc_ids, $new_acc_trans->acc_trans_id;
 198
 199         }
 200       }
 201     }
 202
 203     if ( $params{payment_type} eq 'difference_as_skonto' or $params{payment_type} eq 'with_skonto_pt' ) {
 204
 205       my $total_skonto_amount;
 206       if ( $params{payment_type} eq 'with_skonto_pt' ) {
 207         $total_skonto_amount = $self->skonto_amount;
 208       } elsif ( $params{payment_type} eq 'difference_as_skonto' ) {
 209         $total_skonto_amount = $self->open_amount;
 210       };
 211
 212       my @skonto_bookings = $self->skonto_charts($total_skonto_amount);
 213
 214       # error checking:
 215       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 216         my $calculated_skonto_sum  = sum map { $_->{skonto_amount} } @skonto_bookings;
 217         croak "calculated skonto for difference_as_skonto = $calculated_skonto_sum doesn't add up open amount: " . $self->open_amount unless _round($calculated_skonto_sum) == _round($self->open_amount);
 218       };
 219
 220       my $reference_amount = $total_skonto_amount;
 221
 222       # create an acc_trans entry for each result of $self->skonto_charts
 223       foreach my $skonto_booking ( @skonto_bookings ) {
 224         next unless $skonto_booking->{'chart_id'};
 225         next unless $skonto_booking->{'skonto_amount'} != 0;
 226         my $amount = -1 * $skonto_booking->{skonto_amount};
 227         $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 228                                                      chart_id   => $skonto_booking->{'chart_id'},
 229                                                      chart_link => SL::DB::Manager::Chart->find_by(id => $skonto_booking->{'chart_id'})->link,
 230                                                      amount     => $amount * $mult,
 231                                                      transdate  => $transdate_obj,
 232                                                      source     => $params{source},
 233                                                      taxkey     => 0,
 234                                                      tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 235
 236         # the acc_trans entries are saved individually, not added to $self and then saved all at once
 237         $new_acc_trans->save;
 238         push @new_acc_ids, $new_acc_trans->acc_trans_id;
 239
 240         $reference_amount -= abs($amount);
 241         $paid_amount      += -1 * $amount * $exchangerate;
 242         $skonto_amount_check -= $skonto_booking->{'skonto_amount'};
 243       };
 244       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 245           die "difference_as_skonto calculated incorrectly, sum of calculated payments doesn't add up to open amount $total_open_amount, reference_amount = $reference_amount\n" unless _round($reference_amount) == 0;
 246       }
 247     }
 248
 249     my $arap_amount = 0;
 250
 251     if ( $params{payment_type} eq 'difference_as_skonto' ) {
 252       $arap_amount = $total_open_amount;
 253     } elsif ( $params{payment_type} eq 'without_skonto' ) {
 254       $arap_amount = $rounded_params_amount;
 255     } elsif ( $params{payment_type} eq 'with_skonto_pt' ) {
 256       # this should be amount + sum(amount+skonto), but while we only allow
 257       # with_skonto_pt for completely unpaid invoices we just use the value
 258       # from the invoice
 259       $arap_amount = $total_open_amount;
 260     }
 261
 262     # regardless of payment_type there is always only exactly one arap booking
 263     # TODO: compare $arap_amount to running total
 264     my $arap_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 265                                                   chart_id   => $reference_account->id,
 266                                                   chart_link => $reference_account->link,
 267                                                   amount     => _round($arap_amount * $mult * $exchangerate - $fx_gain_loss_amount),
 268                                                   transdate  => $transdate_obj,
 269                                                   source     => '', #$params{source},
 270                                                   taxkey     => 0,
 271                                                   tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 272     $arap_booking->save;
 273     push @new_acc_ids, $arap_booking->acc_trans_id;
 274
 275     $fx_gain_loss_amount *= -1 if $self->is_sales;
 276     $self->paid($self->paid + _round($paid_amount) + $fx_gain_loss_amount) if $paid_amount;
 277     $self->datepaid($transdate_obj);
 278     $self->save;
 279
 280     # make sure transactions will be reloaded the next time $self->transactions
 281     # is called, as pay_invoice saves the acc_trans objects individually rather
 282     # than adding them to the transaction relation array.
 283     $self->forget_related('transactions');
 284
 285     my $datev_check = 0;
 286     if ( $is_sales )  {
 287       if ( (  $self->invoice && $::instance_conf->get_datev_check_on_sales_invoice  ) ||
 288            ( !$self->invoice && $::instance_conf->get_datev_check_on_ar_transaction )) {
 289         $datev_check = 1;
 290       }
 291     } else {
 292       if ( (  $self->invoice && $::instance_conf->get_datev_check_on_purchase_invoice ) ||
 293            ( !$self->invoice && $::instance_conf->get_datev_check_on_ap_transaction   )) {
 294         $datev_check = 1;
 295       }
 296     }
 297
 298     if ( $datev_check ) {
 299
 300       my $datev = SL::DATEV->new(
 301         dbh        => $db->dbh,
 302         trans_id   => $self->{id},
 303       );
 304
 305       $datev->generate_datev_data;
 306
 307       if ($datev->errors) {
 308         # this exception should be caught by with_transaction, which handles the rollback
 309         die join "\n", $::locale->text('DATEV check returned errors:'), $datev->errors;
 310       }
 311     }
 312
 313     1;
 314
 315   }) || die t8('error while paying invoice #1 : ', $self->invnumber) . $db->error . "\n";
 316   return wantarray ? @new_acc_ids : 1;
 317 }
 318
 319 sub skonto_date {
 320
 321   my $self = shift;
 322
 323   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 324
 325   my $skonto_date;
 326
 327   if ( $is_sales ) {
 328     return undef unless ref $self->payment_terms;
 329     return undef unless $self->payment_terms->terms_skonto > 0;
 330     $skonto_date = DateTime->from_object(object => $self->transdate)->add(days => $self->payment_terms->terms_skonto);
 331   } else {
 332     return undef unless ref $self->vendor->payment_terms;
 333     return undef unless $self->vendor->payment_terms->terms_skonto > 0;
 334     $skonto_date = DateTime->from_object(object => $self->transdate)->add(days => $self->vendor->payment_terms->terms_skonto);
 335   };
 336
 337   return $skonto_date;
 338 };
 339
 340 sub reference_account {
 341   my $self = shift;
 342
 343   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 344
 345   require SL::DB::Manager::AccTransaction;
 346
 347   my $link_filter = $is_sales ? 'AR' : 'AP';
 348
 349   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 350      trans_id   => $self->id,
 351      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 352   );
 353
 354   return undef unless ref $acc_trans;
 355
 356   my $reference_account = SL::DB::Manager::Chart->find_by(id => $acc_trans->chart_id);
 357
 358   return $reference_account;
 359 };
 360
 361 sub reference_amount {
 362   my $self = shift;
 363
 364   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 365
 366   require SL::DB::Manager::AccTransaction;
 367
 368   my $link_filter = $is_sales ? 'AR' : 'AP';
 369
 370   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 371      trans_id   => $self->id,
 372      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 373   );
 374
 375   return undef unless ref $acc_trans;
 376
 377   # this should be the same as $self->amount
 378   return $acc_trans->amount;
 379 };
 380
 381
 382 sub open_amount {
 383   my $self = shift;
 384
 385   # in the future maybe calculate this from acc_trans
 386
 387   # if the difference is 0.01 Cent this may end up as 0.009999999999998
 388   # numerically, so round this value when checking for cent threshold >= 0.01
 389
 390   return ($self->amount // 0) - ($self->paid // 0);
 391 };
 392
 393 sub open_percent {
 394   my $self = shift;
 395
 396   return 0 if $self->amount == 0;
 397   my $open_percent;
 398   if ( $self->open_amount < 0 ) {
 399     # overpaid, currently treated identically
 400     $open_percent = $self->open_amount * 100 / $self->amount;
 401   } else {
 402     $open_percent = $self->open_amount * 100 / $self->amount;
 403   };
 404
 405   return _round($open_percent) || 0;
 406 };
 407
 408 sub skonto_amount {
 409   my $self = shift;
 410
 411   return $self->amount - $self->amount_less_skonto;
 412 };
 413
 414 sub remaining_skonto_days {
 415   my $self = shift;
 416
 417   return undef unless ref $self->skonto_date;
 418
 419   my $dur = DateTime::Duration->new($self->skonto_date - DateTime->today);
 420   return $dur->delta_days();
 421
 422 };
 423
 424 sub percent_skonto {
 425   my $self = shift;
 426
 427   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 428
 429   my $percent_skonto = 0;
 430
 431   if ( $is_sales ) {
 432     return undef unless ref $self->payment_terms;
 433     return undef unless $self->payment_terms->percent_skonto > 0;
 434     $percent_skonto = $self->payment_terms->percent_skonto;
 435   } else {
 436     return undef unless ref $self->vendor->payment_terms;
 437     return undef unless $self->vendor->payment_terms->terms_skonto > 0;
 438     $percent_skonto = $self->vendor->payment_terms->percent_skonto;
 439   };
 440
 441   return $percent_skonto;
 442 };
 443
 444 sub amount_less_skonto {
 445   # amount that has to be paid if skonto applies, always return positive rounded values
 446   # the result is rounded so we can directly compare it with the user input
 447   my $self = shift;
 448
 449   my $percent_skonto = $self->percent_skonto || 0;
 450
 451   return _round($self->amount - ( $self->amount * $percent_skonto) );
 452
 453 };
 454
 455 sub check_skonto_configuration {
 456   my $self = shift;
 457
 458   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 459
 460   my $skonto_configured = 1; # default is assume skonto works
 461
 462   # my $transactions = $self->transactions;
 463   foreach my $transaction (@{ $self->transactions }) {
 464     # find all transactions with an AR_amount or AP_amount link
 465     my $tax = SL::DB::Manager::Tax->get_first( where => [taxkey => $transaction->taxkey, id => $transaction->tax_id ]);
 466     croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 467
 468     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->chart_link) };
 469     if ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) {
 470       $skonto_configured = 0 unless $tax->skonto_sales_chart_id;
 471     } elsif ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) {
 472       $skonto_configured = 0 unless $tax->skonto_purchase_chart_id;
 473     };
 474   };
 475
 476   return $skonto_configured;
 477 };
 478
 479 sub open_sepa_transfer_amount {
 480   my $self = shift;
 481
 482   my ($vc, $key, $type);
 483   if ( ref($self) eq 'SL::DB::Invoice' ) {
 484     $vc   = 'customer';
 485     $key  = 'ap_id';
 486     $type = 'ar';
 487   } else {
 488     $vc   = 'vendor';
 489     $key  = 'ap_id';
 490     $type = 'ap';
 491   };
 492
 493   my $sql = qq|SELECT SUM(sei.amount) AS amount FROM sepa_export_items sei | .
 494             qq| LEFT JOIN sepa_export se ON (sei.sepa_export_id = se.id)   | .
 495             qq| WHERE $key = ? AND NOT se.closed AND (se.vc = '$vc')       |;
 496
 497   my ($open_sepa_amount) = $self->db->dbh->selectrow_array($sql, undef, $self->id);
 498
 499   return $open_sepa_amount || 0;
 500
 501 };
 502
 503
 504 sub skonto_charts {
 505   my $self = shift;
 506
 507   # TODO: use param for amount, may also want to calculate skonto_amounts by
 508   # passing percentage in the future
 509
 510   my $amount = shift || $self->skonto_amount;
 511
 512   croak "no amount passed to skonto_charts" unless abs(_round($amount)) >= 0.01;
 513
 514   # TODO: check whether there are negative values in invoice / acc_trans ... credited items
 515
 516   # don't check whether skonto applies, because user may want to override this
 517   # return undef unless $self->percent_skonto;  # for is_sales
 518   # return undef unless $self->vendor->payment_terms->percent_skonto;  # for purchase
 519
 520   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 521
 522   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign
 523
 524   my @skonto_charts;  # resulting array with all income/expense accounts that have to be corrected
 525
 526   # calculate effective skonto (percentage) in difference_as_skonto mode
 527   # only works if there are no negative acc_trans values
 528   my $effective_skonto_rate = $amount ? $amount / $self->amount : 0;
 529
 530   # checks:
 531   my $total_skonto_amount  = 0;
 532   my $total_rounding_error = 0;
 533
 534   my $reference_ARAP_amount = 0;
 535
 536   # my $transactions = $self->transactions;
 537   foreach my $transaction (@{ $self->transactions }) {
 538     # find all transactions with an AR_amount or AP_amount link
 539     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->{chart_link}) };
 540     # second condition is that we can determine an automatic Skonto account for each AR_amount entry
 541
 542     if ( ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) or ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) ) {
 543         # $reference_ARAP_amount += $transaction->{amount} * $mult;
 544
 545         # quick hack that works around problem of non-unique tax keys in SKR04
 546         # ? use tax_id in acc_trans
 547         my $tax = SL::DB::Manager::Tax->get_first( where => [id => $transaction->{tax_id}]);
 548         croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 549
 550         if ( $is_sales ) {
 551           die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $transaction->{taxkey} , $tax->taxdescription , $tax->rate*100) unless ref $tax->skonto_sales_chart;
 552         } else {
 553           die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $transaction->{taxkey} , $tax->taxdescription , $tax->rate*100) unless ref $tax->skonto_purchase_chart;
 554         };
 555
 556         my $skonto_amount_unrounded;
 557
 558         my $skonto_percent_abs = $self->amount ? abs($transaction->amount * (1 + $tax->rate) * 100 / $self->amount) : 0;
 559
 560         my $transaction_amount = abs($transaction->{amount} * (1 + $tax->rate));
 561         my $transaction_skonto_percent = abs($transaction_amount/$self->amount); # abs($transaction->{amount} * (1 + $tax->rate));
 562
 563
 564         $skonto_amount_unrounded   = abs($amount * $transaction_skonto_percent);
 565         my $skonto_amount_rounded  = _round($skonto_amount_unrounded);
 566         my $rounding_error         = $skonto_amount_unrounded - $skonto_amount_rounded;
 567         my $rounded_rounding_error = _round($rounding_error);
 568
 569         $total_rounding_error += $rounding_error;
 570         $total_skonto_amount  += $skonto_amount_rounded;
 571
 572         my $rec = {
 573           # skonto_percent_abs: relative part of amount + tax to the total invoice amount
 574           'skonto_percent_abs'     => $skonto_percent_abs,
 575           'chart_id'               => $is_sales ? $tax->skonto_sales_chart->id : $tax->skonto_purchase_chart->id,
 576           'skonto_amount'          => $skonto_amount_rounded,
 577           # 'rounding_error'         => $rounding_error,
 578           # 'rounded_rounding_error' => $rounded_rounding_error,
 579         };
 580
 581         push @skonto_charts, $rec;
 582       };
 583   };
 584
 585   # if the rounded sum of all rounding_errors reaches 0.01 this sum is
 586   # subtracted from the largest skonto_amount
 587   my $rounded_total_rounding_error = abs(_round($total_rounding_error));
 588
 589   if ( $rounded_total_rounding_error > 0 ) {
 590     my $highest_amount_pos = 0;
 591     my $highest_amount = 0;
 592     my $i = -1;
 593     foreach my $ref ( @skonto_charts ) {
 594       $i++;
 595       if ( $ref->{skonto_amount} > $highest_amount ) {
 596         $highest_amount     = $ref->{skonto_amount};
 597         $highest_amount_pos = $i;
 598       };
 599     };
 600     $skonto_charts[$i]->{skonto_amount} -= $rounded_total_rounding_error;
 601   };
 602
 603   return @skonto_charts;
 604 };
 605
 606
 607 sub within_skonto_period {
 608   my $self = shift;
 609   my $dateref = shift || DateTime->now->truncate( to => 'day' );
 610
 611   return undef unless ref $dateref eq 'DateTime';
 612   return 0 unless $self->skonto_date;
 613
 614   # return 1 if requested date (or today) is inside skonto period
 615   # this will also return 1 if date is before the invoice date
 616   return $dateref <= $self->skonto_date;
 617 };
 618
 619 sub valid_skonto_amount {
 620   my $self = shift;
 621   my $amount = shift || 0;
 622   my $max_skonto_percent = 0.10;
 623
 624   return 0 unless $amount > 0;
 625
 626   # does this work for other currencies?
 627   return ($self->amount*$max_skonto_percent) > $amount;
 628 };
 629
 630 sub get_payment_select_options_for_bank_transaction {
 631   my ($self, $bt_id, %params) = @_;
 632
 633   # no skonto date  -> no select option
 634   return { payment_type => 'without_skonto', display => t8('without skonto') , selected => 1 } unless $self->skonto_date;
 635
 636   my $bt = SL::DB::BankTransaction->new(id => $bt_id)->load;
 637
 638   my @options;
 639
 640   if ($self->skonto_date && $self->within_skonto_period($bt->transdate)) {
 641     push(@options, { payment_type => 'without_skonto', display => t8('without skonto') });
 642     push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt'), selected => 1 });
 643   } else {
 644     push(@options, { payment_type => 'without_skonto', display => t8('without skonto') , selected => 1 });
 645     push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt')});
 646   }
 647   return @options;
 648 }
 649
 650 sub exchangerate {
 651   my ($self) = @_;
 652
 653   return 1 if $self->currency_id == $::instance_conf->get_currency_id;
 654
 655   die "transdate isn't a DateTime object:" . ref($self->transdate) unless ref($self->transdate) eq 'DateTime';
 656   my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $self->currency_id,
 657                                                     transdate   => $self->transdate,
 658                                                    );
 659   return undef unless $rate;
 660
 661   return $self->is_sales ? $rate->buy : $rate->sell; # also undef if not defined
 662 };
 663
 664 sub get_payment_suggestions {
 665
 666   my ($self, %params) = @_;
 667
 668   my $open_amount = $self->open_amount;
 669   $open_amount   -= $self->open_sepa_transfer_amount if $params{sepa};
 670
 671   $self->{invoice_amount_suggestion} = $open_amount;
 672   undef $self->{payment_select_options};
 673   push(@{$self->{payment_select_options}} , { payment_type => 'without_skonto',  display => t8('without skonto') });
 674   if ( $self->within_skonto_period ) {
 675     # If there have been no payments yet suggest amount_less_skonto, otherwise the open amount
 676     if ( $open_amount &&                   # invoice amount not 0
 677          $open_amount == $self->amount &&  # no payments yet, or sum of payments and sepa export amounts is zero
 678          $self->check_skonto_configuration) {
 679       $self->{invoice_amount_suggestion} = $self->amount_less_skonto;
 680       push(@{$self->{payment_select_options}} , { payment_type => 'with_skonto_pt',  display => t8('with skonto acc. to pt') , selected => 1 });
 681     } else {
 682       if ( ( $self->valid_skonto_amount($self->open_amount) || $self->valid_skonto_amount($open_amount) ) and not $params{sepa} ) {
 683         $self->{invoice_amount_suggestion} = $open_amount;
 684         # only suggest difference_as_skonto if open_amount exactly matches skonto_amount
 685         # AND we aren't in SEPA mode
 686         my $selected = 0;
 687         $selected = 1 if _round($open_amount) == _round($self->skonto_amount);
 688         push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => $selected });
 689       };
 690     };
 691   } else {
 692     # invoice was configured with skonto, but skonto date has passed, or no skonto available
 693     $self->{invoice_amount_suggestion} = $open_amount;
 694     # difference_as_skonto doesn't make any sense for SEPA transfer, as this doesn't cause any actual payment
 695     if ( $self->valid_skonto_amount($self->open_amount) && not $params{sepa} ) {
 696       push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => 0 });
 697     };
 698   };
 699   return 1;
 700 };
 701
 702 # locales for payment type
 703 #
 704 # $main::locale->text('without_skonto')
 705 # $main::locale->text('with_skonto_pt')
 706 # $main::locale->text('difference_as_skonto')
 707 #
 708
 709 sub validate_payment_type {
 710   my $payment_type = shift;
 711
 712   my %allowed_payment_types = map { $_ => 1 } qw(without_skonto with_skonto_pt difference_as_skonto);
 713   croak "illegal payment type: $payment_type, must be one of: " . join(' ', keys %allowed_payment_types) unless $allowed_payment_types{ $payment_type };
 714
 715   return 1;
 716 }
 717
 718 sub forex {
 719   my ($self) = @_;
 720   $self->currency_id == $::instance_conf->get_currency_id ? return 0 : return 1;
 721 };
 722
 723 sub _round {
 724   my $value = shift;
 725   my $num_dec = 2;
 726   return $::form->round_amount($value, 2);
 727 }
 728
 729 1;
 730
 731 __END__
 732
 733 =pod
 734
 735 =head1 NAME
 736
 737 SL::DB::Helper::Payment  Mixin providing helper methods for paying C<Invoice>
 738                          and C<PurchaseInvoice> objects and using skonto
 739
 740 =head1 SYNOPSIS
 741
 742 In addition to actually causing a payment via pay_invoice this helper contains
 743 many methods that help in determining information about the status of the
 744 invoice, such as the remaining open amount, whether skonto applies, until which
 745 date skonto applies, the skonto amount and relative percentages, what to do
 746 with skonto, ...
 747
 748 To prevent duplicate code this was all added in this mixin rather than directly
 749 in SL::DB::Invoice and SL::DB::PurchaseInvoice.
 750
 751 =over 4
 752
 753 =item C<pay_invoice %params>
 754
 755 Create a payment booking for an existing invoice object (type ar/ap/is/ir) via
 756 a configured bank account.
 757
 758 This function deals with all the acc_trans entries and also updates paid and datepaid.
 759
 760 Example:
 761
 762   my $ap   = SL::DB::Manager::PurchaseInvoice->find_by( invnumber => '1');
 763   my $bank = SL::DB::Manager::BankAccount->find_by( name => 'Bank');
 764   $ap->pay_invoice(chart_id      => $bank->chart_id,
 765                    amount        => $ap->open_amount,
 766                    transdate     => DateTime->now->to_kivitendo,
 767                    memo          => 'foobar',
 768                    source        => 'barfoo',
 769                    payment_type  => 'without_skonto',  # default if not specified
 770                    project_id    => 25,
 771                   );
 772
 773 or with skonto:
 774   $ap->pay_invoice(chart_id      => $bank->chart_id,
 775                    amount        => $ap->amount,       # doesn't need to be specified
 776                    transdate     => DateTime->now->to_kivitendo,
 777                    memo          => 'foobar',
 778                    source        => 'barfoo',
 779                    payment_type  => 'with_skonto',
 780                   );
 781
 782 or in a certain currency:
 783   $ap->pay_invoice(chart_id      => $bank->chart_id,
 784                    amount        => 500,
 785                    currency      => 'USD',
 786                    transdate     => DateTime->now->to_kivitendo,
 787                    memo          => 'foobar',
 788                    source        => 'barfoo',
 789                    payment_type  => 'with_skonto_pt',
 790                   );
 791
 792 Allowed payment types are:
 793   without_skonto with_skonto_pt difference_as_skonto
 794
 795 The option C<payment_type> allows for a basic skonto mechanism.
 796
 797 C<without_skonto> is the default mode, "amount" is paid to the account in
 798 chart_id. This can also be used for partial payments and corrections via
 799 negative amounts.
 800
 801 C<with_skonto_pt> can't be used for partial payments. When used on unpaid
 802 invoices the whole amount is paid, with the skonto part automatically being
 803 booked according to the skonto chart configured in the tax settings for each
 804 tax key. If an amount is passed it is ignored and the actual configured skonto
 805 amount is used.
 806
 807 C<difference_as_skonto> can only be used after partial payments have been made,
 808 the whole specified amount is booked according to the skonto charts configured
 809 in the tax settings for each tax key.
 810
 811 So passing amount doesn't have any effect for the cases C<with_skonto_pt> and
 812 C<difference_as_skonto>, as all necessary values are taken from the stored
 813 invoice.
 814
 815 The skonto modes automatically calculate the relative amounts for a mix of
 816 taxes, e.g. items with 7% and 19% in one invoice. There is a helper method
 817 skonto_charts, which calculates the relative percentages according to the
 818 amounts in acc_trans (which are grouped by tax).
 819
 820 There is currently no way of excluding certain items in an invoice from having
 821 skonto applied to them.  If this feature was added to parts the calculation
 822 method of relative skonto would have to be completely rewritten using the
 823 invoice items rather than acc_trans.
 824
 825 The skonto modes also still don't automatically correct the tax, this still has
 826 to be done manually. Therefore all payments generated by pay_invoice have
 827 taxkey 0.
 828
 829 There is currently no way to directly pay an invoice via this method if the
 830 effective skonto differs from the skonto according to the payment terms
 831 configured for the invoice/vendor.
 832
 833 In this case one has to pay in two steps: first the actual paid amount via
 834 "without skonto", and then the remainder via "difference_as_skonto". The user
 835 has to there actively decide whether to accept the differing skonto.
 836
 837 Because of the way skonto_charts works the calculation doesn't work if there
 838 are negative values in acc_trans. E.g. one invoice with a positive value for
 839 19% tax and a negative value for the acc_trans line with 7%
 840
 841 Skonto doesn't/shouldn't apply if the invoice contains credited items.
 842
 843 If no amount is given the whole open amout is paid.
 844
 845 If neither currency or currency_id are given as params, the currency of the
 846 invoice is assumed to be the payment currency.
 847
 848 If successful the return value will be 1 in scalar context or in list context
 849 the two ids (acc_trans_id) of the newly created bookings.
 850 =item C<reference_account>
 851
 852 Returns a chart object which is the chart of the invoice with link AR or AP.
 853
 854 Example (1200 is the AR account for SKR04):
 855   my $invoice = invoice(invnumber => '144');
 856   $invoice->reference_account->accno
 857   # 1200
 858
 859 =item C<percent_skonto>
 860
 861 Returns the configured skonto percentage of the payment terms of an invoice,
 862 e.g. 0.02 for 2%. Payment terms come from invoice settings for ar, from vendor
 863 settings for ap.
 864
 865 =item C<amount_less_skonto>
 866
 867 If the invoice has a payment term (via ar for sales, via vendor for purchase),
 868 calculate the amount to be paid in the case of skonto.  This doesn't check,
 869 whether skonto applies (i.e. skonto doesn't wasn't exceeded), it just subtracts
 870 the configured percentage (e.g. 2%) from the total amount.
 871
 872 The returned value is rounded to two decimals.
 873
 874 =item C<skonto_date>
 875
 876 The date up to which skonto may be taken. This is calculated from the invoice
 877 date + the number of days configured in the payment terms.
 878
 879 This method can also be used to determine whether skonto applies for the
 880 invoice, as it returns undef if there is no payment term or skonto days is set
 881 to 0.
 882
 883 =item C<within_skonto_period [DATE]>
 884
 885 Returns 0 or 1.
 886
 887 Checks whether the invoice has payment terms configured, and whether the date
 888 is within the skonto max date. If no date is passed the current date is used.
 889
 890 You can also pass a dateref object as a parameter to check whether skonto
 891 applies for that date rather than the current date.
 892
 893 =item C<valid_skonto_amount>
 894
 895 Takes an amount as an argument and checks whether the amount is less than 10%
 896 of the total amount of the invoice. The value of 10% is currently hardcoded in
 897 the method. This method is currently used to check whether to offer the payment
 898 option "difference as skonto".
 899
 900 Example:
 901  if ( $invoice->valid_skonto_amount($invoice->open_amount) ) {
 902    # ... do something
 903  }
 904
 905 =item C<skonto_charts [$amount]>
 906
 907 Returns a list of chart_ids and some calculated numbers that can be used for
 908 paying the invoice with skonto. This function will automatically calculate the
 909 relative skonto amounts even if the invoice contains several types of taxes
 910 (e.g. 7% and 19%).
 911
 912 Example usage:
 913   my $invoice = SL::DB::Manager::Invoice->find_by(invnumber => '211');
 914   my @skonto_charts = $invoice->skonto_charts;
 915
 916 or with the total skonto amount as an argument:
 917   my @skonto_charts = $invoice->skonto_charts($invoice->open_amount);
 918
 919 The following values are generated for each chart:
 920
 921 =over 2
 922
 923 =item C<chart_id>
 924
 925 The chart id of the skonto amount to be booked.
 926
 927 =item C<skonto_amount>
 928
 929 The total amount to be paid to the account
 930
 931 =item C<skonto_percent>
 932
 933 The relative percentage of that skonto chart. This can be useful if the actual
 934 ekonto that is paid deviates from the granted skonto, e.g. customer effectively
 935 pays 2.6% skonto instead of 2%, and we accept this. Then we can still calculate
 936 the relative skonto amounts for different taxes based on the absolute
 937 percentages. Used for case C<difference_as_skonto>.
 938
 939 =item C<skonto_percent_abs>
 940
 941 The absolute percentage of that skonto chart in relation to the total amount.
 942 Used to calculate skonto_amount for case C<with_skonto_pt>.
 943
 944 =back
 945
 946 If the invoice contains several types of taxes then skonto_charts can be used
 947 to calculate the relative amounts.
 948
 949 Example in console of an invoice with 100 Euro at 7% and 100 Euro at 19% with
 950 tax not included:
 951
 952   my $invoice = invoice(invnumber => '144');
 953   $invoice->amount
 954   226.00000
 955   $invoice->payment_terms->percent_skonto
 956   0.02
 957   $invoice->skonto_charts
 958   pp $invoice->skonto_charts
 959   #             $VAR1 = {
 960   #               'chart_id'       => 128,
 961   #               'skonto_amount'  => '2.14',
 962   #               'skonto_percent' => '47.3451327433627'
 963   #             };
 964   #             $VAR2 = {
 965   #               'chart_id'       => 130,
 966   #               'skonto_amount'  => '2.38',
 967   #               'skonto_percent' => '52.654867256637'
 968   #             };
 969
 970 C<skonto_charts> always returns positive values (abs) for C<skonto_amount> and
 971 C<skonto_percent>.
 972
 973 C<skonto_charts> generates one entry for each acc_trans entry. ar and ap
 974 bookings only have one acc_trans entry for each taxkey (e.g. 7% and 19%).  This
 975 is because all the items are grouped according to the Buchungsgruppen mechanism
 976 and the totals are written to acc_trans.  For is and ir it is possible to have
 977 several acc_trans entries with the same tax. In this case skonto_charts
 978 generates a skonto booking for each acc_trans income/expense entry.
 979
 980 In the future this function may also be used to calculate the corrections for
 981 the income tax.
 982
 983 =item C<open_amount>
 984
 985 Unrounded total open amount of invoice (amount - paid).
 986 Doesn't take into account pending SEPA transfers.
 987
 988 =item C<open_percent>
 989
 990 Percentage of the invoice that is still unpaid, e.g. 100,00 if no payments have
 991 been made yet, 0,00 if fully paid.
 992
 993 =item C<remaining_skonto_days>
 994
 995 How many days skonto can still be taken, calculated from current day. Returns 0
 996 if current day is the max skonto date, and negative number if skonto date has
 997 already passed.
 998
 999 Returns undef if skonto is not configured for that invoice.
1000
1001 =item C<get_payment_suggestions %params>
1002
1003 Creates data intended for an L.select_tag dropdown that can be used in a
1004 template. Depending on the rules it will choose from the options
1005 without_skonto, with_skonto_pt and difference_as_skonto, and select the most
1006 likely one.
1007
1008 If the parameter "sepa" is passed, the SEPA export payments that haven't been
1009 executed yet are considered when determining the open amount of the invoice.
1010
1011 The current rules are:
1012
1013 =over 2
1014
1015 =item * without_skonto is always an option
1016
1017 =item * with_skonto_pt is only offered if there haven't been any payments yet and the current date is within the skonto period.
1018
1019 =item * difference_as_skonto is only offered if there have already been payments made and the open amount is smaller than 10% of the total amount.
1020
1021 with_skonto_pt will only be offered, if all the AR_amount/AP_amount have a
1022 taxkey with a configured skonto chart
1023
1024 =back
1025
1026 It will also fill $self->{invoice_amount_suggestion} with either the open
1027 amount, or if with_skonto_pt is selected, with amount_less_skonto, so the
1028 template can fill the input with the likely amount.
1029
1030 Example in console:
1031   my $ar = invoice( invnumber => '257');
1032   $ar->get_payment_suggestions;
1033   print $ar->{invoice_amount_suggestion} . "\n";
1034   # 97.23
1035   pp $ar->{payment_select_options}
1036   # $VAR1 = [
1037   #         {
1038   #           'display' => 'ohne Skonto',
1039   #           'payment_type' => 'without_skonto'
1040   #         },
1041   #         {
1042   #           'display' => 'mit Skonto nach ZB',
1043   #           'payment_type' => 'with_skonto_pt',
1044   #           'selected' => 1
1045   #         }
1046   #       ];
1047
1048 The resulting array $ar->{payment_select_options} can be used in a template
1049 select_tag using value_key and title_key:
1050
1051 [% L.select_tag('payment_type_' _ loop.count, invoice.payment_select_options, value_key => 'payment_type', title_key => 'display', id => 'payment_type_' _ loop.count) %]
1052
1053 It would probably make sense to have different rules for the pre-selected items
1054 for sales and purchase, and to also make these rules configurable in the
1055 defaults. E.g. when creating a SEPA bank transfer for vendor invoices a company
1056 might always want to pay quickly making use of skonto, while another company
1057 might always want to pay as late as possible.
1058
1059 =item C<get_payment_select_options_for_bank_transaction $banktransaction_id %params>
1060
1061 Make suggestion for a skonto payment type by returning an HTML blob of the options
1062 of a HTML drop-down select with the most likely option preselected.
1063
1064 This is a helper function for BankTransaction/ajax_payment_suggestion and
1065 template/webpages/bank_transactions/invoices.html
1066
1067 We are working with an existing payment, so difference_as_skonto never makes sense.
1068
1069 If skonto is not possible (skonto_date does not exists) simply return
1070 the single 'no skonto' option as a visual hint.
1071
1072 If skonto is possible (skonto_date exists), add two possibilities:
1073 without_skonto and with_skonto_pt if payment date is within skonto_date,
1074 preselect with_skonto_pt, otherwise preselect without skonto.
1075
1076 =item C<exchangerate>
1077
1078 Returns 1 immediately if the record uses the default currency.
1079
1080 Returns the exchangerate in database format for the invoice according to that
1081 invoice's transdate, returning 'buy' for sales, 'sell' for purchases.
1082
1083 If no exchangerate can be found for that day undef is returned.
1084
1085 =item C<forex>
1086
1087 Returns 1 if record uses a different currency, 0 if the default currency is used.
1088
1089 =back
1090
1091 =head1 TODO AND CAVEATS
1092
1093 =over 4
1094
1095 =item *
1096
1097 when looking at open amount, maybe consider that there may already be queued
1098 amounts in SEPA Export
1099
1100 =back
1101
1102 =head1 AUTHOR
1103
1104 G. Richardson E<lt>grichardson@kivitendo-premium.de<gt>
1105
1106 =cut