SL/DB.pm

   1 package SL::DB;
   2
   3 use strict;
   4
   5 use Carp;
   6 use Data::Dumper;
   7 use English qw(-no_match_vars);
   8 use Rose::DB;
   9
  10 use base qw(Rose::DB);
  11
  12 __PACKAGE__->use_private_registry;
  13
  14 my (%_db_registered, %_initial_sql_executed);
  15
  16 sub create {
  17   my $domain = shift || SL::DB->default_domain;
  18   my $type   = shift || SL::DB->default_type;
  19
  20   my ($domain, $type) = _register_db($domain, $type);
  21
  22   my $db = __PACKAGE__->new_or_cached(domain => $domain, type => $type);
  23
  24   _execute_initial_sql($db);
  25
  26   return $db;
  27 }
  28
  29 my %_dateformats = ( 'yy-mm-dd'   => 'ISO',
  30                      'yyyy-mm-dd' => 'ISO',
  31                      'mm/dd/yy'   => 'SQL, US',
  32                      'mm-dd-yy'   => 'POSTGRES, US',
  33                      'dd/mm/yy'   => 'SQL, EUROPEAN',
  34                      'dd-mm-yy'   => 'POSTGRES, EUROPEAN',
  35                      'dd.mm.yy'   => 'GERMAN'
  36                    );
  37
  38 sub _register_db {
  39   my $domain = shift;
  40   my $type   = shift;
  41
  42   my %connect_settings;
  43   my $initial_sql;
  44
  45   if (!%::myconfig) {
  46     $type = 'LXOFFICE_EMPTY';
  47     %connect_settings = ( driver => 'Pg' );
  48
  49   } elsif ($type eq 'LXOFFICE_AUTH') {
  50     %connect_settings = ( driver          => $::myconfig{dbdriver} || 'Pg',
  51                           database        => $::auth->{DB_config}->{db},
  52                           host            => $::auth->{DB_config}->{host},
  53                           port            => $::auth->{DB_config}->{port} || 5432,
  54                           username        => $::auth->{DB_config}->{user},
  55                           password        => $::auth->{DB_config}->{password},
  56                           connect_options => { pg_enable_utf8 => $::locale && $::locale->is_utf8,
  57                                              });
  58   } else {
  59     my $european_dates = 0;
  60     if ($::myconfig{dateformat}) {
  61       $european_dates = 1 if $_dateformats{ $::myconfig{dateformat} } =~ m/european/i;
  62     }
  63
  64     %connect_settings = ( driver          => $::myconfig{dbdriver} || 'Pg',
  65                           database        => $::myconfig{dbname},
  66                           host            => $::myconfig{dbhost},
  67                           port            => $::myconfig{dbport} || 5432,
  68                           username        => $::myconfig{dbuser},
  69                           password        => $::myconfig{dbpasswd},
  70                           connect_options => { pg_enable_utf8 => $::locale && $::locale->is_utf8,
  71                                              },
  72                           european_dates  => $european_dates);
  73   }
  74
  75   my %flattened_settings = _flatten_settings(%connect_settings);
  76
  77   $domain = 'LXOFFICE' if $type =~ m/^LXOFFICE/;
  78   $type  .= join($SUBSCRIPT_SEPARATOR, map { ($_, $flattened_settings{$_}) } sort keys %flattened_settings);
  79   my $idx = "${domain}::${type}";
  80
  81   if (!$_db_registered{$idx}) {
  82     $_db_registered{$idx} = 1;
  83
  84     __PACKAGE__->register_db(domain => $domain,
  85                              type   => $type,
  86                              %connect_settings,
  87                             );
  88   }
  89
  90   return ($domain, $type);
  91 }
  92
  93 sub _execute_initial_sql {
  94   my ($db) = @_;
  95
  96   return if $_initial_sql_executed{$db} || !%::myconfig || !$::myconfig{dateformat};
  97
  98   $_initial_sql_executed{$db} = 1;
  99
 100   # Don't rely on dboptions being set properly. Chose them from
 101   # dateformat instead.
 102   my $pg_dateformat = $_dateformats{ $::myconfig{dateformat} };
 103   $db->dbh->do("set DateStyle to '${pg_dateformat}'") if $pg_dateformat;
 104 }
 105
 106 sub _flatten_settings {
 107   my %settings  = @_;
 108   my %flattened = ();
 109
 110   while (my ($key, $value) = each %settings) {
 111     if ('HASH' eq ref $value) {
 112       %flattened = ( %flattened, _flatten_settings(%{ $value }) );
 113     } else {
 114       $flattened{$key} = $value;
 115     }
 116   }
 117
 118   return %flattened;
 119 }
 120
 121 1;