SL/DB/Invoice.pm

   1 package SL::DB::Invoice;
   2
   3 use strict;
   4
   5 use Carp;
   6 use List::Util qw(first sum);
   7
   8 use Rose::DB::Object::Helpers qw(has_loaded_related forget_related);
   9 use SL::DB::MetaSetup::Invoice;
  10 use SL::DB::Manager::Invoice;
  11 use SL::DB::Helper::Payment qw(:ALL);
  12 use SL::DB::Helper::AttrHTML;
  13 use SL::DB::Helper::AttrSorted;
  14 use SL::DB::Helper::FlattenToForm;
  15 use SL::DB::Helper::LinkedRecords;
  16 use SL::DB::Helper::PriceTaxCalculator;
  17 use SL::DB::Helper::PriceUpdater;
  18 use SL::DB::Helper::TransNumberGenerator;
  19 use SL::Locale::String qw(t8);
  20 use SL::DB::CustomVariable;
  21
  22 __PACKAGE__->meta->add_relationship(
  23   invoiceitems => {
  24     type         => 'one to many',
  25     class        => 'SL::DB::InvoiceItem',
  26     column_map   => { id => 'trans_id' },
  27     manager_args => {
  28       with_objects => [ 'part' ]
  29     }
  30   },
  31   storno_invoices => {
  32     type          => 'one to many',
  33     class         => 'SL::DB::Invoice',
  34     column_map    => { id => 'storno_id' },
  35   },
  36   sepa_export_items => {
  37     type            => 'one to many',
  38     class           => 'SL::DB::SepaExportItem',
  39     column_map      => { id => 'ar_id' },
  40     manager_args    => { with_objects => [ 'sepa_export' ] }
  41   },
  42   sepa_exports      => {
  43     type            => 'many to many',
  44     map_class       => 'SL::DB::SepaExportItem',
  45     map_from        => 'ar',
  46     map_to          => 'sepa_export',
  47   },
  48   custom_shipto     => {
  49     type            => 'one to one',
  50     class           => 'SL::DB::Shipto',
  51     column_map      => { id => 'trans_id' },
  52     query_args      => [ module => 'AR' ],
  53   },
  54   transactions   => {
  55     type         => 'one to many',
  56     class        => 'SL::DB::AccTransaction',
  57     column_map   => { id => 'trans_id' },
  58     manager_args => {
  59       with_objects => [ 'chart' ],
  60       sort_by      => 'acc_trans_id ASC',
  61     },
  62   },
  63   dunnings       => {
  64     type         => 'one to many',
  65     class        => 'SL::DB::Dunning',
  66     column_map   => { id => 'trans_id' },
  67     manager_args => { with_objects => [ 'dunnings' ] }
  68   },
  69 );
  70
  71 __PACKAGE__->meta->initialize;
  72
  73 __PACKAGE__->attr_html('notes');
  74 __PACKAGE__->attr_sorted('items');
  75
  76 __PACKAGE__->before_save('_before_save_set_invnumber');
  77
  78 # hooks
  79
  80 sub _before_save_set_invnumber {
  81   my ($self) = @_;
  82
  83   $self->create_trans_number if !$self->invnumber;
  84
  85   return 1;
  86 }
  87
  88 # methods
  89
  90 sub items { goto &invoiceitems; }
  91 sub add_items { goto &add_invoiceitems; }
  92 sub record_number { goto &invnumber; };
  93
  94 sub is_sales {
  95   # For compatibility with Order, DeliveryOrder
  96   croak 'not an accessor' if @_ > 1;
  97   return 1;
  98 }
  99
 100 # it is assumed, that ordnumbers are unique here.
 101 sub first_order_by_ordnumber {
 102   my $self = shift;
 103
 104   my $orders = SL::DB::Manager::Order->get_all(
 105     query => [
 106       ordnumber => $self->ordnumber,
 107
 108     ],
 109   );
 110
 111   return first { $_->is_type('sales_order') } @{ $orders };
 112 }
 113
 114 sub abschlag_percentage {
 115   my $self         = shift;
 116   my $order        = $self->first_order_by_ordnumber or return;
 117   my $order_amount = $order->netamount               or return;
 118   return $self->abschlag
 119     ? $self->netamount / $order_amount
 120     : undef;
 121 }
 122
 123 sub taxamount {
 124   my $self = shift;
 125   die 'not a setter method' if @_;
 126
 127   return ($self->amount || 0) - ($self->netamount || 0);
 128 }
 129
 130 __PACKAGE__->meta->make_attr_helpers(taxamount => 'numeric(15,5)');
 131
 132 sub closed {
 133   my ($self) = @_;
 134   return $self->paid >= $self->amount;
 135 }
 136
 137 sub _clone_orderitem_delivery_order_item_cvar {
 138   my ($cvar) = @_;
 139
 140   my $cloned = $_->clone_and_reset;
 141   $cloned->sub_module('invoice');
 142
 143   return $cloned;
 144 }
 145
 146 sub new_from {
 147   my ($class, $source, %params) = @_;
 148
 149   croak("Unsupported source object type '" . ref($source) . "'") unless ref($source) =~ m/^ SL::DB:: (?: Order | DeliveryOrder ) $/x;
 150   croak("Cannot create invoices for purchase records")           unless $source->customer_id;
 151
 152   require SL::DB::Employee;
 153
 154   my (@columns, @item_columns, $item_parent_id_column, $item_parent_column);
 155
 156   if (ref($source) eq 'SL::DB::Order') {
 157     @columns      = qw(quonumber delivery_customer_id delivery_vendor_id);
 158     @item_columns = qw(subtotal);
 159
 160     $item_parent_id_column = 'trans_id';
 161     $item_parent_column    = 'order';
 162
 163   } else {
 164     @columns      = qw(donumber);
 165
 166     $item_parent_id_column = 'delivery_order_id';
 167     $item_parent_column    = 'delivery_order';
 168   }
 169
 170   my $terms = $source->can('payment_id') ? $source->payment_terms : undef;
 171   $terms = $source->customer->payment_terms if !defined $terms && $source->customer;
 172
 173   my %args = ( map({ ( $_ => $source->$_ ) } qw(customer_id taxincluded shippingpoint shipvia notes intnotes salesman_id cusordnumber ordnumber department_id
 174                                                 cp_id language_id taxzone_id globalproject_id transaction_description currency_id delivery_term_id), @columns),
 175                transdate   => DateTime->today_local,
 176                gldate      => DateTime->today_local,
 177                duedate     => $terms ? $terms->calc_date(reference_date => DateTime->today_local) : DateTime->today_local,
 178                invoice     => 1,
 179                type        => 'invoice',
 180                storno      => 0,
 181                paid        => 0,
 182                employee_id => (SL::DB::Manager::Employee->current || SL::DB::Employee->new(id => $source->employee_id))->id,
 183             );
 184
 185   $args{payment_id} = ( $terms ? $terms->id : $source->payment_id);
 186
 187   if ($source->type =~ /_delivery_order$/) {
 188     $args{deliverydate} = $source->reqdate;
 189     if (my $order = SL::DB::Manager::Order->find_by(ordnumber => $source->ordnumber)) {
 190       $args{orddate}    = $order->transdate;
 191     }
 192
 193   } elsif ($source->type =~ /_order$/) {
 194     $args{deliverydate} = $source->reqdate;
 195     $args{orddate}      = $source->transdate;
 196
 197   } else {
 198     $args{quodate}      = $source->transdate;
 199   }
 200
 201   # Custom shipto addresses (the ones specific to the sales/purchase
 202   # record and not to the customer/vendor) are only linked from shipto
 203   # → ar. Meaning ar.shipto_id will not be filled in that
 204   # case.
 205   if (!$source->shipto_id && $source->id) {
 206     $args{custom_shipto} = $source->custom_shipto->clone($class) if $source->can('custom_shipto') && $source->custom_shipto;
 207
 208   } else {
 209     $args{shipto_id} = $source->shipto_id;
 210   }
 211
 212   my $invoice = $class->new(%args);
 213   $invoice->assign_attributes(%{ $params{attributes} }) if $params{attributes};
 214   my $items   = delete($params{items}) || $source->items_sorted;
 215   my %item_parents;
 216
 217   my @items = map {
 218     my $source_item      = $_;
 219     my $source_item_id   = $_->$item_parent_id_column;
 220     my @custom_variables = map { _clone_orderitem_delivery_order_item_cvar($_) } @{ $source_item->custom_variables };
 221
 222     $item_parents{$source_item_id} ||= $source_item->$item_parent_column;
 223     my $item_parent                  = $item_parents{$source_item_id};
 224     my $current_invoice_item =
 225       SL::DB::InvoiceItem->new(map({ ( $_ => $source_item->$_ ) }
 226                                    qw(parts_id description qty sellprice discount project_id serialnumber pricegroup_id transdate cusordnumber unit
 227                                       base_qty longdescription lastcost price_factor_id active_discount_source active_price_source), @item_columns),
 228                                deliverydate     => $source_item->reqdate,
 229                                fxsellprice      => $source_item->sellprice,
 230                                custom_variables => \@custom_variables,
 231                                ordnumber        => ref($item_parent) eq 'SL::DB::Order'         ? $item_parent->ordnumber : $source_item->ordnumber,
 232                                donumber         => ref($item_parent) eq 'SL::DB::DeliveryOrder' ? $item_parent->donumber  : $source_item->can('donumber') ? $source_item->donumber : '',
 233                              );
 234
 235     $current_invoice_item->{"converted_from_orderitems_id"}           = $_->{id} if ref($item_parent) eq 'SL::DB::Order';
 236     $current_invoice_item->{"converted_from_delivery_order_items_id"} = $_->{id} if ref($item_parent) eq 'SL::DB::DeliveryOrder';
 237     $current_invoice_item;
 238   } @{ $items };
 239
 240   @items = grep { $params{item_filter}->($_) } @items if $params{item_filter};
 241   @items = grep { $_->qty * 1 } @items if $params{skip_items_zero_qty};
 242   @items = grep { $_->qty >=0 } @items if $params{skip_items_negative_qty};
 243
 244   $invoice->invoiceitems(\@items);
 245
 246   return $invoice;
 247 }
 248
 249 sub post {
 250   my ($self, %params) = @_;
 251
 252   die "not an invoice" unless $self->invoice;
 253
 254   require SL::DB::Chart;
 255   if (!$params{ar_id}) {
 256     my $chart;
 257     if ($::instance_conf->get_ar_chart_id) {
 258       $chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_ar_chart_id);
 259     } else {
 260       $chart = SL::DB::Manager::Chart->get_all(query   => [ SL::DB::Manager::Chart->link_filter('AR') ],
 261                                                sort_by => 'id ASC',
 262                                                limit   => 1)->[0];
 263     };
 264     croak("No AR chart found and no parameter 'ar_id' given") unless $chart;
 265     $params{ar_id} = $chart->id;
 266   }
 267
 268   if (!$self->db->with_transaction(sub {
 269     my %data = $self->calculate_prices_and_taxes;
 270
 271     $self->_post_create_assemblyitem_entries($data{assembly_items});
 272     $self->save;
 273
 274     $self->_post_add_acctrans($data{amounts_cogs});
 275     $self->_post_add_acctrans($data{amounts});
 276     $self->_post_add_acctrans($data{taxes});
 277
 278     $self->_post_add_acctrans({ $params{ar_id} => $self->amount * -1 });
 279
 280     $self->_post_update_allocated($data{allocated});
 281
 282     $self->_post_book_rounding($data{rounding});
 283
 284     1;
 285   })) {
 286     $::lxdebug->message(LXDebug->WARN(), "convert_to_invoice failed: " . join("\n", (split(/\n/, $self->db->error))[0..2]));
 287     return undef;
 288   }
 289
 290   return $self;
 291 }
 292
 293 sub _post_add_acctrans {
 294   my ($self, $entries) = @_;
 295
 296   my $default_tax_id = SL::DB::Manager::Tax->find_by(taxkey => 0)->id;
 297   my $chart_link;
 298
 299   require SL::DB::AccTransaction;
 300   require SL::DB::Chart;
 301   while (my ($chart_id, $spec) = each %{ $entries }) {
 302     $spec = { taxkey => 0, tax_id => $default_tax_id, amount => $spec } unless ref $spec;
 303     $chart_link = SL::DB::Manager::Chart->find_by(id => $chart_id)->{'link'};
 304     $chart_link ||= '';
 305
 306     if ($spec->{amount} != 0) {
 307       SL::DB::AccTransaction->new(trans_id   => $self->id,
 308                                   chart_id   => $chart_id,
 309                                   amount     => $spec->{amount},
 310                                   tax_id     => $spec->{tax_id},
 311                                   taxkey     => $spec->{taxkey},
 312                                   project_id => $self->globalproject_id,
 313                                   transdate  => $self->transdate,
 314                                   chart_link => $chart_link)->save;
 315     }
 316   }
 317 }
 318
 319 sub _post_book_rounding {
 320   my ($self, $rounding) = @_;
 321
 322   my $tax_id = SL::DB::Manager::Tax->find_by(taxkey => 0)->id;
 323   my $rnd_accno = $rounding == 0 ? 0
 324                 : $rounding > 0  ? SL::DB::Default->get->rndgain_accno_id
 325                 :                  SL::DB::Default->get->rndloss_accno_id
 326   ;
 327   if ($rnd_accno != 0) {
 328     SL::DB::AccTransaction->new(trans_id   => $self->id,
 329                                 chart_id   => $rnd_accno,
 330                                 amount     => $rounding,
 331                                 tax_id     => $tax_id,
 332                                 taxkey     => 0,
 333                                 project_id => $self->globalproject_id,
 334                                 transdate  => $self->transdate,
 335                                 chart_link => $rnd_accno)->save;
 336   }
 337 }
 338
 339 sub add_ar_amount_row {
 340   my ($self, %params ) = @_;
 341
 342   # only allow this method for ar invoices (Debitorenbuchung)
 343   die "not an ar invoice" if $self->invoice and not $self->customer_id;
 344
 345   die "add_ar_amount_row needs a chart object as chart param" unless $params{chart} && $params{chart}->isa('SL::DB::Chart');
 346   die "chart must be an AR_amount chart" unless $params{chart}->link =~ /AR_amount/;
 347
 348   my $acc_trans = [];
 349
 350   my $roundplaces = 2;
 351   my ($netamount,$taxamount);
 352
 353   $netamount = $params{amount} * 1;
 354   my $tax = SL::DB::Manager::Tax->find_by(id => $params{tax_id}) || die "Can't find tax with id " . $params{tax_id};
 355
 356   if ( $tax and $tax->rate != 0 ) {
 357     ($netamount, $taxamount) = Form->calculate_tax($params{amount}, $tax->rate, $self->taxincluded, $roundplaces);
 358   };
 359   next unless $netamount; # netamount mustn't be zero
 360
 361   my $sign = $self->customer_id ? 1 : -1;
 362   my $acc = SL::DB::AccTransaction->new(
 363     amount     => $netamount * $sign,
 364     chart_id   => $params{chart}->id,
 365     chart_link => $params{chart}->link,
 366     transdate  => $self->transdate,
 367     gldate     => $self->gldate,
 368     taxkey     => $tax->taxkey,
 369     tax_id     => $tax->id,
 370     project_id => $params{project_id},
 371   );
 372
 373   $self->add_transactions( $acc );
 374   push( @$acc_trans, $acc );
 375
 376   if ( $taxamount ) {
 377      my $acc = SL::DB::AccTransaction->new(
 378        amount     => $taxamount * $sign,
 379        chart_id   => $tax->chart_id,
 380        chart_link => $tax->chart->link,
 381        transdate  => $self->transdate,
 382        gldate     => $self->gldate,
 383        taxkey     => $tax->taxkey,
 384        tax_id     => $tax->id,
 385      );
 386      $self->add_transactions( $acc );
 387      push( @$acc_trans, $acc );
 388   };
 389   return $acc_trans;
 390 };
 391
 392 sub create_ar_row {
 393   my ($self, %params) = @_;
 394   # to be called after adding all AR_amount rows, adds an AR row
 395
 396   # only allow this method for ar invoices (Debitorenbuchung)
 397   die if $self->invoice and not $self->customer_id;
 398   die "create_ar_row needs a chart object as a parameter" unless $params{chart} and ref($params{chart}) eq 'SL::DB::Chart';
 399
 400   my @transactions = @{$self->transactions};
 401   # die "invoice has no acc_transactions" unless scalar @transactions > 0;
 402   return 0 unless scalar @transactions > 0;
 403
 404   my $chart = $params{chart} || SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_ar_chart_id);
 405   die "illegal chart in create_ar_row" unless $chart;
 406
 407   die "receivables chart must have link 'AR'" unless $chart->link eq 'AR';
 408
 409   my $acc_trans = [];
 410
 411   # hardcoded entry for no tax: tax_id and taxkey should be 0
 412   my $tax = SL::DB::Manager::Tax->find_by(id => 0, taxkey => 0) || die "Can't find tax with id 0 and taxkey 0";
 413
 414   my $sign = $self->customer_id ? -1 : 1;
 415   my $acc = SL::DB::AccTransaction->new(
 416     amount     => $self->amount * $sign,
 417     chart_id   => $params{chart}->id,
 418     chart_link => $params{chart}->link,
 419     transdate  => $self->transdate,
 420     taxkey     => $tax->taxkey,
 421     tax_id     => $tax->id,
 422   );
 423   $self->add_transactions( $acc );
 424   push( @$acc_trans, $acc );
 425   return $acc_trans;
 426 };
 427
 428 sub validate_acc_trans {
 429   my ($self, %params) = @_;
 430   # should be able to check unsaved invoice objects with several acc_trans lines
 431
 432   die "validate_acc_trans can't check invoice object with empty transactions" unless $self->transactions;
 433
 434   my @transactions = @{$self->transactions};
 435   # die "invoice has no acc_transactions" unless scalar @transactions > 0;
 436   return 0 unless scalar @transactions > 0;
 437   return 0 unless $self->has_loaded_related('transactions');
 438   if ( $params{debug} ) {
 439     printf("starting validatation of invoice %s with trans_id %s and taxincluded %s\n", $self->invnumber, $self->id, $self->taxincluded);
 440     foreach my $acc ( @transactions ) {
 441       printf("chart: %s  amount: %s   tax_id: %s  link: %s\n", $acc->chart->accno, $acc->amount, $acc->tax_id, $acc->chart->link);
 442     };
 443   };
 444
 445   my $acc_trans_sum = sum map { $_->amount } @transactions;
 446
 447   unless ( $::form->round_amount($acc_trans_sum, 10) == 0 ) {
 448     my $string = "sum of acc_transactions isn't 0: $acc_trans_sum\n";
 449
 450     if ( $params{debug} ) {
 451       foreach my $trans ( @transactions ) {
 452           $string .= sprintf("  %s %s %s\n", $trans->chart->accno, $trans->taxkey, $trans->amount);
 453       };
 454     };
 455     return 0;
 456   };
 457
 458   # only use the first AR entry, so it also works for paid invoices
 459   my @ar_transactions = map { $_->amount } grep { $_->chart_link eq 'AR' } @transactions;
 460   my $ar_sum = $ar_transactions[0];
 461   # my $ar_sum = sum map { $_->amount } grep { $_->chart_link eq 'AR' } @transactions;
 462
 463   unless ( $::form->round_amount($ar_sum * -1,2) == $::form->round_amount($self->amount,2) ) {
 464     if ( $params{debug} ) {
 465       printf("debug: (ar_sum) %s = %s (amount)\n",  $::form->round_amount($ar_sum * -1,2) , $::form->round_amount($self->amount, 2) );
 466       foreach my $trans ( @transactions ) {
 467         printf("  %s %s %s %s\n", $trans->chart->accno, $trans->taxkey, $trans->amount, $trans->chart->link);
 468       };
 469     };
 470     die sprintf("sum of ar (%s) isn't equal to invoice amount (%s)", $::form->round_amount($ar_sum * -1,2), $::form->round_amount($self->amount,2));
 471   };
 472
 473   return 1;
 474 };
 475
 476 sub recalculate_amounts {
 477   my ($self, %params) = @_;
 478   # calculate and set amount and netamount from acc_trans objects
 479
 480   croak ("Can only recalculate amounts for ar transactions") if $self->invoice;
 481
 482   return undef unless $self->has_loaded_related('transactions');
 483
 484   my ($netamount, $taxamount);
 485
 486   my @transactions = @{$self->transactions};
 487
 488   foreach my $acc ( @transactions ) {
 489     $netamount += $acc->amount if $acc->chart->link =~ /AR_amount/;
 490     $taxamount += $acc->amount if $acc->chart->link =~ /AR_tax/;
 491   };
 492
 493   $self->amount($netamount+$taxamount);
 494   $self->netamount($netamount);
 495 };
 496
 497
 498 sub _post_create_assemblyitem_entries {
 499   my ($self, $assembly_entries) = @_;
 500
 501   my $items = $self->invoiceitems;
 502   my @new_items;
 503
 504   my $item_idx = 0;
 505   foreach my $item (@{ $items }) {
 506     next if $item->assemblyitem;
 507
 508     push @new_items, $item;
 509     $item_idx++;
 510
 511     foreach my $assembly_item (@{ $assembly_entries->[$item_idx] || [ ] }) {
 512       push @new_items, SL::DB::InvoiceItem->new(parts_id     => $assembly_item->{part},
 513                                                 description  => $assembly_item->{part}->description,
 514                                                 unit         => $assembly_item->{part}->unit,
 515                                                 qty          => $assembly_item->{qty},
 516                                                 allocated    => $assembly_item->{allocated},
 517                                                 sellprice    => 0,
 518                                                 fxsellprice  => 0,
 519                                                 assemblyitem => 't');
 520     }
 521   }
 522
 523   $self->invoiceitems(\@new_items);
 524 }
 525
 526 sub _post_update_allocated {
 527   my ($self, $allocated) = @_;
 528
 529   while (my ($invoice_id, $diff) = each %{ $allocated }) {
 530     SL::DB::Manager::InvoiceItem->update_all(set   => { allocated => { sql => "allocated + $diff" } },
 531                                              where => [ id        => $invoice_id ]);
 532   }
 533 }
 534
 535 sub invoice_type {
 536   my ($self) = @_;
 537
 538   return 'ar_transaction'     if !$self->invoice;
 539   return 'credit_note'        if $self->type eq 'credit_note' && $self->amount < 0 && !$self->storno;
 540   return 'invoice_storno'     if $self->type ne 'credit_note' && $self->amount < 0 &&  $self->storno;
 541   return 'credit_note_storno' if $self->type eq 'credit_note' && $self->amount > 0 &&  $self->storno;
 542   return 'invoice';
 543 }
 544
 545 sub displayable_state {
 546   my $self = shift;
 547
 548   return $self->closed ? $::locale->text('closed') : $::locale->text('open');
 549 }
 550
 551 sub displayable_type {
 552   my ($self) = @_;
 553
 554   return t8('AR Transaction')                         if $self->invoice_type eq 'ar_transaction';
 555   return t8('Credit Note')                            if $self->invoice_type eq 'credit_note';
 556   return t8('Invoice') . "(" . t8('Storno') . ")"     if $self->invoice_type eq 'invoice_storno';
 557   return t8('Credit Note') . "(" . t8('Storno') . ")" if $self->invoice_type eq 'credit_note_storno';
 558   return t8('Invoice');
 559 }
 560
 561 sub displayable_name {
 562   join ' ', grep $_, map $_[0]->$_, qw(displayable_type record_number);
 563 };
 564
 565 sub abbreviation {
 566   my ($self) = @_;
 567
 568   return t8('AR Transaction (abbreviation)')         if $self->invoice_type eq 'ar_transaction';
 569   return t8('Credit note (one letter abbreviation)') if $self->invoice_type eq 'credit_note';
 570   return t8('Invoice (one letter abbreviation)') . "(" . t8('Storno (one letter abbreviation)') . ")" if $self->invoice_type eq 'invoice_storno';
 571   return t8('Credit note (one letter abbreviation)') . "(" . t8('Storno (one letter abbreviation)') . ")"  if $self->invoice_type eq 'credit_note_storno';
 572   return t8('Invoice (one letter abbreviation)');
 573 }
 574
 575 sub oneline_summary {
 576   my $self = shift;
 577
 578   return sprintf("%s: %s %s %s (%s)", $self->abbreviation, $self->invnumber, $self->customer->name,
 579                                       $::form->format_amount(\%::myconfig, $self->amount,2), $self->transdate->to_kivitendo);
 580 }
 581
 582 sub date {
 583   goto &transdate;
 584 }
 585
 586 sub reqdate {
 587   goto &duedate;
 588 }
 589
 590 sub customervendor {
 591   goto &customer;
 592 }
 593
 594 sub link {
 595   my ($self) = @_;
 596
 597   my $html;
 598   $html   = $self->presenter->sales_invoice(display => 'inline') if $self->invoice;
 599   $html   = $self->presenter->ar_transaction(display => 'inline') if !$self->invoice;
 600
 601   return $html;
 602 }
 603
 604 sub mark_as_paid {
 605   my ($self) = @_;
 606
 607   $self->update_attributes(paid => $self->amount);
 608 }
 609
 610 1;
 611
 612 __END__
 613
 614 =pod
 615
 616 =encoding UTF-8
 617
 618 =head1 NAME
 619
 620 SL::DB::Invoice: Rose model for invoices (table "ar")
 621
 622 =head1 FUNCTIONS
 623
 624 =over 4
 625
 626 =item C<new_from $source, %params>
 627
 628 Creates a new C<SL::DB::Invoice> instance and copies as much
 629 information from C<$source> as possible. At the moment only sales
 630 orders and sales quotations are supported as sources.
 631
 632 The conversion copies order items into invoice items. Dates are copied
 633 as appropriate, e.g. the C<transdate> field from an order will be
 634 copied into the invoice's C<orddate> field.
 635
 636 C<%params> can include the following options:
 637
 638 =over 2
 639
 640 =item C<items>
 641
 642 An optional array reference of RDBO instances for the items to use. If
 643 missing then the method C<items_sorted> will be called on
 644 C<$source>. This option can be used to override the sorting, to
 645 exclude certain positions or to add additional ones.
 646
 647 =item C<skip_items_negative_qty>
 648
 649 If trueish then items with a negative quantity are skipped. Items with
 650 a quantity of 0 are not affected by this option.
 651
 652 =item C<skip_items_zero_qty>
 653
 654 If trueish then items with a quantity of 0 are skipped.
 655
 656 =item C<item_filter>
 657
 658 An optional code reference that is called for each item with the item
 659 as its sole parameter. Items for which the code reference returns a
 660 falsish value will be skipped.
 661
 662 =item C<attributes>
 663
 664 An optional hash reference. If it exists then it is passed to C<new>
 665 allowing the caller to set certain attributes for the new invoice.
 666 For example to set a different transdate (default is the current date),
 667 call the method like this:
 668
 669    my %params;
 670    $params{attributes}{transdate} = '28.08.2015';
 671    $invoice = SL::DB::Invoice->new_from($self, %params)->post || die;
 672
 673 =back
 674
 675 Amounts, prices and taxes are not
 676 calculated. L<SL::DB::Helper::PriceTaxCalculator::calculate_prices_and_taxes>
 677 can be used for this.
 678
 679 The object returned is not saved.
 680
 681 =item C<post %params>
 682
 683 Posts the invoice. Required parameters are:
 684
 685 =over 2
 686
 687 =item * C<ar_id>
 688
 689 The ID of the accounts receivable chart the invoice's amounts are
 690 posted to. If it is not set then the first chart configured for
 691 accounts receivables is used.
 692
 693 =back
 694
 695 This function implements several steps:
 696
 697 =over 2
 698
 699 =item 1. It calculates all prices, amounts and taxes by calling
 700 L<SL::DB::Helper::PriceTaxCalculator::calculate_prices_and_taxes>.
 701
 702 =item 2. A new and unique invoice number is created.
 703
 704 =item 3. All amounts for costs of goods sold are recorded in
 705 C<acc_trans>.
 706
 707 =item 4. All amounts for parts, services and assemblies are recorded
 708 in C<acc_trans> with their respective charts. This is determined by
 709 the part's buchungsgruppen.
 710
 711 =item 5. The total amount is posted to the accounts receivable chart
 712 and recorded in C<acc_trans>.
 713
 714 =item 6. Items in C<invoice> are updated according to their allocation
 715 status (regarding costs of goods sold). Will only be done if
 716 kivitendo is not configured to use Einnahmenüberschussrechnungen.
 717
 718 =item 7. The invoice and its items are saved.
 719
 720 =back
 721
 722 Returns C<$self> on success and C<undef> on failure. The whole process
 723 is run inside a transaction. If it fails then nothing is saved to or
 724 changed in the database. A new transaction is only started if none are
 725 active.
 726
 727 =item C<basic_info $field>
 728
 729 See L<SL::DB::Object::basic_info>.
 730
 731 =item C<closed>
 732
 733 Returns 1 or 0, depending on whether the invoice is closed or not. Currently
 734 invoices that are overpaid also count as closed and credit notes in general.
 735
 736 =item C<recalculate_amounts %params>
 737
 738 Calculate and set amount and netamount from acc_trans objects by summing up the
 739 values of acc_trans objects with AR_amount and AR_tax link charts.
 740 amount and netamount are set to the calculated values.
 741
 742 =item C<validate_acc_trans>
 743
 744 Checks if the sum of all associated acc_trans objects is 0 and checks whether
 745 the amount of the AR acc_transaction matches the AR amount. Only the first AR
 746 line is checked, because the sum of all AR lines is 0 for paid invoices.
 747
 748 Returns 0 or 1.
 749
 750 Can be called with a debug parameter which writes debug info to STDOUT, which is
 751 useful in console mode or while writing tests.
 752
 753  my $ar = SL::DB::Manager::Invoice->get_first();
 754  $ar->validate_acc_trans(debug => 1);
 755
 756 =item C<create_ar_row %params>
 757
 758 Creates a new acc_trans entry for the receivable (AR) entry of an existing AR
 759 invoice object, which already has some income and tax acc_trans entries.
 760
 761 The acc_trans entry is also returned inside an array ref.
 762
 763 Mandatory params are
 764
 765 =over 2
 766
 767 =item * chart as an RDBO object, e.g. for bank. Must be a 'paid' chart.
 768
 769 =back
 770
 771 Currently the amount of the invoice object is used for the acc_trans amount.
 772 Use C<recalculate_amounts> before calling this method if amount isn't known
 773 yet or you didn't set it manually.
 774
 775 =item C<add_ar_amount_row %params>
 776
 777 Add a new entry for an existing AR invoice object. Creates an acc_trans entry,
 778 and also adds an acc_trans tax entry, if the tax has an associated tax chart.
 779 Also all acc_trans entries that were created are returned inside an array ref.
 780
 781 Mandatory params are
 782
 783 =over 2
 784
 785 =item * chart as an RDBO object, should be an income chart (link = AR_amount)
 786
 787 =item * tax_id
 788
 789 =item * amount
 790
 791 =back
 792
 793 =item C<mark_as_paid>
 794
 795 Marks the invoice as paid by setting its C<paid> member to the value of C<amount>.
 796
 797 =back
 798
 799 =head1 TODO
 800
 801  As explained in the new_from example, it is possible to set transdate to a new value.
 802  From a user / programm point of view transdate is more than holy and there should be
 803  some validity checker available for controller code. At least the same logic like in
 804  Form.pm from ar.pl should be available:
 805   # see old stuff ar.pl post
 806   #$form->error($locale->text('Cannot post transaction above the maximum future booking date!'))
 807   #  if ($form->date_max_future($transdate, \%myconfig));
 808   #$form->error($locale->text('Cannot post transaction for a closed period!')) if ($form->date_closed($form->{"transdate"}, \%myconfig));
 809
 810 =head1 AUTHOR
 811
 812 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 813
 814 =cut