SL/DB/Unit.pm

   1 package SL::DB::Unit;
   2
   3 use strict;
   4
   5 use SL::DB::MetaSetup::Unit;
   6 use SL::DB::Manager::Unit;
   7 use SL::DB::Helper::ActsAsList;
   8
   9 __PACKAGE__->meta->add_relationships(
  10   base => {
  11     type         => 'many to one',
  12     class        => 'SL::DB::Unit',
  13     column_map   => { base_unit => 'name' },
  14   },
  15 );
  16
  17 __PACKAGE__->meta->initialize;
  18
  19 #methods
  20
  21 sub unit_class {
  22   my $self   = shift;
  23
  24   return $self if !$self->base_unit || $self->name eq $self->base_unit;
  25   return $self->base->unit_class;
  26 }
  27
  28 sub convertible_units {
  29   my $self = shift;
  30   my $all_units = scalar(@_) && (ref($_[0]) eq 'ARRAY') ? $_[0] : [ @_ ];
  31   $all_units    = SL::DB::Manager::Unit->all_units if ! @{ $all_units };
  32   return [
  33     sort { $a->sortkey <=> $b->sortkey }
  34     grep { $_->unit_class->name eq $self->unit_class->name }
  35     @{ $all_units }
  36   ];
  37 }
  38
  39 sub base_factor {
  40   my ($self) = @_;
  41
  42   my $cache = $::request->cache('base_factor');
  43
  44   if (!defined $cache->{$self->id}) {
  45     $cache->{$self->id} = !$self->base_unit || !$self->factor || ($self->name eq $self->base_unit) ? 1 : $self->factor * $self->base->base_factor;
  46   }
  47
  48   return $cache->{$self->id};
  49 }
  50
  51 sub convert_to {
  52   my ($self, $qty, $other_unit) = @_;
  53
  54   my $my_base_factor    = $self->base_factor       || 1;
  55   my $other_base_factor = $other_unit->base_factor || 1;
  56
  57   return $qty * $my_base_factor / $other_base_factor;
  58 }
  59
  60 1;