SL/DB/Invoice.pm

   1 package SL::DB::Invoice;
   2
   3 use strict;
   4
   5 use Carp;
   6 use List::Util qw(first sum);
   7
   8 use Rose::DB::Object::Helpers qw(has_loaded_related forget_related);
   9 use SL::DB::MetaSetup::Invoice;
  10 use SL::DB::Manager::Invoice;
  11 use SL::DB::Helper::Payment qw(:ALL);
  12 use SL::DB::Helper::AttrHTML;
  13 use SL::DB::Helper::AttrSorted;
  14 use SL::DB::Helper::FlattenToForm;
  15 use SL::DB::Helper::LinkedRecords;
  16 use SL::DB::Helper::PriceTaxCalculator;
  17 use SL::DB::Helper::PriceUpdater;
  18 use SL::DB::Helper::TransNumberGenerator;
  19 use SL::Locale::String qw(t8);
  20 use SL::DB::CustomVariable;
  21
  22 __PACKAGE__->meta->add_relationship(
  23   invoiceitems => {
  24     type         => 'one to many',
  25     class        => 'SL::DB::InvoiceItem',
  26     column_map   => { id => 'trans_id' },
  27     manager_args => {
  28       with_objects => [ 'part' ]
  29     }
  30   },
  31   storno_invoices => {
  32     type          => 'one to many',
  33     class         => 'SL::DB::Invoice',
  34     column_map    => { id => 'storno_id' },
  35   },
  36   sepa_export_items => {
  37     type            => 'one to many',
  38     class           => 'SL::DB::SepaExportItem',
  39     column_map      => { id => 'ar_id' },
  40     manager_args    => { with_objects => [ 'sepa_export' ] }
  41   },
  42   sepa_exports      => {
  43     type            => 'many to many',
  44     map_class       => 'SL::DB::SepaExportItem',
  45     map_from        => 'ar',
  46     map_to          => 'sepa_export',
  47   },
  48   custom_shipto     => {
  49     type            => 'one to one',
  50     class           => 'SL::DB::Shipto',
  51     column_map      => { id => 'trans_id' },
  52     query_args      => [ module => 'AR' ],
  53   },
  54   transactions   => {
  55     type         => 'one to many',
  56     class        => 'SL::DB::AccTransaction',
  57     column_map   => { id => 'trans_id' },
  58     manager_args => {
  59       with_objects => [ 'chart' ],
  60       sort_by      => 'acc_trans_id ASC',
  61     },
  62   },
  63 );
  64
  65 __PACKAGE__->meta->initialize;
  66
  67 __PACKAGE__->attr_html('notes');
  68 __PACKAGE__->attr_sorted('items');
  69
  70 __PACKAGE__->before_save('_before_save_set_invnumber');
  71
  72 # hooks
  73
  74 sub _before_save_set_invnumber {
  75   my ($self) = @_;
  76
  77   $self->create_trans_number if !$self->invnumber;
  78
  79   return 1;
  80 }
  81
  82 # methods
  83
  84 sub items { goto &invoiceitems; }
  85 sub add_items { goto &add_invoiceitems; }
  86 sub record_number { goto &invnumber; };
  87
  88 sub is_sales {
  89   # For compatibility with Order, DeliveryOrder
  90   croak 'not an accessor' if @_ > 1;
  91   return 1;
  92 }
  93
  94 # it is assumed, that ordnumbers are unique here.
  95 sub first_order_by_ordnumber {
  96   my $self = shift;
  97
  98   my $orders = SL::DB::Manager::Order->get_all(
  99     query => [
 100       ordnumber => $self->ordnumber,
 101
 102     ],
 103   );
 104
 105   return first { $_->is_type('sales_order') } @{ $orders };
 106 }
 107
 108 sub abschlag_percentage {
 109   my $self         = shift;
 110   my $order        = $self->first_order_by_ordnumber or return;
 111   my $order_amount = $order->netamount               or return;
 112   return $self->abschlag
 113     ? $self->netamount / $order_amount
 114     : undef;
 115 }
 116
 117 sub taxamount {
 118   my $self = shift;
 119   die 'not a setter method' if @_;
 120
 121   return ($self->amount || 0) - ($self->netamount || 0);
 122 }
 123
 124 __PACKAGE__->meta->make_attr_helpers(taxamount => 'numeric(15,5)');
 125
 126 sub closed {
 127   my ($self) = @_;
 128   return $self->paid >= $self->amount;
 129 }
 130
 131 sub _clone_orderitem_delivery_order_item_cvar {
 132   my ($cvar) = @_;
 133
 134   my $cloned = $_->clone_and_reset;
 135   $cloned->sub_module('invoice');
 136
 137   return $cloned;
 138 }
 139
 140 sub new_from {
 141   my ($class, $source, %params) = @_;
 142
 143   croak("Unsupported source object type '" . ref($source) . "'") unless ref($source) =~ m/^ SL::DB:: (?: Order | DeliveryOrder ) $/x;
 144   croak("Cannot create invoices for purchase records")           unless $source->customer_id;
 145
 146   require SL::DB::Employee;
 147
 148   my (@columns, @item_columns, $item_parent_id_column, $item_parent_column);
 149
 150   if (ref($source) eq 'SL::DB::Order') {
 151     @columns      = qw(quonumber delivery_customer_id delivery_vendor_id);
 152     @item_columns = qw(subtotal);
 153
 154     $item_parent_id_column = 'trans_id';
 155     $item_parent_column    = 'order';
 156
 157   } else {
 158     @columns      = qw(donumber);
 159
 160     $item_parent_id_column = 'delivery_order_id';
 161     $item_parent_column    = 'delivery_order';
 162   }
 163
 164   my $terms = $source->can('payment_id') ? $source->payment_terms : undef;
 165   $terms = $source->customer->payment_terms if !defined $terms && $source->customer;
 166
 167   my %args = ( map({ ( $_ => $source->$_ ) } qw(customer_id taxincluded shippingpoint shipvia notes intnotes salesman_id cusordnumber ordnumber department_id
 168                                                 cp_id language_id taxzone_id globalproject_id transaction_description currency_id delivery_term_id), @columns),
 169                transdate   => DateTime->today_local,
 170                gldate      => DateTime->today_local,
 171                duedate     => $terms ? $terms->calc_date(reference_date => DateTime->today_local) : DateTime->today_local,
 172                invoice     => 1,
 173                type        => 'invoice',
 174                storno      => 0,
 175                paid        => 0,
 176                employee_id => (SL::DB::Manager::Employee->current || SL::DB::Employee->new(id => $source->employee_id))->id,
 177             );
 178
 179   $args{payment_id} = ( $terms ? $terms->id : $source->payment_id);
 180
 181   if ($source->type =~ /_order$/) {
 182     $args{deliverydate} = $source->reqdate;
 183     $args{orddate}      = $source->transdate;
 184   } else {
 185     $args{quodate}      = $source->transdate;
 186   }
 187
 188   # Custom shipto addresses (the ones specific to the sales/purchase
 189   # record and not to the customer/vendor) are only linked from shipto
 190   # → ar. Meaning ar.shipto_id will not be filled in that
 191   # case.
 192   if (!$source->shipto_id && $source->id) {
 193     $args{custom_shipto} = $source->custom_shipto->clone($class) if $source->can('custom_shipto') && $source->custom_shipto;
 194
 195   } else {
 196     $args{shipto_id} = $source->shipto_id;
 197   }
 198
 199   my $invoice = $class->new(%args);
 200   $invoice->assign_attributes(%{ $params{attributes} }) if $params{attributes};
 201   my $items   = delete($params{items}) || $source->items_sorted;
 202   my %item_parents;
 203
 204   my @items = map {
 205     my $source_item      = $_;
 206     my $source_item_id   = $_->$item_parent_id_column;
 207     my @custom_variables = map { _clone_orderitem_delivery_order_item_cvar($_) } @{ $source_item->custom_variables };
 208
 209     $item_parents{$source_item_id} ||= $source_item->$item_parent_column;
 210     my $item_parent                  = $item_parents{$source_item_id};
 211     my $current_invoice_item =
 212       SL::DB::InvoiceItem->new(map({ ( $_ => $source_item->$_ ) }
 213                                    qw(parts_id description qty sellprice discount project_id serialnumber pricegroup_id transdate cusordnumber unit
 214                                       base_qty longdescription lastcost price_factor_id active_discount_source active_price_source), @item_columns),
 215                                deliverydate     => $source_item->reqdate,
 216                                fxsellprice      => $source_item->sellprice,
 217                                custom_variables => \@custom_variables,
 218                                ordnumber        => ref($item_parent) eq 'SL::DB::Order'         ? $item_parent->ordnumber : $source_item->ordnumber,
 219                                donumber         => ref($item_parent) eq 'SL::DB::DeliveryOrder' ? $item_parent->donumber  : $source_item->can('donumber') ? $source_item->donumber : '',
 220                              );
 221
 222     $current_invoice_item->{"converted_from_orderitems_id"}           = $_->{id} if ref($item_parent) eq 'SL::DB::Order';
 223     $current_invoice_item->{"converted_from_delivery_order_items_id"} = $_->{id} if ref($item_parent) eq 'SL::DB::DeliveryOrder';
 224     $current_invoice_item;
 225   } @{ $items };
 226
 227   @items = grep { $params{item_filter}->($_) } @items if $params{item_filter};
 228   @items = grep { $_->qty * 1 } @items if $params{skip_items_zero_qty};
 229   @items = grep { $_->qty >=0 } @items if $params{skip_items_negative_qty};
 230
 231   $invoice->invoiceitems(\@items);
 232
 233   return $invoice;
 234 }
 235
 236 sub post {
 237   my ($self, %params) = @_;
 238
 239   die "not an invoice" unless $self->invoice;
 240
 241   require SL::DB::Chart;
 242   if (!$params{ar_id}) {
 243     my $chart;
 244     if ($::instance_conf->get_ar_chart_id) {
 245       $chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_ar_chart_id);
 246     } else {
 247       $chart = SL::DB::Manager::Chart->get_all(query   => [ SL::DB::Manager::Chart->link_filter('AR') ],
 248                                                sort_by => 'id ASC',
 249                                                limit   => 1)->[0];
 250     };
 251     croak("No AR chart found and no parameter 'ar_id' given") unless $chart;
 252     $params{ar_id} = $chart->id;
 253   }
 254
 255   if (!$self->db->with_transaction(sub {
 256     my %data = $self->calculate_prices_and_taxes;
 257
 258     $self->_post_create_assemblyitem_entries($data{assembly_items});
 259     $self->save;
 260
 261     $self->_post_add_acctrans($data{amounts_cogs});
 262     $self->_post_add_acctrans($data{amounts});
 263     $self->_post_add_acctrans($data{taxes});
 264
 265     $self->_post_add_acctrans({ $params{ar_id} => $self->amount * -1 });
 266
 267     $self->_post_update_allocated($data{allocated});
 268
 269     $self->_post_book_rounding($data{rounding});
 270
 271     1;
 272   })) {
 273     $::lxdebug->message(LXDebug->WARN(), "convert_to_invoice failed: " . join("\n", (split(/\n/, $self->db->error))[0..2]));
 274     return undef;
 275   }
 276
 277   return $self;
 278 }
 279
 280 sub _post_add_acctrans {
 281   my ($self, $entries) = @_;
 282
 283   my $default_tax_id = SL::DB::Manager::Tax->find_by(taxkey => 0)->id;
 284   my $chart_link;
 285
 286   require SL::DB::AccTransaction;
 287   require SL::DB::Chart;
 288   while (my ($chart_id, $spec) = each %{ $entries }) {
 289     $spec = { taxkey => 0, tax_id => $default_tax_id, amount => $spec } unless ref $spec;
 290     $chart_link = SL::DB::Manager::Chart->find_by(id => $chart_id)->{'link'};
 291     $chart_link ||= '';
 292
 293     SL::DB::AccTransaction->new(trans_id   => $self->id,
 294                                 chart_id   => $chart_id,
 295                                 amount     => $spec->{amount},
 296                                 tax_id     => $spec->{tax_id},
 297                                 taxkey     => $spec->{taxkey},
 298                                 project_id => $self->globalproject_id,
 299                                 transdate  => $self->transdate,
 300                                 chart_link => $chart_link)->save;
 301   }
 302 }
 303
 304 sub _post_book_rounding {
 305   my ($self, $rounding) = @_;
 306
 307   my $tax_id = SL::DB::Manager::Tax->find_by(taxkey => 0)->id;
 308   my $rnd_accno = $rounding == 0 ? 0
 309                 : $rounding > 0  ? SL::DB::Default->get->rndgain_accno_id
 310                 :                  SL::DB::Default->get->rndloss_accno_id
 311   ;
 312   if ($rnd_accno != 0) {
 313     SL::DB::AccTransaction->new(trans_id   => $self->id,
 314                                 chart_id   => $rnd_accno,
 315                                 amount     => $rounding,
 316                                 tax_id     => $tax_id,
 317                                 taxkey     => 0,
 318                                 project_id => $self->globalproject_id,
 319                                 transdate  => $self->transdate,
 320                                 chart_link => $rnd_accno)->save;
 321   }
 322 }
 323
 324 sub add_ar_amount_row {
 325   my ($self, %params ) = @_;
 326
 327   # only allow this method for ar invoices (Debitorenbuchung)
 328   die "not an ar invoice" if $self->invoice and not $self->customer_id;
 329
 330   die "add_ar_amount_row needs a chart object as chart param" unless $params{chart} && $params{chart}->isa('SL::DB::Chart');
 331   die "chart must be an AR_amount chart" unless $params{chart}->link =~ /AR_amount/;
 332
 333   my $acc_trans = [];
 334
 335   my $roundplaces = 2;
 336   my ($netamount,$taxamount);
 337
 338   $netamount = $params{amount} * 1;
 339   my $tax = SL::DB::Manager::Tax->find_by(id => $params{tax_id}) || die "Can't find tax with id " . $params{tax_id};
 340
 341   if ( $tax and $tax->rate != 0 ) {
 342     ($netamount, $taxamount) = Form->calculate_tax($params{amount}, $tax->rate, $self->taxincluded, $roundplaces);
 343   };
 344   next unless $netamount; # netamount mustn't be zero
 345
 346   my $sign = $self->customer_id ? 1 : -1;
 347   my $acc = SL::DB::AccTransaction->new(
 348     amount     => $netamount * $sign,
 349     chart_id   => $params{chart}->id,
 350     chart_link => $params{chart}->link,
 351     transdate  => $self->transdate,
 352     taxkey     => $tax->taxkey,
 353     tax_id     => $tax->id,
 354     project_id => $params{project_id},
 355   );
 356
 357   $self->add_transactions( $acc );
 358   push( @$acc_trans, $acc );
 359
 360   if ( $taxamount ) {
 361      my $acc = SL::DB::AccTransaction->new(
 362        amount     => $taxamount * $sign,
 363        chart_id   => $tax->chart_id,
 364        chart_link => $tax->chart->link,
 365        transdate  => $self->transdate,
 366        taxkey     => $tax->taxkey,
 367        tax_id     => $tax->id,
 368      );
 369      $self->add_transactions( $acc );
 370      push( @$acc_trans, $acc );
 371   };
 372   return $acc_trans;
 373 };
 374
 375 sub create_ar_row {
 376   my ($self, %params) = @_;
 377   # to be called after adding all AR_amount rows, adds an AR row
 378
 379   # only allow this method for ar invoices (Debitorenbuchung)
 380   die if $self->invoice and not $self->customer_id;
 381   die "create_ar_row needs a chart object as a parameter" unless $params{chart} and ref($params{chart}) eq 'SL::DB::Chart';
 382
 383   my @transactions = @{$self->transactions};
 384   # die "invoice has no acc_transactions" unless scalar @transactions > 0;
 385   return 0 unless scalar @transactions > 0;
 386
 387   my $chart = $params{chart} || SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_ar_chart_id);
 388   die "illegal chart in create_ar_row" unless $chart;
 389
 390   die "receivables chart must have link 'AR'" unless $chart->link eq 'AR';
 391
 392   my $acc_trans = [];
 393
 394   # hardcoded entry for no tax: tax_id and taxkey should be 0
 395   my $tax = SL::DB::Manager::Tax->find_by(id => 0, taxkey => 0) || die "Can't find tax with id 0 and taxkey 0";
 396
 397   my $sign = $self->customer_id ? -1 : 1;
 398   my $acc = SL::DB::AccTransaction->new(
 399     amount     => $self->amount * $sign,
 400     chart_id   => $params{chart}->id,
 401     chart_link => $params{chart}->link,
 402     transdate  => $self->transdate,
 403     taxkey     => $tax->taxkey,
 404     tax_id     => $tax->id,
 405   );
 406   $self->add_transactions( $acc );
 407   push( @$acc_trans, $acc );
 408   return $acc_trans;
 409 };
 410
 411 sub validate_acc_trans {
 412   my ($self, %params) = @_;
 413   # should be able to check unsaved invoice objects with several acc_trans lines
 414
 415   die "validate_acc_trans can't check invoice object with empty transactions" unless $self->transactions;
 416
 417   my @transactions = @{$self->transactions};
 418   # die "invoice has no acc_transactions" unless scalar @transactions > 0;
 419   return 0 unless scalar @transactions > 0;
 420   return 0 unless $self->has_loaded_related('transactions');
 421   if ( $params{debug} ) {
 422     printf("starting validatation of invoice %s with trans_id %s and taxincluded %s\n", $self->invnumber, $self->id, $self->taxincluded);
 423     foreach my $acc ( @transactions ) {
 424       printf("chart: %s  amount: %s   tax_id: %s  link: %s\n", $acc->chart->accno, $acc->amount, $acc->tax_id, $acc->chart->link);
 425     };
 426   };
 427
 428   my $acc_trans_sum = sum map { $_->amount } @transactions;
 429
 430   unless ( $::form->round_amount($acc_trans_sum, 10) == 0 ) {
 431     my $string = "sum of acc_transactions isn't 0: $acc_trans_sum\n";
 432
 433     if ( $params{debug} ) {
 434       foreach my $trans ( @transactions ) {
 435           $string .= sprintf("  %s %s %s\n", $trans->chart->accno, $trans->taxkey, $trans->amount);
 436       };
 437     };
 438     return 0;
 439   };
 440
 441   # only use the first AR entry, so it also works for paid invoices
 442   my @ar_transactions = map { $_->amount } grep { $_->chart_link eq 'AR' } @transactions;
 443   my $ar_sum = $ar_transactions[0];
 444   # my $ar_sum = sum map { $_->amount } grep { $_->chart_link eq 'AR' } @transactions;
 445
 446   unless ( $::form->round_amount($ar_sum * -1,2) == $::form->round_amount($self->amount,2) ) {
 447     if ( $params{debug} ) {
 448       printf("debug: (ar_sum) %s = %s (amount)\n",  $::form->round_amount($ar_sum * -1,2) , $::form->round_amount($self->amount, 2) );
 449       foreach my $trans ( @transactions ) {
 450         printf("  %s %s %s %s\n", $trans->chart->accno, $trans->taxkey, $trans->amount, $trans->chart->link);
 451       };
 452     };
 453     die sprintf("sum of ar (%s) isn't equal to invoice amount (%s)", $::form->round_amount($ar_sum * -1,2), $::form->round_amount($self->amount,2));
 454   };
 455
 456   return 1;
 457 };
 458
 459 sub recalculate_amounts {
 460   my ($self, %params) = @_;
 461   # calculate and set amount and netamount from acc_trans objects
 462
 463   croak ("Can only recalculate amounts for ar transactions") if $self->invoice;
 464
 465   return undef unless $self->has_loaded_related('transactions');
 466
 467   my ($netamount, $taxamount);
 468
 469   my @transactions = @{$self->transactions};
 470
 471   foreach my $acc ( @transactions ) {
 472     $netamount += $acc->amount if $acc->chart->link =~ /AR_amount/;
 473     $taxamount += $acc->amount if $acc->chart->link =~ /AR_tax/;
 474   };
 475
 476   $self->amount($netamount+$taxamount);
 477   $self->netamount($netamount);
 478 };
 479
 480
 481 sub _post_create_assemblyitem_entries {
 482   my ($self, $assembly_entries) = @_;
 483
 484   my $items = $self->invoiceitems;
 485   my @new_items;
 486
 487   my $item_idx = 0;
 488   foreach my $item (@{ $items }) {
 489     next if $item->assemblyitem;
 490
 491     push @new_items, $item;
 492     $item_idx++;
 493
 494     foreach my $assembly_item (@{ $assembly_entries->[$item_idx] || [ ] }) {
 495       push @new_items, SL::DB::InvoiceItem->new(parts_id     => $assembly_item->{part},
 496                                                 description  => $assembly_item->{part}->description,
 497                                                 unit         => $assembly_item->{part}->unit,
 498                                                 qty          => $assembly_item->{qty},
 499                                                 allocated    => $assembly_item->{allocated},
 500                                                 sellprice    => 0,
 501                                                 fxsellprice  => 0,
 502                                                 assemblyitem => 't');
 503     }
 504   }
 505
 506   $self->invoiceitems(\@new_items);
 507 }
 508
 509 sub _post_update_allocated {
 510   my ($self, $allocated) = @_;
 511
 512   while (my ($invoice_id, $diff) = each %{ $allocated }) {
 513     SL::DB::Manager::InvoiceItem->update_all(set   => { allocated => { sql => "allocated + $diff" } },
 514                                              where => [ id        => $invoice_id ]);
 515   }
 516 }
 517
 518 sub invoice_type {
 519   my ($self) = @_;
 520
 521   return 'ar_transaction'     if !$self->invoice;
 522   return 'credit_note'        if $self->type eq 'credit_note' && $self->amount < 0 && !$self->storno;
 523   return 'invoice_storno'     if $self->type ne 'credit_note' && $self->amount < 0 &&  $self->storno;
 524   return 'credit_note_storno' if $self->type eq 'credit_note' && $self->amount > 0 &&  $self->storno;
 525   return 'invoice';
 526 }
 527
 528 sub displayable_state {
 529   my $self = shift;
 530
 531   return $self->closed ? $::locale->text('closed') : $::locale->text('open');
 532 }
 533
 534 sub displayable_type {
 535   my ($self) = @_;
 536
 537   return t8('AR Transaction')                         if $self->invoice_type eq 'ar_transaction';
 538   return t8('Credit Note')                            if $self->invoice_type eq 'credit_note';
 539   return t8('Invoice') . "(" . t8('Storno') . ")"     if $self->invoice_type eq 'invoice_storno';
 540   return t8('Credit Note') . "(" . t8('Storno') . ")" if $self->invoice_type eq 'credit_note_storno';
 541   return t8('Invoice');
 542 }
 543
 544 sub displayable_name {
 545   join ' ', grep $_, map $_[0]->$_, qw(displayable_type record_number);
 546 };
 547
 548 sub abbreviation {
 549   my ($self) = @_;
 550
 551   return t8('AR Transaction (abbreviation)')         if $self->invoice_type eq 'ar_transaction';
 552   return t8('Credit note (one letter abbreviation)') if $self->invoice_type eq 'credit_note';
 553   return t8('Invoice (one letter abbreviation)') . "(" . t8('Storno (one letter abbreviation)') . ")" if $self->invoice_type eq 'invoice_storno';
 554   return t8('Credit note (one letter abbreviation)') . "(" . t8('Storno (one letter abbreviation)') . ")"  if $self->invoice_type eq 'credit_note_storno';
 555   return t8('Invoice (one letter abbreviation)');
 556 }
 557
 558 sub date {
 559   goto &transdate;
 560 }
 561
 562 sub reqdate {
 563   goto &duedate;
 564 }
 565
 566 sub customervendor {
 567   goto &customer;
 568 }
 569
 570 sub link {
 571   my ($self) = @_;
 572
 573   my $html;
 574   $html   = SL::Presenter->get->sales_invoice($self, display => 'inline') if $self->invoice;
 575   $html   = SL::Presenter->get->ar_transaction($self, display => 'inline') if !$self->invoice;
 576
 577   return $html;
 578 }
 579
 580 sub mark_as_paid {
 581   my ($self) = @_;
 582
 583   $self->update_attributes(paid => $self->amount);
 584 }
 585
 586 1;
 587
 588 __END__
 589
 590 =pod
 591
 592 =encoding UTF-8
 593
 594 =head1 NAME
 595
 596 SL::DB::Invoice: Rose model for invoices (table "ar")
 597
 598 =head1 FUNCTIONS
 599
 600 =over 4
 601
 602 =item C<new_from $source, %params>
 603
 604 Creates a new C<SL::DB::Invoice> instance and copies as much
 605 information from C<$source> as possible. At the moment only sales
 606 orders and sales quotations are supported as sources.
 607
 608 The conversion copies order items into invoice items. Dates are copied
 609 as appropriate, e.g. the C<transdate> field from an order will be
 610 copied into the invoice's C<orddate> field.
 611
 612 C<%params> can include the following options:
 613
 614 =over 2
 615
 616 =item C<items>
 617
 618 An optional array reference of RDBO instances for the items to use. If
 619 missing then the method C<items_sorted> will be called on
 620 C<$source>. This option can be used to override the sorting, to
 621 exclude certain positions or to add additional ones.
 622
 623 =item C<skip_items_negative_qty>
 624
 625 If trueish then items with a negative quantity are skipped. Items with
 626 a quantity of 0 are not affected by this option.
 627
 628 =item C<skip_items_zero_qty>
 629
 630 If trueish then items with a quantity of 0 are skipped.
 631
 632 =item C<item_filter>
 633
 634 An optional code reference that is called for each item with the item
 635 as its sole parameter. Items for which the code reference returns a
 636 falsish value will be skipped.
 637
 638 =item C<attributes>
 639
 640 An optional hash reference. If it exists then it is passed to C<new>
 641 allowing the caller to set certain attributes for the new invoice.
 642 For example to set a different transdate (default is the current date),
 643 call the method like this:
 644
 645    my %params;
 646    $params{attributes}{transdate} = '28.08.2015';
 647    $invoice = SL::DB::Invoice->new_from($self, %params)->post || die;
 648
 649 =back
 650
 651 Amounts, prices and taxes are not
 652 calculated. L<SL::DB::Helper::PriceTaxCalculator::calculate_prices_and_taxes>
 653 can be used for this.
 654
 655 The object returned is not saved.
 656
 657 =item C<post %params>
 658
 659 Posts the invoice. Required parameters are:
 660
 661 =over 2
 662
 663 =item * C<ar_id>
 664
 665 The ID of the accounts receivable chart the invoice's amounts are
 666 posted to. If it is not set then the first chart configured for
 667 accounts receivables is used.
 668
 669 =back
 670
 671 This function implements several steps:
 672
 673 =over 2
 674
 675 =item 1. It calculates all prices, amounts and taxes by calling
 676 L<SL::DB::Helper::PriceTaxCalculator::calculate_prices_and_taxes>.
 677
 678 =item 2. A new and unique invoice number is created.
 679
 680 =item 3. All amounts for costs of goods sold are recorded in
 681 C<acc_trans>.
 682
 683 =item 4. All amounts for parts, services and assemblies are recorded
 684 in C<acc_trans> with their respective charts. This is determined by
 685 the part's buchungsgruppen.
 686
 687 =item 5. The total amount is posted to the accounts receivable chart
 688 and recorded in C<acc_trans>.
 689
 690 =item 6. Items in C<invoice> are updated according to their allocation
 691 status (regarding costs of goods sold). Will only be done if
 692 kivitendo is not configured to use Einnahmenüberschussrechnungen.
 693
 694 =item 7. The invoice and its items are saved.
 695
 696 =back
 697
 698 Returns C<$self> on success and C<undef> on failure. The whole process
 699 is run inside a transaction. If it fails then nothing is saved to or
 700 changed in the database. A new transaction is only started if none are
 701 active.
 702
 703 =item C<basic_info $field>
 704
 705 See L<SL::DB::Object::basic_info>.
 706
 707 =item C<closed>
 708
 709 Returns 1 or 0, depending on whether the invoice is closed or not. Currently
 710 invoices that are overpaid also count as closed.
 711
 712 =item C<recalculate_amounts %params>
 713
 714 Calculate and set amount and netamount from acc_trans objects by summing up the
 715 values of acc_trans objects with AR_amount and AR_tax link charts.
 716 amount and netamount are set to the calculated values.
 717
 718 =item C<validate_acc_trans>
 719
 720 Checks if the sum of all associated acc_trans objects is 0 and checks whether
 721 the amount of the AR acc_transaction matches the AR amount. Only the first AR
 722 line is checked, because the sum of all AR lines is 0 for paid invoices.
 723
 724 Returns 0 or 1.
 725
 726 Can be called with a debug parameter which writes debug info to STDOUT, which is
 727 useful in console mode or while writing tests.
 728
 729  my $ar = SL::DB::Manager::Invoice->get_first();
 730  $ar->validate_acc_trans(debug => 1);
 731
 732 =item C<create_ar_row %params>
 733
 734 Creates a new acc_trans entry for the receivable (AR) entry of an existing AR
 735 invoice object, which already has some income and tax acc_trans entries.
 736
 737 The acc_trans entry is also returned inside an array ref.
 738
 739 Mandatory params are
 740
 741 =over 2
 742
 743 =item * chart as an RDBO object, e.g. for bank. Must be a 'paid' chart.
 744
 745 =back
 746
 747 Currently the amount of the invoice object is used for the acc_trans amount.
 748 Use C<recalculate_amounts> before calling this method if amount isn't known
 749 yet or you didn't set it manually.
 750
 751 =item C<add_ar_amount_row %params>
 752
 753 Add a new entry for an existing AR invoice object. Creates an acc_trans entry,
 754 and also adds an acc_trans tax entry, if the tax has an associated tax chart.
 755 Also all acc_trans entries that were created are returned inside an array ref.
 756
 757 Mandatory params are
 758
 759 =over 2
 760
 761 =item * chart as an RDBO object, should be an income chart (link = AR_amount)
 762
 763 =item * tax_id
 764
 765 =item * amount
 766
 767 =back
 768
 769 =item C<mark_as_paid>
 770
 771 Marks the invoice as paid by setting its C<paid> member to the value of C<amount>.
 772
 773 =back
 774
 775 =head1 TODO
 776
 777  As explained in the new_from example, it is possible to set transdate to a new value.
 778  From a user / programm point of view transdate is more than holy and there should be
 779  some validity checker available for controller code. At least the same logic like in
 780  Form.pm from ar.pl should be available:
 781   # see old stuff ar.pl post
 782   #$form->error($locale->text('Cannot post transaction above the maximum future booking date!'))
 783   #  if ($form->date_max_future($transdate, \%myconfig));
 784   #$form->error($locale->text('Cannot post transaction for a closed period!')) if ($form->date_closed($form->{"transdate"}, \%myconfig));
 785
 786 =head1 AUTHOR
 787
 788 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 789
 790 =cut