SL/Dev/Record.pm

   1 package SL::Dev::Record;
   2
   3 use strict;
   4 use base qw(Exporter);
   5 our @EXPORT_OK = qw(create_invoice_item
   6                     create_sales_invoice
   7                     create_credit_note
   8                     create_order_item
   9                     create_sales_order
  10                     create_purchase_order
  11                     create_delivery_order_item
  12                     create_sales_delivery_order
  13                     create_purchase_delivery_order
  14                     create_project create_department
  15                     create_ap_transaction
  16                     create_ar_transaction
  17                     create_gl_transaction
  18                    );
  19 our %EXPORT_TAGS = (ALL => \@EXPORT_OK);
  20
  21 use SL::DB::Invoice;
  22 use SL::DB::InvoiceItem;
  23 use SL::DB::Employee;
  24 use SL::Dev::Part qw(new_part);
  25 use SL::Dev::CustomerVendor qw(new_vendor new_customer);
  26 use SL::DB::Project;
  27 use SL::DB::ProjectStatus;
  28 use SL::DB::ProjectType;
  29 use SL::Form;
  30 use DateTime;
  31 use List::Util qw(sum);
  32 use Data::Dumper;
  33 use SL::Locale::String qw(t8);
  34 use SL::DATEV;
  35
  36 my %record_type_to_item_type = ( sales_invoice        => 'SL::DB::InvoiceItem',
  37                                  credit_note          => 'SL::DB::InvoiceItem',
  38                                  sales_order          => 'SL::DB::OrderItem',
  39                                  purchase_order       => 'SL::DB::OrderItem',
  40                                  sales_delivery_order => 'SL::DB::DeliveryOrderItem',
  41                                );
  42
  43 sub create_sales_invoice {
  44   my (%params) = @_;
  45
  46   my $record_type = 'sales_invoice';
  47   my $invoiceitems = delete $params{invoiceitems} // _create_two_items($record_type);
  48   _check_items($invoiceitems, $record_type);
  49
  50   my $customer = delete $params{customer} // new_customer(name => 'Testcustomer')->save;
  51   die "illegal customer" unless defined $customer && ref($customer) eq 'SL::DB::Customer';
  52
  53   my $invoice = SL::DB::Invoice->new(
  54     invoice      => 1,
  55     type         => 'invoice',
  56     customer_id  => $customer->id,
  57     taxzone_id   => $customer->taxzone->id,
  58     invnumber    => delete $params{invnumber}   // undef,
  59     currency_id  => $params{currency_id} // $::instance_conf->get_currency_id,
  60     taxincluded  => $params{taxincluded} // 0,
  61     employee_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
  62     salesman_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
  63     transdate    => $params{transdate}   // DateTime->today_local->to_kivitendo,
  64     payment_id   => $params{payment_id}  // undef,
  65     gldate       => DateTime->today,
  66     invoiceitems => $invoiceitems,
  67   );
  68   $invoice->assign_attributes(%params) if %params;
  69
  70   $invoice->post;
  71   return $invoice;
  72 }
  73
  74 sub create_credit_note {
  75   my (%params) = @_;
  76
  77   my $record_type = 'credit_note';
  78   my $invoiceitems = delete $params{invoiceitems} // _create_two_items($record_type);
  79   _check_items($invoiceitems, $record_type);
  80
  81   my $customer = delete $params{customer} // new_customer(name => 'Testcustomer')->save;
  82   die "illegal customer" unless defined $customer && ref($customer) eq 'SL::DB::Customer';
  83
  84   # adjust qty for credit note items
  85   $_->qty( $_->qty * -1) foreach @{$invoiceitems};
  86
  87   my $invoice = SL::DB::Invoice->new(
  88     invoice      => 1,
  89     type         => 'credit_note',
  90     customer_id  => $customer->id,
  91     taxzone_id   => $customer->taxzone->id,
  92     invnumber    => delete $params{invnumber}   // undef,
  93     currency_id  => $params{currency_id} // $::instance_conf->get_currency_id,
  94     taxincluded  => $params{taxincluded} // 0,
  95     employee_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
  96     salesman_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
  97     transdate    => $params{transdate}   // DateTime->today_local->to_kivitendo,
  98     payment_id   => $params{payment_id}  // undef,
  99     gldate       => DateTime->today,
 100     invoiceitems => $invoiceitems,
 101   );
 102   $invoice->assign_attributes(%params) if %params;
 103
 104   $invoice->post;
 105   return $invoice;
 106 }
 107
 108 sub create_sales_delivery_order {
 109   my (%params) = @_;
 110
 111   my $record_type = 'sales_delivery_order';
 112   my $orderitems = delete $params{orderitems} // _create_two_items($record_type);
 113   _check_items($orderitems, $record_type);
 114
 115   my $customer = $params{customer} // new_customer(name => 'Testcustomer')->save;
 116   die "illegal customer" unless ref($customer) eq 'SL::DB::Customer';
 117
 118   my $delivery_order = SL::DB::DeliveryOrder->new(
 119     'is_sales'   => 'true',
 120     'closed'     => undef,
 121     customer_id  => $customer->id,
 122     taxzone_id   => $customer->taxzone_id,
 123     donumber     => $params{donumber}    // undef,
 124     currency_id  => $params{currency_id} // $::instance_conf->get_currency_id,
 125     taxincluded  => $params{taxincluded} // 0,
 126     employee_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
 127     salesman_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
 128     transdate    => $params{transdate}   // DateTime->today,
 129     orderitems   => $orderitems,
 130   );
 131   $delivery_order->assign_attributes(%params) if %params;
 132   $delivery_order->save;
 133   return $delivery_order;
 134 }
 135
 136 sub create_purchase_delivery_order {
 137   my (%params) = @_;
 138
 139   my $record_type = 'purchase_delivery_order';
 140   my $orderitems = delete $params{orderitems} // _create_two_items($record_type);
 141   _check_items($orderitems, $record_type);
 142
 143   my $vendor = $params{vendor} // new_vendor(name => 'Testvendor')->save;
 144   die "illegal customer" unless ref($vendor) eq 'SL::DB::Vendor';
 145
 146   my $delivery_order = SL::DB::DeliveryOrder->new(
 147     'is_sales'   => 'false',
 148     'closed'     => undef,
 149     vendor_id    => $vendor->id,
 150     taxzone_id   => $vendor->taxzone_id,
 151     donumber     => $params{donumber}    // undef,
 152     currency_id  => $params{currency_id} // $::instance_conf->get_currency_id,
 153     taxincluded  => $params{taxincluded} // 0,
 154     employee_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
 155     salesman_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
 156     transdate    => $params{transdate}   // DateTime->today,
 157     orderitems   => $orderitems,
 158   );
 159   $delivery_order->assign_attributes(%params) if %params;
 160   $delivery_order->save;
 161   return $delivery_order;
 162 }
 163
 164 sub create_sales_order {
 165   my (%params) = @_;
 166
 167   my $record_type = 'sales_order';
 168   my $orderitems = delete $params{orderitems} // _create_two_items($record_type);
 169   _check_items($orderitems, $record_type);
 170
 171   my $save = delete $params{save} // 0;
 172
 173   my $customer = $params{customer} // new_customer(name => 'Testcustomer')->save;
 174   die "illegal customer" unless ref($customer) eq 'SL::DB::Customer';
 175
 176   my $order = SL::DB::Order->new(
 177     customer_id  => delete $params{customer_id} // $customer->id,
 178     taxzone_id   => delete $params{taxzone_id}  // $customer->taxzone->id,
 179     currency_id  => delete $params{currency_id} // $::instance_conf->get_currency_id,
 180     taxincluded  => delete $params{taxincluded} // 0,
 181     employee_id  => delete $params{employee_id} // SL::DB::Manager::Employee->current->id,
 182     salesman_id  => delete $params{employee_id} // SL::DB::Manager::Employee->current->id,
 183     transdate    => delete $params{transdate}   // DateTime->today,
 184     orderitems   => $orderitems,
 185   );
 186   $order->assign_attributes(%params) if %params;
 187
 188   if ( $save ) {
 189     $order->calculate_prices_and_taxes;
 190     $order->save;
 191   }
 192   return $order;
 193 }
 194
 195 sub create_purchase_order {
 196   my (%params) = @_;
 197
 198   my $record_type = 'purchase_order';
 199   my $orderitems = delete $params{orderitems} // _create_two_items($record_type);
 200   _check_items($orderitems, $record_type);
 201
 202   my $save = delete $params{save} // 0;
 203
 204   my $vendor = $params{vendor} // new_vendor(name => 'Testvendor')->save;
 205   die "illegal vendor" unless ref($vendor) eq 'SL::DB::Vendor';
 206
 207   my $order = SL::DB::Order->new(
 208     vendor_id    => delete $params{vendor_id}   // $vendor->id,
 209     taxzone_id   => delete $params{taxzone_id}  // $vendor->taxzone->id,
 210     currency_id  => delete $params{currency_id} // $::instance_conf->get_currency_id,
 211     taxincluded  => delete $params{taxincluded} // 0,
 212     transdate    => delete $params{transdate}   // DateTime->today,
 213     'closed'     => undef,
 214     orderitems   => $orderitems,
 215   );
 216   $order->assign_attributes(%params) if %params;
 217
 218   if ( $save ) {
 219     $order->calculate_prices_and_taxes; # not tested for purchase orders
 220     $order->save;
 221   }
 222   return $order;
 223 };
 224
 225 sub _check_items {
 226   my ($items, $record_type) = @_;
 227
 228   if  ( scalar @{$items} == 0 or grep { ref($_) ne $record_type_to_item_type{"$record_type"} } @{$items} ) {
 229     die "Error: items must be an arrayref of " . $record_type_to_item_type{"$record_type"} . "objects.";
 230   }
 231 }
 232
 233 sub create_invoice_item {
 234   my (%params) = @_;
 235
 236   return _create_item(record_type => 'sales_invoice', %params);
 237 }
 238
 239 sub create_order_item {
 240   my (%params) = @_;
 241
 242   return _create_item(record_type => 'sales_order', %params);
 243 }
 244
 245 sub create_delivery_order_item {
 246   my (%params) = @_;
 247
 248   return _create_item(record_type => 'sales_delivery_order', %params);
 249 }
 250
 251 sub _create_item {
 252   my (%params) = @_;
 253
 254   my $record_type = delete($params{record_type});
 255   my $part        = delete($params{part});
 256
 257   die "illegal record type: $record_type, must be one of: " . join(' ', keys %record_type_to_item_type) unless $record_type_to_item_type{ $record_type };
 258   die "part missing as param" unless $part && ref($part) eq 'SL::DB::Part';
 259
 260   my ($sellprice, $lastcost);
 261
 262   if ( $record_type =~ /^sales/ ) {
 263     $sellprice = delete $params{sellprice} // $part->sellprice;
 264     $lastcost  = delete $params{lastcost}  // $part->lastcost;
 265   } else {
 266     $sellprice = delete $params{sellprice} // $part->lastcost;
 267     $lastcost  = delete $params{lastcost}  // 0; # $part->lastcost;
 268   }
 269
 270   my $item = "$record_type_to_item_type{$record_type}"->new(
 271     parts_id    => $part->id,
 272     sellprice   => $sellprice,
 273     lastcost    => $lastcost,
 274     description => $part->description,
 275     unit        => $part->unit,
 276     qty         => $params{qty} || 5,
 277   );
 278   $item->assign_attributes(%params) if %params;
 279   return $item;
 280 }
 281
 282 sub _create_two_items {
 283   my ($record_type) = @_;
 284
 285   my $part1 = new_part(description => 'Testpart 1',
 286                        sellprice   => 12,
 287                       )->save;
 288   my $part2 = new_part(description => 'Testpart 2',
 289                        sellprice   => 10,
 290                       )->save;
 291   my $item1 = _create_item(record_type => $record_type, part => $part1, qty => 5);
 292   my $item2 = _create_item(record_type => $record_type, part => $part2, qty => 8);
 293   return [ $item1, $item2 ];
 294 }
 295
 296 sub create_project {
 297   my (%params) = @_;
 298   my $project = SL::DB::Project->new(
 299     projectnumber     => delete $params{projectnumber} // 1,
 300     description       => delete $params{description} // "Test project",
 301     active            => 1,
 302     valid             => 1,
 303     project_status_id => SL::DB::Manager::ProjectStatus->find_by(name => "running")->id,
 304     project_type_id   => SL::DB::Manager::ProjectType->find_by(description => "Standard")->id,
 305   )->save;
 306   $project->assign_attributes(%params) if %params;
 307   return $project;
 308 }
 309
 310 sub create_department {
 311   my (%params) = @_;
 312
 313   my $department = SL::DB::Department->new(
 314     'description' => delete $params{description} // 'Test Department',
 315   )->save;
 316
 317   $department->assign_attributes(%params) if %params;
 318   return $department;
 319
 320 }
 321
 322 sub create_ap_transaction {
 323   my (%params) = @_;
 324
 325   my $vendor = delete $params{vendor};
 326   if ( $vendor ) {
 327     die "vendor missing or not a SL::DB::Vendor object" unless ref($vendor) eq 'SL::DB::Vendor';
 328   } else {
 329     # use default SL/Dev vendor if it exists, or create a new one
 330     $vendor = SL::DB::Manager::Vendor->find_by(name => 'Testlieferant') // new_vendor->save;
 331   };
 332
 333   my $taxincluded = $params{taxincluded} // 1;
 334   delete $params{taxincluded};
 335
 336   my $bookings    = delete $params{bookings};
 337   # default bookings
 338   unless ( $bookings ) {
 339     my $chart_postage   = SL::DB::Manager::Chart->find_by(description => 'Porto');
 340     my $chart_telephone = SL::DB::Manager::Chart->find_by(description => 'Telefon');
 341     $bookings = [
 342                   {
 343                     chart  => $chart_postage,
 344                     amount => 1000,
 345                   },
 346                   {
 347                     chart  => $chart_telephone,
 348                     amount => $taxincluded ? 1190 : 1000,
 349                   },
 350                 ]
 351   };
 352
 353   # optional params:
 354   my $project_id         = delete $params{globalproject_id};
 355
 356   # if amount or netamount are given, then it compares them to the final values, and dies if they don't match
 357   my $expected_amount    = delete $params{amount};
 358   my $expected_netamount = delete $params{netamount};
 359
 360   my $dec = delete $params{dec} // 2;
 361
 362   my $transdate  = delete $params{transdate} // DateTime->today;
 363   die "transdate hat to be DateTime object" unless ref($transdate) eq 'DateTime';
 364
 365   my $ap_chart = delete $params{ap_chart} // SL::DB::Manager::Chart->find_by( accno => '1600' );
 366   die "no ap_chart found or not an AP chart" unless $ap_chart and $ap_chart->link eq 'AP';
 367
 368   my $ap_transaction = SL::DB::PurchaseInvoice->new(
 369     vendor_id        => $vendor->id,
 370     invoice          => 0,
 371     transactions     => [],
 372     globalproject_id => $project_id,
 373     invnumber        => delete $params{invnumber} // 'test ap_transaction',
 374     notes            => delete $params{notes}     // 'test ap_transaction',
 375     transdate        => $transdate,
 376     taxincluded      => $taxincluded,
 377     taxzone_id       => $vendor->taxzone_id, # taxzone_id shouldn't have any effect on ap transactions
 378     currency_id      => $::instance_conf->get_currency_id,
 379     type             => undef, # isn't set for ap
 380     employee_id      => SL::DB::Manager::Employee->current->id,
 381   );
 382   # $ap_transaction->assign_attributes(%params) if %params;
 383
 384   foreach my $booking ( @{$bookings} ) {
 385     my $chart = delete $booking->{chart};
 386     die "illegal chart" unless ref($chart) eq 'SL::DB::Chart';
 387
 388     my $tax = _transaction_tax_helper($booking, $chart, $transdate); # will die if tax can't be found
 389
 390     $ap_transaction->add_ap_amount_row(
 391       amount     => $booking->{amount}, # add_ap_amount_row expects the user input amount, does its own calculate_tax
 392       chart      => $chart,
 393       tax_id     => $tax->id,
 394       project_id => $booking->{project_id},
 395     );
 396   }
 397
 398   my $acc_trans_sum = sum map { $_->amount  } grep { $_->chart_link =~ 'AP_amount' } @{$ap_transaction->transactions};
 399   # $main::lxdebug->message(0, sprintf("accno: %s    amount: %s   chart_link: %s\n",
 400   #                                    $_->amount,
 401   #                                    $_->chart->accno,
 402   #                                    $_->chart_link
 403   #                                   )) foreach @{$ap_transaction->transactions};
 404
 405   # determine netamount and amount from the transactions that were added via bookings
 406   $ap_transaction->netamount( -1 * sum map { $_->amount  } grep { $_->chart_link =~ 'AP_amount' } @{$ap_transaction->transactions} );
 407   # $main::lxdebug->message(0, sprintf('found netamount %s', $ap_transaction->netamount));
 408
 409   my $taxamount = -1 * sum map { $_->amount  } grep { $_->chart_link =~ /tax/ } @{$ap_transaction->transactions};
 410   $ap_transaction->amount( $ap_transaction->netamount + $taxamount );
 411   # additional check, add up all transactions before AP-transaction is added
 412   my $refamount = -1 * sum map { $_->amount  } @{$ap_transaction->transactions};
 413   die "refamount = $refamount, ap_transaction->amount = " . $ap_transaction->amount unless $refamount == $ap_transaction->amount;
 414
 415   # if amount or netamount were passed as params, check if the values are still
 416   # the same after recalculating them from the acc_trans entries
 417   if (defined $expected_amount) {
 418     die "amount doesn't match acc_trans amounts: $expected_amount != " . $ap_transaction->amount unless $expected_amount == $ap_transaction->amount;
 419   }
 420   if (defined $expected_netamount) {
 421     die "netamount doesn't match acc_trans netamounts: $expected_netamount != " . $ap_transaction->netamount unless $expected_netamount == $ap_transaction->netamount;
 422   }
 423
 424   $ap_transaction->create_ap_row(chart => $ap_chart);
 425   $ap_transaction->save;
 426   # $main::lxdebug->message(0, sprintf("created ap_transaction with invnumber %s and trans_id %s",
 427   #                                     $ap_transaction->invnumber,
 428   #                                     $ap_transaction->id));
 429   return $ap_transaction;
 430 }
 431
 432 sub create_ar_transaction {
 433   my (%params) = @_;
 434
 435   my $customer = delete $params{customer};
 436   if ( $customer ) {
 437     die "customer missing or not a SL::DB::Customer object" unless ref($customer) eq 'SL::DB::Customer';
 438   } else {
 439     # use default SL/Dev vendor if it exists, or create a new one
 440     $customer = SL::DB::Manager::Customer->find_by(name => 'Testkunde') // new_customer->save;
 441   };
 442
 443   my $taxincluded = $params{taxincluded} // 1;
 444   delete $params{taxincluded};
 445
 446   my $bookings    = delete $params{bookings};
 447   # default bookings
 448   unless ( $bookings ) {
 449     my $chart_19 = SL::DB::Manager::Chart->find_by(accno => '8400');
 450     my $chart_7  = SL::DB::Manager::Chart->find_by(accno => '8300');
 451     my $chart_0  = SL::DB::Manager::Chart->find_by(accno => '8200');
 452     $bookings = [
 453                   {
 454                     chart  => $chart_19,
 455                     amount => $taxincluded ? 119 : 100,
 456                   },
 457                   {
 458                     chart  => $chart_7,
 459                     amount => $taxincluded ? 107 : 100,
 460                   },
 461                   {
 462                     chart  => $chart_0,
 463                     amount => 100,
 464                   },
 465                 ]
 466   };
 467
 468   # optional params:
 469   my $project_id = delete $params{globalproject_id};
 470
 471   # if amount or netamount are given, then it compares them to the final values, and dies if they don't match
 472   my $expected_amount    = delete $params{amount};
 473   my $expected_netamount = delete $params{netamount};
 474
 475   my $dec = delete $params{dec} // 2;
 476
 477   my $transdate  = delete $params{transdate} // DateTime->today;
 478   die "transdate hat to be DateTime object" unless ref($transdate) eq 'DateTime';
 479
 480   my $ar_chart = delete $params{ar_chart} // SL::DB::Manager::Chart->find_by( accno => '1400' );
 481   die "no ar_chart found or not an AR chart" unless $ar_chart and $ar_chart->link eq 'AR';
 482
 483   my $ar_transaction = SL::DB::Invoice->new(
 484     customer_id      => $customer->id,
 485     invoice          => 0,
 486     transactions     => [],
 487     globalproject_id => $project_id,
 488     invnumber        => delete $params{invnumber} // 'test ar_transaction',
 489     notes            => delete $params{notes}     // 'test ar_transaction',
 490     transdate        => $transdate,
 491     taxincluded      => $taxincluded,
 492     taxzone_id       => $customer->taxzone_id, # taxzone_id shouldn't have any effect on ar transactions
 493     currency_id      => $::instance_conf->get_currency_id,
 494     type             => undef, # isn't set for ar
 495     employee_id      => SL::DB::Manager::Employee->current->id,
 496   );
 497   # $ar_transaction->assign_attributes(%params) if %params;
 498
 499   foreach my $booking ( @{$bookings} ) {
 500     my $chart = delete $booking->{chart};
 501     die "illegal chart" unless ref($chart) eq 'SL::DB::Chart';
 502
 503     my $tax = _transaction_tax_helper($booking, $chart, $transdate); # will die if tax can't be found
 504
 505     $ar_transaction->add_ar_amount_row(
 506       amount     => $booking->{amount}, # add_ar_amount_row expects the user input amount, does its own calculate_tax
 507       chart      => $chart,
 508       tax_id     => $tax->id,
 509       project_id => $booking->{project_id},
 510     );
 511   }
 512
 513   my $acc_trans_sum = sum map { $_->amount  } grep { $_->chart_link =~ 'AR_amount' } @{$ar_transaction->transactions};
 514   # $main::lxdebug->message(0, sprintf("accno: %s    amount: %s   chart_link: %s\n",
 515   #                                    $_->amount,
 516   #                                    $_->chart->accno,
 517   #                                    $_->chart_link
 518   #                                   )) foreach @{$ar_transaction->transactions};
 519
 520   # determine netamount and amount from the transactions that were added via bookings
 521   $ar_transaction->netamount( 1 * sum map { $_->amount  } grep { $_->chart_link =~ 'AR_amount' } @{$ar_transaction->transactions} );
 522   # $main::lxdebug->message(0, sprintf('found netamount %s', $ar_transaction->netamount));
 523
 524   my $taxamount = 1 * sum map { $_->amount  } grep { $_->chart_link =~ /tax/ } @{$ar_transaction->transactions};
 525   $ar_transaction->amount( $ar_transaction->netamount + $taxamount );
 526   # additional check, add up all transactions before AP-transaction is added
 527   my $refamount = 1 * sum map { $_->amount  } @{$ar_transaction->transactions};
 528   die "refamount = $refamount, ar_transaction->amount = " . $ar_transaction->amount unless $refamount == $ar_transaction->amount;
 529
 530   # if amount or netamount were passed as params, check if the values are still
 531   # the same after recalculating them from the acc_trans entries
 532   if (defined $expected_amount) {
 533     die "amount doesn't match acc_trans amounts: $expected_amount != " . $ar_transaction->amount unless $expected_amount == $ar_transaction->amount;
 534   }
 535   if (defined $expected_netamount) {
 536     die "netamount doesn't match acc_trans netamounts: $expected_netamount != " . $ar_transaction->netamount unless $expected_netamount == $ar_transaction->netamount;
 537   }
 538
 539   $ar_transaction->create_ar_row(chart => $ar_chart);
 540   $ar_transaction->save;
 541   # $main::lxdebug->message(0, sprintf("created ar_transaction with invnumber %s and trans_id %s",
 542   #                                     $ar_transaction->invnumber,
 543   #                                     $ar_transaction->id));
 544   return $ar_transaction;
 545 }
 546
 547 sub create_gl_transaction {
 548   my (%params) = @_;
 549
 550   my $ob_transaction = delete $params{ob_transaction} // 0;
 551   my $cb_transaction = delete $params{cb_transaction} // 0;
 552   my $dec            = delete $params{rec} // 2;
 553
 554   my $taxincluded = defined $params{taxincluded} ? $params{taxincluded} : 1;
 555
 556   my $today      = DateTime->today_local;
 557   my $transdate  = delete $params{transdate} // $today;
 558
 559   my $reference   = delete $params{reference}   // 'reference';
 560   my $description = delete $params{description} // 'description';
 561
 562   my $department_id = delete $params{department_id};
 563
 564   my $bookings = delete $params{bookings};
 565   unless ( $bookings && scalar @{$bookings} ) {
 566     # default bookings if left empty
 567     my $expense_chart = SL::DB::Manager::Chart->find_by(accno => '4660') or die "Can't find expense chart 4660\n"; # Reisekosten
 568     my $cash_chart    = SL::DB::Manager::Chart->find_by(accno => '1000') or die "Can't find cash chart 1000\n";    # Kasse
 569
 570     $taxincluded = 0;
 571
 572     $reference   = 'Reise';
 573     $description = 'Reise';
 574
 575     $bookings = [
 576                   {
 577                     chart  => $expense_chart, # has default tax of 19%
 578                     credit => 84.03,
 579                     taxkey => 9,
 580                   },
 581                   {
 582                     chart  => $cash_chart,
 583                     debit  => 100,
 584                     taxkey => 0,
 585                   },
 586     ];
 587   }
 588
 589   my $gl_transaction = SL::DB::GLTransaction->new(
 590     reference      => $reference,
 591     description    => $description,
 592     transdate      => $transdate,
 593     gldate         => $today,
 594     taxincluded    => $taxincluded,
 595     type           => undef,
 596     ob_transaction => $ob_transaction,
 597     cb_transaction => $cb_transaction,
 598     storno         => 0,
 599     storno_id      => undef,
 600     transactions   => [],
 601   );
 602
 603   my @acc_trans;
 604   if ( scalar @{$bookings} ) {
 605     # there are several ways of determining the tax:
 606     # * tax_id : fetches SL::DB::Tax object via id (as used in dropdown in interface)
 607     # * tax : SL::DB::Tax object (where $tax->id = tax_id)
 608     # * taxkey : tax is determined from startdate
 609     # * none of the above defined: use the default tax for that chart
 610
 611     foreach my $booking ( @{$bookings} ) {
 612       my $chart = delete $booking->{chart};
 613       die "illegal chart" unless ref($chart) eq 'SL::DB::Chart';
 614
 615       die t8('Empty transaction!')
 616         unless $booking->{debit} or $booking->{credit}; # must exist and not be 0
 617       die t8('Cannot post transaction with a debit and credit entry for the same account!')
 618         if defined($booking->{debit}) and defined($booking->{credit});
 619
 620       my $tax = _transaction_tax_helper($booking, $chart, $transdate); # will die if tax can't be found
 621
 622       $gl_transaction->add_chart_booking(
 623         chart      => $chart,
 624         debit      => $booking->{debit},
 625         credit     => $booking->{credit},
 626         tax_id     => $tax->id,
 627         source     => $booking->{source} // '',
 628         memo       => $booking->{memo}   // '',
 629         project_id => $booking->{project_id}
 630       );
 631     }
 632   };
 633
 634   $gl_transaction->post;
 635
 636   return $gl_transaction;
 637 }
 638
 639 sub _transaction_tax_helper {
 640   # checks for hash-entries with key tax, tax_id or taxkey
 641   # returns an SL::DB::Tax object
 642   # can be used for booking hashref in ar_transaction, ap_transaction and gl_transaction
 643   # will modify hashref, e.g. removing taxkey if tax_id was also supplied
 644
 645   my ($booking, $chart, $transdate) = @_;
 646
 647   die "_transaction_tax_helper: chart missing"     unless $chart && ref($chart) eq 'SL::DB::Chart';
 648   die "_transaction_tax_helper: transdate missing" unless $transdate && ref($transdate) eq 'DateTime';
 649
 650   my $tax;
 651
 652   if ( defined $booking->{tax_id} ) { # tax_id may be 0
 653     delete $booking->{taxkey}; # ignore any taxkeys that may have been added, tax_id has precedence
 654     $tax = SL::DB::Tax->new(id => $booking->{tax_id})->load( with => [ 'chart' ] );
 655   } elsif ( $booking->{tax} ) {
 656     die "illegal tax entry" unless ref($booking->{tax}) eq 'SL::DB::Tax';
 657     $tax = $booking->{tax};
 658   } elsif ( defined $booking->{taxkey} ) {
 659     # If a taxkey is given, find the taxkey entry for that chart that
 660     # matches the stored taxkey and with the correct transdate. This will only work
 661     # if kivitendo has that taxkey configured for that chart, i.e. it should barf if
 662     # e.g. the bank chart is called with taxkey 3.
 663
 664     # example query:
 665     #   select *
 666     #     from taxkeys
 667     #    where     taxkey_id = 3
 668     #          and chart_id = (select id from chart where accno = '8400')
 669     #          and startdate <= '2018-01-01'
 670     # order by startdate desc
 671     #    limit 1;
 672
 673     my $taxkey = SL::DB::Manager::TaxKey->get_first(
 674       query        => [ and => [ chart_id  => $chart->id,
 675                                  startdate => { le => $transdate },
 676                                  taxkey    => $booking->{taxkey}
 677                                ]
 678                       ],
 679       sort_by      => "startdate DESC",
 680       limit        => 1,
 681       with_objects => [ qw(tax) ],
 682     );
 683     die sprintf("Chart %s doesn't have a taxkey chart configured for taxkey %s", $chart->accno, $booking->{taxkey})
 684       unless $taxkey;
 685
 686     $tax = $taxkey->tax;
 687   } else {
 688     # use default tax for that chart if neither tax_id, tax or taxkey were defined
 689     my $active_taxkey = $chart->get_active_taxkey($transdate);
 690     $tax = $active_taxkey->tax;
 691     # $main::lxdebug->message(0, sprintf("found default taxrate %s for chart %s", $tax->rate, $chart->displayable_name));
 692   };
 693
 694   die "no tax" unless $tax && ref($tax) eq 'SL::DB::Tax';
 695   return $tax;
 696 };
 697
 698 1;
 699
 700 __END__
 701
 702 =head1 NAME
 703
 704 SL::Dev::Record - create record objects for testing, with minimal defaults
 705
 706 =head1 FUNCTIONS
 707
 708 =head2 C<create_sales_invoice %PARAMS>
 709
 710 Creates a new sales invoice (table ar, invoice = 1).
 711
 712 If neither customer nor invoiceitems are passed as params a customer and two
 713 parts are created and used for building the invoice.
 714
 715 Minimal usage example:
 716
 717   my $invoice = SL::Dev::Record::create_sales_invoice();
 718
 719 Example with params:
 720
 721   my $invoice2 = SL::Dev::Record::create_sales_invoice(
 722     invnumber   => 777,
 723     transdate   => DateTime->today->subtract(days => 7),
 724     taxincluded => 1,
 725   );
 726
 727 =head2 C<create_credit_note %PARAMS>
 728
 729 Create a credit note (sales). Use positive quantities when adding items.
 730
 731 Example including creation of parts and of credit_note:
 732
 733   my $part1 = SL::Dev::Part::new_part(   partnumber => 'T4254')->save;
 734   my $part2 = SL::Dev::Part::new_service(partnumber => 'Serv1')->save;
 735   my $credit_note = SL::Dev::Record::create_credit_note(
 736     invnumber    => '34',
 737     taxincluded  => 0,
 738     invoiceitems => [ SL::Dev::Record::create_invoice_item(part => $part1, qty =>  3, sellprice => 70),
 739                       SL::Dev::Record::create_invoice_item(part => $part2, qty => 10, sellprice => 50),
 740                     ]
 741   );
 742
 743 =head2 C<create_sales_order %PARAMS>
 744
 745 Examples:
 746
 747 Create a sales order and save it directly via rose, without running
 748 calculate_prices_and_taxes:
 749
 750   my $order = SL::Dev::Record::create_sales_order()->save;
 751
 752 Let create_sales_order run calculate_prices_and_taxes and save:
 753
 754   my $order = SL::Dev::Record::create_sales_order(save => 1);
 755
 756
 757 Example including creation of part and of sales order:
 758
 759   my $part1 = SL::Dev::Part::new_part(   partnumber => 'T4254')->save;
 760   my $part2 = SL::Dev::Part::new_service(partnumber => 'Serv1')->save;
 761   my $order = SL::Dev::Record::create_sales_order(
 762     save         => 1,
 763     taxincluded  => 0,
 764     orderitems => [ SL::Dev::Record::create_order_item(part => $part1, qty =>  3, sellprice => 70),
 765                     SL::Dev::Record::create_order_item(part => $part2, qty => 10, sellprice => 50),
 766                   ]
 767   );
 768
 769 Example: create 100 orders with the same part for 100 new customers:
 770
 771   my $part1 = SL::Dev::Part::new_part(partnumber => 'T6256')->save;
 772   SL::Dev::Record::create_sales_order(
 773     save         => 1,
 774     taxincluded  => 0,
 775     orderitems => [ SL::Dev::Record::create_order_item(part => $part1, qty => 1, sellprice => 9) ]
 776   ) for 1 .. 100;
 777
 778 =head2 C<create_purchase_order %PARAMS>
 779
 780 See comments for C<create_sales_order>.
 781
 782 Example:
 783
 784   my $purchase_order = SL::Dev::Record::create_purchase_order(save => 1);
 785
 786
 787 =head2 C<create_item %PARAMS>
 788
 789 Creates an item from a part object that can be added to a record.
 790
 791 Required params:
 792
 793   record_type (sales_invoice, sales_order, sales_delivery_order)
 794   part        (an SL::DB::Part object)
 795
 796 Example including creation of part and of invoice:
 797
 798   my $part    = SL::Dev::Part::new_part(  partnumber  => 'T4254')->save;
 799   my $item    = SL::Dev::Record::create_invoice_item(part => $part, qty => 2.5);
 800   my $invoice = SL::Dev::Record::create_sales_invoice(
 801     taxincluded  => 0,
 802     invoiceitems => [ $item ],
 803   );
 804
 805 =head2 C<create_project %PARAMS>
 806
 807 Creates a default project.
 808
 809 Minimal example, creating a project with status "running" and type "Standard":
 810
 811   my $project = SL::Dev::Record::create_project();
 812
 813   $project = SL::Dev::Record::create_project(
 814     projectnumber => 'p1',
 815     description   => 'Test project',
 816   )
 817
 818 If C<$params{description}> or C<$params{projectnumber}> exists, this will override the
 819 default value 'Test project'.
 820
 821 C<%params> should only contain alterable keys from the object Project.
 822
 823 =head2 C<create_department %PARAMS>
 824
 825 Creates a default department.
 826
 827 Minimal example:
 828
 829   my $department = SL::Dev::Record::create_department();
 830
 831   my $department = SL::Dev::Record::create_department(
 832     description => 'Hawaii',
 833   )
 834
 835 If C<$params{description}> exists, this will override the
 836 default value 'Test Department'.
 837
 838 C<%params> should only contain alterable keys from the object Department.
 839
 840 =head2 C<create_ap_transaction %PARAMS>
 841
 842 Creates a new AP transaction (table ap, invoice = 0), and will try to add as
 843 many defaults as possible.
 844
 845 Possible parameters:
 846  * vendor (SL::DB::Vendor object, defaults to SL::Dev default vendor)
 847  * taxincluded (0 or 1, defaults to 1)
 848  * transdate (DateTime object, defaults to current date)
 849  * bookings (arrayref for the charts to be booked, see examples below)
 850  * amount (to check if final amount matches this amount)
 851  * netamount (to check if final amount matches this amount)
 852  * dec (number of decimals to round to, defaults to 2)
 853  * ap_chart (SL::DB::Chart object, default to accno 1600)
 854  * invnumber (defaults to 'test ap_transaction')
 855  * notes (defaults to 'test ap_transaction')
 856  * globalproject_id
 857
 858 Currently doesn't support exchange rates.
 859
 860 Minimal usage example, creating an AP transaction with a default vendor and
 861 default bookings (telephone, postage):
 862
 863   use SL::Dev::Record qw(create_ap_transaction);
 864   my $invoice = create_ap_transaction();
 865
 866 Create an AP transaction with a specific vendor and specific charts:
 867
 868   my $vendor = SL::Dev::CustomerVendor::new_vendor(name => 'My Vendor')->save;
 869   my $chart_postage   = SL::DB::Manager::Chart->find_by(description => 'Porto');
 870   my $chart_telephone = SL::DB::Manager::Chart->find_by(description => 'Telefon');
 871
 872   my $ap_transaction = create_ap_transaction(
 873     vendor      => $vendor,
 874     invnumber   => 'test invoice taxincluded',
 875     taxincluded => 1,
 876     amount      => 2190, # optional param for checking whether final amount matches
 877     netamount   => 2000, # optional param for checking whether final netamount matches
 878     bookings    => [
 879                      {
 880                        chart  => $chart_postage,
 881                        amount => 1000,
 882                      },
 883                      {
 884                        chart  => $chart_telephone,
 885                        amount => 1190,
 886                      },
 887                    ]
 888   );
 889
 890 Or the same example with tax not included, but an old transdate and old taxrate (16%):
 891
 892   my $ap_transaction = create_ap_transaction(
 893     vendor      => $vendor,
 894     invnumber   => 'test invoice tax not included',
 895     transdate   => DateTime->new(year => 2000, month => 10, day => 1),
 896     taxincluded => 0,
 897     amount      => 2160, # optional param for checking whether final amount matches
 898     netamount   => 2000, # optional param for checking whether final netamount matches
 899     bookings    => [
 900                      {
 901                        chart  => $chart_postage,
 902                        amount => 1000,
 903                      },
 904                      {
 905                        chart  => $chart_telephone,
 906                        amount => 1000,
 907                      },
 908                  ]
 909   );
 910
 911 Don't use the default tax, e.g. postage with 19%:
 912
 913   my $tax_9          = SL::DB::Manager::Tax->find_by(taxkey => 9, rate => 0.19);
 914   my $chart_postage  = SL::DB::Manager::Chart->find_by(description => 'Porto');
 915   my $ap_transaction = create_ap_transaction(
 916     invnumber   => 'postage with tax',
 917     taxincluded => 0,
 918     bookings    => [
 919                      {
 920                        chart  => $chart_postage,
 921                        amount => 1000,
 922                        tax    => $tax_9,
 923                      },
 924                    ],
 925   );
 926
 927 =head2 C<create_ar_transaction %PARAMS>
 928
 929 See C<create_ap_transaction>, except use customer instead of vendor.
 930
 931 =head2 C<create_gl_transaction %PARAMS>
 932
 933 Creates a new GL transaction (table gl), which is basically a wrapper around
 934 SL::DB::GLTransaction->new(...) and add_chart_booking and post, while setting
 935 as many defaults as possible.
 936
 937 Possible parameters:
 938
 939  * taxincluded (0 or 1, defaults to 1)
 940  * transdate (DateTime object, defaults to current date)
 941  * dec (number of decimals to round to, defaults to 2)
 942  * bookings (arrayref for the charts and taxes to be booked, see examples below)
 943
 944 bookings must include a least:
 945
 946  * chart as an SL::DB::Chart object
 947  * credit or debit, as positive numbers
 948  * tax_id, tax (an SL::DB::Tax object) or taxkey (e.g. 9)
 949
 950 Can't be used to create storno transactions.
 951
 952 Minimal usage example, using all the defaults, creating a GL transaction with
 953 travel expenses:
 954
 955   use SL::Dev::Record qw(create_gl_transaction);
 956   $gl_transaction = create_gl_transaction();
 957
 958 Create a GL transaction with a specific charts and taxes (the default taxes for
 959 those charts are used if none are explicitly given in bookings):
 960
 961   my $cash           = SL::DB::Manager::Chart->find_by( description => 'Kasse'          );
 962   my $betriebsbedarf = SL::DB::Manager::Chart->find_by( description => 'Betriebsbedarf' );
 963   $gl_transaction = create_gl_transaction(
 964     reference   => 'betriebsbedarf',
 965     taxincluded => 1,
 966     bookings    => [
 967                      {
 968                        chart  => $betriebsbedarf,
 969                        memo   => 'foo 1',
 970                        source => 'foo 1',
 971                        credit => 119,
 972                      },
 973                      {
 974                        chart  => $betriebsbedarf,
 975                        memo   => 'foo 2',
 976                        source => 'foo 2',
 977                        credit => 119,
 978                      },
 979                      {
 980                        chart  => $cash,
 981                        debit  => 238,
 982                        memo   => 'foo 1+2',
 983                        source => 'foo 1+2',
 984                      },
 985                    ],
 986   );
 987
 988
 989 =head1 BUGS
 990
 991 Nothing here yet.
 992
 993 =head1 AUTHOR
 994
 995 G. Richardson E<lt>grichardson@kivitec.deE<gt>
 996
 997 =cut