SL/DB/Invoice.pm

   1 package SL::DB::Invoice;
   2
   3 use strict;
   4
   5 use Carp;
   6 use List::Util qw(first sum);
   7
   8 use Rose::DB::Object::Helpers qw(has_loaded_related forget_related);
   9 use SL::DB::MetaSetup::Invoice;
  10 use SL::DB::Manager::Invoice;
  11 use SL::DB::Helper::Payment qw(:ALL);
  12 use SL::DB::Helper::AttrHTML;
  13 use SL::DB::Helper::AttrSorted;
  14 use SL::DB::Helper::FlattenToForm;
  15 use SL::DB::Helper::LinkedRecords;
  16 use SL::DB::Helper::PriceTaxCalculator;
  17 use SL::DB::Helper::PriceUpdater;
  18 use SL::DB::Helper::TransNumberGenerator;
  19 use SL::Locale::String qw(t8);
  20 use SL::DB::CustomVariable;
  21
  22 __PACKAGE__->meta->add_relationship(
  23   invoiceitems => {
  24     type         => 'one to many',
  25     class        => 'SL::DB::InvoiceItem',
  26     column_map   => { id => 'trans_id' },
  27     manager_args => {
  28       with_objects => [ 'part' ]
  29     }
  30   },
  31   storno_invoices => {
  32     type          => 'one to many',
  33     class         => 'SL::DB::Invoice',
  34     column_map    => { id => 'storno_id' },
  35   },
  36   sepa_export_items => {
  37     type            => 'one to many',
  38     class           => 'SL::DB::SepaExportItem',
  39     column_map      => { id => 'ar_id' },
  40     manager_args    => { with_objects => [ 'sepa_export' ] }
  41   },
  42   sepa_exports      => {
  43     type            => 'many to many',
  44     map_class       => 'SL::DB::SepaExportItem',
  45     map_from        => 'ar',
  46     map_to          => 'sepa_export',
  47   },
  48   custom_shipto     => {
  49     type            => 'one to one',
  50     class           => 'SL::DB::Shipto',
  51     column_map      => { id => 'trans_id' },
  52     query_args      => [ module => 'AR' ],
  53   },
  54   transactions   => {
  55     type         => 'one to many',
  56     class        => 'SL::DB::AccTransaction',
  57     column_map   => { id => 'trans_id' },
  58     manager_args => {
  59       with_objects => [ 'chart' ],
  60       sort_by      => 'acc_trans_id ASC',
  61     },
  62   },
  63   dunnings       => {
  64     type         => 'one to many',
  65     class        => 'SL::DB::Dunning',
  66     column_map   => { id => 'trans_id' },
  67     manager_args => { with_objects => [ 'dunnings' ] }
  68   },
  69 );
  70
  71 __PACKAGE__->meta->initialize;
  72
  73 __PACKAGE__->attr_html('notes');
  74 __PACKAGE__->attr_sorted('items');
  75
  76 __PACKAGE__->before_save('_before_save_set_invnumber');
  77
  78 # hooks
  79
  80 sub _before_save_set_invnumber {
  81   my ($self) = @_;
  82
  83   $self->create_trans_number if !$self->invnumber;
  84
  85   return 1;
  86 }
  87
  88 # methods
  89
  90 sub items { goto &invoiceitems; }
  91 sub add_items { goto &add_invoiceitems; }
  92 sub record_number { goto &invnumber; };
  93
  94 sub is_sales {
  95   # For compatibility with Order, DeliveryOrder
  96   croak 'not an accessor' if @_ > 1;
  97   return 1;
  98 }
  99
 100 # it is assumed, that ordnumbers are unique here.
 101 sub first_order_by_ordnumber {
 102   my $self = shift;
 103
 104   my $orders = SL::DB::Manager::Order->get_all(
 105     query => [
 106       ordnumber => $self->ordnumber,
 107
 108     ],
 109   );
 110
 111   return first { $_->is_type('sales_order') } @{ $orders };
 112 }
 113
 114 sub abschlag_percentage {
 115   my $self         = shift;
 116   my $order        = $self->first_order_by_ordnumber or return;
 117   my $order_amount = $order->netamount               or return;
 118   return $self->abschlag
 119     ? $self->netamount / $order_amount
 120     : undef;
 121 }
 122
 123 sub taxamount {
 124   my $self = shift;
 125   die 'not a setter method' if @_;
 126
 127   return ($self->amount || 0) - ($self->netamount || 0);
 128 }
 129
 130 __PACKAGE__->meta->make_attr_helpers(taxamount => 'numeric(15,5)');
 131
 132 sub closed {
 133   my ($self) = @_;
 134   return $self->paid >= $self->amount;
 135 }
 136
 137 sub _clone_orderitem_delivery_order_item_cvar {
 138   my ($cvar) = @_;
 139
 140   my $cloned = $_->clone_and_reset;
 141   $cloned->sub_module('invoice');
 142
 143   return $cloned;
 144 }
 145
 146 sub new_from {
 147   my ($class, $source, %params) = @_;
 148
 149   croak("Unsupported source object type '" . ref($source) . "'") unless ref($source) =~ m/^ SL::DB:: (?: Order | DeliveryOrder ) $/x;
 150   croak("Cannot create invoices for purchase records")           unless $source->customer_id;
 151
 152   require SL::DB::Employee;
 153
 154   my (@columns, @item_columns, $item_parent_id_column, $item_parent_column);
 155
 156   if (ref($source) eq 'SL::DB::Order') {
 157     @columns      = qw(quonumber delivery_customer_id delivery_vendor_id);
 158     @item_columns = qw(subtotal);
 159
 160     $item_parent_id_column = 'trans_id';
 161     $item_parent_column    = 'order';
 162
 163   } else {
 164     @columns      = qw(donumber);
 165
 166     $item_parent_id_column = 'delivery_order_id';
 167     $item_parent_column    = 'delivery_order';
 168   }
 169
 170   my $terms = $source->can('payment_id') ? $source->payment_terms : undef;
 171   $terms = $source->customer->payment_terms if !defined $terms && $source->customer;
 172
 173   my %args = ( map({ ( $_ => $source->$_ ) } qw(customer_id taxincluded shippingpoint shipvia notes intnotes salesman_id cusordnumber ordnumber department_id
 174                                                 cp_id language_id taxzone_id globalproject_id transaction_description currency_id delivery_term_id), @columns),
 175                transdate   => DateTime->today_local,
 176                gldate      => DateTime->today_local,
 177                duedate     => $terms ? $terms->calc_date(reference_date => DateTime->today_local) : DateTime->today_local,
 178                invoice     => 1,
 179                type        => 'invoice',
 180                storno      => 0,
 181                paid        => 0,
 182                employee_id => (SL::DB::Manager::Employee->current || SL::DB::Employee->new(id => $source->employee_id))->id,
 183             );
 184
 185   $args{payment_id} = ( $terms ? $terms->id : $source->payment_id);
 186
 187   if ($source->type =~ /_delivery_order$/) {
 188     $args{deliverydate} = $source->reqdate;
 189     if (my $order = SL::DB::Manager::Order->find_by(ordnumber => $source->ordnumber)) {
 190       $args{orddate}    = $order->transdate;
 191     }
 192
 193   } elsif ($source->type =~ /_order$/) {
 194     $args{deliverydate} = $source->reqdate;
 195     $args{orddate}      = $source->transdate;
 196
 197   } else {
 198     $args{quodate}      = $source->transdate;
 199   }
 200
 201   # Custom shipto addresses (the ones specific to the sales/purchase
 202   # record and not to the customer/vendor) are only linked from shipto
 203   # → ar. Meaning ar.shipto_id will not be filled in that
 204   # case.
 205   if (!$source->shipto_id && $source->id) {
 206     $args{custom_shipto} = $source->custom_shipto->clone($class) if $source->can('custom_shipto') && $source->custom_shipto;
 207
 208   } else {
 209     $args{shipto_id} = $source->shipto_id;
 210   }
 211
 212   my $invoice = $class->new(%args);
 213   $invoice->assign_attributes(%{ $params{attributes} }) if $params{attributes};
 214   my $items   = delete($params{items}) || $source->items_sorted;
 215   my %item_parents;
 216
 217   my @items = map {
 218     my $source_item      = $_;
 219     my $source_item_id   = $_->$item_parent_id_column;
 220     my @custom_variables = map { _clone_orderitem_delivery_order_item_cvar($_) } @{ $source_item->custom_variables };
 221
 222     $item_parents{$source_item_id} ||= $source_item->$item_parent_column;
 223     my $item_parent                  = $item_parents{$source_item_id};
 224     my $current_invoice_item =
 225       SL::DB::InvoiceItem->new(map({ ( $_ => $source_item->$_ ) }
 226                                    qw(parts_id description qty sellprice discount project_id serialnumber pricegroup_id transdate cusordnumber unit
 227                                       base_qty longdescription lastcost price_factor_id active_discount_source active_price_source), @item_columns),
 228                                deliverydate     => $source_item->reqdate,
 229                                fxsellprice      => $source_item->sellprice,
 230                                custom_variables => \@custom_variables,
 231                                ordnumber        => ref($item_parent) eq 'SL::DB::Order'         ? $item_parent->ordnumber : $source_item->ordnumber,
 232                                donumber         => ref($item_parent) eq 'SL::DB::DeliveryOrder' ? $item_parent->donumber  : $source_item->can('donumber') ? $source_item->donumber : '',
 233                              );
 234
 235     $current_invoice_item->{"converted_from_orderitems_id"}           = $_->{id} if ref($item_parent) eq 'SL::DB::Order';
 236     $current_invoice_item->{"converted_from_delivery_order_items_id"} = $_->{id} if ref($item_parent) eq 'SL::DB::DeliveryOrder';
 237     $current_invoice_item;
 238   } @{ $items };
 239
 240   @items = grep { $params{item_filter}->($_) } @items if $params{item_filter};
 241   @items = grep { $_->qty * 1 } @items if $params{skip_items_zero_qty};
 242   @items = grep { $_->qty >=0 } @items if $params{skip_items_negative_qty};
 243
 244   $invoice->invoiceitems(\@items);
 245
 246   return $invoice;
 247 }
 248
 249 sub post {
 250   my ($self, %params) = @_;
 251
 252   die "not an invoice" unless $self->invoice;
 253
 254   require SL::DB::Chart;
 255   if (!$params{ar_id}) {
 256     my $chart;
 257     if ($::instance_conf->get_ar_chart_id) {
 258       $chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_ar_chart_id);
 259     } else {
 260       $chart = SL::DB::Manager::Chart->get_all(query   => [ SL::DB::Manager::Chart->link_filter('AR') ],
 261                                                sort_by => 'id ASC',
 262                                                limit   => 1)->[0];
 263     };
 264     croak("No AR chart found and no parameter 'ar_id' given") unless $chart;
 265     $params{ar_id} = $chart->id;
 266   }
 267
 268   if (!$self->db->with_transaction(sub {
 269     my %data = $self->calculate_prices_and_taxes;
 270
 271     $self->_post_create_assemblyitem_entries($data{assembly_items});
 272     $self->save;
 273
 274     $self->_post_add_acctrans($data{amounts_cogs});
 275     $self->_post_add_acctrans($data{amounts});
 276     $self->_post_add_acctrans($data{taxes});
 277
 278     $self->_post_add_acctrans({ $params{ar_id} => $self->amount * -1 });
 279
 280     $self->_post_update_allocated($data{allocated});
 281
 282     $self->_post_book_rounding($data{rounding});
 283
 284     1;
 285   })) {
 286     $::lxdebug->message(LXDebug->WARN(), "convert_to_invoice failed: " . join("\n", (split(/\n/, $self->db->error))[0..2]));
 287     return undef;
 288   }
 289
 290   return $self;
 291 }
 292
 293 sub _post_add_acctrans {
 294   my ($self, $entries) = @_;
 295
 296   my $default_tax_id = SL::DB::Manager::Tax->find_by(taxkey => 0)->id;
 297   my $chart_link;
 298
 299   require SL::DB::AccTransaction;
 300   require SL::DB::Chart;
 301   while (my ($chart_id, $spec) = each %{ $entries }) {
 302     $spec = { taxkey => 0, tax_id => $default_tax_id, amount => $spec } unless ref $spec;
 303     $chart_link = SL::DB::Manager::Chart->find_by(id => $chart_id)->{'link'};
 304     $chart_link ||= '';
 305
 306     SL::DB::AccTransaction->new(trans_id   => $self->id,
 307                                 chart_id   => $chart_id,
 308                                 amount     => $spec->{amount},
 309                                 tax_id     => $spec->{tax_id},
 310                                 taxkey     => $spec->{taxkey},
 311                                 project_id => $self->globalproject_id,
 312                                 transdate  => $self->transdate,
 313                                 chart_link => $chart_link)->save;
 314   }
 315 }
 316
 317 sub _post_book_rounding {
 318   my ($self, $rounding) = @_;
 319
 320   my $tax_id = SL::DB::Manager::Tax->find_by(taxkey => 0)->id;
 321   my $rnd_accno = $rounding == 0 ? 0
 322                 : $rounding > 0  ? SL::DB::Default->get->rndgain_accno_id
 323                 :                  SL::DB::Default->get->rndloss_accno_id
 324   ;
 325   if ($rnd_accno != 0) {
 326     SL::DB::AccTransaction->new(trans_id   => $self->id,
 327                                 chart_id   => $rnd_accno,
 328                                 amount     => $rounding,
 329                                 tax_id     => $tax_id,
 330                                 taxkey     => 0,
 331                                 project_id => $self->globalproject_id,
 332                                 transdate  => $self->transdate,
 333                                 chart_link => $rnd_accno)->save;
 334   }
 335 }
 336
 337 sub add_ar_amount_row {
 338   my ($self, %params ) = @_;
 339
 340   # only allow this method for ar invoices (Debitorenbuchung)
 341   die "not an ar invoice" if $self->invoice and not $self->customer_id;
 342
 343   die "add_ar_amount_row needs a chart object as chart param" unless $params{chart} && $params{chart}->isa('SL::DB::Chart');
 344   die "chart must be an AR_amount chart" unless $params{chart}->link =~ /AR_amount/;
 345
 346   my $acc_trans = [];
 347
 348   my $roundplaces = 2;
 349   my ($netamount,$taxamount);
 350
 351   $netamount = $params{amount} * 1;
 352   my $tax = SL::DB::Manager::Tax->find_by(id => $params{tax_id}) || die "Can't find tax with id " . $params{tax_id};
 353
 354   if ( $tax and $tax->rate != 0 ) {
 355     ($netamount, $taxamount) = Form->calculate_tax($params{amount}, $tax->rate, $self->taxincluded, $roundplaces);
 356   };
 357   next unless $netamount; # netamount mustn't be zero
 358
 359   my $sign = $self->customer_id ? 1 : -1;
 360   my $acc = SL::DB::AccTransaction->new(
 361     amount     => $netamount * $sign,
 362     chart_id   => $params{chart}->id,
 363     chart_link => $params{chart}->link,
 364     transdate  => $self->transdate,
 365     taxkey     => $tax->taxkey,
 366     tax_id     => $tax->id,
 367     project_id => $params{project_id},
 368   );
 369
 370   $self->add_transactions( $acc );
 371   push( @$acc_trans, $acc );
 372
 373   if ( $taxamount ) {
 374      my $acc = SL::DB::AccTransaction->new(
 375        amount     => $taxamount * $sign,
 376        chart_id   => $tax->chart_id,
 377        chart_link => $tax->chart->link,
 378        transdate  => $self->transdate,
 379        taxkey     => $tax->taxkey,
 380        tax_id     => $tax->id,
 381      );
 382      $self->add_transactions( $acc );
 383      push( @$acc_trans, $acc );
 384   };
 385   return $acc_trans;
 386 };
 387
 388 sub create_ar_row {
 389   my ($self, %params) = @_;
 390   # to be called after adding all AR_amount rows, adds an AR row
 391
 392   # only allow this method for ar invoices (Debitorenbuchung)
 393   die if $self->invoice and not $self->customer_id;
 394   die "create_ar_row needs a chart object as a parameter" unless $params{chart} and ref($params{chart}) eq 'SL::DB::Chart';
 395
 396   my @transactions = @{$self->transactions};
 397   # die "invoice has no acc_transactions" unless scalar @transactions > 0;
 398   return 0 unless scalar @transactions > 0;
 399
 400   my $chart = $params{chart} || SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_ar_chart_id);
 401   die "illegal chart in create_ar_row" unless $chart;
 402
 403   die "receivables chart must have link 'AR'" unless $chart->link eq 'AR';
 404
 405   my $acc_trans = [];
 406
 407   # hardcoded entry for no tax: tax_id and taxkey should be 0
 408   my $tax = SL::DB::Manager::Tax->find_by(id => 0, taxkey => 0) || die "Can't find tax with id 0 and taxkey 0";
 409
 410   my $sign = $self->customer_id ? -1 : 1;
 411   my $acc = SL::DB::AccTransaction->new(
 412     amount     => $self->amount * $sign,
 413     chart_id   => $params{chart}->id,
 414     chart_link => $params{chart}->link,
 415     transdate  => $self->transdate,
 416     taxkey     => $tax->taxkey,
 417     tax_id     => $tax->id,
 418   );
 419   $self->add_transactions( $acc );
 420   push( @$acc_trans, $acc );
 421   return $acc_trans;
 422 };
 423
 424 sub validate_acc_trans {
 425   my ($self, %params) = @_;
 426   # should be able to check unsaved invoice objects with several acc_trans lines
 427
 428   die "validate_acc_trans can't check invoice object with empty transactions" unless $self->transactions;
 429
 430   my @transactions = @{$self->transactions};
 431   # die "invoice has no acc_transactions" unless scalar @transactions > 0;
 432   return 0 unless scalar @transactions > 0;
 433   return 0 unless $self->has_loaded_related('transactions');
 434   if ( $params{debug} ) {
 435     printf("starting validatation of invoice %s with trans_id %s and taxincluded %s\n", $self->invnumber, $self->id, $self->taxincluded);
 436     foreach my $acc ( @transactions ) {
 437       printf("chart: %s  amount: %s   tax_id: %s  link: %s\n", $acc->chart->accno, $acc->amount, $acc->tax_id, $acc->chart->link);
 438     };
 439   };
 440
 441   my $acc_trans_sum = sum map { $_->amount } @transactions;
 442
 443   unless ( $::form->round_amount($acc_trans_sum, 10) == 0 ) {
 444     my $string = "sum of acc_transactions isn't 0: $acc_trans_sum\n";
 445
 446     if ( $params{debug} ) {
 447       foreach my $trans ( @transactions ) {
 448           $string .= sprintf("  %s %s %s\n", $trans->chart->accno, $trans->taxkey, $trans->amount);
 449       };
 450     };
 451     return 0;
 452   };
 453
 454   # only use the first AR entry, so it also works for paid invoices
 455   my @ar_transactions = map { $_->amount } grep { $_->chart_link eq 'AR' } @transactions;
 456   my $ar_sum = $ar_transactions[0];
 457   # my $ar_sum = sum map { $_->amount } grep { $_->chart_link eq 'AR' } @transactions;
 458
 459   unless ( $::form->round_amount($ar_sum * -1,2) == $::form->round_amount($self->amount,2) ) {
 460     if ( $params{debug} ) {
 461       printf("debug: (ar_sum) %s = %s (amount)\n",  $::form->round_amount($ar_sum * -1,2) , $::form->round_amount($self->amount, 2) );
 462       foreach my $trans ( @transactions ) {
 463         printf("  %s %s %s %s\n", $trans->chart->accno, $trans->taxkey, $trans->amount, $trans->chart->link);
 464       };
 465     };
 466     die sprintf("sum of ar (%s) isn't equal to invoice amount (%s)", $::form->round_amount($ar_sum * -1,2), $::form->round_amount($self->amount,2));
 467   };
 468
 469   return 1;
 470 };
 471
 472 sub recalculate_amounts {
 473   my ($self, %params) = @_;
 474   # calculate and set amount and netamount from acc_trans objects
 475
 476   croak ("Can only recalculate amounts for ar transactions") if $self->invoice;
 477
 478   return undef unless $self->has_loaded_related('transactions');
 479
 480   my ($netamount, $taxamount);
 481
 482   my @transactions = @{$self->transactions};
 483
 484   foreach my $acc ( @transactions ) {
 485     $netamount += $acc->amount if $acc->chart->link =~ /AR_amount/;
 486     $taxamount += $acc->amount if $acc->chart->link =~ /AR_tax/;
 487   };
 488
 489   $self->amount($netamount+$taxamount);
 490   $self->netamount($netamount);
 491 };
 492
 493
 494 sub _post_create_assemblyitem_entries {
 495   my ($self, $assembly_entries) = @_;
 496
 497   my $items = $self->invoiceitems;
 498   my @new_items;
 499
 500   my $item_idx = 0;
 501   foreach my $item (@{ $items }) {
 502     next if $item->assemblyitem;
 503
 504     push @new_items, $item;
 505     $item_idx++;
 506
 507     foreach my $assembly_item (@{ $assembly_entries->[$item_idx] || [ ] }) {
 508       push @new_items, SL::DB::InvoiceItem->new(parts_id     => $assembly_item->{part},
 509                                                 description  => $assembly_item->{part}->description,
 510                                                 unit         => $assembly_item->{part}->unit,
 511                                                 qty          => $assembly_item->{qty},
 512                                                 allocated    => $assembly_item->{allocated},
 513                                                 sellprice    => 0,
 514                                                 fxsellprice  => 0,
 515                                                 assemblyitem => 't');
 516     }
 517   }
 518
 519   $self->invoiceitems(\@new_items);
 520 }
 521
 522 sub _post_update_allocated {
 523   my ($self, $allocated) = @_;
 524
 525   while (my ($invoice_id, $diff) = each %{ $allocated }) {
 526     SL::DB::Manager::InvoiceItem->update_all(set   => { allocated => { sql => "allocated + $diff" } },
 527                                              where => [ id        => $invoice_id ]);
 528   }
 529 }
 530
 531 sub invoice_type {
 532   my ($self) = @_;
 533
 534   return 'ar_transaction'     if !$self->invoice;
 535   return 'credit_note'        if $self->type eq 'credit_note' && $self->amount < 0 && !$self->storno;
 536   return 'invoice_storno'     if $self->type ne 'credit_note' && $self->amount < 0 &&  $self->storno;
 537   return 'credit_note_storno' if $self->type eq 'credit_note' && $self->amount > 0 &&  $self->storno;
 538   return 'invoice';
 539 }
 540
 541 sub displayable_state {
 542   my $self = shift;
 543
 544   return $self->closed ? $::locale->text('closed') : $::locale->text('open');
 545 }
 546
 547 sub displayable_type {
 548   my ($self) = @_;
 549
 550   return t8('AR Transaction')                         if $self->invoice_type eq 'ar_transaction';
 551   return t8('Credit Note')                            if $self->invoice_type eq 'credit_note';
 552   return t8('Invoice') . "(" . t8('Storno') . ")"     if $self->invoice_type eq 'invoice_storno';
 553   return t8('Credit Note') . "(" . t8('Storno') . ")" if $self->invoice_type eq 'credit_note_storno';
 554   return t8('Invoice');
 555 }
 556
 557 sub displayable_name {
 558   join ' ', grep $_, map $_[0]->$_, qw(displayable_type record_number);
 559 };
 560
 561 sub abbreviation {
 562   my ($self) = @_;
 563
 564   return t8('AR Transaction (abbreviation)')         if $self->invoice_type eq 'ar_transaction';
 565   return t8('Credit note (one letter abbreviation)') if $self->invoice_type eq 'credit_note';
 566   return t8('Invoice (one letter abbreviation)') . "(" . t8('Storno (one letter abbreviation)') . ")" if $self->invoice_type eq 'invoice_storno';
 567   return t8('Credit note (one letter abbreviation)') . "(" . t8('Storno (one letter abbreviation)') . ")"  if $self->invoice_type eq 'credit_note_storno';
 568   return t8('Invoice (one letter abbreviation)');
 569 }
 570
 571 sub oneline_summary {
 572   my $self = shift;
 573
 574   return sprintf("%s: %s %s %s (%s)", $self->abbreviation, $self->invnumber, $self->customer->name,
 575                                       $::form->format_amount(\%::myconfig, $self->amount,2), $self->transdate->to_kivitendo);
 576 }
 577
 578 sub date {
 579   goto &transdate;
 580 }
 581
 582 sub reqdate {
 583   goto &duedate;
 584 }
 585
 586 sub customervendor {
 587   goto &customer;
 588 }
 589
 590 sub link {
 591   my ($self) = @_;
 592
 593   my $html;
 594   $html   = $self->presenter->sales_invoice(display => 'inline') if $self->invoice;
 595   $html   = $self->presenter->ar_transaction(display => 'inline') if !$self->invoice;
 596
 597   return $html;
 598 }
 599
 600 sub mark_as_paid {
 601   my ($self) = @_;
 602
 603   $self->update_attributes(paid => $self->amount);
 604 }
 605
 606 1;
 607
 608 __END__
 609
 610 =pod
 611
 612 =encoding UTF-8
 613
 614 =head1 NAME
 615
 616 SL::DB::Invoice: Rose model for invoices (table "ar")
 617
 618 =head1 FUNCTIONS
 619
 620 =over 4
 621
 622 =item C<new_from $source, %params>
 623
 624 Creates a new C<SL::DB::Invoice> instance and copies as much
 625 information from C<$source> as possible. At the moment only sales
 626 orders and sales quotations are supported as sources.
 627
 628 The conversion copies order items into invoice items. Dates are copied
 629 as appropriate, e.g. the C<transdate> field from an order will be
 630 copied into the invoice's C<orddate> field.
 631
 632 C<%params> can include the following options:
 633
 634 =over 2
 635
 636 =item C<items>
 637
 638 An optional array reference of RDBO instances for the items to use. If
 639 missing then the method C<items_sorted> will be called on
 640 C<$source>. This option can be used to override the sorting, to
 641 exclude certain positions or to add additional ones.
 642
 643 =item C<skip_items_negative_qty>
 644
 645 If trueish then items with a negative quantity are skipped. Items with
 646 a quantity of 0 are not affected by this option.
 647
 648 =item C<skip_items_zero_qty>
 649
 650 If trueish then items with a quantity of 0 are skipped.
 651
 652 =item C<item_filter>
 653
 654 An optional code reference that is called for each item with the item
 655 as its sole parameter. Items for which the code reference returns a
 656 falsish value will be skipped.
 657
 658 =item C<attributes>
 659
 660 An optional hash reference. If it exists then it is passed to C<new>
 661 allowing the caller to set certain attributes for the new invoice.
 662 For example to set a different transdate (default is the current date),
 663 call the method like this:
 664
 665    my %params;
 666    $params{attributes}{transdate} = '28.08.2015';
 667    $invoice = SL::DB::Invoice->new_from($self, %params)->post || die;
 668
 669 =back
 670
 671 Amounts, prices and taxes are not
 672 calculated. L<SL::DB::Helper::PriceTaxCalculator::calculate_prices_and_taxes>
 673 can be used for this.
 674
 675 The object returned is not saved.
 676
 677 =item C<post %params>
 678
 679 Posts the invoice. Required parameters are:
 680
 681 =over 2
 682
 683 =item * C<ar_id>
 684
 685 The ID of the accounts receivable chart the invoice's amounts are
 686 posted to. If it is not set then the first chart configured for
 687 accounts receivables is used.
 688
 689 =back
 690
 691 This function implements several steps:
 692
 693 =over 2
 694
 695 =item 1. It calculates all prices, amounts and taxes by calling
 696 L<SL::DB::Helper::PriceTaxCalculator::calculate_prices_and_taxes>.
 697
 698 =item 2. A new and unique invoice number is created.
 699
 700 =item 3. All amounts for costs of goods sold are recorded in
 701 C<acc_trans>.
 702
 703 =item 4. All amounts for parts, services and assemblies are recorded
 704 in C<acc_trans> with their respective charts. This is determined by
 705 the part's buchungsgruppen.
 706
 707 =item 5. The total amount is posted to the accounts receivable chart
 708 and recorded in C<acc_trans>.
 709
 710 =item 6. Items in C<invoice> are updated according to their allocation
 711 status (regarding costs of goods sold). Will only be done if
 712 kivitendo is not configured to use Einnahmenüberschussrechnungen.
 713
 714 =item 7. The invoice and its items are saved.
 715
 716 =back
 717
 718 Returns C<$self> on success and C<undef> on failure. The whole process
 719 is run inside a transaction. If it fails then nothing is saved to or
 720 changed in the database. A new transaction is only started if none are
 721 active.
 722
 723 =item C<basic_info $field>
 724
 725 See L<SL::DB::Object::basic_info>.
 726
 727 =item C<closed>
 728
 729 Returns 1 or 0, depending on whether the invoice is closed or not. Currently
 730 invoices that are overpaid also count as closed and credit notes in general.
 731
 732 =item C<recalculate_amounts %params>
 733
 734 Calculate and set amount and netamount from acc_trans objects by summing up the
 735 values of acc_trans objects with AR_amount and AR_tax link charts.
 736 amount and netamount are set to the calculated values.
 737
 738 =item C<validate_acc_trans>
 739
 740 Checks if the sum of all associated acc_trans objects is 0 and checks whether
 741 the amount of the AR acc_transaction matches the AR amount. Only the first AR
 742 line is checked, because the sum of all AR lines is 0 for paid invoices.
 743
 744 Returns 0 or 1.
 745
 746 Can be called with a debug parameter which writes debug info to STDOUT, which is
 747 useful in console mode or while writing tests.
 748
 749  my $ar = SL::DB::Manager::Invoice->get_first();
 750  $ar->validate_acc_trans(debug => 1);
 751
 752 =item C<create_ar_row %params>
 753
 754 Creates a new acc_trans entry for the receivable (AR) entry of an existing AR
 755 invoice object, which already has some income and tax acc_trans entries.
 756
 757 The acc_trans entry is also returned inside an array ref.
 758
 759 Mandatory params are
 760
 761 =over 2
 762
 763 =item * chart as an RDBO object, e.g. for bank. Must be a 'paid' chart.
 764
 765 =back
 766
 767 Currently the amount of the invoice object is used for the acc_trans amount.
 768 Use C<recalculate_amounts> before calling this method if amount isn't known
 769 yet or you didn't set it manually.
 770
 771 =item C<add_ar_amount_row %params>
 772
 773 Add a new entry for an existing AR invoice object. Creates an acc_trans entry,
 774 and also adds an acc_trans tax entry, if the tax has an associated tax chart.
 775 Also all acc_trans entries that were created are returned inside an array ref.
 776
 777 Mandatory params are
 778
 779 =over 2
 780
 781 =item * chart as an RDBO object, should be an income chart (link = AR_amount)
 782
 783 =item * tax_id
 784
 785 =item * amount
 786
 787 =back
 788
 789 =item C<mark_as_paid>
 790
 791 Marks the invoice as paid by setting its C<paid> member to the value of C<amount>.
 792
 793 =back
 794
 795 =head1 TODO
 796
 797  As explained in the new_from example, it is possible to set transdate to a new value.
 798  From a user / programm point of view transdate is more than holy and there should be
 799  some validity checker available for controller code. At least the same logic like in
 800  Form.pm from ar.pl should be available:
 801   # see old stuff ar.pl post
 802   #$form->error($locale->text('Cannot post transaction above the maximum future booking date!'))
 803   #  if ($form->date_max_future($transdate, \%myconfig));
 804   #$form->error($locale->text('Cannot post transaction for a closed period!')) if ($form->date_closed($form->{"transdate"}, \%myconfig));
 805
 806 =head1 AUTHOR
 807
 808 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 809
 810 =cut