SL/DB/Helper/ZUGFeRD.pm

   1 package SL::DB::Helper::ZUGFeRD;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(Exporter);
   7 our @EXPORT = qw(create_zugferd_data create_zugferd_xmp_data);
   8
   9 use SL::DB::GenericTranslation;
  10 use SL::DB::Tax;
  11 use SL::DB::TaxKey;
  12 use SL::Helper::ISO3166;
  13 use SL::Helper::ISO4217;
  14 use SL::Helper::UNECERecommendation20;
  15
  16 use Carp;
  17 use Encode qw(encode);
  18 use List::MoreUtils qw(pairwise);
  19 use List::Util qw(first sum);
  20 use Template;
  21 use XML::Writer;
  22
  23 my @line_names = qw(LineOne LineTwo LineThree);
  24
  25 sub _u8 {
  26   my ($value) = @_;
  27   return encode('UTF-8', $value // '');
  28 }
  29
  30 sub _r2 {
  31   my ($value) = @_;
  32   return $::form->round_amount($value, 2);
  33 }
  34
  35 sub _type_name {
  36   my ($self) = @_;
  37   my $type   = $self->invoice_type;
  38
  39   no warnings 'once';
  40   return $type eq 'ar_transaction' ? $::locale->text('Invoice') : $self->displayable_type;
  41 }
  42
  43 sub _type_code {
  44   my ($self) = @_;
  45   my $type   = $self->invoice_type;
  46
  47   # 326 (Partial invoice)
  48   # 380 (Commercial invoice)
  49   # 384 (Corrected Invoice)
  50   # 381 (Credit note)
  51   # 389 (Credit note, self billed invoice)
  52
  53   return $type eq 'credit_note' ? 381 : 380;
  54 }
  55
  56 sub _unit_code {
  57   my ($unit) = @_;
  58
  59   # Mapping from kivitendo's units to UN/ECE Recommendation 20 & 21.
  60   my $code = SL::Helper::UNECERecommendation20::map_name_to_code($unit);
  61   return $code if $code;
  62
  63   $::lxdebug->message(LXDebug::WARN(), "ZUGFeRD unit name mapping: no UN/ECE Recommendation 20/21 unit known for kivitendo unit '$unit'; using 'C62'");
  64
  65   return 'C62';
  66 }
  67
  68 sub _parse_our_address {
  69   my @result;
  70   my @street = grep { $_ } ($::instance_conf->get_address_street1, $::instance_conf->get_address_street2);
  71
  72   push @result, [ 'PostcodeCode', $::instance_conf->get_address_zipcode ] if $::instance_conf->get_address_zipcode;
  73   push @result, grep { $_->[1] } pairwise { [ $a, $b] } @line_names, @street;
  74   push @result, [ 'CityName', $::instance_conf->get_address_city ] if $::instance_conf->get_address_city;
  75   push @result, [ 'CountryID', SL::Helper::ISO3166::map_name_to_alpha_2_code($::instance_conf->get_address_country) // 'DE' ];
  76
  77   return @result;
  78 }
  79
  80 sub _customer_postal_trade_address {
  81   my (%params) = @_;
  82
  83   #       <ram:PostalTradeAddress>
  84   $params{xml}->startTag("ram:PostalTradeAddress");
  85
  86   my @parts = grep { $_ } map { $params{customer}->$_ } qw(department_1 department_2 street);
  87
  88   $params{xml}->dataElement("ram:PostcodeCode", _u8($params{customer}->zipcode));
  89   $params{xml}->dataElement("ram:" . $_->[0],   _u8($_->[1])) for grep { $_->[1] } pairwise { [ $a, $b] } @line_names, @parts;
  90   $params{xml}->dataElement("ram:CityName",     _u8($params{customer}->city));
  91   $params{xml}->dataElement("ram:CountryID",    _u8(SL::Helper::ISO3166::map_name_to_alpha_2_code($params{customer}->country) // 'DE'));
  92   $params{xml}->endTag;
  93   #       </ram:PostalTradeAddress>
  94 }
  95
  96 sub _tax_rate_and_code {
  97   my ($taxzone, $tax) = @_;
  98
  99   my ($tax_rate, $tax_code) = @_;
 100
 101   if ($taxzone->description =~ m{Au.*erhalb}) {
 102     $tax_rate = 0;
 103     $tax_code = 'G';
 104
 105   } elsif ($taxzone->description =~ m{EU mit}) {
 106     $tax_rate = 0;
 107     $tax_code = 'K';
 108
 109   } else {
 110     $tax_rate = $tax->rate * 100;
 111     $tax_code = !$tax_rate ? 'Z' : 'S';
 112   }
 113
 114   return (rate => $tax_rate, code => $tax_code);
 115 }
 116
 117 sub _line_item {
 118   my ($self, %params) = @_;
 119
 120   my $item_ptc = $params{ptc_data}->{items}->[$params{line_number}];
 121
 122   my $taxkey   = $item_ptc->{taxkey_id} ? SL::DB::TaxKey->load_cached($item_ptc->{taxkey_id}) : undef;
 123   my $tax      = $item_ptc->{taxkey_id} ? SL::DB::Tax->load_cached($taxkey->tax_id)           : undef;
 124   my %tax_info = _tax_rate_and_code($self->taxzone, $tax);
 125
 126   # <ram:IncludedSupplyChainTradeLineItem>
 127   $params{xml}->startTag("ram:IncludedSupplyChainTradeLineItem");
 128
 129   #   <ram:AssociatedDocumentLineDocument>
 130   $params{xml}->startTag("ram:AssociatedDocumentLineDocument");
 131   $params{xml}->dataElement("ram:LineID", $params{line_number} + 1);
 132   $params{xml}->endTag;
 133
 134   $params{xml}->startTag("ram:SpecifiedTradeProduct");
 135   $params{xml}->dataElement("ram:SellerAssignedID", _u8($params{item}->part->partnumber));
 136   $params{xml}->dataElement("ram:Name",             _u8($params{item}->description));
 137   $params{xml}->endTag;
 138
 139   $params{xml}->startTag("ram:SpecifiedLineTradeAgreement");
 140   $params{xml}->startTag("ram:NetPriceProductTradePrice");
 141   $params{xml}->dataElement("ram:ChargeAmount", _r2($item_ptc->{sellprice}));
 142   $params{xml}->endTag;
 143   $params{xml}->endTag;
 144   #   </ram:SpecifiedLineTradeAgreement>
 145
 146   #   <ram:SpecifiedLineTradeDelivery>
 147   $params{xml}->startTag("ram:SpecifiedLineTradeDelivery");
 148   $params{xml}->dataElement("ram:BilledQuantity", $params{item}->qty, "unitCode" => _unit_code($params{item}->unit));
 149   $params{xml}->endTag;
 150   #   </ram:SpecifiedLineTradeDelivery>
 151
 152   #   <ram:SpecifiedLineTradeSettlement>
 153   $params{xml}->startTag("ram:SpecifiedLineTradeSettlement");
 154
 155   #     <ram:ApplicableTradeTax>
 156   $params{xml}->startTag("ram:ApplicableTradeTax");
 157   $params{xml}->dataElement("ram:TypeCode",              "VAT");
 158   $params{xml}->dataElement("ram:CategoryCode",          $tax_info{code});
 159   $params{xml}->dataElement("ram:RateApplicablePercent", _r2($tax_info{rate}));
 160   $params{xml}->endTag;
 161   #     </ram:ApplicableTradeTax>
 162
 163   #     <ram:SpecifiedTradeSettlementLineMonetarySummation>
 164   $params{xml}->startTag("ram:SpecifiedTradeSettlementLineMonetarySummation");
 165   $params{xml}->dataElement("ram:LineTotalAmount", _r2($item_ptc->{linetotal}));
 166   $params{xml}->endTag;
 167   #     </ram:SpecifiedTradeSettlementLineMonetarySummation>
 168
 169   $params{xml}->endTag;
 170   #   </ram:SpecifiedLineTradeSettlement>
 171
 172   $params{xml}->endTag;
 173   # <ram:IncludedSupplyChainTradeLineItem>
 174 }
 175
 176 sub _taxes {
 177   my ($self, %params) = @_;
 178
 179   my %taxkey_info;
 180
 181   foreach my $item (@{ $params{ptc_data}->{items} }) {
 182     $taxkey_info{$item->{taxkey_id}} //= {
 183       linetotal  => 0,
 184       tax_amount => 0,
 185     };
 186     my $info             = $taxkey_info{$item->{taxkey_id}};
 187     $info->{taxkey}    //= SL::DB::TaxKey->load_cached($item->{taxkey_id});
 188     $info->{tax}       //= SL::DB::Tax->load_cached($info->{taxkey}->tax_id);
 189     $info->{linetotal}  += $item->{linetotal};
 190     $info->{tax_amount} += $item->{tax_amount};
 191   }
 192
 193   foreach my $taxkey_id (sort keys %taxkey_info) {
 194     my $info     = $taxkey_info{$taxkey_id};
 195     my %tax_info = _tax_rate_and_code($self->taxzone, $info->{tax});
 196
 197     #     <ram:ApplicableTradeTax>
 198     $params{xml}->startTag("ram:ApplicableTradeTax");
 199     $params{xml}->dataElement("ram:CalculatedAmount",      _r2($params{ptc_data}->{taxes}->{$info->{tax}->{chart_id}}));
 200     $params{xml}->dataElement("ram:TypeCode",              "VAT");
 201     $params{xml}->dataElement("ram:BasisAmount",           _r2($info->{linetotal}));
 202     $params{xml}->dataElement("ram:CategoryCode",          $tax_info{code});
 203     $params{xml}->dataElement("ram:RateApplicablePercent", _r2($tax_info{rate}));
 204     $params{xml}->endTag;
 205     #     </ram:ApplicableTradeTax>
 206   }
 207 }
 208
 209 sub _format_payment_terms_description {
 210   my ($self) = @_;
 211
 212   my (%vars, %amounts, %formatted_amounts);
 213
 214   local $::myconfig{numberformat} = $::myconfig{numberformat};
 215   local $::myconfig{dateformat}   = $::myconfig{dateformat};
 216
 217   if ($self->language_id) {
 218     my $language = SL::DB::Language->load_cached($self->language_id);
 219     $::myconfig{dateformat}   = $language->output_dateformat   if $language->output_dateformat;
 220     $::myconfig{numberformat} = $language->output_numberformat if $language->output_numberformat;
 221   }
 222
 223   $vars{currency}              = $self->currency->name if $self->currency;
 224   $vars{$_}                    = $self->customer->$_      for qw(account_number bank bank_code bic iban mandate_date_of_signature mandator_id);
 225   $vars{$_}                    = $self->payment_terms->$_ for qw(terms_netto terms_skonto percent_skonto);
 226   $vars{payment_description}   = $self->payment_terms->description;
 227   $vars{netto_date}            = $self->payment_terms->calc_date(reference_date => $self->transdate, due_date => $self->duedate, terms => 'net')->to_kivitendo;
 228   $vars{skonto_date}           = $self->payment_terms->calc_date(reference_date => $self->transdate, due_date => $self->duedate, terms => 'discount')->to_kivitendo;
 229
 230   $amounts{invtotal}           = $self->amount;
 231   $amounts{total}              = $self->amount - $self->paid;
 232
 233   $amounts{skonto_in_percent}  = 100.0 * $vars{percent_skonto};
 234   $amounts{skonto_amount}      = $amounts{invtotal} * $vars{percent_skonto};
 235   $amounts{invtotal_wo_skonto} = $amounts{invtotal} * (1 - $vars{percent_skonto});
 236   $amounts{total_wo_skonto}    = $amounts{total}    * (1 - $vars{percent_skonto});
 237
 238   foreach (keys %amounts) {
 239     $amounts{$_}           = $::form->round_amount($amounts{$_}, 2);
 240     $formatted_amounts{$_} = $::form->format_amount(\%::myconfig, $amounts{$_}, 2);
 241   }
 242
 243   my $description = ($self->payment_terms->translated_attribute('description_long_invoice', $self->language_id) // '') || $self->payment_terms->description_long_invoice;
 244   $description    =~ s{<\%$_\%>}{ $vars{$_} }ge              for keys %vars;
 245   $description    =~ s{<\%$_\%>}{ $formatted_amounts{$_} }ge for keys %formatted_amounts;
 246
 247   return $description;
 248 }
 249
 250 sub _payment_terms {
 251   my ($self, %params) = @_;
 252
 253   return unless $self->payment_terms;
 254
 255   #     <ram:SpecifiedTradePaymentTerms>
 256   $params{xml}->startTag("ram:SpecifiedTradePaymentTerms");
 257
 258   $params{xml}->dataElement("ram:Description", _u8(_format_payment_terms_description($self)));
 259
 260   #       <ram:DueDateDateTime>
 261   $params{xml}->startTag("ram:DueDateDateTime");
 262   $params{xml}->dataElement("udt:DateTimeString", $self->duedate->strftime('%Y%m%d'), "format" => "102");
 263   $params{xml}->endTag;
 264   #       </ram:DueDateDateTime>
 265
 266   if ($self->payment_terms->percent_skonto && $self->payment_terms->terms_skonto) {
 267     #       <ram:ApplicableTradePaymentDiscountTerms>
 268     $params{xml}->startTag("ram:ApplicableTradePaymentDiscountTerms");
 269     $params{xml}->dataElement("ram:BasisPeriodMeasure", $self->payment_terms->terms_skonto, "unitCode" => "DAY");
 270     $params{xml}->dataElement("ram:CalculationPercent", _r2($self->payment_terms->percent_skonto * 100));
 271     $params{xml}->endTag;
 272     #       </ram:ApplicableTradePaymentDiscountTerms>
 273   }
 274
 275   $params{xml}->endTag;
 276   #     </ram:SpecifiedTradePaymentTerms>
 277 }
 278
 279 sub _totals {
 280   my ($self, %params) = @_;
 281
 282   #     <ram:SpecifiedTradeSettlementHeaderMonetarySummation>
 283   $params{xml}->startTag("ram:SpecifiedTradeSettlementHeaderMonetarySummation");
 284
 285   $params{xml}->dataElement("ram:LineTotalAmount",     _r2($self->netamount));
 286   $params{xml}->dataElement("ram:TaxBasisTotalAmount", _r2($self->netamount));
 287   $params{xml}->dataElement("ram:TaxTotalAmount",      _r2(sum(values %{ $params{ptc_data}->{taxes} })), "currencyID" => "EUR");
 288   $params{xml}->dataElement("ram:GrandTotalAmount",    _r2($self->amount));
 289   $params{xml}->dataElement("ram:TotalPrepaidAmount",  _r2($self->paid));
 290   $params{xml}->dataElement("ram:DuePayableAmount",    _r2($self->amount - $self->paid));
 291
 292   $params{xml}->endTag;
 293   #     </ram:SpecifiedTradeSettlementHeaderMonetarySummation>
 294 }
 295
 296 sub _exchanged_document_context {
 297   my ($self, %params) = @_;
 298
 299   #   <rsm:ExchangedDocumentContext>
 300   $params{xml}->startTag("rsm:ExchangedDocumentContext");
 301   $params{xml}->startTag("ram:TestIndicator");
 302   $params{xml}->dataElement("udt:Indicator", "true"); # TODO: change to 'false'
 303   $params{xml}->endTag;
 304
 305   $params{xml}->startTag("ram:GuidelineSpecifiedDocumentContextParameter");
 306   $params{xml}->dataElement("ram:ID", "urn:cen.eu:en16931:2017#conformant#urn:zugferd.de:2p0:extended");
 307   $params{xml}->endTag;
 308   $params{xml}->endTag;
 309   #   </rsm:ExchangedDocumentContext>
 310 }
 311
 312 sub _included_note {
 313   my ($self, %params) = @_;
 314
 315   $params{xml}->startTag("ram:IncludedNote");
 316   $params{xml}->dataElement("ram:Content", _u8($params{note}));
 317   $params{xml}->endTag;
 318 }
 319
 320 sub _exchanged_document {
 321   my ($self, %params) = @_;
 322
 323   #   <rsm:ExchangedDocument>
 324   $params{xml}->startTag("rsm:ExchangedDocument");
 325
 326   $params{xml}->dataElement("ram:ID",       _u8($self->invnumber));
 327   $params{xml}->dataElement("ram:Name",     _u8(_type_name($self)));
 328   $params{xml}->dataElement("ram:TypeCode", _u8(_type_code($self)));
 329
 330   #     <ram:IssueDateTime>
 331   $params{xml}->startTag("ram:IssueDateTime");
 332   $params{xml}->dataElement("udt:DateTimeString", $self->transdate->strftime('%Y%m%d'), "format" => "102");
 333   $params{xml}->endTag;
 334   #     </ram:IssueDateTime>
 335
 336   if ($self->language && (($self->language->template_code // '') =~ m{^(de|en)}i)) {
 337     $params{xml}->dataElement("ram:LanguageID", uc($1));
 338   }
 339
 340   my $std_notes = SL::DB::Manager::GenericTranslation->get_all(
 341     where => [
 342       translation_type => 'ZUGFeRD/notes',
 343       or               => [
 344         language_id    => undef,
 345         language_id    => $self->language_id,
 346       ],
 347       '!translation'   => undef,
 348       '!translation'   => '',
 349     ],
 350   );
 351
 352   my $std_note = first { $_->language_id == $self->language_id } @{ $std_notes };
 353   $std_note  //= first { !defined $_->language_id }              @{ $std_notes };
 354
 355   my $notes = $self->notes_as_stripped_html;
 356
 357   _included_note($self, %params, note => $self->transaction_description) if $self->transaction_description;
 358   _included_note($self, %params, note => $notes)                         if $notes;
 359   _included_note($self, %params, note => $std_note->translation)         if $std_note;
 360
 361   $params{xml}->endTag;
 362   #   </rsm:ExchangedDocument>
 363 }
 364
 365 sub _seller_trade_party {
 366   my ($self, %params) = @_;
 367
 368   my @our_address            = _parse_our_address();
 369
 370   my $sales_person           = $self->salesman;
 371   my $sales_person_auth      = SL::DB::Manager::AuthUser->find_by(login => $sales_person->login);
 372   my %sales_person_cfg       = $sales_person_auth ? %{ $sales_person_auth->config_values } : ();
 373   $sales_person_cfg{email} ||= $sales_person->deleted_email;
 374   $sales_person_cfg{tel}   ||= $sales_person->deleted_tel;
 375
 376   #       <ram:SellerTradeParty>
 377   $params{xml}->startTag("ram:SellerTradeParty");
 378   $params{xml}->dataElement("ram:ID",   _u8($self->customer->c_vendor_id)) if ($self->customer->c_vendor_id // '') ne '';
 379   $params{xml}->dataElement("ram:Name", _u8($::instance_conf->get_company));
 380
 381   #         <ram:DefinedTradeContact>
 382   $params{xml}->startTag("ram:DefinedTradeContact");
 383
 384   $params{xml}->dataElement("ram:PersonName", _u8($sales_person_cfg{name} || $sales_person_cfg{login}));
 385
 386   if ($sales_person_cfg{tel}) {
 387     $params{xml}->startTag("ram:TelephoneUniversalCommunication");
 388     $params{xml}->dataElement("ram:CompleteNumber", _u8($sales_person_cfg{tel}));
 389     $params{xml}->endTag;
 390   }
 391
 392   if ($sales_person_cfg{email}) {
 393     $params{xml}->startTag("ram:EmailURIUniversalCommunication");
 394     $params{xml}->dataElement("ram:URIID", _u8($sales_person_cfg{email}));
 395     $params{xml}->endTag;
 396   }
 397
 398   $params{xml}->endTag;
 399   #         </ram:DefinedTradeContact>
 400
 401   if (@our_address) {
 402     #         <ram:PostalTradeAddress>
 403     $params{xml}->startTag("ram:PostalTradeAddress");
 404     foreach my $element (@our_address) {
 405       $params{xml}->dataElement("ram:" . $element->[0], _u8($element->[1]));
 406     }
 407     $params{xml}->endTag;
 408     #         </ram:PostalTradeAddress>
 409   }
 410
 411   my $ustid_nr = $::instance_conf->get_co_ustid;
 412   if ($ustid_nr) {
 413     $ustid_nr = "DE$ustid_nr" unless $ustid_nr =~ m{^[A-Z]{2}};
 414     #         <ram:SpecifiedTaxRegistration>
 415     $params{xml}->startTag("ram:SpecifiedTaxRegistration");
 416     $params{xml}->dataElement("ram:ID", _u8($ustid_nr), "schemeID" => "VA");
 417     $params{xml}->endTag;
 418     #         </ram:SpecifiedTaxRegistration>
 419   }
 420
 421   $params{xml}->endTag;
 422   #     </ram:SellerTradeParty>
 423 }
 424
 425 sub _buyer_trade_party {
 426   my ($self, %params) = @_;
 427
 428   #       <ram:BuyerTradeParty>
 429   $params{xml}->startTag("ram:BuyerTradeParty");
 430   $params{xml}->dataElement("ram:ID",   _u8($self->customer->customernumber));
 431   $params{xml}->dataElement("ram:Name", _u8($self->customer->name));
 432
 433   _customer_postal_trade_address(%params, customer => $self->customer);
 434
 435   $params{xml}->endTag;
 436   #       </ram:BuyerTradeParty>
 437 }
 438
 439 sub _included_supply_chain_trade_line_item {
 440   my ($self, %params) = @_;
 441
 442   my $line_number = 0;
 443   foreach my $item (@{ $self->items }) {
 444     _line_item($self, %params, item => $item, line_number => $line_number);
 445     $line_number++;
 446   }
 447 }
 448
 449 sub _applicable_header_trade_agreement {
 450   my ($self, %params) = @_;
 451
 452   #     <ram:ApplicableHeaderTradeAgreement>
 453   $params{xml}->startTag("ram:ApplicableHeaderTradeAgreement");
 454
 455   _seller_trade_party($self, %params);
 456   _buyer_trade_party($self, %params);
 457
 458   if ($self->cusordnumber) {
 459     #     <ram:BuyerOrderReferencedDocument>
 460     $params{xml}->startTag("ram:BuyerOrderReferencedDocument");
 461     $params{xml}->dataElement("ram:IssuerAssignedID", _u8($self->cusordnumber));
 462     $params{xml}->endTag;
 463     #     </ram:BuyerOrderReferencedDocument>
 464   }
 465
 466   $params{xml}->endTag;
 467   #     </ram:ApplicableHeaderTradeAgreement>
 468 }
 469
 470 sub _applicable_header_trade_delivery {
 471   my ($self, %params) = @_;
 472
 473   #     <ram:ApplicableHeaderTradeDelivery>
 474   $params{xml}->startTag("ram:ApplicableHeaderTradeDelivery");
 475   #       <ram:ActualDeliverySupplyChainEvent>
 476   $params{xml}->startTag("ram:ActualDeliverySupplyChainEvent");
 477
 478   $params{xml}->startTag("ram:OccurrenceDateTime");
 479   $params{xml}->dataElement("udt:DateTimeString", ($self->deliverydate // $self->transdate)->strftime('%Y%m%d'), "format" => "102");
 480   $params{xml}->endTag;
 481
 482   $params{xml}->endTag;
 483   #       </ram:ActualDeliverySupplyChainEvent>
 484   $params{xml}->endTag;
 485   #     </ram:ApplicableHeaderTradeDelivery>
 486 }
 487
 488 sub _applicable_header_trade_settlement {
 489   my ($self, %params) = @_;
 490
 491   #     <ram:ApplicableHeaderTradeSettlement>
 492   $params{xml}->startTag("ram:ApplicableHeaderTradeSettlement");
 493   $params{xml}->dataElement("ram:InvoiceCurrencyCode", _u8(SL::Helper::ISO4217::map_currency_name_to_code($self->currency->name) // 'EUR'));
 494
 495   _taxes($self, %params);
 496   _payment_terms($self, %params);
 497   _totals($self, %params);
 498
 499   $params{xml}->endTag;
 500   #     </ram:ApplicableHeaderTradeSettlement>
 501 }
 502
 503 sub _supply_chain_trade_transaction {
 504   my ($self, %params) = @_;
 505
 506   #   <rsm:SupplyChainTradeTransaction>
 507   $params{xml}->startTag("rsm:SupplyChainTradeTransaction");
 508
 509   _included_supply_chain_trade_line_item($self, %params);
 510   _applicable_header_trade_agreement($self, %params);
 511   _applicable_header_trade_delivery($self, %params);
 512   _applicable_header_trade_settlement($self, %params);
 513
 514   $params{xml}->endTag;
 515   #   </rsm:SupplyChainTradeTransaction>
 516 }
 517
 518 sub create_zugferd_data {
 519   my ($self) = @_;
 520
 521   my %ptc_data = $self->calculate_prices_and_taxes;
 522   my $output   = '';
 523   my $xml      = XML::Writer->new(
 524     OUTPUT      => \$output,
 525     DATA_MODE   => 1,
 526     DATA_INDENT => 2,
 527     ENCODING    => 'utf-8',
 528   );
 529
 530   my %params = (
 531     ptc_data => \%ptc_data,
 532     xml      => $xml,
 533   );
 534
 535   $xml->xmlDecl();
 536
 537   # <rsm:CrossIndustryInvoice>
 538   $xml->startTag("rsm:CrossIndustryInvoice",
 539                  "xmlns:a"   => "urn:un:unece:uncefact:data:standard:QualifiedDataType:100",
 540                  "xmlns:rsm" => "urn:un:unece:uncefact:data:standard:CrossIndustryInvoice:100",
 541                  "xmlns:qdt" => "urn:un:unece:uncefact:data:standard:QualifiedDataType:10",
 542                  "xmlns:ram" => "urn:un:unece:uncefact:data:standard:ReusableAggregateBusinessInformationEntity:100",
 543                  "xmlns:xs"  => "http://www.w3.org/2001/XMLSchema",
 544                  "xmlns:udt" => "urn:un:unece:uncefact:data:standard:UnqualifiedDataType:100");
 545
 546   _exchanged_document_context($self, %params);
 547   _exchanged_document($self, %params);
 548   _supply_chain_trade_transaction($self, %params);
 549
 550   $xml->endTag;
 551   # </rsm:CrossIndustryInvoice>
 552
 553   return $output;
 554 }
 555
 556 sub create_zugferd_xmp_data {
 557   my ($self) = @_;
 558
 559   return {
 560     conformance_level  => 'EXTENDED',
 561     document_file_name => 'ZUGFeRD-invoice.xml',
 562     document_type      => 'INVOICE',
 563     version            => '1.0',
 564   };
 565 }
 566
 567 1;