SL/DB/Part.pm

   1 package SL::DB::Part;
   2
   3 use strict;
   4
   5 use Carp;
   6 use List::MoreUtils qw(any);
   7 use Rose::DB::Object::Helpers qw(as_tree);
   8
   9 use SL::DBUtils;
  10 use SL::DB::MetaSetup::Part;
  11 use SL::DB::Manager::Part;
  12 use SL::DB::Chart;
  13 use SL::DB::Helper::AttrHTML;
  14 use SL::DB::Helper::TransNumberGenerator;
  15 use SL::DB::Helper::CustomVariables (
  16   module      => 'IC',
  17   cvars_alias => 1,
  18 );
  19
  20 __PACKAGE__->meta->add_relationships(
  21   assemblies                     => {
  22     type         => 'one to many',
  23     class        => 'SL::DB::Assembly',
  24     column_map   => { id => 'id' },
  25   },
  26   prices         => {
  27     type         => 'one to many',
  28     class        => 'SL::DB::Price',
  29     column_map   => { id => 'parts_id' },
  30   },
  31   makemodels     => {
  32     type         => 'one to many',
  33     class        => 'SL::DB::MakeModel',
  34     column_map   => { id => 'parts_id' },
  35   },
  36   translations   => {
  37     type         => 'one to many',
  38     class        => 'SL::DB::Translation',
  39     column_map   => { id => 'parts_id' },
  40   },
  41   assortment_items => {
  42     type         => 'one to many',
  43     class        => 'SL::DB::AssortmentItem',
  44     column_map   => { id => 'assortment_id' },
  45   },
  46 );
  47
  48 __PACKAGE__->meta->initialize;
  49
  50 __PACKAGE__->attr_html('notes');
  51
  52 __PACKAGE__->before_save('_before_save_set_partnumber');
  53
  54 sub _before_save_set_partnumber {
  55   my ($self) = @_;
  56
  57   $self->create_trans_number if !$self->partnumber;
  58   return 1;
  59 }
  60
  61 sub is_type {
  62   my $self = shift;
  63   my $type  = lc(shift || '');
  64   die 'invalid type' unless $type =~ /^(?:part|service|assembly|assortment)$/;
  65
  66   return $self->type eq $type ? 1 : 0;
  67 }
  68
  69 sub is_part       { $_[0]->part_type eq 'part'       }
  70 sub is_assembly   { $_[0]->part_type eq 'assembly'   }
  71 sub is_service    { $_[0]->part_type eq 'service'    }
  72 sub is_assortment { $_[0]->part_type eq 'assortment' }
  73
  74 sub type {
  75   return $_[0]->part_type;
  76   # my ($self, $type) = @_;
  77   # if (@_ > 1) {
  78   #   die 'invalid type' unless $type =~ /^(?:part|service|assembly)$/;
  79   #   $self->assembly(          $type eq 'assembly' ? 1 : 0);
  80   #   $self->inventory_accno_id($type ne 'service'  ? 1 : undef);
  81   # }
  82
  83   # return 'assembly' if $self->assembly;
  84   # return 'part'     if $self->inventory_accno_id;
  85   # return 'service';
  86 }
  87
  88 sub new_part {
  89   my ($class, %params) = @_;
  90   $class->new(%params, part_type => 'part');
  91 }
  92
  93 sub new_assembly {
  94   my ($class, %params) = @_;
  95   $class->new(%params, part_type => 'assembly');
  96 }
  97
  98 sub new_service {
  99   my ($class, %params) = @_;
 100   $class->new(%params, part_type => 'service');
 101 }
 102
 103 sub new_assortment {
 104   my ($class, %params) = @_;
 105   $class->new(%params, part_type => 'assortment');
 106 }
 107
 108 sub orphaned {
 109   my ($self) = @_;
 110   die 'not an accessor' if @_ > 1;
 111
 112   my @relations = qw(
 113     SL::DB::InvoiceItem
 114     SL::DB::OrderItem
 115     SL::DB::Inventory
 116     SL::DB::Assembly
 117     SL::DB::AssortmentItem
 118   );
 119
 120   for my $class (@relations) {
 121     eval "require $class";
 122     return 0 if $class->_get_manager_class->get_all_count(query => [ parts_id => $self->id ]);
 123   }
 124   return 1;
 125 }
 126
 127 sub get_sellprice_info {
 128   my $self   = shift;
 129   my %params = @_;
 130
 131   confess "Missing part id" unless $self->id;
 132
 133   my $object = $self->load;
 134
 135   return { sellprice       => $object->sellprice,
 136            price_factor_id => $object->price_factor_id };
 137 }
 138
 139 sub get_ordered_qty {
 140   my $self   = shift;
 141   my %result = SL::DB::Manager::Part->get_ordered_qty($self->id);
 142
 143   return $result{ $self->id };
 144 }
 145
 146 sub available_units {
 147   shift->unit_obj->convertible_units;
 148 }
 149
 150 # autogenerated accessor is slightly off...
 151 sub buchungsgruppe {
 152   shift->buchungsgruppen(@_);
 153 }
 154
 155 sub get_taxkey {
 156   my ($self, %params) = @_;
 157
 158   my $date     = $params{date} || DateTime->today_local;
 159   my $is_sales = !!$params{is_sales};
 160   my $taxzone  = $params{ defined($params{taxzone}) ? 'taxzone' : 'taxzone_id' } * 1;
 161   my $tk_info  = $::request->cache('get_taxkey');
 162
 163   $tk_info->{$self->id}                                      //= {};
 164   $tk_info->{$self->id}->{$taxzone}                          //= { };
 165   my $cache = $tk_info->{$self->id}->{$taxzone}->{$is_sales} //= { };
 166
 167   if (!exists $cache->{$date}) {
 168     $cache->{$date} =
 169       $self->get_chart(type => $is_sales ? 'income' : 'expense', taxzone => $taxzone)
 170       ->get_active_taxkey($date);
 171   }
 172
 173   return $cache->{$date};
 174 }
 175
 176 sub get_chart {
 177   my ($self, %params) = @_;
 178
 179   my $type    = (any { $_ eq $params{type} } qw(income expense inventory)) ? $params{type} : croak("Invalid 'type' parameter '$params{type}'");
 180   my $taxzone = $params{ defined($params{taxzone}) ? 'taxzone' : 'taxzone_id' } * 1;
 181
 182   my $charts     = $::request->cache('get_chart_id/by_part_id_and_taxzone')->{$self->id} //= {};
 183   my $all_charts = $::request->cache('get_chart_id/by_id');
 184
 185   $charts->{$taxzone} ||= { };
 186
 187   if (!exists $charts->{$taxzone}->{$type}) {
 188     require SL::DB::Buchungsgruppe;
 189     my $bugru    = SL::DB::Buchungsgruppe->load_cached($self->buchungsgruppen_id);
 190     my $chart_id = ($type eq 'inventory') ? ($self->inventory_accno_id ? $bugru->inventory_accno_id : undef)
 191                  :                          $bugru->call_sub("${type}_accno_id", $taxzone);
 192
 193     if ($chart_id) {
 194       my $chart                    = $all_charts->{$chart_id} // SL::DB::Chart->load_cached($chart_id)->load;
 195       $all_charts->{$chart_id}     = $chart;
 196       $charts->{$taxzone}->{$type} = $chart;
 197     }
 198   }
 199
 200   return $charts->{$taxzone}->{$type};
 201 }
 202
 203 # this is designed to ignore chargenumbers, expiration dates and just give a list of how much <-> where
 204 sub get_simple_stock {
 205   my ($self, %params) = @_;
 206
 207   return [] unless $self->id;
 208
 209   my $query = <<'';
 210     SELECT sum(qty), warehouse_id, bin_id FROM inventory WHERE parts_id = ?
 211     GROUP BY warehouse_id, bin_id
 212
 213   my $stock_info = selectall_hashref_query($::form, $::form->get_standard_dbh, $query, $self->id);
 214   [ map { bless $_, 'SL::DB::Part::SimpleStock'} @$stock_info ];
 215 }
 216 # helper class to have bin/warehouse accessors in stock result
 217 { package SL::DB::Part::SimpleStock;
 218   sub warehouse { require SL::DB::Warehouse; SL::DB::Manager::Warehouse->find_by_or_create(id => $_[0]->{warehouse_id}) }
 219   sub bin       { require SL::DB::Bin;       SL::DB::Manager::Bin      ->find_by_or_create(id => $_[0]->{bin_id}) }
 220 }
 221
 222 sub displayable_name {
 223   join ' ', grep $_, map $_[0]->$_, qw(partnumber description);
 224 }
 225
 226 1;
 227
 228 __END__
 229
 230 =pod
 231
 232 =encoding utf-8
 233
 234 =head1 NAME
 235
 236 SL::DB::Part: Model for the 'parts' table
 237
 238 =head1 SYNOPSIS
 239
 240 This is a standard Rose::DB::Object based model and can be used as one.
 241
 242 =head1 TYPES
 243
 244 Although the base class is called C<Part> we usually talk about C<Articles> if
 245 we mean instances of this class. This is because articles come in three
 246 flavours called:
 247
 248 =over 4
 249
 250 =item Part     - a single part
 251
 252 =item Service  - a part without onhand, and without inventory accounting
 253
 254 =item Assembly - a collection of both parts and services
 255
 256 =item Assortment - a collection of parts
 257
 258 =back
 259
 260 These types are sadly represented by data inside the class and cannot be
 261 migrated into a flag. To work around this, each C<Part> object knows what type
 262 it currently is. Since the type is data driven, there ist no explicit setting
 263 method for it, but you can construct them explicitly with C<new_part>,
 264 C<new_service>, C<new_assembly> and C<new_assortment>. A Buchungsgruppe should be supplied in this
 265 case, but it will use the default Buchungsgruppe if you don't.
 266
 267 Matching these there are assorted helper methods dealing with types,
 268 e.g.  L</new_part>, L</new_service>, L</new_assembly>, L</type>,
 269 L</is_type> and others.
 270
 271 =head1 FUNCTIONS
 272
 273 =over 4
 274
 275 =item C<new_part %PARAMS>
 276
 277 =item C<new_service %PARAMS>
 278
 279 =item C<new_assembly %PARAMS>
 280
 281 Will set the appropriate data fields so that the resulting instance will be of
 282 the requested type. Since accounting targets are part of the distinction,
 283 providing a C<Buchungsgruppe> is recommended. If none is given the constructor
 284 will load a default one and set the accounting targets from it.
 285
 286 =item C<type>
 287
 288 Returns the type as a string. Can be one of C<part>, C<service>, C<assembly>.
 289
 290 =item C<is_type $TYPE>
 291
 292 Tests if the current object is a part, a service or an
 293 assembly. C<$type> must be one of the words 'part', 'service' or
 294 'assembly' (their plurals are ok, too).
 295
 296 Returns 1 if the requested type matches, 0 if it doesn't and
 297 C<confess>es if an unknown C<$type> parameter is encountered.
 298
 299 =item C<is_part>
 300
 301 =item C<is_service>
 302
 303 =item C<is_assembly>
 304
 305 Shorthand for C<is_type('part')> etc.
 306
 307 =item C<get_sellprice_info %params>
 308
 309 Retrieves the C<sellprice> and C<price_factor_id> for a part under
 310 different conditions and returns a hash reference with those two keys.
 311
 312 If C<%params> contains a key C<project_id> then a project price list
 313 will be consulted if one exists for that project. In this case the
 314 parameter C<country_id> is evaluated as well: if a price list entry
 315 has been created for this country then it will be used. Otherwise an
 316 entry without a country set will be used.
 317
 318 If none of the above conditions is met then the information from
 319 C<$self> is used.
 320
 321 =item C<get_ordered_qty %params>
 322
 323 Retrieves the quantity that has been ordered from a vendor but that
 324 has not been delivered yet. Only open purchase orders are considered.
 325
 326 =item C<get_taxkey %params>
 327
 328 Retrieves and returns a taxkey object valid for the given date
 329 C<$params{date}> and tax zone C<$params{taxzone}>
 330 (C<$params{taxzone_id}> is also recognized). The date defaults to the
 331 current date if undefined.
 332
 333 This function looks up the income (for trueish values of
 334 C<$params{is_sales}>) or expense (for falsish values of
 335 C<$params{is_sales}>) account for the current part. It uses the part's
 336 associated buchungsgruppe and uses the fields belonging to the tax
 337 zone given by C<$params{taxzone}>.
 338
 339 The information retrieved by the function is cached.
 340
 341 =item C<get_chart %params>
 342
 343 Retrieves and returns a chart object valid for the given type
 344 C<$params{type}> and tax zone C<$params{taxzone}>
 345 (C<$params{taxzone_id}> is also recognized). The type must be one of
 346 the three key words C<income>, C<expense> and C<inventory>.
 347
 348 This function uses the part's associated buchungsgruppe and uses the
 349 fields belonging to the tax zone given by C<$params{taxzone}>.
 350
 351 The information retrieved by the function is cached.
 352
 353 =item C<orphaned>
 354
 355 Checks if this article is used in orders, invoices, delivery orders or
 356 assemblies.
 357
 358 =item C<buchungsgruppe BUCHUNGSGRUPPE>
 359
 360 Used to set the accounting information from a L<SL:DB::Buchungsgruppe> object.
 361 Please note, that this is a write only accessor, the original Buchungsgruppe can
 362 not be retrieved from an article once set.
 363
 364 =back
 365
 366 =head1 AUTHORS
 367
 368 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>,
 369 Sven Schöling E<lt>s.schoeling@linet-services.deE<gt>
 370
 371 =cut