SL/DB/Helper/ZUGFeRD.pm

   1 package SL::DB::Helper::ZUGFeRD;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(Exporter);
   7 our @EXPORT = qw(create_zugferd_data create_zugferd_xmp_data);
   8
   9 use SL::DB::GenericTranslation;
  10 use SL::DB::Tax;
  11 use SL::DB::TaxKey;
  12 use SL::Helper::ISO3166;
  13 use SL::Helper::ISO4217;
  14 use SL::Helper::UNECERecommendation20;
  15
  16 use Carp;
  17 use Encode qw(encode);
  18 use List::MoreUtils qw(any pairwise);
  19 use List::Util qw(first sum);
  20 use Template;
  21 use XML::Writer;
  22
  23 my @line_names = qw(LineOne LineTwo LineThree);
  24
  25 sub _u8 {
  26   my ($value) = @_;
  27   return encode('UTF-8', $value // '');
  28 }
  29
  30 sub _r2 {
  31   my ($value) = @_;
  32   return $::form->round_amount($value, 2);
  33 }
  34
  35 sub _type_name {
  36   my ($self) = @_;
  37   my $type   = $self->invoice_type;
  38
  39   no warnings 'once';
  40   return $type eq 'ar_transaction' ? $::locale->text('Invoice') : $self->displayable_type;
  41 }
  42
  43 sub _type_code {
  44   my ($self) = @_;
  45   my $type   = $self->invoice_type;
  46
  47   # 326 (Partial invoice)
  48   # 380 (Commercial invoice)
  49   # 384 (Corrected Invoice)
  50   # 381 (Credit note)
  51   # 389 (Credit note, self billed invoice)
  52
  53   return $type eq 'credit_note'        ? 381
  54        : $type eq 'invoice_storno'     ? 457
  55        : $type eq 'credit_note_storno' ? 458
  56        :                                 380;
  57 }
  58
  59 sub _unit_code {
  60   my ($unit) = @_;
  61
  62   # Mapping from kivitendo's units to UN/ECE Recommendation 20 & 21.
  63   my $code = SL::Helper::UNECERecommendation20::map_name_to_code($unit);
  64   return $code if $code;
  65
  66   $::lxdebug->message(LXDebug::WARN(), "ZUGFeRD unit name mapping: no UN/ECE Recommendation 20/21 unit known for kivitendo unit '$unit'; using 'C62'");
  67
  68   return 'C62';
  69 }
  70
  71 sub _parse_our_address {
  72   my @result;
  73   my @street = grep { $_ } ($::instance_conf->get_address_street1, $::instance_conf->get_address_street2);
  74
  75   push @result, [ 'PostcodeCode', $::instance_conf->get_address_zipcode ] if $::instance_conf->get_address_zipcode;
  76   push @result, grep { $_->[1] } pairwise { [ $a, $b] } @line_names, @street;
  77   push @result, [ 'CityName', $::instance_conf->get_address_city ] if $::instance_conf->get_address_city;
  78   push @result, [ 'CountryID', SL::Helper::ISO3166::map_name_to_alpha_2_code($::instance_conf->get_address_country) // 'DE' ];
  79
  80   return @result;
  81 }
  82
  83 sub _customer_postal_trade_address {
  84   my (%params) = @_;
  85
  86   #       <ram:PostalTradeAddress>
  87   $params{xml}->startTag("ram:PostalTradeAddress");
  88
  89   my @parts = grep { $_ } map { $params{customer}->$_ } qw(department_1 department_2 street);
  90
  91   $params{xml}->dataElement("ram:PostcodeCode", _u8($params{customer}->zipcode));
  92   $params{xml}->dataElement("ram:" . $_->[0],   _u8($_->[1])) for grep { $_->[1] } pairwise { [ $a, $b] } @line_names, @parts;
  93   $params{xml}->dataElement("ram:CityName",     _u8($params{customer}->city));
  94   $params{xml}->dataElement("ram:CountryID",    _u8(SL::Helper::ISO3166::map_name_to_alpha_2_code($params{customer}->country) // 'DE'));
  95   $params{xml}->endTag;
  96   #       </ram:PostalTradeAddress>
  97 }
  98
  99 sub _tax_rate_and_code {
 100   my ($taxzone, $tax) = @_;
 101
 102   my ($tax_rate, $tax_code) = @_;
 103
 104   if ($taxzone->description =~ m{Au.*erhalb}) {
 105     $tax_rate = 0;
 106     $tax_code = 'G';
 107
 108   } elsif ($taxzone->description =~ m{EU mit}) {
 109     $tax_rate = 0;
 110     $tax_code = 'K';
 111
 112   } else {
 113     $tax_rate = $tax->rate * 100;
 114     $tax_code = !$tax_rate ? 'Z' : 'S';
 115   }
 116
 117   return (rate => $tax_rate, code => $tax_code);
 118 }
 119
 120 sub _line_item {
 121   my ($self, %params) = @_;
 122
 123   my $item_ptc = $params{ptc_data}->{items}->[$params{line_number}];
 124
 125   my $taxkey   = $item_ptc->{taxkey_id} ? SL::DB::TaxKey->load_cached($item_ptc->{taxkey_id}) : undef;
 126   my $tax      = $item_ptc->{taxkey_id} ? SL::DB::Tax->load_cached($taxkey->tax_id)           : undef;
 127   my %tax_info = _tax_rate_and_code($self->taxzone, $tax);
 128
 129   # <ram:IncludedSupplyChainTradeLineItem>
 130   $params{xml}->startTag("ram:IncludedSupplyChainTradeLineItem");
 131
 132   #   <ram:AssociatedDocumentLineDocument>
 133   $params{xml}->startTag("ram:AssociatedDocumentLineDocument");
 134   $params{xml}->dataElement("ram:LineID", $params{line_number} + 1);
 135   $params{xml}->endTag;
 136
 137   $params{xml}->startTag("ram:SpecifiedTradeProduct");
 138   $params{xml}->dataElement("ram:SellerAssignedID", _u8($params{item}->part->partnumber));
 139   $params{xml}->dataElement("ram:Name",             _u8($params{item}->description));
 140   $params{xml}->endTag;
 141
 142   $params{xml}->startTag("ram:SpecifiedLineTradeAgreement");
 143   $params{xml}->startTag("ram:NetPriceProductTradePrice");
 144   $params{xml}->dataElement("ram:ChargeAmount", _r2($item_ptc->{sellprice}));
 145   $params{xml}->endTag;
 146   $params{xml}->endTag;
 147   #   </ram:SpecifiedLineTradeAgreement>
 148
 149   #   <ram:SpecifiedLineTradeDelivery>
 150   $params{xml}->startTag("ram:SpecifiedLineTradeDelivery");
 151   $params{xml}->dataElement("ram:BilledQuantity", $params{item}->qty, "unitCode" => _unit_code($params{item}->unit));
 152   $params{xml}->endTag;
 153   #   </ram:SpecifiedLineTradeDelivery>
 154
 155   #   <ram:SpecifiedLineTradeSettlement>
 156   $params{xml}->startTag("ram:SpecifiedLineTradeSettlement");
 157
 158   #     <ram:ApplicableTradeTax>
 159   $params{xml}->startTag("ram:ApplicableTradeTax");
 160   $params{xml}->dataElement("ram:TypeCode",              "VAT");
 161   $params{xml}->dataElement("ram:CategoryCode",          $tax_info{code});
 162   $params{xml}->dataElement("ram:RateApplicablePercent", _r2($tax_info{rate}));
 163   $params{xml}->endTag;
 164   #     </ram:ApplicableTradeTax>
 165
 166   #     <ram:SpecifiedTradeSettlementLineMonetarySummation>
 167   $params{xml}->startTag("ram:SpecifiedTradeSettlementLineMonetarySummation");
 168   $params{xml}->dataElement("ram:LineTotalAmount", _r2($item_ptc->{linetotal}));
 169   $params{xml}->endTag;
 170   #     </ram:SpecifiedTradeSettlementLineMonetarySummation>
 171
 172   $params{xml}->endTag;
 173   #   </ram:SpecifiedLineTradeSettlement>
 174
 175   $params{xml}->endTag;
 176   # <ram:IncludedSupplyChainTradeLineItem>
 177 }
 178
 179 sub _taxes {
 180   my ($self, %params) = @_;
 181
 182   my %taxkey_info;
 183
 184   foreach my $item (@{ $params{ptc_data}->{items} }) {
 185     $taxkey_info{$item->{taxkey_id}} //= {
 186       linetotal  => 0,
 187       tax_amount => 0,
 188     };
 189     my $info             = $taxkey_info{$item->{taxkey_id}};
 190     $info->{taxkey}    //= SL::DB::TaxKey->load_cached($item->{taxkey_id});
 191     $info->{tax}       //= SL::DB::Tax->load_cached($info->{taxkey}->tax_id);
 192     $info->{linetotal}  += $item->{linetotal};
 193     $info->{tax_amount} += $item->{tax_amount};
 194   }
 195
 196   foreach my $taxkey_id (sort keys %taxkey_info) {
 197     my $info     = $taxkey_info{$taxkey_id};
 198     my %tax_info = _tax_rate_and_code($self->taxzone, $info->{tax});
 199
 200     #     <ram:ApplicableTradeTax>
 201     $params{xml}->startTag("ram:ApplicableTradeTax");
 202     $params{xml}->dataElement("ram:CalculatedAmount",      _r2($params{ptc_data}->{taxes}->{$info->{tax}->{chart_id}}));
 203     $params{xml}->dataElement("ram:TypeCode",              "VAT");
 204     $params{xml}->dataElement("ram:BasisAmount",           _r2($info->{linetotal}));
 205     $params{xml}->dataElement("ram:CategoryCode",          $tax_info{code});
 206     $params{xml}->dataElement("ram:RateApplicablePercent", _r2($tax_info{rate}));
 207     $params{xml}->endTag;
 208     #     </ram:ApplicableTradeTax>
 209   }
 210 }
 211
 212 sub _format_payment_terms_description {
 213   my ($self) = @_;
 214
 215   my (%vars, %amounts, %formatted_amounts);
 216
 217   local $::myconfig{numberformat} = $::myconfig{numberformat};
 218   local $::myconfig{dateformat}   = $::myconfig{dateformat};
 219
 220   if ($self->language_id) {
 221     my $language = SL::DB::Language->load_cached($self->language_id);
 222     $::myconfig{dateformat}   = $language->output_dateformat   if $language->output_dateformat;
 223     $::myconfig{numberformat} = $language->output_numberformat if $language->output_numberformat;
 224   }
 225
 226   $vars{currency}              = $self->currency->name if $self->currency;
 227   $vars{$_}                    = $self->customer->$_      for qw(account_number bank bank_code bic iban mandate_date_of_signature mandator_id);
 228   $vars{$_}                    = $self->payment_terms->$_ for qw(terms_netto terms_skonto percent_skonto);
 229   $vars{payment_description}   = $self->payment_terms->description;
 230   $vars{netto_date}            = $self->payment_terms->calc_date(reference_date => $self->transdate, due_date => $self->duedate, terms => 'net')->to_kivitendo;
 231   $vars{skonto_date}           = $self->payment_terms->calc_date(reference_date => $self->transdate, due_date => $self->duedate, terms => 'discount')->to_kivitendo;
 232
 233   $amounts{invtotal}           = $self->amount;
 234   $amounts{total}              = $self->amount - $self->paid;
 235
 236   $amounts{skonto_in_percent}  = 100.0 * $vars{percent_skonto};
 237   $amounts{skonto_amount}      = $amounts{invtotal} * $vars{percent_skonto};
 238   $amounts{invtotal_wo_skonto} = $amounts{invtotal} * (1 - $vars{percent_skonto});
 239   $amounts{total_wo_skonto}    = $amounts{total}    * (1 - $vars{percent_skonto});
 240
 241   foreach (keys %amounts) {
 242     $amounts{$_}           = $::form->round_amount($amounts{$_}, 2);
 243     $formatted_amounts{$_} = $::form->format_amount(\%::myconfig, $amounts{$_}, 2);
 244   }
 245
 246   my $description = ($self->payment_terms->translated_attribute('description_long_invoice', $self->language_id) // '') || $self->payment_terms->description_long_invoice;
 247   $description    =~ s{<\%$_\%>}{ $vars{$_} }ge              for keys %vars;
 248   $description    =~ s{<\%$_\%>}{ $formatted_amounts{$_} }ge for keys %formatted_amounts;
 249
 250   return $description;
 251 }
 252
 253 sub _payment_terms {
 254   my ($self, %params) = @_;
 255
 256   return unless $self->payment_terms;
 257
 258   #     <ram:SpecifiedTradePaymentTerms>
 259   $params{xml}->startTag("ram:SpecifiedTradePaymentTerms");
 260
 261   $params{xml}->dataElement("ram:Description", _u8(_format_payment_terms_description($self)));
 262
 263   #       <ram:DueDateDateTime>
 264   $params{xml}->startTag("ram:DueDateDateTime");
 265   $params{xml}->dataElement("udt:DateTimeString", $self->duedate->strftime('%Y%m%d'), "format" => "102");
 266   $params{xml}->endTag;
 267   #       </ram:DueDateDateTime>
 268
 269   if ($self->payment_terms->percent_skonto && $self->payment_terms->terms_skonto) {
 270     #       <ram:ApplicableTradePaymentDiscountTerms>
 271     $params{xml}->startTag("ram:ApplicableTradePaymentDiscountTerms");
 272     $params{xml}->dataElement("ram:BasisPeriodMeasure", $self->payment_terms->terms_skonto, "unitCode" => "DAY");
 273     $params{xml}->dataElement("ram:CalculationPercent", _r2($self->payment_terms->percent_skonto * 100));
 274     $params{xml}->endTag;
 275     #       </ram:ApplicableTradePaymentDiscountTerms>
 276   }
 277
 278   $params{xml}->endTag;
 279   #     </ram:SpecifiedTradePaymentTerms>
 280 }
 281
 282 sub _totals {
 283   my ($self, %params) = @_;
 284
 285   #     <ram:SpecifiedTradeSettlementHeaderMonetarySummation>
 286   $params{xml}->startTag("ram:SpecifiedTradeSettlementHeaderMonetarySummation");
 287
 288   $params{xml}->dataElement("ram:LineTotalAmount",     _r2($self->netamount));
 289   $params{xml}->dataElement("ram:TaxBasisTotalAmount", _r2($self->netamount));
 290   $params{xml}->dataElement("ram:TaxTotalAmount",      _r2(sum(values %{ $params{ptc_data}->{taxes} })), "currencyID" => "EUR");
 291   $params{xml}->dataElement("ram:GrandTotalAmount",    _r2($self->amount));
 292   $params{xml}->dataElement("ram:TotalPrepaidAmount",  _r2($self->paid));
 293   $params{xml}->dataElement("ram:DuePayableAmount",    _r2($self->amount - $self->paid));
 294
 295   $params{xml}->endTag;
 296   #     </ram:SpecifiedTradeSettlementHeaderMonetarySummation>
 297 }
 298
 299 sub _exchanged_document_context {
 300   my ($self, %params) = @_;
 301
 302   #   <rsm:ExchangedDocumentContext>
 303   $params{xml}->startTag("rsm:ExchangedDocumentContext");
 304
 305   if ($::instance_conf->get_create_zugferd_invoices == 2) {
 306     $params{xml}->startTag("ram:TestIndicator");
 307     $params{xml}->dataElement("udt:Indicator", "true");
 308     $params{xml}->endTag;
 309   }
 310
 311   $params{xml}->startTag("ram:GuidelineSpecifiedDocumentContextParameter");
 312   $params{xml}->dataElement("ram:ID", "urn:cen.eu:en16931:2017#conformant#urn:zugferd.de:2p0:extended");
 313   $params{xml}->endTag;
 314   $params{xml}->endTag;
 315   #   </rsm:ExchangedDocumentContext>
 316 }
 317
 318 sub _included_note {
 319   my ($self, %params) = @_;
 320
 321   $params{xml}->startTag("ram:IncludedNote");
 322   $params{xml}->dataElement("ram:Content", _u8($params{note}));
 323   $params{xml}->endTag;
 324 }
 325
 326 sub _exchanged_document {
 327   my ($self, %params) = @_;
 328
 329   #   <rsm:ExchangedDocument>
 330   $params{xml}->startTag("rsm:ExchangedDocument");
 331
 332   $params{xml}->dataElement("ram:ID",       _u8($self->invnumber));
 333   $params{xml}->dataElement("ram:Name",     _u8(_type_name($self)));
 334   $params{xml}->dataElement("ram:TypeCode", _u8(_type_code($self)));
 335
 336   #     <ram:IssueDateTime>
 337   $params{xml}->startTag("ram:IssueDateTime");
 338   $params{xml}->dataElement("udt:DateTimeString", $self->transdate->strftime('%Y%m%d'), "format" => "102");
 339   $params{xml}->endTag;
 340   #     </ram:IssueDateTime>
 341
 342   if ($self->language && (($self->language->template_code // '') =~ m{^(de|en)}i)) {
 343     $params{xml}->dataElement("ram:LanguageID", uc($1));
 344   }
 345
 346   my $std_notes = SL::DB::Manager::GenericTranslation->get_all(
 347     where => [
 348       translation_type => 'ZUGFeRD/notes',
 349       or               => [
 350         language_id    => undef,
 351         language_id    => $self->language_id,
 352       ],
 353       '!translation'   => undef,
 354       '!translation'   => '',
 355     ],
 356   );
 357
 358   my $std_note = first { $_->language_id == $self->language_id } @{ $std_notes };
 359   $std_note  //= first { !defined $_->language_id }              @{ $std_notes };
 360
 361   my $notes = $self->notes_as_stripped_html;
 362
 363   _included_note($self, %params, note => $self->transaction_description) if $self->transaction_description;
 364   _included_note($self, %params, note => $notes)                         if $notes;
 365   _included_note($self, %params, note => $std_note->translation)         if $std_note;
 366
 367   $params{xml}->endTag;
 368   #   </rsm:ExchangedDocument>
 369 }
 370
 371 sub _specified_tax_registration {
 372   my ($ustid_nr, %params) = @_;
 373
 374   return unless $ustid_nr;
 375
 376   $ustid_nr = "DE$ustid_nr" unless $ustid_nr =~ m{^[A-Z]{2}};
 377
 378   #         <ram:SpecifiedTaxRegistration>
 379   $params{xml}->startTag("ram:SpecifiedTaxRegistration");
 380   $params{xml}->dataElement("ram:ID", _u8($ustid_nr), "schemeID" => "VA");
 381   $params{xml}->endTag;
 382   #         </ram:SpecifiedTaxRegistration>
 383 }
 384
 385 sub _seller_trade_party {
 386   my ($self, %params) = @_;
 387
 388   my @our_address            = _parse_our_address();
 389
 390   my $sales_person           = $self->salesman;
 391   my $sales_person_auth      = SL::DB::Manager::AuthUser->find_by(login => $sales_person->login);
 392   my %sales_person_cfg       = $sales_person_auth ? %{ $sales_person_auth->config_values } : ();
 393   $sales_person_cfg{email} ||= $sales_person->deleted_email;
 394   $sales_person_cfg{tel}   ||= $sales_person->deleted_tel;
 395
 396   #       <ram:SellerTradeParty>
 397   $params{xml}->startTag("ram:SellerTradeParty");
 398   $params{xml}->dataElement("ram:ID",   _u8($self->customer->c_vendor_id)) if ($self->customer->c_vendor_id // '') ne '';
 399   $params{xml}->dataElement("ram:Name", _u8($::instance_conf->get_company));
 400
 401   #         <ram:DefinedTradeContact>
 402   $params{xml}->startTag("ram:DefinedTradeContact");
 403
 404   $params{xml}->dataElement("ram:PersonName", _u8($sales_person_cfg{name} || $sales_person_cfg{login}));
 405
 406   if ($sales_person_cfg{tel}) {
 407     $params{xml}->startTag("ram:TelephoneUniversalCommunication");
 408     $params{xml}->dataElement("ram:CompleteNumber", _u8($sales_person_cfg{tel}));
 409     $params{xml}->endTag;
 410   }
 411
 412   if ($sales_person_cfg{email}) {
 413     $params{xml}->startTag("ram:EmailURIUniversalCommunication");
 414     $params{xml}->dataElement("ram:URIID", _u8($sales_person_cfg{email}));
 415     $params{xml}->endTag;
 416   }
 417
 418   $params{xml}->endTag;
 419   #         </ram:DefinedTradeContact>
 420
 421   if (@our_address) {
 422     #         <ram:PostalTradeAddress>
 423     $params{xml}->startTag("ram:PostalTradeAddress");
 424     foreach my $element (@our_address) {
 425       $params{xml}->dataElement("ram:" . $element->[0], _u8($element->[1]));
 426     }
 427     $params{xml}->endTag;
 428     #         </ram:PostalTradeAddress>
 429   }
 430
 431   _specified_tax_registration($::instance_conf->get_co_ustid, %params);
 432
 433   $params{xml}->endTag;
 434   #     </ram:SellerTradeParty>
 435 }
 436
 437 sub _buyer_trade_party {
 438   my ($self, %params) = @_;
 439
 440   #       <ram:BuyerTradeParty>
 441   $params{xml}->startTag("ram:BuyerTradeParty");
 442   $params{xml}->dataElement("ram:ID",   _u8($self->customer->customernumber));
 443   $params{xml}->dataElement("ram:Name", _u8($self->customer->name));
 444
 445   _customer_postal_trade_address(%params, customer => $self->customer);
 446   _specified_tax_registration($self->customer->ustid, %params);
 447
 448   $params{xml}->endTag;
 449   #       </ram:BuyerTradeParty>
 450 }
 451
 452 sub _included_supply_chain_trade_line_item {
 453   my ($self, %params) = @_;
 454
 455   my $line_number = 0;
 456   foreach my $item (@{ $self->items }) {
 457     _line_item($self, %params, item => $item, line_number => $line_number);
 458     $line_number++;
 459   }
 460 }
 461
 462 sub _applicable_header_trade_agreement {
 463   my ($self, %params) = @_;
 464
 465   #     <ram:ApplicableHeaderTradeAgreement>
 466   $params{xml}->startTag("ram:ApplicableHeaderTradeAgreement");
 467
 468   _seller_trade_party($self, %params);
 469   _buyer_trade_party($self, %params);
 470
 471   if ($self->cusordnumber) {
 472     #     <ram:BuyerOrderReferencedDocument>
 473     $params{xml}->startTag("ram:BuyerOrderReferencedDocument");
 474     $params{xml}->dataElement("ram:IssuerAssignedID", _u8($self->cusordnumber));
 475     $params{xml}->endTag;
 476     #     </ram:BuyerOrderReferencedDocument>
 477   }
 478
 479   $params{xml}->endTag;
 480   #     </ram:ApplicableHeaderTradeAgreement>
 481 }
 482
 483 sub _applicable_header_trade_delivery {
 484   my ($self, %params) = @_;
 485
 486   #     <ram:ApplicableHeaderTradeDelivery>
 487   $params{xml}->startTag("ram:ApplicableHeaderTradeDelivery");
 488   #       <ram:ActualDeliverySupplyChainEvent>
 489   $params{xml}->startTag("ram:ActualDeliverySupplyChainEvent");
 490
 491   $params{xml}->startTag("ram:OccurrenceDateTime");
 492   $params{xml}->dataElement("udt:DateTimeString", ($self->deliverydate // $self->transdate)->strftime('%Y%m%d'), "format" => "102");
 493   $params{xml}->endTag;
 494
 495   $params{xml}->endTag;
 496   #       </ram:ActualDeliverySupplyChainEvent>
 497   $params{xml}->endTag;
 498   #     </ram:ApplicableHeaderTradeDelivery>
 499 }
 500
 501 sub _applicable_header_trade_settlement {
 502   my ($self, %params) = @_;
 503
 504   #     <ram:ApplicableHeaderTradeSettlement>
 505   $params{xml}->startTag("ram:ApplicableHeaderTradeSettlement");
 506   $params{xml}->dataElement("ram:InvoiceCurrencyCode", _u8(SL::Helper::ISO4217::map_currency_name_to_code($self->currency->name) // 'EUR'));
 507
 508   _taxes($self, %params);
 509   _payment_terms($self, %params);
 510   _totals($self, %params);
 511
 512   $params{xml}->endTag;
 513   #     </ram:ApplicableHeaderTradeSettlement>
 514 }
 515
 516 sub _supply_chain_trade_transaction {
 517   my ($self, %params) = @_;
 518
 519   #   <rsm:SupplyChainTradeTransaction>
 520   $params{xml}->startTag("rsm:SupplyChainTradeTransaction");
 521
 522   _included_supply_chain_trade_line_item($self, %params);
 523   _applicable_header_trade_agreement($self, %params);
 524   _applicable_header_trade_delivery($self, %params);
 525   _applicable_header_trade_settlement($self, %params);
 526
 527   $params{xml}->endTag;
 528   #   </rsm:SupplyChainTradeTransaction>
 529 }
 530
 531 sub _validate_data {
 532   my ($self) = @_;
 533
 534   my $prefix = $::locale->text('The ZUGFeRD invoice data cannot be generated because the data validation failed.') . ' ';
 535
 536   if (!$::instance_conf->get_co_ustid) {
 537     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('The VAT registration number is missing in the client configuration.'));
 538   }
 539
 540   if (!$::instance_conf->get_company || any { my $get = "get_address_$_"; !$::instance_conf->$get } qw(street1 zipcode city)) {
 541     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('The company\'s address information is incomplete in the client configuration.'));
 542   }
 543
 544   if ($::instance_conf->get_address_country && !SL::Helper::ISO3166::map_name_to_alpha_2_code($::instance_conf->get_address_country)) {
 545     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('The country from the company\'s address in the client configuration cannot be mapped to an ISO 3166-1 alpha 2 code.'));
 546   }
 547
 548   if ($self->customer->country && !SL::Helper::ISO3166::map_name_to_alpha_2_code($self->customer->country)) {
 549     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('The country from the customer\'s address cannot be mapped to an ISO 3166-1 alpha 2 code.'));
 550   }
 551
 552   if (!SL::Helper::ISO4217::map_currency_name_to_code($self->currency->name)) {
 553     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('The currency "#1" cannot be mapped to an ISO 4217 currency code.', $self->currency->name));
 554   }
 555
 556   my $failed_unit = first { !SL::Helper::UNECERecommendation20::map_name_to_code($_) } map { $_->unit } @{ $self->items };
 557   if ($failed_unit) {
 558     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('One of the units used (#1) cannot be mapped to a known unit code from the UN/ECE Recommendation 20 list.', $failed_unit));
 559   }
 560 }
 561
 562 sub create_zugferd_data {
 563   my ($self) = @_;
 564
 565   _validate_data($self);
 566
 567   my %ptc_data = $self->calculate_prices_and_taxes;
 568   my $output   = '';
 569   my $xml      = XML::Writer->new(
 570     OUTPUT      => \$output,
 571     DATA_MODE   => 1,
 572     DATA_INDENT => 2,
 573     ENCODING    => 'utf-8',
 574   );
 575
 576   my %params = (
 577     ptc_data => \%ptc_data,
 578     xml      => $xml,
 579   );
 580
 581   $xml->xmlDecl();
 582
 583   # <rsm:CrossIndustryInvoice>
 584   $xml->startTag("rsm:CrossIndustryInvoice",
 585                  "xmlns:a"   => "urn:un:unece:uncefact:data:standard:QualifiedDataType:100",
 586                  "xmlns:rsm" => "urn:un:unece:uncefact:data:standard:CrossIndustryInvoice:100",
 587                  "xmlns:qdt" => "urn:un:unece:uncefact:data:standard:QualifiedDataType:10",
 588                  "xmlns:ram" => "urn:un:unece:uncefact:data:standard:ReusableAggregateBusinessInformationEntity:100",
 589                  "xmlns:xs"  => "http://www.w3.org/2001/XMLSchema",
 590                  "xmlns:udt" => "urn:un:unece:uncefact:data:standard:UnqualifiedDataType:100");
 591
 592   _exchanged_document_context($self, %params);
 593   _exchanged_document($self, %params);
 594   _supply_chain_trade_transaction($self, %params);
 595
 596   $xml->endTag;
 597   # </rsm:CrossIndustryInvoice>
 598
 599   return $output;
 600 }
 601
 602 sub create_zugferd_xmp_data {
 603   my ($self) = @_;
 604
 605   return {
 606     conformance_level  => 'EXTENDED',
 607     document_file_name => 'ZUGFeRD-invoice.xml',
 608     document_type      => 'INVOICE',
 609     version            => '1.0',
 610   };
 611 }
 612
 613 1;