SL/DN.pm

   1 #======================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2006
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (C) 1998-2002
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #  Contributors:
  16 #
  17 # This program is free software; you can redistribute it and/or modify
  18 # it under the terms of the GNU General Public License as published by
  19 # the Free Software Foundation; either version 2 of the License, or
  20 # (at your option) any later version.
  21 #
  22 # This program is distributed in the hope that it will be useful,
  23 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  24 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25 # GNU General Public License for more details.
  26 # You should have received a copy of the GNU General Public License
  27 # along with this program; if not, write to the Free Software
  28 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  29 #======================================================================
  30 #
  31 # Dunning process module
  32 #
  33 #======================================================================
  34
  35 package DN;
  36
  37 use SL::Common;
  38 use SL::DBUtils;
  39 use SL::IS;
  40 use SL::Mailer;
  41 use SL::MoreCommon;
  42 use SL::Template;
  43
  44 sub get_config {
  45   $main::lxdebug->enter_sub();
  46
  47   my ($self, $myconfig, $form) = @_;
  48
  49   # connect to database
  50   my $dbh = $form->dbconnect($myconfig);
  51
  52   my $query =
  53     qq|SELECT * | .
  54     qq|FROM dunning_config | .
  55     qq|ORDER BY dunning_level|;
  56   $form->{DUNNING} = selectall_hashref_query($form, $dbh, $query);
  57
  58   foreach my $ref (@{ $form->{DUNNING} }) {
  59     $ref->{fee} = $form->format_amount($myconfig, $ref->{fee}, 2);
  60     $ref->{interest_rate} = $form->format_amount($myconfig, ($ref->{interest_rate} * 100));
  61   }
  62
  63   $query =
  64     qq|SELECT dunning_ar_amount_fee, dunning_ar_amount_interest, dunning_ar
  65        FROM defaults|;
  66   ($form->{AR_amount_fee}, $form->{AR_amount_interest}, $form->{AR}) = selectrow_query($form, $dbh, $query);
  67
  68   $dbh->disconnect();
  69
  70   $main::lxdebug->leave_sub();
  71 }
  72
  73 sub save_config {
  74   $main::lxdebug->enter_sub();
  75
  76   my ($self, $myconfig, $form) = @_;
  77
  78   # connect to database
  79   my $dbh = $form->dbconnect_noauto($myconfig);
  80
  81   my ($query, @values);
  82
  83   for my $i (1 .. $form->{rowcount}) {
  84     $form->{"fee_$i"} = $form->parse_amount($myconfig, $form->{"fee_$i"}) * 1;
  85     $form->{"interest_rate_$i"} = $form->parse_amount($myconfig, $form->{"interest_rate_$i"}) / 100;
  86
  87     if (($form->{"dunning_level_$i"} ne "") &&
  88         ($form->{"dunning_description_$i"} ne "")) {
  89       @values = (conv_i($form->{"dunning_level_$i"}), $form->{"dunning_description_$i"},
  90                  $form->{"email_subject_$i"}, $form->{"email_body_$i"},
  91                  $form->{"template_$i"}, $form->{"fee_$i"}, $form->{"interest_rate_$i"},
  92                  $form->{"active_$i"} ? 't' : 'f', $form->{"auto_$i"} ? 't' : 'f', $form->{"email_$i"} ? 't' : 'f',
  93                  $form->{"email_attachment_$i"} ? 't' : 'f', conv_i($form->{"payment_terms_$i"}), conv_i($form->{"terms_$i"}),
  94                  $form->{"create_invoices_for_fees_$i"} ? 't' : 'f');
  95       if ($form->{"id_$i"}) {
  96         $query =
  97           qq|UPDATE dunning_config SET
  98                dunning_level = ?, dunning_description = ?,
  99                email_subject = ?, email_body = ?,
 100                template = ?, fee = ?, interest_rate = ?,
 101                active = ?, auto = ?, email = ?,
 102                email_attachment = ?, payment_terms = ?, terms = ?,
 103                create_invoices_for_fees = ?
 104              WHERE id = ?|;
 105         push(@values, conv_i($form->{"id_$i"}));
 106       } else {
 107         $query =
 108           qq|INSERT INTO dunning_config
 109                (dunning_level, dunning_description, email_subject, email_body,
 110                 template, fee, interest_rate, active, auto, email,
 111                 email_attachment, payment_terms, terms, create_invoices_for_fees)
 112              VALUES (?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?)|;
 113       }
 114       do_query($form, $dbh, $query, @values);
 115     }
 116
 117     if (($form->{"dunning_description_$i"} eq "") && ($form->{"id_$i"})) {
 118       $query = qq|DELETE FROM dunning_config WHERE id = ?|;
 119       do_query($form, $dbh, $query, $form->{"id_$i"});
 120     }
 121   }
 122
 123   $query  = qq|UPDATE defaults SET dunning_ar_amount_fee = ?, dunning_ar_amount_interest = ?, dunning_ar = ?|;
 124   @values = (conv_i($form->{AR_amount_fee}), conv_i($form->{AR_amount_interest}), conv_i($form->{AR}));
 125   do_query($form, $dbh, $query, @values);
 126
 127   $dbh->commit();
 128   $dbh->disconnect();
 129
 130   $main::lxdebug->leave_sub();
 131 }
 132
 133 sub create_invoice_for_fees {
 134   $main::lxdebug->enter_sub();
 135
 136   my ($self, $myconfig, $form, $dbh, $dunning_id) = @_;
 137
 138   my ($query, @values, $sth, $ref);
 139
 140   $query = qq|SELECT dcfg.create_invoices_for_fees
 141               FROM dunning d
 142               LEFT JOIN dunning_config dcfg ON (d.dunning_config_id = dcfg.id)
 143               WHERE d.dunning_id = ?|;
 144   my ($create_invoices_for_fees) = selectrow_query($form, $dbh, $query, $dunning_id);
 145
 146   if (!$create_invoices_for_fees) {
 147     $main::lxdebug->leave_sub();
 148     return;
 149   }
 150
 151   $query = qq|SELECT dunning_ar_amount_fee, dunning_ar_amount_interest, dunning_ar FROM defaults|;
 152   ($form->{AR_amount_fee}, $form->{AR_amount_interest}, $form->{AR}) = selectrow_query($form, $dbh, $query);
 153
 154   $query =
 155     qq|SELECT
 156          fee,
 157          COALESCE((
 158            SELECT MAX(d_fee.fee)
 159            FROM dunning d_fee
 160            WHERE (d_fee.trans_id   =  d.trans_id)
 161              AND (d_fee.dunning_id <> ?)
 162              AND NOT (d_fee.fee_interest_ar_id ISNULL)
 163          ), 0)
 164          AS max_previous_fee,
 165          interest,
 166          COALESCE((
 167            SELECT MAX(d_interest.interest)
 168            FROM dunning d_interest
 169            WHERE (d_interest.trans_id   =  d.trans_id)
 170              AND (d_interest.dunning_id <> ?)
 171              AND NOT (d_interest.fee_interest_ar_id ISNULL)
 172          ), 0)
 173          AS max_previous_interest
 174        FROM dunning d
 175        WHERE dunning_id = ?|;
 176   @values = ($dunning_id, $dunning_id, $dunning_id);
 177   $sth = prepare_execute_query($form, $dbh, $query, @values);
 178
 179   my ($fee_remaining, $interest_remaining) = (0, 0);
 180   my ($fee_total, $interest_total) = (0, 0);
 181
 182   while (my $ref = $sth->fetchrow_hashref()) {
 183     $fee_remaining      += $form->round_amount($ref->{fee}, 2);
 184     $fee_remaining      -= $form->round_amount($ref->{max_previous_fee}, 2);
 185     $fee_total          += $form->round_amount($ref->{fee}, 2);
 186     $interest_remaining += $form->round_amount($ref->{interest}, 2);
 187     $interest_remaining -= $form->round_amount($ref->{max_previous_interest}, 2);
 188     $interest_total     += $form->round_amount($ref->{interest}, 2);
 189   }
 190
 191   $sth->finish();
 192
 193   my $amount = $fee_remaining + $interest_remaining;
 194
 195   if (!$amount) {
 196     $main::lxdebug->leave_sub();
 197     return;
 198   }
 199
 200   my ($ar_id) = selectrow_query($form, $dbh, qq|SELECT nextval('glid')|);
 201   my $curr = $form->get_default_currency($myconfig);
 202
 203   $query =
 204     qq|INSERT INTO ar (id,          invnumber, transdate, gldate, customer_id,
 205                        taxincluded, amount,    netamount, paid,   duedate,
 206                        invoice,     curr,      notes,
 207                        employee_id)
 208        VALUES (
 209          ?,                     -- id
 210          ?,                     -- invnumber
 211          current_date,          -- transdate
 212          current_date,          -- gldate
 213          -- customer_id:
 214          (SELECT ar.customer_id
 215           FROM dunning dn
 216           LEFT JOIN ar ON (dn.trans_id = ar.id)
 217           WHERE dn.dunning_id = ?
 218           LIMIT 1),
 219          'f',                   -- taxincluded
 220          ?,                     -- amount
 221          ?,                     -- netamount
 222          0,                     -- paid
 223          -- duedate:
 224          (SELECT duedate FROM dunning WHERE dunning_id = ? LIMIT 1),
 225          'f',                   -- invoice
 226          ?,                     -- curr
 227          ?,                     -- notes
 228          -- employee_id:
 229          (SELECT id FROM employee WHERE login = ?)
 230        )|;
 231   @values = ($ar_id,            # id
 232              $form->update_defaults($myconfig, 'invnumber', $dbh), # invnumber
 233              $dunning_id,       # customer_id
 234              $amount,
 235              $amount,
 236              $dunning_id,       # duedate
 237              $curr,             # default currency
 238              sprintf($main::locale->text('Automatically created invoice for fee and interest for dunning %s'), $dunning_id), # notes
 239              $form->{login});   # employee_id
 240   do_query($form, $dbh, $query, @values);
 241
 242   $query =
 243     qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, gldate, taxkey)
 244        VALUES (?, ?, ?, current_date, current_date, 0)|;
 245   $sth = prepare_query($form, $dbh, $query);
 246
 247   @values = ($ar_id, conv_i($form->{AR_amount_fee}), $fee_remaining);
 248   do_statement($form, $sth, $query, @values);
 249
 250   if ($interest_remaining) {
 251     @values = ($ar_id, conv_i($form->{AR_amount_interest}), $interest_remaining);
 252     do_statement($form, $sth, $query, @values);
 253   }
 254
 255   @values = ($ar_id, conv_i($form->{AR}), -1 * $amount);
 256   do_statement($form, $sth, $query, @values);
 257
 258   $sth->finish();
 259
 260   $query = qq|UPDATE dunning SET fee_interest_ar_id = ? WHERE dunning_id = ?|;
 261   do_query($form, $dbh, $query, $ar_id, $dunning_id);
 262
 263   $main::lxdebug->leave_sub();
 264 }
 265
 266 sub save_dunning {
 267   $main::lxdebug->enter_sub();
 268
 269   my ($self, $myconfig, $form, $rows, $userspath, $spool) = @_;
 270   # connect to database
 271   my $dbh = $form->dbconnect_noauto($myconfig);
 272
 273   my ($query, @values);
 274
 275   my ($dunning_id) = selectrow_query($form, $dbh, qq|SELECT nextval('id')|);
 276
 277   my $q_update_ar = qq|UPDATE ar SET dunning_config_id = ? WHERE id = ?|;
 278   my $h_update_ar = prepare_query($form, $dbh, $q_update_ar);
 279
 280   my $q_insert_dunning =
 281     qq|INSERT INTO dunning (dunning_id, dunning_config_id, dunning_level, trans_id,
 282                             fee,        interest,          transdate,     duedate)
 283        VALUES (?, ?,
 284                (SELECT dunning_level FROM dunning_config WHERE id = ?),
 285                ?,
 286                (SELECT SUM(fee)
 287                 FROM dunning_config
 288                 WHERE dunning_level <= (SELECT dunning_level FROM dunning_config WHERE id = ?)),
 289                (SELECT (amount - paid) * (current_date - transdate) FROM ar WHERE id = ?)
 290                  * (SELECT interest_rate FROM dunning_config WHERE id = ?)
 291                  / 360,
 292                current_date,
 293                current_date + (SELECT payment_terms FROM dunning_config WHERE id = ?))|;
 294   my $h_insert_dunning = prepare_query($form, $dbh, $q_insert_dunning);
 295
 296   my @invoice_ids;
 297   my ($next_dunning_config_id, $customer_id);
 298   my $send_email = 0;
 299
 300   foreach my $row (@{ $rows }) {
 301     push @invoice_ids, $row->{invoice_id};
 302     $next_dunning_config_id = $row->{next_dunning_config_id};
 303     $customer_id            = $row->{customer_id};
 304
 305     @values = ($row->{next_dunning_config_id}, $row->{invoice_id});
 306     do_statement($form, $h_update_ar, $q_update_ar, @values);
 307
 308     $send_email |= $row->{email};
 309
 310     my $next_config_id = conv_i($row->{next_dunning_config_id});
 311     my $invoice_id     = conv_i($row->{invoice_id});
 312
 313     @values = ($dunning_id,     $next_config_id, $next_config_id,
 314                $invoice_id,     $next_config_id, $invoice_id,
 315                $next_config_id, $next_config_id);
 316     do_statement($form, $h_insert_dunning, $q_insert_dunning, @values);
 317   }
 318
 319   $h_update_ar->finish();
 320   $h_insert_dunning->finish();
 321
 322   $form->{DUNNING_PDFS_EMAIL} = [];
 323
 324   $self->create_invoice_for_fees($myconfig, $form, $dbh, $dunning_id);
 325
 326   $self->print_invoice_for_fees($myconfig, $form, $dunning_id, $dbh);
 327   $self->print_dunning($myconfig, $form, $dunning_id, $dbh);
 328
 329   $form->{dunning_id} = $dunning_id;
 330
 331   if ($send_email) {
 332     $self->send_email($myconfig, $form, $dunning_id, $dbh);
 333   }
 334
 335   $dbh->commit();
 336   $dbh->disconnect();
 337
 338   $main::lxdebug->leave_sub();
 339 }
 340
 341 sub send_email {
 342   $main::lxdebug->enter_sub();
 343
 344   my ($self, $myconfig, $form, $dunning_id, $dbh) = @_;
 345
 346   my $query =
 347     qq|SELECT
 348          dcfg.email_body,     dcfg.email_subject, dcfg.email_attachment,
 349          c.email AS recipient
 350
 351        FROM dunning d
 352        LEFT JOIN dunning_config dcfg ON (d.dunning_config_id = dcfg.id)
 353        LEFT JOIN ar                  ON (d.trans_id          = ar.id)
 354        LEFT JOIN customer c          ON (ar.customer_id      = c.id)
 355        WHERE (d.dunning_id = ?)
 356        LIMIT 1|;
 357   my $ref = selectfirst_hashref_query($form, $dbh, $query, $dunning_id);
 358
 359   if (!$ref || !$ref->{recipient} || !$myconfig->{email}) {
 360     $main::lxdebug->leave_sub();
 361     return;
 362   }
 363
 364   my $template     = PlainTextTemplate->new(undef, $form, $myconfig);
 365   my $mail         = Mailer->new();
 366   $mail->{from}    = $myconfig->{email};
 367   $mail->{to}      = $ref->{recipient};
 368   $mail->{subject} = $template->parse_block($ref->{email_subject});
 369   $mail->{message} = $template->parse_block($ref->{email_body});
 370
 371   if ($myconfig->{signature}) {
 372     $mail->{message} .= "\n-- \n$myconfig->{signature}";
 373   }
 374
 375   $mail->{message} =~ s/\r\n/\n/g;
 376
 377   if ($ref->{email_attachment} && @{ $form->{DUNNING_PDFS_EMAIL} }) {
 378     $mail->{attachments} = $form->{DUNNING_PDFS_EMAIL};
 379   }
 380
 381   $mail->send();
 382
 383   $main::lxdebug->leave_sub();
 384 }
 385
 386 sub set_template_options {
 387   $main::lxdebug->enter_sub();
 388
 389   my ($self, $myconfig, $form) = @_;
 390
 391   $form->{templates}    = "$myconfig->{templates}";
 392   $form->{language}     = $form->get_template_language($myconfig);
 393   $form->{printer_code} = $form->get_printer_code($myconfig);
 394
 395   if ($form->{language} ne "") {
 396     $form->{language} = "_" . $form->{language};
 397   }
 398
 399   if ($form->{printer_code} ne "") {
 400     $form->{printer_code} = "_" . $form->{printer_code};
 401   }
 402
 403   $form->{IN}  = "$form->{formname}$form->{language}$form->{printer_code}.html";
 404   $form->{pdf} = 1;
 405
 406   if ($form->{"format"} =~ /opendocument/) {
 407     $form->{IN} =~ s/html$/odt/;
 408   } else {
 409     $form->{IN} =~ s/html$/tex/;
 410   }
 411
 412   $main::lxdebug->leave_sub();
 413 }
 414
 415 sub get_invoices {
 416
 417   $main::lxdebug->enter_sub();
 418
 419   my ($self, $myconfig, $form) = @_;
 420
 421   # connect to database
 422   my $dbh = $form->dbconnect($myconfig);
 423
 424   my $where;
 425   my @values;
 426
 427   $form->{customer_id} = $1 if ($form->{customer} =~ /--(\d+)$/);
 428
 429   if ($form->{customer_id}) {
 430     $where .= qq| AND (a.customer_id = ?)|;
 431     push(@values, $form->{customer_id});
 432
 433   } elsif ($form->{customer}) {
 434     $where .= qq| AND (ct.name ILIKE ?)|;
 435     push(@values, '%' . $form->{customer} . '%');
 436   }
 437
 438   my %columns = (
 439     "ordnumber" => "a.ordnumber",
 440     "invnumber" => "a.invnumber",
 441     "notes"     => "a.notes",
 442     );
 443   foreach my $key (keys(%columns)) {
 444     next unless ($form->{$key});
 445     $where .= qq| AND $columns{$key} ILIKE ?|;
 446     push(@values, '%' . $form->{$key} . '%');
 447   }
 448
 449   if ($form->{dunning_level}) {
 450     $where .= qq| AND nextcfg.id = ?|;
 451     push(@values, conv_i($form->{dunning_level}));
 452   }
 453
 454   $form->{minamount} = $form->parse_amount($myconfig,$form->{minamount});
 455   if ($form->{minamount}) {
 456     $where .= qq| AND ((a.amount - a.paid) > ?) |;
 457     push(@values, $form->{minamount});
 458   }
 459
 460   my $query =
 461     qq|SELECT id
 462        FROM dunning_config
 463        WHERE dunning_level = (SELECT MAX(dunning_level) FROM dunning_config)|;
 464   my ($id_for_max_dunning_level) = selectrow_query($form, $dbh, $query);
 465
 466   $query =
 467     qq|SELECT
 468          a.id, a.ordnumber, a.transdate, a.invnumber, a.amount,
 469          ct.name AS customername, a.customer_id, a.duedate,
 470
 471          cfg.dunning_description, cfg.dunning_level,
 472
 473          d.transdate AS dunning_date, d.duedate AS dunning_duedate,
 474          d.fee, d.interest,
 475
 476          a.duedate + cfg.terms - current_date AS nextlevel,
 477          current_date - COALESCE(d.duedate, a.duedate) AS pastdue,
 478          current_date + cfg.payment_terms AS next_duedate,
 479
 480          nextcfg.dunning_description AS next_dunning_description,
 481          nextcfg.id AS next_dunning_config_id,
 482          nextcfg.terms, nextcfg.active, nextcfg.email
 483
 484        FROM ar a
 485
 486        LEFT JOIN customer ct ON (a.customer_id = ct.id)
 487        LEFT JOIN dunning_config cfg ON (a.dunning_config_id = cfg.id)
 488        LEFT JOIN dunning_config nextcfg ON
 489          (nextcfg.id =
 490            COALESCE(
 491              (SELECT id
 492               FROM dunning_config
 493               WHERE dunning_level >
 494                 COALESCE((SELECT dunning_level
 495                           FROM dunning_config
 496                           WHERE id = a.dunning_config_id
 497                           ORDER BY dunning_level DESC
 498                           LIMIT 1),
 499                          0)
 500               ORDER BY dunning_level ASC
 501               LIMIT 1)
 502              , ?))
 503        LEFT JOIN dunning d ON ((d.trans_id = a.id) AND (cfg.dunning_level = d.dunning_level))
 504
 505        WHERE (a.paid < a.amount)
 506          AND (a.duedate < current_date)
 507
 508        $where
 509
 510        ORDER BY a.id, transdate, duedate, name|;
 511   my $sth = prepare_execute_query($form, $dbh, $query, $id_for_max_dunning_level, @values);
 512
 513   $form->{DUNNINGS} = [];
 514
 515   while (my $ref = $sth->fetchrow_hashref("NAME_lc")) {
 516     next if ($ref->{pastdue} < $ref->{terms});
 517
 518     $ref->{interest} = $form->round_amount($ref->{interest}, 2);
 519     push(@{ $form->{DUNNINGS} }, $ref);
 520   }
 521
 522   $sth->finish;
 523
 524   $query = qq|SELECT id, dunning_description FROM dunning_config ORDER BY dunning_level|;
 525   $form->{DUNNING_CONFIG} = selectall_hashref_query($form, $dbh, $query);
 526
 527   $dbh->disconnect;
 528   $main::lxdebug->leave_sub();
 529 }
 530
 531 sub get_dunning {
 532
 533   $main::lxdebug->enter_sub();
 534
 535   my ($self, $myconfig, $form) = @_;
 536
 537   # connect to database
 538   my $dbh = $form->dbconnect($myconfig);
 539
 540   my $where = qq| WHERE (da.trans_id = a.id)|;
 541
 542   my @values;
 543
 544   if ($form->{customer_id}) {
 545     $where .= qq| AND (a.customer_id = ?)|;
 546     push(@values, $form->{customer_id});
 547
 548   } elsif ($form->{customer}) {
 549     $where .= qq| AND (ct.name ILIKE ?)|;
 550     push(@values, '%' . $form->{customer} . '%');
 551   }
 552
 553   my %columns = (
 554     "ordnumber" => "a.ordnumber",
 555     "invnumber" => "a.invnumber",
 556     "notes" => "a.notes",
 557     );
 558   foreach my $key (keys(%columns)) {
 559     next unless ($form->{$key});
 560     $where .= qq| AND $columns{$key} ILIKE ?|;
 561     push(@values, '%' . $form->{$key} . '%');
 562   }
 563
 564   if ($form->{dunning_level}) {
 565     $where .= qq| AND a.dunning_config_id = ?|;
 566     push(@values, conv_i($form->{dunning_level}));
 567   }
 568
 569   if ($form->{department_id}) {
 570     $where .= qq| AND a.department_id = ?|;
 571     push @values, conv_i($form->{department_id});
 572   }
 573
 574   $form->{minamount} = $form->parse_amount($myconfig, $form->{minamount});
 575   if ($form->{minamount}) {
 576     $where .= qq| AND ((a.amount - a.paid) > ?) |;
 577     push(@values, $form->{minamount});
 578   }
 579
 580   if (!$form->{showold}) {
 581     $where .= qq| AND (a.amount > a.paid) AND (da.dunning_config_id = a.dunning_config_id) |;
 582   }
 583
 584   if ($form->{transdatefrom}) {
 585     $where .= qq| AND a.transdate >= ?|;
 586     push(@values, $form->{transdatefrom});
 587   }
 588   if ($form->{transdateto}) {
 589     $where .= qq| AND a.transdate <= ?|;
 590     push(@values, $form->{transdateto});
 591   }
 592   if ($form->{dunningfrom}) {
 593     $where .= qq| AND da.transdate >= ?|;
 594     push(@values, $form->{dunningfrom});
 595   }
 596   if ($form->{dunningto}) {
 597     $where .= qq| AND da.transdate >= ?|;
 598     push(@values, $form->{dunningto});
 599   }
 600
 601   my %sort_columns = (
 602     'dunning_description' => [ qw(dn.dunning_description customername invnumber) ],
 603     'customername'        => [ qw(customername invnumber) ],
 604     'invnumber'           => [ qw(a.invnumber) ],
 605     'transdate'           => [ qw(a.transdate a.invnumber) ],
 606     'duedate'             => [ qw(a.duedate a.invnumber) ],
 607     'dunning_date'        => [ qw(dunning_date a.invnumber) ],
 608     'dunning_duedate'     => [ qw(dunning_duedate a.invnumber) ],
 609     );
 610
 611   my $sortdir   = !defined $form->{sortdir}    ? 'ASC'         : $form->{sortdir} ? 'ASC' : 'DESC';
 612   my $sortkey   = $sort_columns{$form->{sort}} ? $form->{sort} : 'customername';
 613   my $sortorder = join ', ', map { "$_ $sortdir" } @{ $sort_columns{$sortkey} };
 614
 615   my $query =
 616     qq|SELECT a.id, a.ordnumber, a.invoice, a.transdate, a.invnumber, a.amount,
 617          ct.name AS customername, ct.id AS customer_id, a.duedate, da.fee,
 618          da.interest, dn.dunning_description, da.transdate AS dunning_date,
 619          da.duedate AS dunning_duedate, da.dunning_id, da.dunning_config_id
 620        FROM ar a
 621        JOIN customer ct ON (a.customer_id = ct.id), dunning da
 622        LEFT JOIN dunning_config dn ON (da.dunning_config_id = dn.id)
 623        $where
 624        ORDER BY $sortorder|;
 625
 626   $form->{DUNNINGS} = selectall_hashref_query($form, $dbh, $query, @values);
 627
 628   foreach my $ref (@{ $form->{DUNNINGS} }) {
 629     map { $ref->{$_} = $form->format_amount($myconfig, $ref->{$_}, 2)} qw(amount fee interest);
 630   }
 631
 632   $dbh->disconnect;
 633   $main::lxdebug->leave_sub();
 634 }
 635
 636 sub melt_pdfs {
 637
 638   $main::lxdebug->enter_sub();
 639
 640   my ($self, $myconfig, $form, $copies) = @_;
 641
 642   # Don't allow access outside of $spool.
 643   map { $_ =~ s|.*/||; } @{ $form->{DUNNING_PDFS} };
 644
 645   $copies        *= 1;
 646   $copies         = 1 unless $copies;
 647   my $inputfiles  = join " ", map { "${main::spool}/$_ " x $copies } @{ $form->{DUNNING_PDFS} };
 648   my $dunning_id  = $form->{dunning_id};
 649
 650   $dunning_id     =~ s|[^\d]||g;
 651
 652   my $in = IO::File->new("gs -dBATCH -dNOPAUSE -q -sDEVICE=pdfwrite -sOutputFile=- $inputfiles |");
 653   $form->error($main::locale->text('Could not spawn ghostscript.')) unless $in;
 654
 655   my $out;
 656
 657   if ($form->{media} eq 'printer') {
 658     $form->get_printer_code($myconfig);
 659     if ($form->{printer_command}) {
 660       $out = IO::File->new("| $form->{printer_command}");
 661     }
 662
 663     $form->error($main::locale->text('Could not spawn the printer command.')) unless $out;
 664
 665   } else {
 666     my $dunning_filename = $form->get_formname_translation('dunning');
 667     $out = IO::File->new('>-');
 668     $out->print(qq|Content-Type: Application/PDF\n| .
 669                 qq|Content-Disposition: attachment; filename="${dunning_filename}_${dunning_id}.pdf"\n\n|);
 670   }
 671
 672   while (my $line = <$in>) {
 673     $out->print($line);
 674   }
 675
 676   $in->close();
 677   $out->close();
 678
 679   map { unlink("${main::spool}/$_") } @{ $form->{DUNNING_PDFS} };
 680
 681   $main::lxdebug->leave_sub();
 682 }
 683
 684 sub print_dunning {
 685   $main::lxdebug->enter_sub();
 686
 687   my ($self, $myconfig, $form, $dunning_id, $provided_dbh) = @_;
 688
 689   # connect to database
 690   my $dbh = $provided_dbh ? $provided_dbh : $form->dbconnect_noauto($myconfig);
 691
 692   $dunning_id =~ s|[^\d]||g;
 693
 694   my $query =
 695     qq|SELECT
 696          da.fee, da.interest,
 697          da.transdate  AS dunning_date,
 698          da.duedate    AS dunning_duedate,
 699
 700          dcfg.template AS formname,
 701          dcfg.email_subject, dcfg.email_body, dcfg.email_attachment,
 702
 703          ar.transdate,       ar.duedate,      ar.customer_id,
 704          ar.invnumber,       ar.ordnumber,    ar.cp_id,
 705          ar.amount,          ar.netamount,    ar.paid,
 706          ar.amount - ar.paid AS open_amount,
 707          ar.amount - ar.paid + da.fee + da.interest AS linetotal
 708
 709        FROM dunning da
 710        LEFT JOIN dunning_config dcfg ON (dcfg.id = da.dunning_config_id)
 711        LEFT JOIN ar ON (ar.id = da.trans_id)
 712        WHERE (da.dunning_id = ?)|;
 713
 714   my $sth = prepare_execute_query($form, $dbh, $query, $dunning_id);
 715   my $first = 1;
 716   while (my $ref = $sth->fetchrow_hashref("NAME_lc")) {
 717     if ($first) {
 718       $form->{TEMPLATE_ARRAYS} = {};
 719       map({ $form->{TEMPLATE_ARRAYS}->{"dn_$_"} = []; } keys(%{$ref}));
 720       $first = 0;
 721     }
 722     map { $ref->{$_} = $form->format_amount($myconfig, $ref->{$_}, 2) } qw(amount netamount paid open_amount fee interest linetotal);
 723     map { $form->{$_} = $ref->{$_} } keys %$ref;
 724     map { push @{ $form->{TEMPLATE_ARRAYS}->{"dn_$_"} }, $ref->{$_} } keys %$ref;
 725   }
 726   $sth->finish();
 727
 728   $query =
 729     qq|SELECT
 730          c.id AS customer_id, c.name,         c.street,       c.zipcode,   c.city,
 731          c.country,           c.department_1, c.department_2, c.email,     c.customernumber,
 732          c.greeting,          c.contact,      c.phone,        c.fax,       c.homepage,
 733          c.email,             c.taxincluded,  c.business_id,  c.taxnumber, c.iban,
 734          co.*
 735        FROM dunning d
 736        LEFT JOIN ar          ON (d.trans_id = ar.id)
 737        LEFT JOIN customer c  ON (ar.customer_id = c.id)
 738        LEFT JOIN contacts co ON (ar.cp_id = co.cp_id)
 739        WHERE (d.dunning_id = ?)
 740        LIMIT 1|;
 741   my $ref = selectfirst_hashref_query($form, $dbh, $query, $dunning_id);
 742   map { $form->{$_} = $ref->{$_} } keys %{ $ref };
 743
 744   $query =
 745     qq|SELECT
 746          cfg.interest_rate, cfg.template AS formname,
 747          cfg.email_subject, cfg.email_body, cfg.email_attachment,
 748          d.transdate AS dunning_date,
 749          (SELECT SUM(fee)
 750           FROM dunning
 751           WHERE dunning_id = ?)
 752          AS fee,
 753          (SELECT SUM(interest)
 754           FROM dunning
 755           WHERE dunning_id = ?)
 756          AS total_interest,
 757          (SELECT SUM(amount) - SUM(paid)
 758           FROM ar
 759           WHERE id IN
 760             (SELECT trans_id
 761              FROM dunning
 762              WHERE dunning_id = ?))
 763          AS total_open_amount
 764        FROM dunning d
 765        LEFT JOIN dunning_config cfg ON (d.dunning_config_id = cfg.id)
 766        WHERE d.dunning_id = ?
 767        LIMIT 1|;
 768   $ref = selectfirst_hashref_query($form, $dbh, $query, $dunning_id, $dunning_id, $dunning_id, $dunning_id);
 769   map { $form->{$_} = $ref->{$_} } keys %{ $ref };
 770
 771   $form->{interest_rate}     = $form->format_amount($myconfig, $ref->{interest_rate} * 100);
 772   $form->{fee}               = $form->format_amount($myconfig, $ref->{fee}, 2);
 773   $form->{total_interest}    = $form->format_amount($myconfig, $form->round_amount($ref->{total_interest}, 2), 2);
 774   $form->{total_open_amount} = $form->format_amount($myconfig, $form->round_amount($ref->{total_open_amount}, 2), 2);
 775   $form->{total_amount}      = $form->format_amount($myconfig, $form->round_amount($ref->{fee} + $ref->{total_interest} + $ref->{total_open_amount}, 2), 2);
 776
 777   $self->set_template_options($myconfig, $form);
 778
 779   my $filename          = "dunning_${dunning_id}_" . Common::unique_id() . ".pdf";
 780   $form->{OUT}          = ">${main::spool}/$filename";
 781   $form->{keep_tmpfile} = 1;
 782
 783   delete $form->{tmpfile};
 784
 785   push @{ $form->{DUNNING_PDFS} }, $filename;
 786   push @{ $form->{DUNNING_PDFS_EMAIL} }, { 'filename' => "${main::spool}/$filename",
 787                                            'name'     => "dunning_${dunning_id}.pdf" };
 788
 789   $form->parse_template($myconfig, $main::userspath);
 790
 791   $dbh->disconnect() unless $provided_dbh;
 792
 793   $main::lxdebug->leave_sub();
 794 }
 795
 796 sub print_invoice_for_fees {
 797   $main::lxdebug->enter_sub();
 798
 799   my ($self, $myconfig, $form, $dunning_id, $provided_dbh) = @_;
 800
 801   my $dbh = $provided_dbh ? $provided_dbh : $form->dbconnect($myconfig);
 802
 803   my ($query, @values, $sth);
 804
 805   $query =
 806     qq|SELECT
 807          d.fee_interest_ar_id,
 808          dcfg.template
 809        FROM dunning d
 810        LEFT JOIN dunning_config dcfg ON (d.dunning_config_id = dcfg.id)
 811        WHERE d.dunning_id = ?|;
 812   my ($ar_id, $template) = selectrow_query($form, $dbh, $query, $dunning_id);
 813
 814   if (!$ar_id) {
 815     $main::lxdebug->leave_sub();
 816     return;
 817   }
 818
 819   my $saved_form = save_form();
 820
 821   $query = qq|SELECT SUM(fee), SUM(interest) FROM dunning WHERE id = ?|;
 822   my ($fee_total, $interest_total) = selectrow_query($form, $dbh, $query, $dunning_id);
 823
 824   $query =
 825     qq|SELECT
 826          ar.invnumber, ar.transdate AS invdate, ar.amount, ar.netamount,
 827          ar.duedate,   ar.notes,     ar.notes AS invoicenotes,
 828
 829          c.name,      c.department_1,   c.department_2, c.street, c.zipcode, c.city, c.country,
 830          c.contact,   c.customernumber, c.phone,        c.fax,    c.email,
 831          c.taxnumber, c.greeting
 832
 833        FROM ar
 834        LEFT JOIN customer c ON (ar.customer_id = c.id)
 835        WHERE ar.id = ?|;
 836   my $ref = selectfirst_hashref_query($form, $dbh, $query, $ar_id);
 837   map { $form->{$_} = $ref->{$_} } keys %{ $ref };
 838
 839   $query = qq|SELECT * FROM employee WHERE login = ?|;
 840   $ref = selectfirst_hashref_query($form, $dbh, $query, $form->{login});
 841   map { $form->{"employee_${_}"} = $ref->{$_} } keys %{ $ref };
 842
 843   $query = qq|SELECT * FROM acc_trans WHERE trans_id = ? ORDER BY acc_trans_id ASC|;
 844   $sth   = prepare_execute_query($form, $dbh, $query, $ar_id);
 845
 846   my ($row, $fee, $interest) = (0, 0, 0);
 847
 848   while ($ref = $sth->fetchrow_hashref()) {
 849     next if ($ref->{amount} < 0);
 850
 851     $row++;
 852
 853     if ($row == 1) {
 854       $fee = $ref->{amount};
 855     } else {
 856       $interest = $ref->{amount};
 857     }
 858   }
 859
 860   $form->{fee}        = $form->round_amount($fee,             2);
 861   $form->{interest}   = $form->round_amount($interest,        2);
 862   $form->{invamount}  = $form->round_amount($fee + $interest, 2);
 863   $form->{dunning_id} = $dunning_id;
 864   $form->{formname}   = "${template}_invoice";
 865
 866   map { $form->{$_} = $form->format_amount($myconfig, $form->{$_}, 2) } qw(fee interest invamount);
 867
 868   $self->set_template_options($myconfig, $form);
 869
 870   my $filename = Common::unique_id() . "dunning_invoice_${dunning_id}.pdf";
 871
 872   $form->{OUT}          = ">$main::spool/$filename";
 873   $form->{keep_tmpfile} = 1;
 874   delete $form->{tmpfile};
 875
 876   map { delete $form->{$_} } grep /^[a-z_]+_\d+$/, keys %{ $form };
 877
 878   $form->parse_template($myconfig, $main::userspath);
 879
 880   restore_form($saved_form);
 881
 882   push @{ $form->{DUNNING_PDFS} }, $filename;
 883   push @{ $form->{DUNNING_PDFS_EMAIL} }, { 'filename' => "${main::spool}/$filename",
 884                                            'name'     => "dunning_invoice_${dunning_id}.pdf" };
 885
 886   $dbh->disconnect() unless $provided_dbh;
 887
 888   $main::lxdebug->leave_sub();
 889 }
 890
 891 1;