SL/DO.pm

   1 #====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (C) 1999-2003
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #  Contributors:
  16 #
  17 # This program is free software; you can redistribute it and/or modify
  18 # it under the terms of the GNU General Public License as published by
  19 # the Free Software Foundation; either version 2 of the License, or
  20 # (at your option) any later version.
  21 #
  22 # This program is distributed in the hope that it will be useful,
  23 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  24 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25 # GNU General Public License for more details.
  26 # You should have received a copy of the GNU General Public License
  27 # along with this program; if not, write to the Free Software
  28 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  29 #======================================================================
  30 #
  31 # Delivery Order entry module
  32 #======================================================================
  33
  34 package DO;
  35
  36 use List::Util qw(max);
  37 use YAML;
  38
  39 use SL::AM;
  40 use SL::Common;
  41 use SL::CVar;
  42 use SL::DBUtils;
  43 use SL::RecordLinks;
  44 use SL::IC;
  45
  46 use strict;
  47
  48 sub transactions {
  49   $main::lxdebug->enter_sub();
  50
  51   my ($self)   = @_;
  52
  53   my $myconfig = \%main::myconfig;
  54   my $form     = $main::form;
  55
  56   # connect to database
  57   my $dbh = $form->get_standard_dbh($myconfig);
  58
  59   my (@where, @values, $where);
  60
  61   my $vc = $form->{vc} eq "customer" ? "customer" : "vendor";
  62
  63   my $query =
  64     qq|SELECT dord.id, dord.donumber, dord.ordnumber, dord.transdate,
  65          ct.name, dord.${vc}_id, dord.globalproject_id,
  66          dord.closed, dord.delivered, dord.shippingpoint, dord.shipvia,
  67          dord.transaction_description,
  68          pr.projectnumber AS globalprojectnumber,
  69          e.name AS employee,
  70          sm.name AS salesman
  71        FROM delivery_orders dord
  72        LEFT JOIN $vc ct ON (dord.${vc}_id = ct.id)
  73        LEFT JOIN employee e ON (dord.employee_id = e.id)
  74        LEFT JOIN employee sm ON (dord.salesman_id = sm.id)
  75        LEFT JOIN project pr ON (dord.globalproject_id = pr.id)|;
  76
  77   push @where, ($form->{type} eq 'sales_delivery_order' ? '' : 'NOT ') . qq|COALESCE(dord.is_sales, FALSE)|;
  78
  79   my $department_id = (split /--/, $form->{department})[1];
  80   if ($department_id) {
  81     push @where,  qq|dord.department_id = ?|;
  82     push @values, conv_i($department_id);
  83   }
  84
  85   if ($form->{project_id}) {
  86     push @where,
  87       qq|(dord.globalproject_id = ?) OR EXISTS
  88           (SELECT * FROM delivery_order_items doi
  89            WHERE (doi.project_id = ?) AND (doi.delivery_order_id = dord.id))|;
  90     push @values, conv_i($form->{project_id}), conv_i($form->{project_id});
  91   }
  92
  93   if ($form->{"${vc}_id"}) {
  94     push @where,  qq|dord.${vc}_id = ?|;
  95     push @values, $form->{"${vc}_id"};
  96
  97   } elsif ($form->{$vc}) {
  98     push @where,  qq|ct.name ILIKE ?|;
  99     push @values, '%' . $form->{$vc} . '%';
 100   }
 101
 102   foreach my $item (qw(employee_id salesman_id)) {
 103     next unless ($form->{$item});
 104     push @where, "dord.$item = ?";
 105     push @values, conv_i($form->{$item});
 106   }
 107   if (!$main::auth->assert('sales_all_edit', 1)) {
 108     push @where, qq|dord.employee_id = (select id from employee where login= ?)|;
 109     push @values, $form->{login};
 110   }
 111
 112   foreach my $item (qw(donumber ordnumber cusordnumber transaction_description)) {
 113     next unless ($form->{$item});
 114     push @where,  qq|dord.$item ILIKE ?|;
 115     push @values, '%' . $form->{$item} . '%';
 116   }
 117
 118   if (($form->{open} || $form->{closed}) &&
 119       ($form->{open} ne $form->{closed})) {
 120     push @where, ($form->{open} ? "NOT " : "") . "COALESCE(dord.closed, FALSE)";
 121   }
 122
 123   if (($form->{notdelivered} || $form->{delivered}) &&
 124       ($form->{notdelivered} ne $form->{delivered})) {
 125     push @where, ($form->{delivered} ? "" : "NOT ") . "COALESCE(dord.delivered, FALSE)";
 126   }
 127
 128   if($form->{transdatefrom}) {
 129     push @where,  qq|dord.transdate >= ?|;
 130     push @values, conv_date($form->{transdatefrom});
 131   }
 132
 133   if($form->{transdateto}) {
 134     push @where,  qq|dord.transdate <= ?|;
 135     push @values, conv_date($form->{transdateto});
 136   }
 137
 138   if (@where) {
 139     $query .= " WHERE " . join(" AND ", map { "($_)" } @where);
 140   }
 141
 142   my %allowed_sort_columns = (
 143     "transdate"               => "dord.transdate",
 144     "id"                      => "dord.id",
 145     "donumber"                => "dord.donumber",
 146     "ordnumber"               => "dord.ordnumber",
 147     "name"                    => "ct.name",
 148     "employee"                => "e.name",
 149     "salesman"                => "sm.name",
 150     "shipvia"                 => "dord.shipvia",
 151     "transaction_description" => "dord.transaction_description"
 152   );
 153
 154   my $sortdir   = !defined $form->{sortdir} ? 'ASC' : $form->{sortdir} ? 'ASC' : 'DESC';
 155   my $sortorder = "dord.id";
 156   if ($form->{sort} && grep($form->{sort}, keys(%allowed_sort_columns))) {
 157     $sortorder = $allowed_sort_columns{$form->{sort}};
 158   }
 159
 160   $query .= qq| ORDER by | . $sortorder . " $sortdir";
 161
 162   $form->{DO} = selectall_hashref_query($form, $dbh, $query, @values);
 163
 164   if (scalar @{ $form->{DO} }) {
 165     $query =
 166       qq|SELECT id
 167          FROM oe
 168          WHERE NOT COALESCE(quotation, FALSE)
 169            AND (ordnumber = ?)
 170            AND (COALESCE(${vc}_id, 0) != 0)|;
 171
 172     my $sth = prepare_query($form, $dbh, $query);
 173
 174     foreach my $dord (@{ $form->{DO} }) {
 175       next unless ($dord->{ordnumber});
 176       do_statement($form, $sth, $query, $dord->{ordnumber});
 177       ($dord->{oe_id}) = $sth->fetchrow_array();
 178     }
 179
 180     $sth->finish();
 181   }
 182
 183   $main::lxdebug->leave_sub();
 184 }
 185
 186 sub save {
 187   $main::lxdebug->enter_sub();
 188
 189   my ($self)   = @_;
 190
 191   my $myconfig = \%main::myconfig;
 192   my $form     = $main::form;
 193
 194   # connect to database, turn off autocommit
 195   my $dbh = $form->get_standard_dbh($myconfig);
 196
 197   my ($query, @values, $sth, $null);
 198
 199   my $all_units = AM->retrieve_units($myconfig, $form);
 200   $form->{all_units} = $all_units;
 201
 202   my $ic_cvar_configs = CVar->get_configs(module => 'IC',
 203                                           dbh    => $dbh);
 204
 205   $form->{donumber}    = $form->update_defaults($myconfig, $form->{type} eq 'sales_delivery_order' ? 'sdonumber' : 'pdonumber', $dbh) unless $form->{donumber};
 206   $form->{employee_id} = (split /--/, $form->{employee})[1] if !$form->{employee_id};
 207   $form->get_employee($dbh) unless ($form->{employee_id});
 208
 209   my $ml = ($form->{type} eq 'sales_delivery_order') ? 1 : -1;
 210
 211   if ($form->{id}) {
 212
 213     $query = qq|DELETE FROM delivery_order_items_stock WHERE delivery_order_item_id IN (SELECT id FROM delivery_order_items WHERE delivery_order_id = ?)|;
 214     do_query($form, $dbh, $query, conv_i($form->{id}));
 215
 216     $query = qq|DELETE FROM delivery_order_items WHERE delivery_order_id = ?|;
 217     do_query($form, $dbh, $query, conv_i($form->{id}));
 218
 219     $query = qq|DELETE FROM shipto WHERE trans_id = ? AND module = 'DO'|;
 220     do_query($form, $dbh, $query, conv_i($form->{id}));
 221
 222   } else {
 223
 224     $query = qq|SELECT nextval('id')|;
 225     ($form->{id}) = selectrow_query($form, $dbh, $query);
 226
 227     $query = qq|INSERT INTO delivery_orders (id, donumber, employee_id) VALUES (?, '', ?)|;
 228     do_query($form, $dbh, $query, $form->{id}, conv_i($form->{employee_id}));
 229   }
 230
 231   my $project_id;
 232   my $reqdate;
 233
 234   $form->get_lists('price_factors' => 'ALL_PRICE_FACTORS');
 235   my %price_factors = map { $_->{id} => $_->{factor} } @{ $form->{ALL_PRICE_FACTORS} };
 236   my $price_factor;
 237
 238   my %part_id_map = map { $_ => 1 } grep { $_ } map { $form->{"id_$_"} } (1 .. $form->{rowcount});
 239   my @part_ids    = keys %part_id_map;
 240   my %part_unit_map;
 241
 242   if (@part_ids) {
 243     $query         = qq|SELECT id, unit FROM parts WHERE id IN (| . join(', ', map { '?' } @part_ids) . qq|)|;
 244     %part_unit_map = selectall_as_map($form, $dbh, $query, 'id', 'unit', @part_ids);
 245   }
 246
 247   my $q_item_id = qq|SELECT nextval('delivery_order_items_id')|;
 248   my $h_item_id = prepare_query($form, $dbh, $q_item_id);
 249
 250   my $q_item =
 251     qq|INSERT INTO delivery_order_items (
 252          id, delivery_order_id, parts_id, description, longdescription, qty, base_qty,
 253          sellprice, discount, unit, reqdate, project_id, serialnumber,
 254          ordnumber, transdate, cusordnumber,
 255          lastcost, price_factor_id, price_factor, marge_price_factor, pricegroup_id)
 256        VALUES (?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?,
 257          (SELECT factor FROM price_factors WHERE id = ?), ?, ?)|;
 258   my $h_item = prepare_query($form, $dbh, $q_item);
 259
 260   my $q_item_stock =
 261     qq|INSERT INTO delivery_order_items_stock (delivery_order_item_id, qty, unit, warehouse_id, bin_id, chargenumber, bestbefore)
 262        VALUES (?, ?, ?, ?, ?, ?, ?)|;
 263   my $h_item_stock = prepare_query($form, $dbh, $q_item_stock);
 264
 265   my $in_out       = $form->{type} =~ /^sales/ ? 'out' : 'in';
 266
 267   for my $i (1 .. $form->{rowcount}) {
 268     next if (!$form->{"id_$i"});
 269
 270     $form->{"qty_$i"} = $form->parse_amount($myconfig, $form->{"qty_$i"});
 271
 272     my $item_unit = $part_unit_map{$form->{"id_$i"}};
 273
 274     my $basefactor = 1;
 275     if (defined($all_units->{$item_unit}->{factor}) && (($all_units->{$item_unit}->{factor} * 1) != 0)) {
 276       $basefactor = $all_units->{$form->{"unit_$i"}}->{factor} / $all_units->{$item_unit}->{factor};
 277     }
 278     my $baseqty = $form->{"qty_$i"} * $basefactor;
 279
 280     # set values to 0 if nothing entered
 281     $form->{"discount_$i"}  = $form->parse_amount($myconfig, $form->{"discount_$i"});
 282     $form->{"sellprice_$i"} = $form->parse_amount($myconfig, $form->{"sellprice_$i"});
 283     $form->{"lastcost_$i"} = $form->parse_amount($myconfig, $form->{"lastcost_$i"});
 284
 285     $price_factor = $price_factors{ $form->{"price_factor_id_$i"} } || 1;
 286     my $linetotal    = $form->round_amount($form->{"sellprice_$i"} * $form->{"qty_$i"} / $price_factor, 2);
 287
 288     $reqdate = ($form->{"reqdate_$i"}) ? $form->{"reqdate_$i"} : undef;
 289
 290     do_statement($form, $h_item_id, $q_item_id);
 291     my ($item_id) = $h_item_id->fetchrow_array();
 292
 293     # save detail record in delivery_order_items table
 294     @values = (conv_i($item_id), conv_i($form->{id}), conv_i($form->{"id_$i"}),
 295                $form->{"description_$i"}, $form->{"longdescription_$i"},
 296                $form->{"qty_$i"}, $baseqty,
 297                $form->{"sellprice_$i"}, $form->{"discount_$i"} / 100,
 298                $form->{"unit_$i"}, conv_date($reqdate), conv_i($form->{"project_id_$i"}),
 299                $form->{"serialnumber_$i"},
 300                $form->{"ordnumber_$i"}, conv_date($form->{"transdate_$i"}),
 301                $form->{"cusordnumber_$i"},
 302                $form->{"lastcost_$i"},
 303                conv_i($form->{"price_factor_id_$i"}), conv_i($form->{"price_factor_id_$i"}),
 304                conv_i($form->{"marge_price_factor_$i"}),
 305                conv_i($form->{"pricegroup_id_$i"}));
 306     do_statement($form, $h_item, $q_item, @values);
 307
 308     my $stock_info = DO->unpack_stock_information('packed' => $form->{"stock_${in_out}_$i"});
 309
 310     foreach my $sinfo (@{ $stock_info }) {
 311       @values = ($item_id, $sinfo->{qty}, $sinfo->{unit}, conv_i($sinfo->{warehouse_id}),
 312                  conv_i($sinfo->{bin_id}), $sinfo->{chargenumber}, conv_date($sinfo->{bestbefore}));
 313       do_statement($form, $h_item_stock, $q_item_stock, @values);
 314     }
 315
 316     CVar->save_custom_variables(module       => 'IC',
 317                                 sub_module   => 'delivery_order_items',
 318                                 trans_id     => $item_id,
 319                                 configs      => $ic_cvar_configs,
 320                                 variables    => $form,
 321                                 name_prefix  => 'ic_',
 322                                 name_postfix => "_$i",
 323                                 dbh          => $dbh);
 324   }
 325
 326   $h_item_id->finish();
 327   $h_item->finish();
 328   $h_item_stock->finish();
 329
 330   ($null, $form->{department_id}) = split(/--/, $form->{department});
 331
 332   # save DO record
 333   $query =
 334     qq|UPDATE delivery_orders SET
 335          donumber = ?, ordnumber = ?, cusordnumber = ?, transdate = ?, vendor_id = ?,
 336          customer_id = ?, reqdate = ?,
 337          shippingpoint = ?, shipvia = ?, notes = ?, intnotes = ?, closed = ?,
 338          delivered = ?, department_id = ?, language_id = ?, shipto_id = ?,
 339          globalproject_id = ?, employee_id = ?, salesman_id = ?, cp_id = ?, transaction_description = ?,
 340          is_sales = ?, taxzone_id = ?, taxincluded = ?, terms = ?, curr = ?
 341        WHERE id = ?|;
 342
 343   @values = ($form->{donumber}, $form->{ordnumber},
 344              $form->{cusordnumber}, conv_date($form->{transdate}),
 345              conv_i($form->{vendor_id}), conv_i($form->{customer_id}),
 346              conv_date($reqdate), $form->{shippingpoint}, $form->{shipvia},
 347              $form->{notes}, $form->{intnotes},
 348              $form->{closed} ? 't' : 'f', $form->{delivered} ? "t" : "f",
 349              conv_i($form->{department_id}), conv_i($form->{language_id}), conv_i($form->{shipto_id}),
 350              conv_i($form->{globalproject_id}), conv_i($form->{employee_id}),
 351              conv_i($form->{salesman_id}), conv_i($form->{cp_id}),
 352              $form->{transaction_description},
 353              $form->{type} =~ /^sales/ ? 't' : 'f',
 354              conv_i($form->{taxzone_id}), $form->{taxincluded} ? 't' : 'f', conv_i($form->{terms}), substr($form->{currency}, 0, 3),
 355              conv_i($form->{id}));
 356   do_query($form, $dbh, $query, @values);
 357
 358   # add shipto
 359   $form->{name} = $form->{ $form->{vc} };
 360   $form->{name} =~ s/--$form->{"$form->{vc}_id"}//;
 361
 362   if (!$form->{shipto_id}) {
 363     $form->add_shipto($dbh, $form->{id}, "DO");
 364   }
 365
 366   # save printed, emailed, queued
 367   $form->save_status($dbh);
 368
 369   # Link this delivery order to the quotations it was created from.
 370   RecordLinks->create_links('dbh'        => $dbh,
 371                             'mode'       => 'ids',
 372                             'from_table' => 'oe',
 373                             'from_ids'   => $form->{convert_from_oe_ids},
 374                             'to_table'   => 'delivery_orders',
 375                             'to_id'      => $form->{id},
 376     );
 377   delete $form->{convert_from_oe_ids};
 378
 379   $self->mark_orders_if_delivered('do_id' => $form->{id},
 380                                   'type'  => $form->{type} eq 'sales_delivery_order' ? 'sales' : 'purchase',
 381                                   'dbh'   => $dbh,);
 382
 383   my $rc = $dbh->commit();
 384
 385   $form->{saved_donumber} = $form->{donumber};
 386
 387   Common::webdav_folder($form);
 388
 389   $main::lxdebug->leave_sub();
 390
 391   return $rc;
 392 }
 393
 394 sub mark_orders_if_delivered {
 395   $main::lxdebug->enter_sub();
 396
 397   my $self   = shift;
 398   my %params = @_;
 399
 400   Common::check_params(\%params, qw(do_id type));
 401
 402   my $myconfig = \%main::myconfig;
 403   my $form     = $main::form;
 404
 405   my $dbh      = $params{dbh} || $form->get_standard_dbh($myconfig);
 406
 407   my @links    = RecordLinks->get_links('dbh'        => $dbh,
 408                                         'from_table' => 'oe',
 409                                         'to_table'   => 'delivery_orders',
 410                                         'to_id'      => $params{do_id});
 411
 412   my $oe_id  = @links ? $links[0]->{from_id} : undef;
 413
 414   return $main::lxdebug->leave_sub() if (!$oe_id);
 415
 416   my $all_units = AM->retrieve_all_units();
 417
 418   my $query     = qq|SELECT oi.parts_id, oi.qty, oi.unit, p.unit AS partunit
 419                      FROM orderitems oi
 420                      LEFT JOIN parts p ON (oi.parts_id = p.id)
 421                      WHERE (oi.trans_id = ?)|;
 422   my $sth       = prepare_execute_query($form, $dbh, $query, $oe_id);
 423
 424   my %shipped   = $self->get_shipped_qty('type'  => $params{type},
 425                                          'oe_id' => $oe_id,);
 426   my %ordered   = ();
 427
 428   while (my $ref = $sth->fetchrow_hashref()) {
 429     $ref->{baseqty} = $ref->{qty} * $all_units->{$ref->{unit}}->{factor} / $all_units->{$ref->{partunit}}->{factor};
 430
 431     if ($ordered{$ref->{parts_id}}) {
 432       $ordered{$ref->{parts_id}}->{baseqty} += $ref->{baseqty};
 433     } else {
 434       $ordered{$ref->{parts_id}}             = $ref;
 435     }
 436   }
 437
 438   $sth->finish();
 439
 440   map { $_->{baseqty} = $_->{qty} * $all_units->{$_->{unit}}->{factor} / $all_units->{$_->{partunit}}->{factor} } values %shipped;
 441
 442   my $delivered = 1;
 443   foreach my $part (values %ordered) {
 444     if (!$shipped{$part->{parts_id}} || ($shipped{$part->{parts_id}}->{baseqty} < $part->{baseqty})) {
 445       $delivered = 0;
 446       last;
 447     }
 448   }
 449
 450   if ($delivered) {
 451     $query = qq|UPDATE oe
 452                 SET delivered = TRUE
 453                 WHERE id = ?|;
 454     do_query($form, $dbh, $query, $oe_id);
 455     $dbh->commit() if (!$params{dbh});
 456   }
 457
 458   $main::lxdebug->leave_sub();
 459 }
 460
 461 sub close_orders {
 462   $main::lxdebug->enter_sub();
 463
 464   my $self     = shift;
 465   my %params   = @_;
 466
 467   Common::check_params(\%params, qw(ids));
 468
 469   if (('ARRAY' ne ref $params{ids}) || !scalar @{ $params{ids} }) {
 470     $main::lxdebug->leave_sub();
 471     return;
 472   }
 473
 474   my $myconfig = \%main::myconfig;
 475   my $form     = $main::form;
 476
 477   my $dbh      = $params{dbh} || $form->get_standard_dbh($myconfig);
 478
 479   my $query    = qq|UPDATE delivery_orders SET closed = TRUE WHERE id IN (| . join(', ', ('?') x scalar(@{ $params{ids} })) . qq|)|;
 480
 481   do_query($form, $dbh, $query, map { conv_i($_) } @{ $params{ids} });
 482
 483   $dbh->commit() unless ($params{dbh});
 484
 485   $main::lxdebug->leave_sub();
 486 }
 487
 488 sub delete {
 489   $main::lxdebug->enter_sub();
 490
 491   my ($self)   = @_;
 492
 493   my $myconfig = \%main::myconfig;
 494   my $form     = $main::form;
 495   my $spool    = $::lx_office_conf{paths}->{spool};
 496
 497   # connect to database
 498   my $dbh = $form->get_standard_dbh($myconfig);
 499
 500   # delete spool files
 501   my $query = qq|SELECT s.spoolfile FROM status s WHERE s.trans_id = ?|;
 502   my $sth   = prepare_execute_query($form, $dbh, $query, conv_i($form->{id}));
 503
 504   my $spoolfile;
 505   my @spoolfiles = ();
 506   my @values;
 507
 508   while (($spoolfile) = $sth->fetchrow_array) {
 509     push @spoolfiles, $spoolfile;
 510   }
 511   $sth->finish();
 512
 513   # delete-values
 514   @values = (conv_i($form->{id}));
 515
 516   # delete status entries
 517   $query = qq|DELETE FROM status
 518               WHERE trans_id = ?|;
 519   do_query($form, $dbh, $query, @values);
 520
 521   # delete individual entries
 522   $query = qq|DELETE FROM delivery_order_items_stock
 523               WHERE delivery_order_item_id IN (
 524                 SELECT id FROM delivery_order_items
 525                 WHERE delivery_order_id = ?
 526               )|;
 527   do_query($form, $dbh, $query, @values);
 528
 529   # delete individual entries
 530   $query = qq|DELETE FROM delivery_order_items
 531               WHERE delivery_order_id = ?|;
 532   do_query($form, $dbh, $query, @values);
 533
 534   # delete DO record
 535   $query = qq|DELETE FROM delivery_orders
 536               WHERE id = ?|;
 537   do_query($form, $dbh, $query, @values);
 538
 539   $query = qq|DELETE FROM shipto
 540               WHERE trans_id = ? AND module = 'DO'|;
 541   do_query($form, $dbh, $query, @values);
 542
 543   my $rc = $dbh->commit();
 544
 545   if ($rc) {
 546     foreach $spoolfile (@spoolfiles) {
 547       unlink "$spool/$spoolfile" if $spoolfile;
 548     }
 549   }
 550
 551   $main::lxdebug->leave_sub();
 552
 553   return $rc;
 554 }
 555
 556 sub retrieve {
 557   $main::lxdebug->enter_sub();
 558
 559   my $self     = shift;
 560   my %params   = @_;
 561
 562   my $myconfig = \%main::myconfig;
 563   my $form     = $main::form;
 564
 565   # connect to database
 566   my $dbh = $form->get_standard_dbh($myconfig);
 567
 568   my ($query, $query_add, @values, $sth, $ref);
 569
 570   my $ic_cvar_configs = CVar->get_configs(module => 'IC',
 571                                           dbh    => $dbh);
 572
 573   my $vc   = $params{vc} eq 'customer' ? 'customer' : 'vendor';
 574
 575   my $mode = !$params{ids} ? 'default' : ref $params{ids} eq 'ARRAY' ? 'multi' : 'single';
 576
 577   if ($mode eq 'default') {
 578     $ref = selectfirst_hashref_query($form, $dbh, qq|SELECT current_date AS transdate, current_date AS reqdate|);
 579     map { $form->{$_} = $ref->{$_} } keys %$ref;
 580
 581     # get last name used
 582     $form->lastname_used($dbh, $myconfig, $vc) unless $form->{"${vc}_id"};
 583
 584     $main::lxdebug->leave_sub();
 585
 586     return 1;
 587   }
 588
 589   my @do_ids              = map { conv_i($_) } ($mode eq 'multi' ? @{ $params{ids} } : ($params{ids}));
 590   my $do_ids_placeholders = join(', ', ('?') x scalar(@do_ids));
 591
 592   # retrieve order for single id
 593   # NOTE: this query is intended to fetch all information only ONCE.
 594   # so if any of these infos is important (or even different) for any item,
 595   # it will be killed out and then has to be fetched from the item scope query further down
 596   $query =
 597     qq|SELECT dord.cp_id, dord.donumber, dord.ordnumber, dord.transdate, dord.reqdate,
 598          dord.shippingpoint, dord.shipvia, dord.notes, dord.intnotes,
 599          e.name AS employee, dord.employee_id, dord.salesman_id,
 600          dord.${vc}_id, cv.name AS ${vc},
 601          dord.closed, dord.reqdate, dord.department_id, dord.cusordnumber,
 602          d.description AS department, dord.language_id,
 603          dord.shipto_id,
 604          dord.globalproject_id, dord.delivered, dord.transaction_description,
 605          dord.taxzone_id, dord.taxincluded, dord.terms, dord.curr AS currency
 606        FROM delivery_orders dord
 607        JOIN ${vc} cv ON (dord.${vc}_id = cv.id)
 608        LEFT JOIN employee e ON (dord.employee_id = e.id)
 609        LEFT JOIN department d ON (dord.department_id = d.id)
 610        WHERE dord.id IN ($do_ids_placeholders)|;
 611   $sth = prepare_execute_query($form, $dbh, $query, @do_ids);
 612
 613   delete $form->{"${vc}_id"};
 614   while (my $ref = $sth->fetchrow_hashref("NAME_lc")) {
 615     if ($form->{"${vc}_id"} && ($ref->{"${vc}_id"} != $form->{"${vc}_id"})) {
 616       $sth->finish();
 617       $main::lxdebug->leave_sub();
 618
 619       return 0;
 620     }
 621
 622     map { $form->{$_} = $ref->{$_} } keys %$ref if ($ref);
 623     $form->{donumber_array} .= $form->{donumber} . ' ';
 624   }
 625   $sth->finish();
 626
 627   # remove any trailing whitespace
 628   $form->{currency} =~ s/\s*$//;
 629
 630   $form->{donumber_array} =~ s/\s*$//g;
 631
 632   $form->{saved_donumber} = $form->{donumber};
 633
 634   # if not given, fill transdate with current_date
 635   $form->{transdate} = $form->current_date($myconfig) unless $form->{transdate};
 636
 637   if ($mode eq 'single') {
 638     $query = qq|SELECT s.* FROM shipto s WHERE s.trans_id = ? AND s.module = 'DO'|;
 639     $sth   = prepare_execute_query($form, $dbh, $query, $form->{id});
 640
 641     $ref   = $sth->fetchrow_hashref("NAME_lc");
 642     delete $ref->{id};
 643     map { $form->{$_} = $ref->{$_} } keys %$ref;
 644     $sth->finish();
 645
 646     # get printed, emailed and queued
 647     $query = qq|SELECT s.printed, s.emailed, s.spoolfile, s.formname FROM status s WHERE s.trans_id = ?|;
 648     $sth   = prepare_execute_query($form, $dbh, $query, conv_i($form->{id}));
 649
 650     while ($ref = $sth->fetchrow_hashref("NAME_lc")) {
 651       $form->{printed} .= "$ref->{formname} " if $ref->{printed};
 652       $form->{emailed} .= "$ref->{formname} " if $ref->{emailed};
 653       $form->{queued}  .= "$ref->{formname} $ref->{spoolfile} " if $ref->{spoolfile};
 654     }
 655     $sth->finish();
 656     map { $form->{$_} =~ s/ +$//g } qw(printed emailed queued);
 657
 658   } else {
 659     delete $form->{id};
 660   }
 661
 662   my %oid = ('Pg'     => 'oid',
 663              'Oracle' => 'rowid');
 664
 665   # retrieve individual items
 666   # this query looks up all information about the items
 667   # stuff different from the whole will not be overwritten, but saved with a suffix.
 668   $query =
 669     qq|SELECT doi.id AS delivery_order_items_id,
 670          p.partnumber, p.assembly, p.listprice, doi.description, doi.qty,
 671          doi.sellprice, doi.parts_id AS id, doi.unit, doi.discount, p.bin, p.notes AS partnotes,
 672          doi.reqdate, doi.project_id, doi.serialnumber, doi.lastcost,
 673          doi.ordnumber, doi.transdate, doi.cusordnumber, doi.longdescription,
 674          doi.price_factor_id, doi.price_factor, doi.marge_price_factor, doi.pricegroup_id,
 675          pr.projectnumber, dord.transdate AS dord_transdate,
 676          pg.partsgroup
 677        FROM delivery_order_items doi
 678        JOIN parts p ON (doi.parts_id = p.id)
 679        JOIN delivery_orders dord ON (doi.delivery_order_id = dord.id)
 680        LEFT JOIN project pr ON (doi.project_id = pr.id)
 681        LEFT JOIN partsgroup pg ON (p.partsgroup_id = pg.id)
 682        WHERE doi.delivery_order_id IN ($do_ids_placeholders)
 683        ORDER BY doi.$oid{$myconfig->{dbdriver}}|;
 684
 685   $form->{form_details} = selectall_hashref_query($form, $dbh, $query, @do_ids);
 686
 687   # Retrieve custom variables.
 688   foreach my $doi (@{ $form->{form_details} }) {
 689     my $cvars = CVar->get_custom_variables(dbh        => $dbh,
 690                                            module     => 'IC',
 691                                            sub_module => 'delivery_order_items',
 692                                            trans_id   => $doi->{delivery_order_items_id},
 693                                           );
 694     map { $doi->{"ic_cvar_$_->{name}"} = $_->{value} } @{ $cvars };
 695   }
 696
 697   if ($mode eq 'single') {
 698     my $in_out = $form->{type} =~ /^sales/ ? 'out' : 'in';
 699
 700     $query =
 701       qq|SELECT qty, unit, bin_id, warehouse_id, chargenumber, bestbefore
 702          FROM delivery_order_items_stock
 703          WHERE delivery_order_item_id = ?|;
 704     my $sth = prepare_query($form, $dbh, $query);
 705
 706     foreach my $doi (@{ $form->{form_details} }) {
 707       do_statement($form, $sth, $query, conv_i($doi->{delivery_order_items_id}));
 708       my $requests = [];
 709       while (my $ref = $sth->fetchrow_hashref()) {
 710         push @{ $requests }, $ref;
 711       }
 712
 713       $doi->{"stock_${in_out}"} = YAML::Dump($requests);
 714     }
 715
 716     $sth->finish();
 717   }
 718
 719   Common::webdav_folder($form);
 720
 721   $main::lxdebug->leave_sub();
 722
 723   return 1;
 724 }
 725
 726 sub order_details {
 727   $main::lxdebug->enter_sub();
 728
 729   my ($self)   = @_;
 730
 731   my $myconfig = \%main::myconfig;
 732   my $form     = $main::form;
 733
 734   # connect to database
 735   my $dbh = $form->get_standard_dbh($myconfig);
 736   my $query;
 737   my @values = ();
 738   my $sth;
 739   my $item;
 740   my $i;
 741   my @partsgroup = ();
 742   my $partsgroup;
 743   my $position = 0;
 744
 745   my %oid = ('Pg'     => 'oid',
 746              'Oracle' => 'rowid');
 747
 748   my (@project_ids, %projectnumbers, %projectdescriptions);
 749
 750   push(@project_ids, $form->{"globalproject_id"}) if ($form->{"globalproject_id"});
 751
 752   # sort items by partsgroup
 753   for $i (1 .. $form->{rowcount}) {
 754     $partsgroup = "";
 755     if ($form->{"partsgroup_$i"} && $form->{groupitems}) {
 756       $partsgroup = $form->{"partsgroup_$i"};
 757     }
 758     push @partsgroup, [$i, $partsgroup];
 759     push(@project_ids, $form->{"project_id_$i"}) if ($form->{"project_id_$i"});
 760   }
 761
 762   if (@project_ids) {
 763     $query = "SELECT id, projectnumber, description FROM project WHERE id IN (" .
 764       join(", ", map("?", @project_ids)) . ")";
 765     $sth = prepare_execute_query($form, $dbh, $query, @project_ids);
 766     while (my $ref = $sth->fetchrow_hashref()) {
 767       $projectnumbers{$ref->{id}} = $ref->{projectnumber};
 768       $projectdescriptions{$ref->{id}} = $ref->{description};
 769     }
 770     $sth->finish();
 771   }
 772
 773   $form->{"globalprojectnumber"} =
 774     $projectnumbers{$form->{"globalproject_id"}};
 775   $form->{"globalprojectdescription"} =
 776       $projectdescriptions{$form->{"globalproject_id"}};
 777
 778   my $q_pg     = qq|SELECT p.partnumber, p.description, p.unit, a.qty, pg.partsgroup
 779                     FROM assembly a
 780                     JOIN parts p ON (a.parts_id = p.id)
 781                     LEFT JOIN partsgroup pg ON (p.partsgroup_id = pg.id)
 782                     WHERE a.bom = '1'
 783                       AND a.id = ?|;
 784   my $h_pg     = prepare_query($form, $dbh, $q_pg);
 785
 786   my $q_bin_wh = qq|SELECT (SELECT description FROM bin       WHERE id = ?) AS bin,
 787                            (SELECT description FROM warehouse WHERE id = ?) AS warehouse|;
 788   my $h_bin_wh = prepare_query($form, $dbh, $q_bin_wh);
 789
 790   my $in_out   = $form->{type} =~ /^sales/ ? 'out' : 'in';
 791
 792   my $num_si   = 0;
 793
 794   my $ic_cvar_configs = CVar->get_configs(module => 'IC');
 795
 796   $form->{TEMPLATE_ARRAYS} = { };
 797   IC->prepare_parts_for_printing();
 798
 799   my @arrays =
 800     qw(runningnumber number description longdescription qty unit
 801        partnotes serialnumber reqdate projectnumber projectdescription
 802        si_runningnumber si_number si_description
 803        si_warehouse si_bin si_chargenumber si_bestbefore si_qty si_unit);
 804
 805   map { $form->{TEMPLATE_ARRAYS}->{$_} = [] } (@arrays);
 806
 807   push @arrays, map { "ic_cvar_$_->{name}" } @{ $ic_cvar_configs };
 808
 809   $form->get_lists('price_factors' => 'ALL_PRICE_FACTORS');
 810   my %price_factors = map { $_->{id} => $_->{factor} } @{ $form->{ALL_PRICE_FACTORS} };
 811
 812   my $sameitem = "";
 813   foreach $item (sort { $a->[1] cmp $b->[1] } @partsgroup) {
 814     $i = $item->[0];
 815
 816     next if (!$form->{"id_$i"});
 817
 818     $position++;
 819
 820     if ($item->[1] ne $sameitem) {
 821       push(@{ $form->{description} }, qq|$item->[1]|);
 822       $sameitem = $item->[1];
 823
 824       map({ push(@{ $form->{$_} }, "") } grep({ $_ ne "description" } @arrays));
 825     }
 826
 827     $form->{"qty_$i"} = $form->parse_amount($myconfig, $form->{"qty_$i"});
 828
 829     # add number, description and qty to $form->{number}, ....
 830
 831     my $price_factor = $price_factors{$form->{"price_factor_id_$i"}} || { 'factor' => 1 };
 832
 833     push @{ $form->{TEMPLATE_ARRAYS}{runningnumber} },   $position;
 834     push @{ $form->{TEMPLATE_ARRAYS}{number} },          $form->{"partnumber_$i"};
 835     push @{ $form->{TEMPLATE_ARRAYS}{description} },     $form->{"description_$i"};
 836     push @{ $form->{TEMPLATE_ARRAYS}{longdescription} }, $form->{"longdescription_$i"};
 837     push @{ $form->{TEMPLATE_ARRAYS}{qty} },             $form->format_amount($myconfig, $form->{"qty_$i"});
 838     push @{ $form->{TEMPLATE_ARRAYS}{qty_nofmt} },       $form->{"qty_$i"};
 839     push @{ $form->{TEMPLATE_ARRAYS}{unit} },            $form->{"unit_$i"};
 840     push @{ $form->{TEMPLATE_ARRAYS}{partnotes} },       $form->{"partnotes_$i"};
 841     push @{ $form->{TEMPLATE_ARRAYS}{serialnumber} },    $form->{"serialnumber_$i"};
 842     push @{ $form->{TEMPLATE_ARRAYS}{reqdate} },         $form->{"reqdate_$i"};
 843     push @{ $form->{TEMPLATE_ARRAYS}{projectnumber} },   $projectnumbers{$form->{"project_id_$i"}};
 844     push @{ $form->{TEMPLATE_ARRAYS}{projectdescription} },
 845       $projectdescriptions{$form->{"project_id_$i"}};
 846
 847     if ($form->{"assembly_$i"}) {
 848       $sameitem = "";
 849
 850       # get parts and push them onto the stack
 851       my $sortorder = "";
 852       if ($form->{groupitems}) {
 853         $sortorder =
 854           qq|ORDER BY pg.partsgroup, a.$oid{$myconfig->{dbdriver}}|;
 855       } else {
 856         $sortorder = qq|ORDER BY a.$oid{$myconfig->{dbdriver}}|;
 857       }
 858
 859       do_statement($form, $h_pg, $q_pg, conv_i($form->{"id_$i"}));
 860
 861       while (my $ref = $h_pg->fetchrow_hashref("NAME_lc")) {
 862         if ($form->{groupitems} && $ref->{partsgroup} ne $sameitem) {
 863           map({ push(@{ $form->{$_} }, "") } grep({ $_ ne "description" } @arrays));
 864           $sameitem = ($ref->{partsgroup}) ? $ref->{partsgroup} : "--";
 865           push(@{ $form->{description} }, $sameitem);
 866         }
 867         push(@{ $form->{description} }, $form->format_amount($myconfig, $ref->{qty} * $form->{"qty_$i"}) . qq|, $ref->{partnumber}, $ref->{description}|);
 868
 869         map({ push(@{ $form->{$_} }, "") } grep({ $_ ne "description" } @arrays));
 870       }
 871     }
 872
 873     if ($form->{"inventory_accno_$i"} && !$form->{"assembly_$i"}) {
 874       my $stock_info = DO->unpack_stock_information('packed' => $form->{"stock_${in_out}_$i"});
 875
 876       foreach my $si (@{ $stock_info }) {
 877         $num_si++;
 878
 879         do_statement($form, $h_bin_wh, $q_bin_wh, conv_i($si->{bin_id}), conv_i($si->{warehouse_id}));
 880         my $bin_wh = $h_bin_wh->fetchrow_hashref();
 881
 882         push @{ $form->{TEMPLATE_ARRAYS}{si_runningnumber}[$position-1] }, $num_si;
 883         push @{ $form->{TEMPLATE_ARRAYS}{si_number}[$position-1] },        $form->{"partnumber_$i"};
 884         push @{ $form->{TEMPLATE_ARRAYS}{si_description}[$position-1] },   $form->{"description_$i"};
 885         push @{ $form->{TEMPLATE_ARRAYS}{si_warehouse}[$position-1] },     $bin_wh->{warehouse};
 886         push @{ $form->{TEMPLATE_ARRAYS}{si_bin}[$position-1] },           $bin_wh->{bin};
 887         push @{ $form->{TEMPLATE_ARRAYS}{si_chargenumber}[$position-1] },  $si->{chargenumber};
 888         push @{ $form->{TEMPLATE_ARRAYS}{si_bestbefore}[$position-1] },    $si->{bestbefore};
 889         push @{ $form->{TEMPLATE_ARRAYS}{si_qty}[$position-1] },           $form->format_amount($myconfig, $si->{qty} * 1);
 890         push @{ $form->{TEMPLATE_ARRAYS}{si_qty_nofmt}[$position-1] },     $si->{qty} * 1;
 891         push @{ $form->{TEMPLATE_ARRAYS}{si_unit}[$position-1] },          $si->{unit};
 892       }
 893     }
 894
 895     push @{ $form->{TEMPLATE_ARRAYS}->{"ic_cvar_$_->{name}"} },
 896       CVar->format_to_template(CVar->parse($form->{"ic_cvar_$_->{name}_$i"}, $_), $_)
 897         for @{ $ic_cvar_configs };
 898   }
 899
 900   $h_pg->finish();
 901   $h_bin_wh->finish();
 902
 903   $form->{username} = $myconfig->{name};
 904
 905   $main::lxdebug->leave_sub();
 906 }
 907
 908 sub project_description {
 909   $main::lxdebug->enter_sub();
 910
 911   my ($self, $dbh, $id) = @_;
 912
 913   my $form     =  $main::form;
 914
 915   my $query = qq|SELECT description FROM project WHERE id = ?|;
 916   my ($value) = selectrow_query($form, $dbh, $query, $id);
 917
 918   $main::lxdebug->leave_sub();
 919
 920   return $value;
 921 }
 922
 923 sub unpack_stock_information {
 924   $main::lxdebug->enter_sub();
 925
 926   my $self   = shift;
 927   my %params = @_;
 928
 929   Common::check_params_x(\%params, qw(packed));
 930
 931   my $unpacked;
 932
 933   eval { $unpacked = $params{packed} ? YAML::Load($params{packed}) : []; };
 934
 935   $unpacked = [] if (!$unpacked || ('ARRAY' ne ref $unpacked));
 936
 937   foreach my $entry (@{ $unpacked }) {
 938     next if ('HASH' eq ref $entry);
 939     $unpacked = [];
 940     last;
 941   }
 942
 943   $main::lxdebug->leave_sub();
 944
 945   return $unpacked;
 946 }
 947
 948 sub get_item_availability {
 949   $::lxdebug->enter_sub;
 950
 951   my $self     = shift;
 952   my %params   = @_;
 953
 954   Common::check_params(\%params, qw(parts_id));
 955
 956   my @parts_ids = 'ARRAY' eq ref $params{parts_id} ? @{ $params{parts_id} } : ($params{parts_id});
 957
 958   my $query     =
 959     qq|SELECT i.warehouse_id, i.bin_id, i.chargenumber, i.bestbefore, SUM(qty) AS qty, i.parts_id,
 960          w.description AS warehousedescription,
 961          b.description AS bindescription
 962        FROM inventory i
 963        LEFT JOIN warehouse w ON (i.warehouse_id = w.id)
 964        LEFT JOIN bin b       ON (i.bin_id       = b.id)
 965        WHERE (i.parts_id IN (| . join(', ', ('?') x scalar(@parts_ids)) . qq|))
 966        GROUP BY i.warehouse_id, i.bin_id, i.chargenumber, i.bestbefore, i.parts_id, w.description, b.description
 967        HAVING SUM(qty) > 0
 968        ORDER BY LOWER(w.description), LOWER(b.description), LOWER(i.chargenumber), i.bestbefore
 969 |;
 970   my $contents = selectall_hashref_query($::form, $::form->get_standard_dbh, $query, @parts_ids);
 971
 972   $::lxdebug->leave_sub;
 973
 974   return @{ $contents };
 975 }
 976
 977
 978 sub check_stock_availability {
 979   $main::lxdebug->enter_sub();
 980
 981   my $self     = shift;
 982   my %params   = @_;
 983
 984   Common::check_params(\%params, qw(requests parts_id));
 985
 986   my $myconfig    = \%main::myconfig;
 987   my $form        =  $main::form;
 988
 989   my $dbh         = $form->get_standard_dbh($myconfig);
 990
 991   my $units       = AM->retrieve_units($myconfig, $form);
 992
 993   my ($partunit)  = selectrow_query($form, $dbh, qq|SELECT unit FROM parts WHERE id = ?|, conv_i($params{parts_id}));
 994   my $unit_factor = $units->{$partunit}->{factor} || 1;
 995
 996   my @contents    = $self->get_item_availability(%params);
 997
 998   my @errors;
 999
1000   foreach my $sinfo (@{ $params{requests} }) {
1001     my $found = 0;
1002
1003     foreach my $row (@contents) {
1004       next if (($row->{bin_id}       != $sinfo->{bin_id}) ||
1005                ($row->{warehouse_id} != $sinfo->{warehouse_id}) ||
1006                ($row->{chargenumber} ne $sinfo->{chargenumber}) ||
1007                ($row->{bestbefore}   ne $sinfo->{bestbefore}));
1008
1009       $found       = 1;
1010
1011       my $base_qty = $sinfo->{qty} * $units->{$sinfo->{unit}}->{factor} / $unit_factor;
1012
1013       if ($base_qty > $row->{qty}) {
1014         $sinfo->{error} = 1;
1015         push @errors, $sinfo;
1016
1017         last;
1018       }
1019     }
1020
1021     push @errors, $sinfo if (!$found);
1022   }
1023
1024   $main::lxdebug->leave_sub();
1025
1026   return @errors;
1027 }
1028
1029 sub transfer_in_out {
1030   $main::lxdebug->enter_sub();
1031
1032   my $self     = shift;
1033   my %params   = @_;
1034
1035   Common::check_params(\%params, qw(direction requests));
1036
1037   if (!@{ $params{requests} }) {
1038     $main::lxdebug->leave_sub();
1039     return;
1040   }
1041
1042   my $myconfig = \%main::myconfig;
1043   my $form     = $main::form;
1044
1045   my $prefix   = $params{direction} eq 'in' ? 'dst' : 'src';
1046
1047   my @transfers;
1048
1049   foreach my $request (@{ $params{requests} }) {
1050     push @transfers, {
1051       'parts_id'               => $request->{parts_id},
1052       "${prefix}_warehouse_id" => $request->{warehouse_id},
1053       "${prefix}_bin_id"       => $request->{bin_id},
1054       'chargenumber'           => $request->{chargenumber},
1055       'bestbefore'             => $request->{bestbefore},
1056       'qty'                    => $request->{qty},
1057       'unit'                   => $request->{unit},
1058       'oe_id'                  => $form->{id},
1059       'shippingdate'           => 'current_date',
1060       'transfer_type'          => $params{direction} eq 'in' ? 'stock' : 'shipped',
1061       'project_id'             => $request->{project_id},
1062     };
1063   }
1064
1065   WH->transfer(@transfers);
1066
1067   $main::lxdebug->leave_sub();
1068 }
1069
1070 sub get_shipped_qty {
1071   $main::lxdebug->enter_sub();
1072
1073   my $self     = shift;
1074   my %params   = @_;
1075
1076   Common::check_params(\%params, qw(type oe_id));
1077
1078   my $myconfig = \%main::myconfig;
1079   my $form     = $main::form;
1080
1081   my $dbh      = $params{dbh} || $form->get_standard_dbh($myconfig);
1082
1083   my @links    = RecordLinks->get_links('dbh'        => $dbh,
1084                                         'from_table' => 'oe',
1085                                         'from_id'    => $params{oe_id},
1086                                         'to_table'   => 'delivery_orders');
1087   my @values   = map { $_->{to_id} } @links;
1088
1089   if (!scalar @values) {
1090     $main::lxdebug->leave_sub();
1091     return ();
1092   }
1093
1094   my $query =
1095     qq|SELECT doi.parts_id, doi.qty, doi.unit, p.unit AS partunit
1096        FROM delivery_order_items doi
1097        LEFT JOIN delivery_orders o ON (doi.delivery_order_id = o.id)
1098        LEFT JOIN parts p ON (doi.parts_id = p.id)
1099        WHERE o.id IN (| . join(', ', ('?') x scalar @values) . qq|)|;
1100
1101   my %ship      = ();
1102   my $entries   = selectall_hashref_query($form, $dbh, $query, @values);
1103   my $all_units = AM->retrieve_all_units();
1104
1105   foreach my $entry (@{ $entries }) {
1106     $entry->{qty} *= AM->convert_unit($entry->{unit}, $entry->{partunit}, $all_units);
1107
1108     if (!$ship{$entry->{parts_id}}) {
1109       $ship{$entry->{parts_id}} = $entry;
1110     } else {
1111       $ship{$entry->{parts_id}}->{qty} += $entry->{qty};
1112     }
1113   }
1114
1115   $main::lxdebug->leave_sub();
1116
1117   return %ship;
1118 }
1119
1120 sub is_marked_as_delivered {
1121   $main::lxdebug->enter_sub();
1122
1123   my $self     = shift;
1124   my %params   = @_;
1125
1126   Common::check_params(\%params, qw(id));
1127
1128   my $myconfig    = \%main::myconfig;
1129   my $form        = $main::form;
1130
1131   my $dbh         = $params{dbh} || $form->get_standard_dbh($myconfig);
1132
1133   my ($delivered) = selectfirst_array_query($form, $dbh, qq|SELECT delivered FROM delivery_orders WHERE id = ?|, conv_i($params{id}));
1134
1135   $main::lxdebug->leave_sub();
1136
1137   return $delivered ? 1 : 0;
1138 }
1139
1140
1141 1;