SL/DB/Manager/Part.pm

   1 package SL::DB::Manager::Part;
   2
   3 use strict;
   4
   5 use SL::DB::Helper::Manager;
   6 use SL::DB::Helper::Sorted;
   7 use SL::DB::Helper::Paginated;
   8 use SL::DB::Helper::Filtered;
   9 use base qw(SL::DB::Helper::Manager);
  10
  11 use Carp;
  12 use SL::DBUtils;
  13 use SL::MoreCommon qw(listify);
  14
  15 sub object_class { 'SL::DB::Part' }
  16
  17 __PACKAGE__->make_manager_methods;
  18 __PACKAGE__->add_filter_specs(
  19   type => sub {
  20     my ($key, $value, $prefix) = @_;
  21     return __PACKAGE__->type_filter($value, $prefix);
  22   },
  23   all => sub {
  24     my ($key, $value, $prefix) = @_;
  25     return or => [ map { $prefix . $_ => $value } qw(partnumber description) ]
  26   }
  27 );
  28
  29 sub type_filter {
  30   my ($class, $type, $prefix) = @_;
  31
  32   return () unless $type;
  33
  34   $prefix //= '';
  35
  36   # this is to make selections like part_type => { part => 1, service => 1 } work
  37   if ('HASH' eq ref $type) {
  38     $type = [ grep { $type->{$_} } keys %$type ];
  39   }
  40
  41   my @types = grep { $_ } listify($type);
  42   my @filter;
  43
  44   for my $type (@types) {
  45     if ($type =~ m/^part/) {
  46       push @filter, ($prefix . part_type => 'part');
  47     } elsif ($type =~ m/^service/) {
  48       push @filter, ($prefix . part_type => 'service');
  49     } elsif ($type =~ m/^assembly/) {
  50       push @filter, ($prefix . part_type => 'assembly');
  51     }
  52   }
  53
  54   return @filter > 2 ? (or => \@filter) : @filter;
  55 }
  56
  57 sub get_ordered_qty {
  58   my $class    = shift;
  59   my @part_ids = @_;
  60
  61   return () unless @part_ids;
  62
  63   my $placeholders = join ',', ('?') x @part_ids;
  64   my $query        = <<SQL;
  65     SELECT oi.parts_id, SUM(oi.base_qty) AS qty
  66     FROM orderitems oi
  67     LEFT JOIN oe ON (oi.trans_id = oe.id)
  68     WHERE (oi.parts_id IN ($placeholders))
  69       AND (NOT COALESCE(oe.quotation, FALSE))
  70       AND (NOT COALESCE(oe.closed,    FALSE))
  71       AND (NOT COALESCE(oe.delivered, FALSE))
  72       AND (COALESCE(oe.vendor_id, 0) <> 0)
  73     GROUP BY oi.parts_id
  74 SQL
  75
  76   my %qty_by_id = map { $_->{parts_id} => $_->{qty} * 1 } @{ selectall_hashref_query($::form, $class->object_class->init_db->dbh, $query, @part_ids) };
  77   map { $qty_by_id{$_} ||= 0 } @part_ids;
  78
  79   return %qty_by_id;
  80 }
  81
  82 sub _sort_spec {
  83   (
  84     default  => [ 'partnumber', 1 ],
  85     columns  => {
  86       SIMPLE => 'ALL',
  87     },
  88     nulls    => {},
  89   );
  90 }
  91
  92 1;
  93 __END__
  94
  95 =pod
  96
  97 =encoding utf8
  98
  99 =head1 NAME
 100
 101 SL::DB::Manager::Part - RDBO manager for the C<parts> table
 102
 103 =head1 FUNCTIONS
 104
 105 =over 4
 106
 107 =item C<get_ordered_qty @part_ids>
 108
 109 For each of the given part IDs the ordered quantity is
 110 calculated. This is done by summing over all open purchase orders.
 111
 112 Returns a hash with the part IDs being the keys and the ordered
 113 quantities being the values.
 114
 115 =item C<type_filter @types>
 116
 117 Constructs a partial filter for matching any of the article types
 118 given with C<@types>. The returned partial filter is suitable for a
 119 Rose manager query.
 120
 121 Each type can be either 'C<part>', 'C<service>' or 'C<assembly>'
 122 (their plurals are recognized as well). If multiple types are given
 123 then they're combined with C<OR>.
 124
 125 =back
 126
 127 =head1 BUGS
 128
 129 Nothing here yet.
 130
 131 =head1 AUTHOR
 132
 133 Sven Schöling E<lt>s.schoeling@linet-services.deE<gt>,
 134 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 135
 136 =cut