SL/DB/Helper/ZUGFeRD.pm

   1 package SL::DB::Helper::ZUGFeRD;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(Exporter);
   7 our @EXPORT = qw(create_zugferd_data create_zugferd_xmp_data);
   8
   9 use SL::DB::GenericTranslation;
  10 use SL::DB::Tax;
  11 use SL::DB::TaxKey;
  12 use SL::Helper::ISO3166;
  13 use SL::Helper::ISO4217;
  14 use SL::Helper::UNECERecommendation20;
  15
  16 use Carp;
  17 use Encode qw(encode);
  18 use List::MoreUtils qw(any pairwise);
  19 use List::Util qw(first sum);
  20 use Template;
  21 use XML::Writer;
  22
  23 my @line_names = qw(LineOne LineTwo LineThree);
  24
  25 sub _u8 {
  26   my ($value) = @_;
  27   return encode('UTF-8', $value // '');
  28 }
  29
  30 sub _r2 {
  31   my ($value) = @_;
  32   return $::form->round_amount($value, 2);
  33 }
  34
  35 sub _type_name {
  36   my ($self) = @_;
  37   my $type   = $self->invoice_type;
  38
  39   no warnings 'once';
  40   return $type eq 'ar_transaction' ? $::locale->text('Invoice') : $self->displayable_type;
  41 }
  42
  43 sub _type_code {
  44   my ($self) = @_;
  45   my $type   = $self->invoice_type;
  46
  47   # 326 (Partial invoice)
  48   # 380 (Commercial invoice)
  49   # 384 (Corrected Invoice)
  50   # 381 (Credit note)
  51   # 389 (Credit note, self billed invoice)
  52
  53   return $type eq 'credit_note' ? 381 : 380;
  54 }
  55
  56 sub _unit_code {
  57   my ($unit) = @_;
  58
  59   # Mapping from kivitendo's units to UN/ECE Recommendation 20 & 21.
  60   my $code = SL::Helper::UNECERecommendation20::map_name_to_code($unit);
  61   return $code if $code;
  62
  63   $::lxdebug->message(LXDebug::WARN(), "ZUGFeRD unit name mapping: no UN/ECE Recommendation 20/21 unit known for kivitendo unit '$unit'; using 'C62'");
  64
  65   return 'C62';
  66 }
  67
  68 sub _parse_our_address {
  69   my @result;
  70   my @street = grep { $_ } ($::instance_conf->get_address_street1, $::instance_conf->get_address_street2);
  71
  72   push @result, [ 'PostcodeCode', $::instance_conf->get_address_zipcode ] if $::instance_conf->get_address_zipcode;
  73   push @result, grep { $_->[1] } pairwise { [ $a, $b] } @line_names, @street;
  74   push @result, [ 'CityName', $::instance_conf->get_address_city ] if $::instance_conf->get_address_city;
  75   push @result, [ 'CountryID', SL::Helper::ISO3166::map_name_to_alpha_2_code($::instance_conf->get_address_country) // 'DE' ];
  76
  77   return @result;
  78 }
  79
  80 sub _customer_postal_trade_address {
  81   my (%params) = @_;
  82
  83   #       <ram:PostalTradeAddress>
  84   $params{xml}->startTag("ram:PostalTradeAddress");
  85
  86   my @parts = grep { $_ } map { $params{customer}->$_ } qw(department_1 department_2 street);
  87
  88   $params{xml}->dataElement("ram:PostcodeCode", _u8($params{customer}->zipcode));
  89   $params{xml}->dataElement("ram:" . $_->[0],   _u8($_->[1])) for grep { $_->[1] } pairwise { [ $a, $b] } @line_names, @parts;
  90   $params{xml}->dataElement("ram:CityName",     _u8($params{customer}->city));
  91   $params{xml}->dataElement("ram:CountryID",    _u8(SL::Helper::ISO3166::map_name_to_alpha_2_code($params{customer}->country) // 'DE'));
  92   $params{xml}->endTag;
  93   #       </ram:PostalTradeAddress>
  94 }
  95
  96 sub _tax_rate_and_code {
  97   my ($taxzone, $tax) = @_;
  98
  99   my ($tax_rate, $tax_code) = @_;
 100
 101   if ($taxzone->description =~ m{Au.*erhalb}) {
 102     $tax_rate = 0;
 103     $tax_code = 'G';
 104
 105   } elsif ($taxzone->description =~ m{EU mit}) {
 106     $tax_rate = 0;
 107     $tax_code = 'K';
 108
 109   } else {
 110     $tax_rate = $tax->rate * 100;
 111     $tax_code = !$tax_rate ? 'Z' : 'S';
 112   }
 113
 114   return (rate => $tax_rate, code => $tax_code);
 115 }
 116
 117 sub _line_item {
 118   my ($self, %params) = @_;
 119
 120   my $item_ptc = $params{ptc_data}->{items}->[$params{line_number}];
 121
 122   my $taxkey   = $item_ptc->{taxkey_id} ? SL::DB::TaxKey->load_cached($item_ptc->{taxkey_id}) : undef;
 123   my $tax      = $item_ptc->{taxkey_id} ? SL::DB::Tax->load_cached($taxkey->tax_id)           : undef;
 124   my %tax_info = _tax_rate_and_code($self->taxzone, $tax);
 125
 126   # <ram:IncludedSupplyChainTradeLineItem>
 127   $params{xml}->startTag("ram:IncludedSupplyChainTradeLineItem");
 128
 129   #   <ram:AssociatedDocumentLineDocument>
 130   $params{xml}->startTag("ram:AssociatedDocumentLineDocument");
 131   $params{xml}->dataElement("ram:LineID", $params{line_number} + 1);
 132   $params{xml}->endTag;
 133
 134   $params{xml}->startTag("ram:SpecifiedTradeProduct");
 135   $params{xml}->dataElement("ram:SellerAssignedID", _u8($params{item}->part->partnumber));
 136   $params{xml}->dataElement("ram:Name",             _u8($params{item}->description));
 137   $params{xml}->endTag;
 138
 139   $params{xml}->startTag("ram:SpecifiedLineTradeAgreement");
 140   $params{xml}->startTag("ram:NetPriceProductTradePrice");
 141   $params{xml}->dataElement("ram:ChargeAmount", _r2($item_ptc->{sellprice}));
 142   $params{xml}->endTag;
 143   $params{xml}->endTag;
 144   #   </ram:SpecifiedLineTradeAgreement>
 145
 146   #   <ram:SpecifiedLineTradeDelivery>
 147   $params{xml}->startTag("ram:SpecifiedLineTradeDelivery");
 148   $params{xml}->dataElement("ram:BilledQuantity", $params{item}->qty, "unitCode" => _unit_code($params{item}->unit));
 149   $params{xml}->endTag;
 150   #   </ram:SpecifiedLineTradeDelivery>
 151
 152   #   <ram:SpecifiedLineTradeSettlement>
 153   $params{xml}->startTag("ram:SpecifiedLineTradeSettlement");
 154
 155   #     <ram:ApplicableTradeTax>
 156   $params{xml}->startTag("ram:ApplicableTradeTax");
 157   $params{xml}->dataElement("ram:TypeCode",              "VAT");
 158   $params{xml}->dataElement("ram:CategoryCode",          $tax_info{code});
 159   $params{xml}->dataElement("ram:RateApplicablePercent", _r2($tax_info{rate}));
 160   $params{xml}->endTag;
 161   #     </ram:ApplicableTradeTax>
 162
 163   #     <ram:SpecifiedTradeSettlementLineMonetarySummation>
 164   $params{xml}->startTag("ram:SpecifiedTradeSettlementLineMonetarySummation");
 165   $params{xml}->dataElement("ram:LineTotalAmount", _r2($item_ptc->{linetotal}));
 166   $params{xml}->endTag;
 167   #     </ram:SpecifiedTradeSettlementLineMonetarySummation>
 168
 169   $params{xml}->endTag;
 170   #   </ram:SpecifiedLineTradeSettlement>
 171
 172   $params{xml}->endTag;
 173   # <ram:IncludedSupplyChainTradeLineItem>
 174 }
 175
 176 sub _taxes {
 177   my ($self, %params) = @_;
 178
 179   my %taxkey_info;
 180
 181   foreach my $item (@{ $params{ptc_data}->{items} }) {
 182     $taxkey_info{$item->{taxkey_id}} //= {
 183       linetotal  => 0,
 184       tax_amount => 0,
 185     };
 186     my $info             = $taxkey_info{$item->{taxkey_id}};
 187     $info->{taxkey}    //= SL::DB::TaxKey->load_cached($item->{taxkey_id});
 188     $info->{tax}       //= SL::DB::Tax->load_cached($info->{taxkey}->tax_id);
 189     $info->{linetotal}  += $item->{linetotal};
 190     $info->{tax_amount} += $item->{tax_amount};
 191   }
 192
 193   foreach my $taxkey_id (sort keys %taxkey_info) {
 194     my $info     = $taxkey_info{$taxkey_id};
 195     my %tax_info = _tax_rate_and_code($self->taxzone, $info->{tax});
 196
 197     #     <ram:ApplicableTradeTax>
 198     $params{xml}->startTag("ram:ApplicableTradeTax");
 199     $params{xml}->dataElement("ram:CalculatedAmount",      _r2($params{ptc_data}->{taxes}->{$info->{tax}->{chart_id}}));
 200     $params{xml}->dataElement("ram:TypeCode",              "VAT");
 201     $params{xml}->dataElement("ram:BasisAmount",           _r2($info->{linetotal}));
 202     $params{xml}->dataElement("ram:CategoryCode",          $tax_info{code});
 203     $params{xml}->dataElement("ram:RateApplicablePercent", _r2($tax_info{rate}));
 204     $params{xml}->endTag;
 205     #     </ram:ApplicableTradeTax>
 206   }
 207 }
 208
 209 sub _format_payment_terms_description {
 210   my ($self) = @_;
 211
 212   my (%vars, %amounts, %formatted_amounts);
 213
 214   local $::myconfig{numberformat} = $::myconfig{numberformat};
 215   local $::myconfig{dateformat}   = $::myconfig{dateformat};
 216
 217   if ($self->language_id) {
 218     my $language = SL::DB::Language->load_cached($self->language_id);
 219     $::myconfig{dateformat}   = $language->output_dateformat   if $language->output_dateformat;
 220     $::myconfig{numberformat} = $language->output_numberformat if $language->output_numberformat;
 221   }
 222
 223   $vars{currency}              = $self->currency->name if $self->currency;
 224   $vars{$_}                    = $self->customer->$_      for qw(account_number bank bank_code bic iban mandate_date_of_signature mandator_id);
 225   $vars{$_}                    = $self->payment_terms->$_ for qw(terms_netto terms_skonto percent_skonto);
 226   $vars{payment_description}   = $self->payment_terms->description;
 227   $vars{netto_date}            = $self->payment_terms->calc_date(reference_date => $self->transdate, due_date => $self->duedate, terms => 'net')->to_kivitendo;
 228   $vars{skonto_date}           = $self->payment_terms->calc_date(reference_date => $self->transdate, due_date => $self->duedate, terms => 'discount')->to_kivitendo;
 229
 230   $amounts{invtotal}           = $self->amount;
 231   $amounts{total}              = $self->amount - $self->paid;
 232
 233   $amounts{skonto_in_percent}  = 100.0 * $vars{percent_skonto};
 234   $amounts{skonto_amount}      = $amounts{invtotal} * $vars{percent_skonto};
 235   $amounts{invtotal_wo_skonto} = $amounts{invtotal} * (1 - $vars{percent_skonto});
 236   $amounts{total_wo_skonto}    = $amounts{total}    * (1 - $vars{percent_skonto});
 237
 238   foreach (keys %amounts) {
 239     $amounts{$_}           = $::form->round_amount($amounts{$_}, 2);
 240     $formatted_amounts{$_} = $::form->format_amount(\%::myconfig, $amounts{$_}, 2);
 241   }
 242
 243   my $description = ($self->payment_terms->translated_attribute('description_long_invoice', $self->language_id) // '') || $self->payment_terms->description_long_invoice;
 244   $description    =~ s{<\%$_\%>}{ $vars{$_} }ge              for keys %vars;
 245   $description    =~ s{<\%$_\%>}{ $formatted_amounts{$_} }ge for keys %formatted_amounts;
 246
 247   return $description;
 248 }
 249
 250 sub _payment_terms {
 251   my ($self, %params) = @_;
 252
 253   return unless $self->payment_terms;
 254
 255   #     <ram:SpecifiedTradePaymentTerms>
 256   $params{xml}->startTag("ram:SpecifiedTradePaymentTerms");
 257
 258   $params{xml}->dataElement("ram:Description", _u8(_format_payment_terms_description($self)));
 259
 260   #       <ram:DueDateDateTime>
 261   $params{xml}->startTag("ram:DueDateDateTime");
 262   $params{xml}->dataElement("udt:DateTimeString", $self->duedate->strftime('%Y%m%d'), "format" => "102");
 263   $params{xml}->endTag;
 264   #       </ram:DueDateDateTime>
 265
 266   if ($self->payment_terms->percent_skonto && $self->payment_terms->terms_skonto) {
 267     #       <ram:ApplicableTradePaymentDiscountTerms>
 268     $params{xml}->startTag("ram:ApplicableTradePaymentDiscountTerms");
 269     $params{xml}->dataElement("ram:BasisPeriodMeasure", $self->payment_terms->terms_skonto, "unitCode" => "DAY");
 270     $params{xml}->dataElement("ram:CalculationPercent", _r2($self->payment_terms->percent_skonto * 100));
 271     $params{xml}->endTag;
 272     #       </ram:ApplicableTradePaymentDiscountTerms>
 273   }
 274
 275   $params{xml}->endTag;
 276   #     </ram:SpecifiedTradePaymentTerms>
 277 }
 278
 279 sub _totals {
 280   my ($self, %params) = @_;
 281
 282   #     <ram:SpecifiedTradeSettlementHeaderMonetarySummation>
 283   $params{xml}->startTag("ram:SpecifiedTradeSettlementHeaderMonetarySummation");
 284
 285   $params{xml}->dataElement("ram:LineTotalAmount",     _r2($self->netamount));
 286   $params{xml}->dataElement("ram:TaxBasisTotalAmount", _r2($self->netamount));
 287   $params{xml}->dataElement("ram:TaxTotalAmount",      _r2(sum(values %{ $params{ptc_data}->{taxes} })), "currencyID" => "EUR");
 288   $params{xml}->dataElement("ram:GrandTotalAmount",    _r2($self->amount));
 289   $params{xml}->dataElement("ram:TotalPrepaidAmount",  _r2($self->paid));
 290   $params{xml}->dataElement("ram:DuePayableAmount",    _r2($self->amount - $self->paid));
 291
 292   $params{xml}->endTag;
 293   #     </ram:SpecifiedTradeSettlementHeaderMonetarySummation>
 294 }
 295
 296 sub _exchanged_document_context {
 297   my ($self, %params) = @_;
 298
 299   #   <rsm:ExchangedDocumentContext>
 300   $params{xml}->startTag("rsm:ExchangedDocumentContext");
 301
 302   if ($::instance_conf->get_create_zugferd_invoices == 2) {
 303     $params{xml}->startTag("ram:TestIndicator");
 304     $params{xml}->dataElement("udt:Indicator", "true");
 305     $params{xml}->endTag;
 306   }
 307
 308   $params{xml}->startTag("ram:GuidelineSpecifiedDocumentContextParameter");
 309   $params{xml}->dataElement("ram:ID", "urn:cen.eu:en16931:2017#conformant#urn:zugferd.de:2p0:extended");
 310   $params{xml}->endTag;
 311   $params{xml}->endTag;
 312   #   </rsm:ExchangedDocumentContext>
 313 }
 314
 315 sub _included_note {
 316   my ($self, %params) = @_;
 317
 318   $params{xml}->startTag("ram:IncludedNote");
 319   $params{xml}->dataElement("ram:Content", _u8($params{note}));
 320   $params{xml}->endTag;
 321 }
 322
 323 sub _exchanged_document {
 324   my ($self, %params) = @_;
 325
 326   #   <rsm:ExchangedDocument>
 327   $params{xml}->startTag("rsm:ExchangedDocument");
 328
 329   $params{xml}->dataElement("ram:ID",       _u8($self->invnumber));
 330   $params{xml}->dataElement("ram:Name",     _u8(_type_name($self)));
 331   $params{xml}->dataElement("ram:TypeCode", _u8(_type_code($self)));
 332
 333   #     <ram:IssueDateTime>
 334   $params{xml}->startTag("ram:IssueDateTime");
 335   $params{xml}->dataElement("udt:DateTimeString", $self->transdate->strftime('%Y%m%d'), "format" => "102");
 336   $params{xml}->endTag;
 337   #     </ram:IssueDateTime>
 338
 339   if ($self->language && (($self->language->template_code // '') =~ m{^(de|en)}i)) {
 340     $params{xml}->dataElement("ram:LanguageID", uc($1));
 341   }
 342
 343   my $std_notes = SL::DB::Manager::GenericTranslation->get_all(
 344     where => [
 345       translation_type => 'ZUGFeRD/notes',
 346       or               => [
 347         language_id    => undef,
 348         language_id    => $self->language_id,
 349       ],
 350       '!translation'   => undef,
 351       '!translation'   => '',
 352     ],
 353   );
 354
 355   my $std_note = first { $_->language_id == $self->language_id } @{ $std_notes };
 356   $std_note  //= first { !defined $_->language_id }              @{ $std_notes };
 357
 358   my $notes = $self->notes_as_stripped_html;
 359
 360   _included_note($self, %params, note => $self->transaction_description) if $self->transaction_description;
 361   _included_note($self, %params, note => $notes)                         if $notes;
 362   _included_note($self, %params, note => $std_note->translation)         if $std_note;
 363
 364   $params{xml}->endTag;
 365   #   </rsm:ExchangedDocument>
 366 }
 367
 368 sub _seller_trade_party {
 369   my ($self, %params) = @_;
 370
 371   my @our_address            = _parse_our_address();
 372
 373   my $sales_person           = $self->salesman;
 374   my $sales_person_auth      = SL::DB::Manager::AuthUser->find_by(login => $sales_person->login);
 375   my %sales_person_cfg       = $sales_person_auth ? %{ $sales_person_auth->config_values } : ();
 376   $sales_person_cfg{email} ||= $sales_person->deleted_email;
 377   $sales_person_cfg{tel}   ||= $sales_person->deleted_tel;
 378
 379   #       <ram:SellerTradeParty>
 380   $params{xml}->startTag("ram:SellerTradeParty");
 381   $params{xml}->dataElement("ram:ID",   _u8($self->customer->c_vendor_id)) if ($self->customer->c_vendor_id // '') ne '';
 382   $params{xml}->dataElement("ram:Name", _u8($::instance_conf->get_company));
 383
 384   #         <ram:DefinedTradeContact>
 385   $params{xml}->startTag("ram:DefinedTradeContact");
 386
 387   $params{xml}->dataElement("ram:PersonName", _u8($sales_person_cfg{name} || $sales_person_cfg{login}));
 388
 389   if ($sales_person_cfg{tel}) {
 390     $params{xml}->startTag("ram:TelephoneUniversalCommunication");
 391     $params{xml}->dataElement("ram:CompleteNumber", _u8($sales_person_cfg{tel}));
 392     $params{xml}->endTag;
 393   }
 394
 395   if ($sales_person_cfg{email}) {
 396     $params{xml}->startTag("ram:EmailURIUniversalCommunication");
 397     $params{xml}->dataElement("ram:URIID", _u8($sales_person_cfg{email}));
 398     $params{xml}->endTag;
 399   }
 400
 401   $params{xml}->endTag;
 402   #         </ram:DefinedTradeContact>
 403
 404   if (@our_address) {
 405     #         <ram:PostalTradeAddress>
 406     $params{xml}->startTag("ram:PostalTradeAddress");
 407     foreach my $element (@our_address) {
 408       $params{xml}->dataElement("ram:" . $element->[0], _u8($element->[1]));
 409     }
 410     $params{xml}->endTag;
 411     #         </ram:PostalTradeAddress>
 412   }
 413
 414   my $ustid_nr = $::instance_conf->get_co_ustid;
 415   if ($ustid_nr) {
 416     $ustid_nr = "DE$ustid_nr" unless $ustid_nr =~ m{^[A-Z]{2}};
 417     #         <ram:SpecifiedTaxRegistration>
 418     $params{xml}->startTag("ram:SpecifiedTaxRegistration");
 419     $params{xml}->dataElement("ram:ID", _u8($ustid_nr), "schemeID" => "VA");
 420     $params{xml}->endTag;
 421     #         </ram:SpecifiedTaxRegistration>
 422   }
 423
 424   $params{xml}->endTag;
 425   #     </ram:SellerTradeParty>
 426 }
 427
 428 sub _buyer_trade_party {
 429   my ($self, %params) = @_;
 430
 431   #       <ram:BuyerTradeParty>
 432   $params{xml}->startTag("ram:BuyerTradeParty");
 433   $params{xml}->dataElement("ram:ID",   _u8($self->customer->customernumber));
 434   $params{xml}->dataElement("ram:Name", _u8($self->customer->name));
 435
 436   _customer_postal_trade_address(%params, customer => $self->customer);
 437
 438   $params{xml}->endTag;
 439   #       </ram:BuyerTradeParty>
 440 }
 441
 442 sub _included_supply_chain_trade_line_item {
 443   my ($self, %params) = @_;
 444
 445   my $line_number = 0;
 446   foreach my $item (@{ $self->items }) {
 447     _line_item($self, %params, item => $item, line_number => $line_number);
 448     $line_number++;
 449   }
 450 }
 451
 452 sub _applicable_header_trade_agreement {
 453   my ($self, %params) = @_;
 454
 455   #     <ram:ApplicableHeaderTradeAgreement>
 456   $params{xml}->startTag("ram:ApplicableHeaderTradeAgreement");
 457
 458   _seller_trade_party($self, %params);
 459   _buyer_trade_party($self, %params);
 460
 461   if ($self->cusordnumber) {
 462     #     <ram:BuyerOrderReferencedDocument>
 463     $params{xml}->startTag("ram:BuyerOrderReferencedDocument");
 464     $params{xml}->dataElement("ram:IssuerAssignedID", _u8($self->cusordnumber));
 465     $params{xml}->endTag;
 466     #     </ram:BuyerOrderReferencedDocument>
 467   }
 468
 469   $params{xml}->endTag;
 470   #     </ram:ApplicableHeaderTradeAgreement>
 471 }
 472
 473 sub _applicable_header_trade_delivery {
 474   my ($self, %params) = @_;
 475
 476   #     <ram:ApplicableHeaderTradeDelivery>
 477   $params{xml}->startTag("ram:ApplicableHeaderTradeDelivery");
 478   #       <ram:ActualDeliverySupplyChainEvent>
 479   $params{xml}->startTag("ram:ActualDeliverySupplyChainEvent");
 480
 481   $params{xml}->startTag("ram:OccurrenceDateTime");
 482   $params{xml}->dataElement("udt:DateTimeString", ($self->deliverydate // $self->transdate)->strftime('%Y%m%d'), "format" => "102");
 483   $params{xml}->endTag;
 484
 485   $params{xml}->endTag;
 486   #       </ram:ActualDeliverySupplyChainEvent>
 487   $params{xml}->endTag;
 488   #     </ram:ApplicableHeaderTradeDelivery>
 489 }
 490
 491 sub _applicable_header_trade_settlement {
 492   my ($self, %params) = @_;
 493
 494   #     <ram:ApplicableHeaderTradeSettlement>
 495   $params{xml}->startTag("ram:ApplicableHeaderTradeSettlement");
 496   $params{xml}->dataElement("ram:InvoiceCurrencyCode", _u8(SL::Helper::ISO4217::map_currency_name_to_code($self->currency->name) // 'EUR'));
 497
 498   _taxes($self, %params);
 499   _payment_terms($self, %params);
 500   _totals($self, %params);
 501
 502   $params{xml}->endTag;
 503   #     </ram:ApplicableHeaderTradeSettlement>
 504 }
 505
 506 sub _supply_chain_trade_transaction {
 507   my ($self, %params) = @_;
 508
 509   #   <rsm:SupplyChainTradeTransaction>
 510   $params{xml}->startTag("rsm:SupplyChainTradeTransaction");
 511
 512   _included_supply_chain_trade_line_item($self, %params);
 513   _applicable_header_trade_agreement($self, %params);
 514   _applicable_header_trade_delivery($self, %params);
 515   _applicable_header_trade_settlement($self, %params);
 516
 517   $params{xml}->endTag;
 518   #   </rsm:SupplyChainTradeTransaction>
 519 }
 520
 521 sub _validate_data {
 522   my ($self) = @_;
 523
 524   my $prefix = $::locale->text('The ZUGFeRD invoice data cannot be generated because the data validation failed.') . ' ';
 525
 526   if (!$::instance_conf->get_co_ustid) {
 527     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('The VAT registration number is missing in the client configuration.'));
 528   }
 529
 530   if (!$::instance_conf->get_company || any { my $get = "get_address_$_"; !$::instance_conf->$get } qw(street1 zipcode city)) {
 531     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('The company\'s address information is incomplete in the client configuration.'));
 532   }
 533
 534   if ($::instance_conf->get_address_country && !SL::Helper::ISO3166::map_name_to_alpha_2_code($::instance_conf->get_address_country)) {
 535     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('The country from the company\'s address in the client configuration cannot be mapped to an ISO 3166-1 alpha 2 code.'));
 536   }
 537
 538   if ($self->customer->country && !SL::Helper::ISO3166::map_name_to_alpha_2_code($self->customer->country)) {
 539     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('The country from the customer\'s address cannot be mapped to an ISO 3166-1 alpha 2 code.'));
 540   }
 541
 542   if (!SL::Helper::ISO4217::map_currency_name_to_code($self->currency->name)) {
 543     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('The currency "#1" cannot be mapped to an ISO 4217 currency code.', $self->currency->name));
 544   }
 545
 546   my $failed_unit = first { !SL::Helper::UNECERecommendation20::map_name_to_code($_) } map { $_->unit } @{ $self->items };
 547   if ($failed_unit) {
 548     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('One of the units used (#1) cannot be mapped to a known unit code from the UN/ECE Recommendation 20 list.', $failed_unit));
 549   }
 550 }
 551
 552 sub create_zugferd_data {
 553   my ($self) = @_;
 554
 555   _validate_data($self);
 556
 557   my %ptc_data = $self->calculate_prices_and_taxes;
 558   my $output   = '';
 559   my $xml      = XML::Writer->new(
 560     OUTPUT      => \$output,
 561     DATA_MODE   => 1,
 562     DATA_INDENT => 2,
 563     ENCODING    => 'utf-8',
 564   );
 565
 566   my %params = (
 567     ptc_data => \%ptc_data,
 568     xml      => $xml,
 569   );
 570
 571   $xml->xmlDecl();
 572
 573   # <rsm:CrossIndustryInvoice>
 574   $xml->startTag("rsm:CrossIndustryInvoice",
 575                  "xmlns:a"   => "urn:un:unece:uncefact:data:standard:QualifiedDataType:100",
 576                  "xmlns:rsm" => "urn:un:unece:uncefact:data:standard:CrossIndustryInvoice:100",
 577                  "xmlns:qdt" => "urn:un:unece:uncefact:data:standard:QualifiedDataType:10",
 578                  "xmlns:ram" => "urn:un:unece:uncefact:data:standard:ReusableAggregateBusinessInformationEntity:100",
 579                  "xmlns:xs"  => "http://www.w3.org/2001/XMLSchema",
 580                  "xmlns:udt" => "urn:un:unece:uncefact:data:standard:UnqualifiedDataType:100");
 581
 582   _exchanged_document_context($self, %params);
 583   _exchanged_document($self, %params);
 584   _supply_chain_trade_transaction($self, %params);
 585
 586   $xml->endTag;
 587   # </rsm:CrossIndustryInvoice>
 588
 589   return $output;
 590 }
 591
 592 sub create_zugferd_xmp_data {
 593   my ($self) = @_;
 594
 595   return {
 596     conformance_level  => 'EXTENDED',
 597     document_file_name => 'ZUGFeRD-invoice.xml',
 598     document_type      => 'INVOICE',
 599     version            => '1.0',
 600   };
 601 }
 602
 603 1;