SL/DB/RequirementSpecItem.pm

   1 package SL::DB::RequirementSpecItem;
   2
   3 use strict;
   4
   5 use Carp;
   6 use List::MoreUtils qw(any);
   7 use Rose::DB::Object::Helpers;
   8 use Rose::DB::Object::Util;
   9
  10 use SL::Common ();
  11 use SL::DB::MetaSetup::RequirementSpecItem;
  12 use SL::DB::Manager::RequirementSpecItem;
  13 use SL::DB::Helper::ActsAsList;
  14 use SL::DB::Helper::AttrDuration;
  15 use SL::DB::Helper::AttrHTML;
  16 use SL::DB::Default;
  17 use SL::Locale::String;
  18 use SL::PrefixedNumber;
  19
  20 __PACKAGE__->meta->add_relationship(
  21   children     => {
  22     type       => 'one to many',
  23     class      => 'SL::DB::RequirementSpecItem',
  24     column_map => { id => 'parent_id' },
  25   },
  26   dependencies => {
  27     map_class  => 'SL::DB::RequirementSpecDependency',
  28     map_from   => 'depending_item',
  29     map_to     => 'depended_item',
  30     type       => 'many to many',
  31   },
  32   dependents   => {
  33     map_class  => 'SL::DB::RequirementSpecDependency',
  34     map_from   => 'depended_item',
  35     map_to     => 'depending_item',
  36     type       => 'many to many',
  37   },
  38 );
  39
  40 __PACKAGE__->meta->initialize;
  41
  42 __PACKAGE__->configure_acts_as_list(group_by => [qw(requirement_spec_id parent_id)]);
  43 __PACKAGE__->attr_duration(qw(time_estimation));
  44 __PACKAGE__->attr_html('description');
  45
  46 __PACKAGE__->before_save(\&_before_save_create_fb_number);
  47 __PACKAGE__->before_save(\&_before_save_invalidate_requirement_spec_version);
  48 __PACKAGE__->before_delete(\&_before_delete_invalidate_requirement_spec_version);
  49
  50 sub _before_save_create_fb_number {
  51   my ($self) = @_;
  52
  53   return 1 if  $self->fb_number;
  54   return 0 if !$self->requirement_spec_id;
  55
  56   my $method      = 'previous_' . ($self->parent_id ? 'fb' : 'section') . '_number';
  57   my $next_number = $self->requirement_spec->$method + 1;
  58
  59   $self->requirement_spec->update_attributes($method => $next_number) || return 0;
  60
  61   $method    = ($self->parent_id ? 'function_block' : 'section') . '_number_format';
  62   my $format = $self->requirement_spec->type->$method;
  63
  64   $self->fb_number(SL::PrefixedNumber->new(number => $format || 0)->set_to($next_number));
  65
  66   return 1;
  67 }
  68
  69 sub _before_save_invalidate_requirement_spec_version {
  70   my ($self, %params) = @_;
  71
  72   return 1 if !$self->requirement_spec_id || $self->requirement_spec->working_copy_id;
  73
  74   my %changed_columns = map { $_ => 1 } (Rose::DB::Object::Helpers::dirty_columns($self));
  75   my $has_changed     = !Rose::DB::Object::Util::is_in_db($self);
  76   $has_changed      ||= any { $changed_columns{$_} } qw(requirement_spec_id parent_id position fb_number title description);
  77
  78   if (!$has_changed && $self->id) {
  79     my $old_item = SL::DB::RequirementSpecItem->new(id => $self->id)->load;
  80     $has_changed = join(':', sort map { $_->id } @{ $self->dependencies }) ne join(':', sort map { $_->id } @{ $old_item->dependencies });
  81   }
  82
  83   $self->requirement_spec->invalidate_version if $has_changed;
  84
  85   return 1;
  86 }
  87
  88 sub _before_delete_invalidate_requirement_spec_version {
  89   my ($self, %params) = @_;
  90
  91   $self->requirement_spec->invalidate_version if $self->requirement_spec_id;
  92
  93   return 1;
  94 }
  95
  96 sub validate {
  97   my ($self) = @_;
  98
  99   my @errors;
 100   push @errors, t8('The title is missing.') if !$self->parent_id && !$self->title;
 101
 102   return @errors;
 103 }
 104
 105 sub children_sorted {
 106   my ($self, @args) = @_;
 107
 108   croak "Not a writer" if @args;
 109
 110   return [ sort { $a->position <=> $b->position } $self->children ];
 111 }
 112
 113 sub section {
 114   my ($self, @args) = @_;
 115
 116   croak "Not a writer" if @args;
 117   $self = $self->parent while $self->parent_id;
 118
 119   return $self;
 120 }
 121
 122 sub child_type {
 123   my ($self, @args) = @_;
 124
 125   croak "Not a writer" if @args;
 126
 127   return $self->item_type eq 'section' ? 'function-block' : 'sub-function-block';
 128 }
 129
 130 sub content_excerpt {
 131   my ($self) = @_;
 132
 133   return Common::truncate($self->description_as_stripped_html // '', at => 200);
 134 }
 135
 136
 137 1;
 138 __END__
 139
 140 =pod
 141
 142 =encoding utf8
 143
 144 =head1 NAME
 145
 146 SL::DB::RequirementSpecItem - Items for requirement specs
 147
 148 =head1 OVERVIEW
 149
 150 Please see L<SL::DB::RequirementSpec> for the architectual overview.
 151
 152 =head1 FUNCTIONS
 153
 154 =over 4
 155
 156 =item C<child_type>
 157
 158 Returns the C<item_type> for children of C<$self>.
 159
 160 =item C<children_sorted>
 161
 162 Returns an array reference of direct children (not of grandchildren)
 163 for C<$self> ordered by their positional column in ascending order.
 164
 165 =item C<section>
 166
 167 Returns the section this item belongs to. It can be C<$self> if
 168 C<$self> is already a section, its parent or grandparent.
 169
 170 =item C<validate>
 171
 172 Validates before saving and returns an array of human-readable error
 173 messages in case of an error.
 174
 175 =back
 176
 177 =head1 BUGS
 178
 179 Nothing here yet.
 180
 181 =head1 AUTHOR
 182
 183 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 184
 185 =cut