SL/DB/Part.pm

   1 package SL::DB::Part;
   2
   3 use strict;
   4
   5 use Carp;
   6 use SL::DBUtils;
   7 use SL::DB::MetaSetup::Part;
   8 use SL::DB::Manager::Part;
   9
  10 __PACKAGE__->meta->add_relationships(
  11   unit_obj                     => {
  12     type         => 'one to one',
  13     class        => 'SL::DB::Unit',
  14     column_map   => { unit => 'name' },
  15   },
  16   assemblies                     => {
  17     type         => 'one to many',
  18     class        => 'SL::DB::Assembly',
  19     column_map   => { id => 'id' },
  20   },
  21 );
  22
  23 __PACKAGE__->meta->initialize;
  24
  25 sub is_type {
  26   my $self = shift;
  27   my $type  = lc(shift || '');
  28   die 'invalid type' unless $type =~ /^(?:part|service|assembly)$/;
  29
  30   return $self->type eq $type ? 1 : 0;
  31 }
  32
  33 sub is_part     { $_[0]->is_type('part') }
  34 sub is_assembly { $_[0]->is_type('assembly') }
  35 sub is_service  { $_[0]->is_type('service') }
  36
  37 sub type {
  38   my ($self, $type) = @_;
  39   if (@_ > 1) {
  40     die 'invalid type' unless $type =~ /^(?:part|service|assembly)$/;
  41     $self->assembly(          $type eq 'assembly' ? 1 : 0);
  42     $self->inventory_accno_id($type ne 'service'  ? 1 : undef);
  43   }
  44
  45   return 'assembly' if $self->assembly;
  46   return 'part'     if $self->inventory_accno_id;
  47   return 'service';
  48 }
  49
  50 sub new_part {
  51   my ($class, %params) = @_;
  52   $class->new(%params, type => 'part');
  53 }
  54
  55 sub new_assembly {
  56   my ($class, %params) = @_;
  57   $class->new(%params, type => 'assembly');
  58 }
  59
  60 sub new_service {
  61   my ($class, %params) = @_;
  62   $class->new(%params, type => 'service');
  63 }
  64
  65 sub orphaned {
  66   my ($self) = @_;
  67   die 'not an accessor' if @_ > 1;
  68
  69   my @relations = qw(
  70     SL::DB::InvoiceItem
  71     SL::DB::OrderItem
  72     SL::DB::Inventory
  73     SL::DB::RMAItem
  74   );
  75
  76   for my $class (@relations) {
  77     eval "require $class";
  78     return 0 if $class->_get_manager_class->get_all_count(query => [ parts_id => $self->id ]);
  79   }
  80   return 1;
  81 }
  82
  83 sub get_sellprice_info {
  84   my $self   = shift;
  85   my %params = @_;
  86
  87   confess "Missing part id" unless $self->id;
  88
  89   my $object = $self->load;
  90
  91   return { sellprice       => $object->sellprice,
  92            price_factor_id => $object->price_factor_id };
  93 }
  94
  95 sub get_ordered_qty {
  96   my $self   = shift;
  97   my %result = SL::DB::Manager::Part->get_ordered_qty($self->id);
  98
  99   return $result{ $self->id };
 100 }
 101
 102 sub available_units {
 103   shift->unit_obj->convertible_units;
 104 }
 105
 106 1;
 107
 108 __END__
 109
 110 =pod
 111
 112 =head1 NAME
 113
 114 SL::DB::Part: Model for the 'parts' table
 115
 116 =head1 SYNOPSIS
 117
 118 This is a standard Rose::DB::Object based model and can be used as one.
 119
 120 =head1 TYPES
 121
 122 Although the base class is called C<Part> we usually talk about C<Articles> if
 123 we mean instances of this class. This is because articles come in three
 124 flavours called:
 125
 126 =over 4
 127
 128 =item Part     - a single part
 129
 130 =item Service  - a part without onhand, and without inventory accounting
 131
 132 =item Assembly - a collection of both parts and services
 133
 134 =back
 135
 136 These types are sadly represented by data inside the class and cannot be
 137 migrated into a flag. To work around this, each C<Part> object knows what type
 138 it currently is. Since the type ist data driven, there ist no explicit setting
 139 method for it, but you can construct them explicitly with C<new_part>,
 140 C<new_service>, and C<new_assembly>. A Buchungsgruppe should be supplied in this
 141 case, but it will use the default Buchungsgruppe if you don't.
 142
 143 Matching these there are assorted helper methods dealing with type:
 144
 145 =head2 new_part PARAMS
 146
 147 =head2 new_service PARAMS
 148
 149 =head2 new_assembly PARAMS
 150
 151 Will set the appropriate data fields so that the resulting instance will be of
 152 tthe requested type. Since part of the distinction are accounting targets,
 153 providing a C<Buchungsgruppe> is recommended. If none is given the constructor
 154 will load a default one and set the accounting targets from it.
 155
 156 =head2 type
 157
 158 Returns the type as a string. Can be one of C<part>, C<service>, C<assembly>.
 159
 160 =head2 is_type TYPE
 161
 162 Tests if the current object is a part, a service or an
 163 assembly. C<$type> must be one of the words 'part', 'service' or
 164 'assembly' (their plurals are ok, too).
 165
 166 Returns 1 if the requested type matches, 0 if it doesn't and
 167 C<confess>es if an unknown C<$type> parameter is encountered.
 168
 169 =head2 is_part
 170
 171 =head2 is_service
 172
 173 =head2 is_assembly
 174
 175 Shorthand for is_type('part') etc.
 176
 177 =head1 FUNCTIONS
 178
 179 =head2 get_sellprice_info %params
 180
 181 Retrieves the C<sellprice> and C<price_factor_id> for a part under
 182 different conditions and returns a hash reference with those two keys.
 183
 184 If C<%params> contains a key C<project_id> then a project price list
 185 will be consulted if one exists for that project. In this case the
 186 parameter C<country_id> is evaluated as well: if a price list entry
 187 has been created for this country then it will be used. Otherwise an
 188 entry without a country set will be used.
 189
 190 If none of the above conditions is met then the information from
 191 C<$self> is used.
 192
 193 =head2 get_ordered_qty %params
 194
 195 Retrieves the quantity that has been ordered from a vendor but that
 196 has not been delivered yet. Only open purchase orders are considered.
 197
 198 =head2 orphaned
 199
 200 Checks if this articke is used in orders, invoices, delivery orders or
 201 assemblies.
 202
 203 =head2 buchungsgruppe BUCHUNGSGRUPPE
 204
 205 Used to set the accounting informations from a L<SL:DB::Buchungsgruppe> object.
 206 Please note, that this is a write only accessor, the original Buchungsgruppe can
 207 not be retrieved from an article once set.
 208
 209 =head1 AUTHOR
 210
 211 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 212
 213 =cut