SL/DB/Helper/ZUGFeRD.pm

   1 package SL::DB::Helper::ZUGFeRD;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(Exporter);
   7 our @EXPORT = qw(create_zugferd_data create_zugferd_xmp_data);
   8
   9 use SL::DB::BankAccount;
  10 use SL::DB::GenericTranslation;
  11 use SL::DB::Tax;
  12 use SL::DB::TaxKey;
  13 use SL::Helper::ISO3166;
  14 use SL::Helper::ISO4217;
  15 use SL::Helper::UNECERecommendation20;
  16 use SL::VATIDNr;
  17
  18 use Carp;
  19 use Encode qw(encode);
  20 use List::MoreUtils qw(any pairwise);
  21 use List::Util qw(first sum);
  22 use Template;
  23 use XML::Writer;
  24
  25 my @line_names = qw(LineOne LineTwo LineThree);
  26
  27 sub _u8 {
  28   my ($value) = @_;
  29   return encode('UTF-8', $value // '');
  30 }
  31
  32 sub _r2 {
  33   my ($value) = @_;
  34   return $::form->round_amount($value, 2);
  35 }
  36
  37 sub _type_name {
  38   my ($self) = @_;
  39   my $type   = $self->invoice_type;
  40
  41   no warnings 'once';
  42   return $type eq 'ar_transaction' ? $::locale->text('Invoice') : $self->displayable_type;
  43 }
  44
  45 sub _type_code {
  46   my ($self) = @_;
  47   my $type   = $self->invoice_type;
  48
  49   # 326 (Partial invoice)
  50   # 380 (Commercial invoice)
  51   # 384 (Corrected Invoice)
  52   # 381 (Credit note)
  53   # 389 (Credit note, self billed invoice)
  54
  55   return $type eq 'credit_note'        ? 381
  56        : $type eq 'invoice_storno'     ? 457
  57        : $type eq 'credit_note_storno' ? 458
  58        :                                 380;
  59 }
  60
  61 sub _unit_code {
  62   my ($unit) = @_;
  63
  64   # Mapping from kivitendo's units to UN/ECE Recommendation 20 & 21.
  65   my $code = SL::Helper::UNECERecommendation20::map_name_to_code($unit);
  66   return $code if $code;
  67
  68   $::lxdebug->message(LXDebug::WARN(), "ZUGFeRD unit name mapping: no UN/ECE Recommendation 20/21 unit known for kivitendo unit '$unit'; using 'C62'");
  69
  70   return 'C62';
  71 }
  72
  73 sub _parse_our_address {
  74   my @result;
  75   my @street = grep { $_ } ($::instance_conf->get_address_street1, $::instance_conf->get_address_street2);
  76
  77   push @result, [ 'PostcodeCode', $::instance_conf->get_address_zipcode ] if $::instance_conf->get_address_zipcode;
  78   push @result, grep { $_->[1] } pairwise { [ $a, $b] } @line_names, @street;
  79   push @result, [ 'CityName', $::instance_conf->get_address_city ] if $::instance_conf->get_address_city;
  80   push @result, [ 'CountryID', SL::Helper::ISO3166::map_name_to_alpha_2_code($::instance_conf->get_address_country) // 'DE' ];
  81
  82   return @result;
  83 }
  84
  85 sub _customer_postal_trade_address {
  86   my (%params) = @_;
  87
  88   #       <ram:PostalTradeAddress>
  89   $params{xml}->startTag("ram:PostalTradeAddress");
  90
  91   my @parts = grep { $_ } map { $params{customer}->$_ } qw(department_1 department_2 street);
  92
  93   $params{xml}->dataElement("ram:PostcodeCode", _u8($params{customer}->zipcode));
  94   $params{xml}->dataElement("ram:" . $_->[0],   _u8($_->[1])) for grep { $_->[1] } pairwise { [ $a, $b] } @line_names, @parts;
  95   $params{xml}->dataElement("ram:CityName",     _u8($params{customer}->city));
  96   $params{xml}->dataElement("ram:CountryID",    _u8(SL::Helper::ISO3166::map_name_to_alpha_2_code($params{customer}->country) // 'DE'));
  97   $params{xml}->endTag;
  98   #       </ram:PostalTradeAddress>
  99 }
 100
 101 sub _tax_rate_and_code {
 102   my ($taxzone, $tax) = @_;
 103
 104   my ($tax_rate, $tax_code) = @_;
 105
 106   if ($taxzone->description =~ m{Au.*erhalb}) {
 107     $tax_rate = 0;
 108     $tax_code = 'G';
 109
 110   } elsif ($taxzone->description =~ m{EU mit}) {
 111     $tax_rate = 0;
 112     $tax_code = 'K';
 113
 114   } else {
 115     $tax_rate = $tax->rate * 100;
 116     $tax_code = !$tax_rate ? 'Z' : 'S';
 117   }
 118
 119   return (rate => $tax_rate, code => $tax_code);
 120 }
 121
 122 sub _line_item {
 123   my ($self, %params) = @_;
 124
 125   my $item_ptc = $params{ptc_data}->{items}->[$params{line_number}];
 126
 127   my $taxkey   = $item_ptc->{taxkey_id} ? SL::DB::TaxKey->load_cached($item_ptc->{taxkey_id}) : undef;
 128   my $tax      = $item_ptc->{taxkey_id} ? SL::DB::Tax->load_cached($taxkey->tax_id)           : undef;
 129   my %tax_info = _tax_rate_and_code($self->taxzone, $tax);
 130
 131   # <ram:IncludedSupplyChainTradeLineItem>
 132   $params{xml}->startTag("ram:IncludedSupplyChainTradeLineItem");
 133
 134   #   <ram:AssociatedDocumentLineDocument>
 135   $params{xml}->startTag("ram:AssociatedDocumentLineDocument");
 136   $params{xml}->dataElement("ram:LineID", $params{line_number} + 1);
 137   $params{xml}->endTag;
 138
 139   $params{xml}->startTag("ram:SpecifiedTradeProduct");
 140   $params{xml}->dataElement("ram:SellerAssignedID", _u8($params{item}->part->partnumber));
 141   $params{xml}->dataElement("ram:Name",             _u8($params{item}->description));
 142   $params{xml}->endTag;
 143
 144   $params{xml}->startTag("ram:SpecifiedLineTradeAgreement");
 145   $params{xml}->startTag("ram:NetPriceProductTradePrice");
 146   $params{xml}->dataElement("ram:ChargeAmount", _r2($item_ptc->{sellprice}));
 147   $params{xml}->endTag;
 148   $params{xml}->endTag;
 149   #   </ram:SpecifiedLineTradeAgreement>
 150
 151   #   <ram:SpecifiedLineTradeDelivery>
 152   $params{xml}->startTag("ram:SpecifiedLineTradeDelivery");
 153   $params{xml}->dataElement("ram:BilledQuantity", $params{item}->qty, unitCode => _unit_code($params{item}->unit));
 154   $params{xml}->endTag;
 155   #   </ram:SpecifiedLineTradeDelivery>
 156
 157   #   <ram:SpecifiedLineTradeSettlement>
 158   $params{xml}->startTag("ram:SpecifiedLineTradeSettlement");
 159
 160   #     <ram:ApplicableTradeTax>
 161   $params{xml}->startTag("ram:ApplicableTradeTax");
 162   $params{xml}->dataElement("ram:TypeCode",              "VAT");
 163   $params{xml}->dataElement("ram:CategoryCode",          $tax_info{code});
 164   $params{xml}->dataElement("ram:RateApplicablePercent", _r2($tax_info{rate}));
 165   $params{xml}->endTag;
 166   #     </ram:ApplicableTradeTax>
 167
 168   #     <ram:SpecifiedTradeSettlementLineMonetarySummation>
 169   $params{xml}->startTag("ram:SpecifiedTradeSettlementLineMonetarySummation");
 170   $params{xml}->dataElement("ram:LineTotalAmount", _r2($item_ptc->{linetotal}));
 171   $params{xml}->endTag;
 172   #     </ram:SpecifiedTradeSettlementLineMonetarySummation>
 173
 174   $params{xml}->endTag;
 175   #   </ram:SpecifiedLineTradeSettlement>
 176
 177   $params{xml}->endTag;
 178   # <ram:IncludedSupplyChainTradeLineItem>
 179 }
 180
 181 sub _specified_trade_settlement_payment_means {
 182   my ($self, %params) = @_;
 183
 184   #     <ram:SpecifiedTradeSettlementPaymentMeans>
 185   $params{xml}->startTag('ram:SpecifiedTradeSettlementPaymentMeans');
 186   $params{xml}->dataElement('ram:TypeCode', $self->direct_debit ? 59 : 58); # 59 = SEPA direct debit, 58 = SEPA credit transfer
 187
 188   if ($self->direct_debit) {
 189     $params{xml}->startTag('ram:PayerPartyDebtorFinancialAccount');
 190     $params{xml}->dataElement('ram:IBANID', $self->customer->iban);
 191     $params{xml}->endTag;
 192
 193   } else {
 194     $params{xml}->startTag('ram:PayeePartyCreditorFinancialAccount');
 195     $params{xml}->dataElement('ram:IBANID', $params{bank_account}->iban);
 196     $params{xml}->endTag;
 197   }
 198
 199   $params{xml}->endTag;
 200   #     </ram:SpecifiedTradeSettlementPaymentMeans>
 201 }
 202
 203 sub _taxes {
 204   my ($self, %params) = @_;
 205
 206   my %taxkey_info;
 207
 208   foreach my $item (@{ $params{ptc_data}->{items} }) {
 209     $taxkey_info{$item->{taxkey_id}} //= {
 210       linetotal  => 0,
 211       tax_amount => 0,
 212     };
 213     my $info             = $taxkey_info{$item->{taxkey_id}};
 214     $info->{taxkey}    //= SL::DB::TaxKey->load_cached($item->{taxkey_id});
 215     $info->{tax}       //= SL::DB::Tax->load_cached($info->{taxkey}->tax_id);
 216     $info->{linetotal}  += $item->{linetotal};
 217     $info->{tax_amount} += $item->{tax_amount};
 218   }
 219
 220   foreach my $taxkey_id (sort keys %taxkey_info) {
 221     my $info     = $taxkey_info{$taxkey_id};
 222     my %tax_info = _tax_rate_and_code($self->taxzone, $info->{tax});
 223
 224     #     <ram:ApplicableTradeTax>
 225     $params{xml}->startTag("ram:ApplicableTradeTax");
 226     $params{xml}->dataElement("ram:CalculatedAmount",      _r2($params{ptc_data}->{taxes}->{$info->{tax}->{chart_id}}));
 227     $params{xml}->dataElement("ram:TypeCode",              "VAT");
 228     $params{xml}->dataElement("ram:BasisAmount",           _r2($info->{linetotal}));
 229     $params{xml}->dataElement("ram:CategoryCode",          $tax_info{code});
 230     $params{xml}->dataElement("ram:RateApplicablePercent", _r2($tax_info{rate}));
 231     $params{xml}->endTag;
 232     #     </ram:ApplicableTradeTax>
 233   }
 234 }
 235
 236 sub _calculate_payment_terms_values {
 237   my ($self) = @_;
 238
 239   my (%vars, %amounts, %formatted_amounts);
 240
 241   local $::myconfig{numberformat} = $::myconfig{numberformat};
 242   local $::myconfig{dateformat}   = $::myconfig{dateformat};
 243
 244   if ($self->language_id) {
 245     my $language = SL::DB::Language->load_cached($self->language_id);
 246     $::myconfig{dateformat}   = $language->output_dateformat   if $language->output_dateformat;
 247     $::myconfig{numberformat} = $language->output_numberformat if $language->output_numberformat;
 248   }
 249
 250   $vars{currency}              = $self->currency->name if $self->currency;
 251   $vars{$_}                    = $self->customer->$_      for qw(account_number bank bank_code bic iban mandate_date_of_signature mandator_id);
 252   $vars{$_}                    = $self->payment_terms->$_ for qw(terms_netto terms_skonto percent_skonto);
 253   $vars{payment_description}   = $self->payment_terms->description;
 254   $vars{netto_date}            = $self->payment_terms->calc_date(reference_date => $self->transdate, due_date => $self->duedate, terms => 'net')->to_kivitendo;
 255   $vars{skonto_date}           = $self->payment_terms->calc_date(reference_date => $self->transdate, due_date => $self->duedate, terms => 'discount')->to_kivitendo;
 256
 257   $amounts{invtotal}           = $self->amount;
 258   $amounts{total}              = $self->amount - $self->paid;
 259
 260   $amounts{skonto_in_percent}  = 100.0 * $vars{percent_skonto};
 261   $amounts{skonto_amount}      = $amounts{invtotal} * $vars{percent_skonto};
 262   $amounts{invtotal_wo_skonto} = $amounts{invtotal} * (1 - $vars{percent_skonto});
 263   $amounts{total_wo_skonto}    = $amounts{total}    * (1 - $vars{percent_skonto});
 264
 265   foreach (keys %amounts) {
 266     $amounts{$_}           = $::form->round_amount($amounts{$_}, 2);
 267     $formatted_amounts{$_} = $::form->format_amount(\%::myconfig, $amounts{$_}, 2);
 268   }
 269
 270   return (
 271     vars              => \%vars,
 272     amounts           => \%amounts,
 273     formatted_amounts => \%formatted_amounts,
 274   );
 275 }
 276
 277 sub _format_payment_terms_description {
 278   my ($self, %params) = @_;
 279
 280   my $description = ($self->payment_terms->translated_attribute('description_long_invoice', $self->language_id) // '') || $self->payment_terms->description_long_invoice;
 281   $description    =~ s{<\%$_\%>}{ $params{vars}->{$_} }ge              for keys %{ $params{vars} };
 282   $description    =~ s{<\%$_\%>}{ $params{formatted_amounts}->{$_} }ge for keys %{ $params{formatted_amounts} };
 283
 284   return $description;
 285 }
 286
 287 sub _payment_terms {
 288   my ($self, %params) = @_;
 289
 290   return unless $self->payment_terms;
 291
 292   my %payment_terms_vars = _calculate_payment_terms_values($self);
 293
 294   #     <ram:SpecifiedTradePaymentTerms>
 295   $params{xml}->startTag("ram:SpecifiedTradePaymentTerms");
 296
 297   $params{xml}->dataElement("ram:Description", _u8(_format_payment_terms_description($self, %payment_terms_vars)));
 298
 299   #       <ram:DueDateDateTime>
 300   $params{xml}->startTag("ram:DueDateDateTime");
 301   $params{xml}->dataElement("udt:DateTimeString", $self->duedate->strftime('%Y%m%d'), format => "102");
 302   $params{xml}->endTag;
 303   #       </ram:DueDateDateTime>
 304
 305   if ($self->payment_terms->percent_skonto && $self->payment_terms->terms_skonto) {
 306     my $currency_id = _u8(SL::Helper::ISO4217::map_currency_name_to_code($self->currency->name) // 'EUR');
 307
 308     #       <ram:ApplicableTradePaymentDiscountTerms>
 309     $params{xml}->startTag("ram:ApplicableTradePaymentDiscountTerms");
 310     $params{xml}->dataElement("ram:BasisPeriodMeasure", $self->payment_terms->terms_skonto, unitCode => "DAY");
 311     $params{xml}->dataElement("ram:BasisAmount",        _r2($payment_terms_vars{amounts}->{invtotal}), currencyID => $currency_id);
 312     $params{xml}->dataElement("ram:CalculationPercent", _r2($self->payment_terms->percent_skonto * 100));
 313     $params{xml}->endTag;
 314     #       </ram:ApplicableTradePaymentDiscountTerms>
 315   }
 316
 317   $params{xml}->endTag;
 318   #     </ram:SpecifiedTradePaymentTerms>
 319 }
 320
 321 sub _totals {
 322   my ($self, %params) = @_;
 323
 324   #     <ram:SpecifiedTradeSettlementHeaderMonetarySummation>
 325   $params{xml}->startTag("ram:SpecifiedTradeSettlementHeaderMonetarySummation");
 326
 327   $params{xml}->dataElement("ram:LineTotalAmount",     _r2($self->netamount));
 328   $params{xml}->dataElement("ram:TaxBasisTotalAmount", _r2($self->netamount));
 329   $params{xml}->dataElement("ram:TaxTotalAmount",      _r2(sum(values %{ $params{ptc_data}->{taxes} })), currencyID => "EUR");
 330   $params{xml}->dataElement("ram:GrandTotalAmount",    _r2($self->amount));
 331   $params{xml}->dataElement("ram:TotalPrepaidAmount",  _r2($self->paid));
 332   $params{xml}->dataElement("ram:DuePayableAmount",    _r2($self->amount - $self->paid));
 333
 334   $params{xml}->endTag;
 335   #     </ram:SpecifiedTradeSettlementHeaderMonetarySummation>
 336 }
 337
 338 sub _exchanged_document_context {
 339   my ($self, %params) = @_;
 340
 341   #   <rsm:ExchangedDocumentContext>
 342   $params{xml}->startTag("rsm:ExchangedDocumentContext");
 343
 344   if ($self->customer->create_zugferd_invoices_for_this_customer == 2) {
 345     $params{xml}->startTag("ram:TestIndicator");
 346     $params{xml}->dataElement("udt:Indicator", "true");
 347     $params{xml}->endTag;
 348   }
 349
 350   $params{xml}->startTag("ram:GuidelineSpecifiedDocumentContextParameter");
 351   $params{xml}->dataElement("ram:ID", "urn:cen.eu:en16931:2017#conformant#urn:zugferd.de:2p0:extended");
 352   $params{xml}->endTag;
 353   $params{xml}->endTag;
 354   #   </rsm:ExchangedDocumentContext>
 355 }
 356
 357 sub _included_note {
 358   my ($self, %params) = @_;
 359
 360   $params{xml}->startTag("ram:IncludedNote");
 361   $params{xml}->dataElement("ram:Content", _u8($params{note}));
 362   $params{xml}->endTag;
 363 }
 364
 365 sub _exchanged_document {
 366   my ($self, %params) = @_;
 367
 368   #   <rsm:ExchangedDocument>
 369   $params{xml}->startTag("rsm:ExchangedDocument");
 370
 371   $params{xml}->dataElement("ram:ID",       _u8($self->invnumber));
 372   $params{xml}->dataElement("ram:Name",     _u8(_type_name($self)));
 373   $params{xml}->dataElement("ram:TypeCode", _u8(_type_code($self)));
 374
 375   #     <ram:IssueDateTime>
 376   $params{xml}->startTag("ram:IssueDateTime");
 377   $params{xml}->dataElement("udt:DateTimeString", $self->transdate->strftime('%Y%m%d'), format => "102");
 378   $params{xml}->endTag;
 379   #     </ram:IssueDateTime>
 380
 381   if ($self->language && (($self->language->template_code // '') =~ m{^(de|en)}i)) {
 382     $params{xml}->dataElement("ram:LanguageID", uc($1));
 383   }
 384
 385   my $std_notes = SL::DB::Manager::GenericTranslation->get_all(
 386     where => [
 387       translation_type => 'ZUGFeRD/notes',
 388       or               => [
 389         language_id    => undef,
 390         language_id    => $self->language_id,
 391       ],
 392       '!translation'   => undef,
 393       '!translation'   => '',
 394     ],
 395   );
 396
 397   my $std_note = first { $_->language_id == $self->language_id } @{ $std_notes };
 398   $std_note  //= first { !defined $_->language_id }              @{ $std_notes };
 399
 400   my $notes = $self->notes_as_stripped_html;
 401
 402   _included_note($self, %params, note => $self->transaction_description) if $self->transaction_description;
 403   _included_note($self, %params, note => $notes)                         if $notes;
 404   _included_note($self, %params, note => $std_note->translation)         if $std_note;
 405
 406   $params{xml}->endTag;
 407   #   </rsm:ExchangedDocument>
 408 }
 409
 410 sub _specified_tax_registration {
 411   my ($ustid_nr, %params) = @_;
 412
 413   #         <ram:SpecifiedTaxRegistration>
 414   $params{xml}->startTag("ram:SpecifiedTaxRegistration");
 415   $params{xml}->dataElement("ram:ID", _u8(SL::VATIDNr->normalize($ustid_nr)), schemeID => "VA");
 416   $params{xml}->endTag;
 417   #         </ram:SpecifiedTaxRegistration>
 418 }
 419
 420 sub _seller_trade_party {
 421   my ($self, %params) = @_;
 422
 423   my @our_address            = _parse_our_address();
 424
 425   my $sales_person           = $self->salesman;
 426   my $sales_person_auth      = SL::DB::Manager::AuthUser->find_by(login => $sales_person->login);
 427   my %sales_person_cfg       = $sales_person_auth ? %{ $sales_person_auth->config_values } : ();
 428   $sales_person_cfg{email} ||= $sales_person->deleted_email;
 429   $sales_person_cfg{tel}   ||= $sales_person->deleted_tel;
 430
 431   #       <ram:SellerTradeParty>
 432   $params{xml}->startTag("ram:SellerTradeParty");
 433   $params{xml}->dataElement("ram:ID",   _u8($self->customer->c_vendor_id)) if ($self->customer->c_vendor_id // '') ne '';
 434   $params{xml}->dataElement("ram:Name", _u8($::instance_conf->get_company));
 435
 436   #         <ram:DefinedTradeContact>
 437   $params{xml}->startTag("ram:DefinedTradeContact");
 438
 439   $params{xml}->dataElement("ram:PersonName", _u8($sales_person_cfg{name} || $sales_person_cfg{login}));
 440
 441   if ($sales_person_cfg{tel}) {
 442     $params{xml}->startTag("ram:TelephoneUniversalCommunication");
 443     $params{xml}->dataElement("ram:CompleteNumber", _u8($sales_person_cfg{tel}));
 444     $params{xml}->endTag;
 445   }
 446
 447   if ($sales_person_cfg{email}) {
 448     $params{xml}->startTag("ram:EmailURIUniversalCommunication");
 449     $params{xml}->dataElement("ram:URIID", _u8($sales_person_cfg{email}));
 450     $params{xml}->endTag;
 451   }
 452
 453   $params{xml}->endTag;
 454   #         </ram:DefinedTradeContact>
 455
 456   if (@our_address) {
 457     #         <ram:PostalTradeAddress>
 458     $params{xml}->startTag("ram:PostalTradeAddress");
 459     foreach my $element (@our_address) {
 460       $params{xml}->dataElement("ram:" . $element->[0], _u8($element->[1]));
 461     }
 462     $params{xml}->endTag;
 463     #         </ram:PostalTradeAddress>
 464   }
 465
 466   _specified_tax_registration($::instance_conf->get_co_ustid, %params);
 467
 468   $params{xml}->endTag;
 469   #     </ram:SellerTradeParty>
 470 }
 471
 472 sub _buyer_trade_party {
 473   my ($self, %params) = @_;
 474
 475   #       <ram:BuyerTradeParty>
 476   $params{xml}->startTag("ram:BuyerTradeParty");
 477   $params{xml}->dataElement("ram:ID",   _u8($self->customer->customernumber));
 478   $params{xml}->dataElement("ram:Name", _u8($self->customer->name));
 479
 480   _customer_postal_trade_address(%params, customer => $self->customer);
 481   _specified_tax_registration($self->customer->ustid, %params);
 482
 483   $params{xml}->endTag;
 484   #       </ram:BuyerTradeParty>
 485 }
 486
 487 sub _included_supply_chain_trade_line_item {
 488   my ($self, %params) = @_;
 489
 490   my $line_number = 0;
 491   foreach my $item (@{ $self->items }) {
 492     _line_item($self, %params, item => $item, line_number => $line_number);
 493     $line_number++;
 494   }
 495 }
 496
 497 sub _applicable_header_trade_agreement {
 498   my ($self, %params) = @_;
 499
 500   #     <ram:ApplicableHeaderTradeAgreement>
 501   $params{xml}->startTag("ram:ApplicableHeaderTradeAgreement");
 502
 503   _seller_trade_party($self, %params);
 504   _buyer_trade_party($self, %params);
 505
 506   if ($self->cusordnumber) {
 507     #     <ram:BuyerOrderReferencedDocument>
 508     $params{xml}->startTag("ram:BuyerOrderReferencedDocument");
 509     $params{xml}->dataElement("ram:IssuerAssignedID", _u8($self->cusordnumber));
 510     $params{xml}->endTag;
 511     #     </ram:BuyerOrderReferencedDocument>
 512   }
 513
 514   $params{xml}->endTag;
 515   #     </ram:ApplicableHeaderTradeAgreement>
 516 }
 517
 518 sub _applicable_header_trade_delivery {
 519   my ($self, %params) = @_;
 520
 521   #     <ram:ApplicableHeaderTradeDelivery>
 522   $params{xml}->startTag("ram:ApplicableHeaderTradeDelivery");
 523   #       <ram:ActualDeliverySupplyChainEvent>
 524   $params{xml}->startTag("ram:ActualDeliverySupplyChainEvent");
 525
 526   $params{xml}->startTag("ram:OccurrenceDateTime");
 527   $params{xml}->dataElement("udt:DateTimeString", ($self->deliverydate // $self->transdate)->strftime('%Y%m%d'), format => "102");
 528   $params{xml}->endTag;
 529
 530   $params{xml}->endTag;
 531   #       </ram:ActualDeliverySupplyChainEvent>
 532   $params{xml}->endTag;
 533   #     </ram:ApplicableHeaderTradeDelivery>
 534 }
 535
 536 sub _applicable_header_trade_settlement {
 537   my ($self, %params) = @_;
 538
 539   #     <ram:ApplicableHeaderTradeSettlement>
 540   $params{xml}->startTag("ram:ApplicableHeaderTradeSettlement");
 541   $params{xml}->dataElement("ram:InvoiceCurrencyCode", _u8(SL::Helper::ISO4217::map_currency_name_to_code($self->currency->name) // 'EUR'));
 542
 543   _specified_trade_settlement_payment_means($self, %params);
 544   _taxes($self, %params);
 545   _payment_terms($self, %params);
 546   _totals($self, %params);
 547
 548   $params{xml}->endTag;
 549   #     </ram:ApplicableHeaderTradeSettlement>
 550 }
 551
 552 sub _supply_chain_trade_transaction {
 553   my ($self, %params) = @_;
 554
 555   #   <rsm:SupplyChainTradeTransaction>
 556   $params{xml}->startTag("rsm:SupplyChainTradeTransaction");
 557
 558   _included_supply_chain_trade_line_item($self, %params);
 559   _applicable_header_trade_agreement($self, %params);
 560   _applicable_header_trade_delivery($self, %params);
 561   _applicable_header_trade_settlement($self, %params);
 562
 563   $params{xml}->endTag;
 564   #   </rsm:SupplyChainTradeTransaction>
 565 }
 566
 567 sub _validate_data {
 568   my ($self) = @_;
 569
 570   my %result;
 571   my $prefix = $::locale->text('The ZUGFeRD invoice data cannot be generated because the data validation failed.') . ' ';
 572
 573   if (!$::instance_conf->get_co_ustid) {
 574     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('The VAT registration number is missing in the client configuration.'));
 575   }
 576
 577   if (!SL::VATIDNr->validate($::instance_conf->get_co_ustid)) {
 578     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text("The VAT ID number in the client configuration is invalid."));
 579   }
 580
 581   if (!$::instance_conf->get_company || any { my $get = "get_address_$_"; !$::instance_conf->$get } qw(street1 zipcode city)) {
 582     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('The company\'s address information is incomplete in the client configuration.'));
 583   }
 584
 585   if ($::instance_conf->get_address_country && !SL::Helper::ISO3166::map_name_to_alpha_2_code($::instance_conf->get_address_country)) {
 586     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('The country from the company\'s address in the client configuration cannot be mapped to an ISO 3166-1 alpha 2 code.'));
 587   }
 588
 589   if ($self->customer->country && !SL::Helper::ISO3166::map_name_to_alpha_2_code($self->customer->country)) {
 590     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('The country from the customer\'s address cannot be mapped to an ISO 3166-1 alpha 2 code.'));
 591   }
 592
 593   if (!SL::Helper::ISO4217::map_currency_name_to_code($self->currency->name)) {
 594     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('The currency "#1" cannot be mapped to an ISO 4217 currency code.', $self->currency->name));
 595   }
 596
 597   my $failed_unit = first { !SL::Helper::UNECERecommendation20::map_name_to_code($_) } map { $_->unit } @{ $self->items };
 598   if ($failed_unit) {
 599     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('One of the units used (#1) cannot be mapped to a known unit code from the UN/ECE Recommendation 20 list.', $failed_unit));
 600   }
 601
 602   if ($self->direct_debit) {
 603     if (!$self->customer->iban) {
 604       SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('The customer\'s bank account number (IBAN) is missing.'));
 605     }
 606
 607   } else {
 608     my $bank_accounts     = SL::DB::Manager::BankAccount->get_all;
 609     $result{bank_account} = scalar(@{ $bank_accounts }) == 1 ? $bank_accounts->[0] : first { $_->use_for_zugferd } @{ $bank_accounts };
 610
 611     if (!$result{bank_account}) {
 612       SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('No bank account flagged for ZUGFeRD usage was found.'));
 613     }
 614   }
 615
 616   return %result;
 617 }
 618
 619 sub create_zugferd_data {
 620   my ($self)        = @_;
 621
 622   my $output        = '';
 623
 624   my %params        = _validate_data($self);
 625   $params{ptc_data} = { $self->calculate_prices_and_taxes };
 626   $params{xml}      = XML::Writer->new(
 627     OUTPUT          => \$output,
 628     DATA_MODE       => 1,
 629     DATA_INDENT     => 2,
 630     ENCODING        => 'utf-8',
 631   );
 632
 633   $params{xml}->xmlDecl();
 634
 635   # <rsm:CrossIndustryInvoice>
 636   $params{xml}->startTag("rsm:CrossIndustryInvoice",
 637                          "xmlns:a"   => "urn:un:unece:uncefact:data:standard:QualifiedDataType:100",
 638                          "xmlns:rsm" => "urn:un:unece:uncefact:data:standard:CrossIndustryInvoice:100",
 639                          "xmlns:qdt" => "urn:un:unece:uncefact:data:standard:QualifiedDataType:10",
 640                          "xmlns:ram" => "urn:un:unece:uncefact:data:standard:ReusableAggregateBusinessInformationEntity:100",
 641                          "xmlns:xs"  => "http://www.w3.org/2001/XMLSchema",
 642                          "xmlns:udt" => "urn:un:unece:uncefact:data:standard:UnqualifiedDataType:100");
 643
 644   _exchanged_document_context($self, %params);
 645   _exchanged_document($self, %params);
 646   _supply_chain_trade_transaction($self, %params);
 647
 648   $params{xml}->endTag;
 649   # </rsm:CrossIndustryInvoice>
 650
 651   return $output;
 652 }
 653
 654 sub create_zugferd_xmp_data {
 655   my ($self) = @_;
 656
 657   return {
 658     conformance_level  => 'EXTENDED',
 659     document_file_name => 'ZUGFeRD-invoice.xml',
 660     document_type      => 'INVOICE',
 661     version            => '1.0',
 662   };
 663 }
 664
 665 1;