SL/DB/Part.pm

   1 package SL::DB::Part;
   2
   3 use strict;
   4
   5 use Carp;
   6 use List::MoreUtils qw(any);
   7 use Rose::DB::Object::Helpers qw(as_tree);
   8
   9 use SL::DBUtils;
  10 use SL::DB::MetaSetup::Part;
  11 use SL::DB::Manager::Part;
  12 use SL::DB::Chart;
  13 use SL::DB::Helper::TransNumberGenerator;
  14 use SL::DB::Helper::CustomVariables (
  15   module      => 'IC',
  16   cvars_alias => 1,
  17 );
  18
  19 __PACKAGE__->meta->add_relationships(
  20   assemblies                     => {
  21     type         => 'one to many',
  22     class        => 'SL::DB::Assembly',
  23     column_map   => { id => 'id' },
  24   },
  25   prices         => {
  26     type         => 'one to many',
  27     class        => 'SL::DB::Price',
  28     column_map   => { id => 'parts_id' },
  29   },
  30   makemodels     => {
  31     type         => 'one to many',
  32     class        => 'SL::DB::MakeModel',
  33     column_map   => { id => 'parts_id' },
  34   },
  35   translations   => {
  36     type         => 'one to many',
  37     class        => 'SL::DB::Translation',
  38     column_map   => { id => 'parts_id' },
  39   },
  40 );
  41
  42 __PACKAGE__->meta->initialize;
  43
  44 __PACKAGE__->before_save('_before_save_set_partnumber');
  45
  46 sub _before_save_set_partnumber {
  47   my ($self) = @_;
  48
  49   $self->create_trans_number if !$self->partnumber;
  50   return 1;
  51 }
  52
  53 sub is_type {
  54   my $self = shift;
  55   my $type  = lc(shift || '');
  56   die 'invalid type' unless $type =~ /^(?:part|service|assembly)$/;
  57
  58   return $self->type eq $type ? 1 : 0;
  59 }
  60
  61 sub is_part     { $_[0]->is_type('part') }
  62 sub is_assembly { $_[0]->is_type('assembly') }
  63 sub is_service  { $_[0]->is_type('service') }
  64
  65 sub type {
  66   my ($self, $type) = @_;
  67   if (@_ > 1) {
  68     die 'invalid type' unless $type =~ /^(?:part|service|assembly)$/;
  69     $self->assembly(          $type eq 'assembly' ? 1 : 0);
  70     $self->inventory_accno_id($type ne 'service'  ? 1 : undef);
  71   }
  72
  73   return 'assembly' if $self->assembly;
  74   return 'part'     if $self->inventory_accno_id;
  75   return 'service';
  76 }
  77
  78 sub new_part {
  79   my ($class, %params) = @_;
  80   $class->new(%params, type => 'part');
  81 }
  82
  83 sub new_assembly {
  84   my ($class, %params) = @_;
  85   $class->new(%params, type => 'assembly');
  86 }
  87
  88 sub new_service {
  89   my ($class, %params) = @_;
  90   $class->new(%params, type => 'service');
  91 }
  92
  93 sub orphaned {
  94   my ($self) = @_;
  95   die 'not an accessor' if @_ > 1;
  96
  97   my @relations = qw(
  98     SL::DB::InvoiceItem
  99     SL::DB::OrderItem
 100     SL::DB::Inventory
 101   );
 102
 103   for my $class (@relations) {
 104     eval "require $class";
 105     return 0 if $class->_get_manager_class->get_all_count(query => [ parts_id => $self->id ]);
 106   }
 107   return 1;
 108 }
 109
 110 sub get_sellprice_info {
 111   my $self   = shift;
 112   my %params = @_;
 113
 114   confess "Missing part id" unless $self->id;
 115
 116   my $object = $self->load;
 117
 118   return { sellprice       => $object->sellprice,
 119            price_factor_id => $object->price_factor_id };
 120 }
 121
 122 sub get_ordered_qty {
 123   my $self   = shift;
 124   my %result = SL::DB::Manager::Part->get_ordered_qty($self->id);
 125
 126   return $result{ $self->id };
 127 }
 128
 129 sub available_units {
 130   shift->unit_obj->convertible_units;
 131 }
 132
 133 # autogenerated accessor is slightly off...
 134 sub buchungsgruppe {
 135   shift->buchungsgruppen(@_);
 136 }
 137
 138 sub get_taxkey {
 139   my ($self, %params) = @_;
 140
 141   my $date     = $params{date} || DateTime->today_local;
 142   my $is_sales = !!$params{is_sales};
 143   my $taxzone  = $params{ defined($params{taxzone}) ? 'taxzone' : 'taxzone_id' } * 1;
 144
 145   $self->{__partpriv_taxkey_information} ||= { };
 146   my $tk_info = $self->{__partpriv_taxkey_information};
 147
 148   $tk_info->{$taxzone}              ||= { };
 149   $tk_info->{$taxzone}->{$is_sales} ||= { };
 150
 151   if (!exists $tk_info->{$taxzone}->{$is_sales}->{$date}) {
 152     $tk_info->{$taxzone}->{$is_sales}->{$date} =
 153       $self->get_chart(type => $is_sales ? 'income' : 'expense', taxzone => $taxzone)
 154       ->load
 155       ->get_active_taxkey($date);
 156   }
 157
 158   return $tk_info->{$taxzone}->{$is_sales}->{$date};
 159 }
 160
 161 sub get_chart {
 162   my ($self, %params) = @_;
 163
 164   my $type    = (any { $_ eq $params{type} } qw(income expense inventory)) ? $params{type} : croak("Invalid 'type' parameter '$params{type}'");
 165   my $taxzone = $params{ defined($params{taxzone}) ? 'taxzone' : 'taxzone_id' } * 1;
 166
 167   $self->{__partpriv_get_chart_id} ||= { };
 168   my $charts = $self->{__partpriv_get_chart_id};
 169
 170   $charts->{$taxzone} ||= { };
 171
 172   if (!exists $charts->{$taxzone}->{$type}) {
 173     my $bugru    = $self->buchungsgruppe;
 174     my $chart_id = ($type eq 'inventory') ? ($self->inventory_accno_id ? $bugru->inventory_accno_id : undef)
 175                  :                          $bugru->call_sub("${type}_accno_id_${taxzone}");
 176
 177     $charts->{$taxzone}->{$type} = $chart_id ? SL::DB::Chart->new(id => $chart_id)->load : undef;
 178   }
 179
 180   return $charts->{$taxzone}->{$type};
 181 }
 182
 183 # this is designed to ignore chargenumbers, expiration dates and just give a list of how much <-> where
 184 sub get_simple_stock {
 185   my ($self, %params) = @_;
 186
 187   return [] unless $self->id;
 188
 189   my $query = <<'';
 190     SELECT sum(qty), warehouse_id, bin_id FROM inventory WHERE parts_id = ?
 191     GROUP BY warehouse_id, bin_id
 192
 193   my $stock_info = selectall_hashref_query($::form, $::form->get_standard_dbh, $query, $self->id);
 194   [ map { bless $_, 'SL::DB::Part::SimpleStock'} @$stock_info ];
 195 }
 196 # helper class to have bin/warehouse accessors in stock result
 197 { package SL::DB::Part::SimpleStock;
 198   sub warehouse { require SL::DB::Warehouse; SL::DB::Manager::Warehouse->find_by_or_create(id => $_[0]->{warehouse_id}) }
 199   sub bin       { require SL::DB::Bin;       SL::DB::Manager::Bin      ->find_by_or_create(id => $_[0]->{bin_id}) }
 200 }
 201
 202 sub long_description {
 203   join ' ', grep $_, map $_[0]->$_, qw(partnumber description);
 204 }
 205
 206 1;
 207
 208 __END__
 209
 210 =pod
 211
 212 =encoding utf-8
 213
 214 =head1 NAME
 215
 216 SL::DB::Part: Model for the 'parts' table
 217
 218 =head1 SYNOPSIS
 219
 220 This is a standard Rose::DB::Object based model and can be used as one.
 221
 222 =head1 TYPES
 223
 224 Although the base class is called C<Part> we usually talk about C<Articles> if
 225 we mean instances of this class. This is because articles come in three
 226 flavours called:
 227
 228 =over 4
 229
 230 =item Part     - a single part
 231
 232 =item Service  - a part without onhand, and without inventory accounting
 233
 234 =item Assembly - a collection of both parts and services
 235
 236 =back
 237
 238 These types are sadly represented by data inside the class and cannot be
 239 migrated into a flag. To work around this, each C<Part> object knows what type
 240 it currently is. Since the type ist data driven, there ist no explicit setting
 241 method for it, but you can construct them explicitly with C<new_part>,
 242 C<new_service>, and C<new_assembly>. A Buchungsgruppe should be supplied in this
 243 case, but it will use the default Buchungsgruppe if you don't.
 244
 245 Matching these there are assorted helper methods dealing with types,
 246 e.g.  L</new_part>, L</new_service>, L</new_assembly>, L</type>,
 247 L</is_type> and others.
 248
 249 =head1 FUNCTIONS
 250
 251 =over 4
 252
 253 =item C<new_part %PARAMS>
 254
 255 =item C<new_service %PARAMS>
 256
 257 =item C<new_assembly %PARAMS>
 258
 259 Will set the appropriate data fields so that the resulting instance will be of
 260 tthe requested type. Since part of the distinction are accounting targets,
 261 providing a C<Buchungsgruppe> is recommended. If none is given the constructor
 262 will load a default one and set the accounting targets from it.
 263
 264 =item C<type>
 265
 266 Returns the type as a string. Can be one of C<part>, C<service>, C<assembly>.
 267
 268 =item C<is_type $TYPE>
 269
 270 Tests if the current object is a part, a service or an
 271 assembly. C<$type> must be one of the words 'part', 'service' or
 272 'assembly' (their plurals are ok, too).
 273
 274 Returns 1 if the requested type matches, 0 if it doesn't and
 275 C<confess>es if an unknown C<$type> parameter is encountered.
 276
 277 =item C<is_part>
 278
 279 =item C<is_service>
 280
 281 =item C<is_assembly>
 282
 283 Shorthand for C<is_type('part')> etc.
 284
 285 =item C<get_sellprice_info %params>
 286
 287 Retrieves the C<sellprice> and C<price_factor_id> for a part under
 288 different conditions and returns a hash reference with those two keys.
 289
 290 If C<%params> contains a key C<project_id> then a project price list
 291 will be consulted if one exists for that project. In this case the
 292 parameter C<country_id> is evaluated as well: if a price list entry
 293 has been created for this country then it will be used. Otherwise an
 294 entry without a country set will be used.
 295
 296 If none of the above conditions is met then the information from
 297 C<$self> is used.
 298
 299 =item C<get_ordered_qty %params>
 300
 301 Retrieves the quantity that has been ordered from a vendor but that
 302 has not been delivered yet. Only open purchase orders are considered.
 303
 304 =item C<get_taxkey %params>
 305
 306 Retrieves and returns a taxkey object valid for the given date
 307 C<$params{date}> and tax zone C<$params{taxzone}>
 308 (C<$params{taxzone_id}> is also recognized). The date defaults to the
 309 current date if undefined.
 310
 311 This function looks up the income (for trueish values of
 312 C<$params{is_sales}>) or expense (for falsish values of
 313 C<$params{is_sales}>) account for the current part. It uses the part's
 314 associated buchungsgruppe and uses the fields belonging to the tax
 315 zone given by C<$params{taxzone}> (range 0..3).
 316
 317 The information retrieved by the function is cached.
 318
 319 =item C<get_chart %params>
 320
 321 Retrieves and returns a chart object valid for the given type
 322 C<$params{type}> and tax zone C<$params{taxzone}>
 323 (C<$params{taxzone_id}> is also recognized). The type must be one of
 324 the three key words C<income>, C<expense> and C<inventory>.
 325
 326 This function uses the part's associated buchungsgruppe and uses the
 327 fields belonging to the tax zone given by C<$params{taxzone}> (range
 328 0..3).
 329
 330 The information retrieved by the function is cached.
 331
 332 =item C<orphaned>
 333
 334 Checks if this articke is used in orders, invoices, delivery orders or
 335 assemblies.
 336
 337 =item C<buchungsgruppe BUCHUNGSGRUPPE>
 338
 339 Used to set the accounting informations from a L<SL:DB::Buchungsgruppe> object.
 340 Please note, that this is a write only accessor, the original Buchungsgruppe can
 341 not be retrieved from an article once set.
 342
 343 =back
 344
 345 =head1 AUTHORS
 346
 347 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>,
 348 Sven Schöling E<lt>s.schoeling@linet-services.deE<gt>
 349
 350 =cut