SL/Dev/Record.pm

   1 package SL::Dev::Record;
   2
   3 use strict;
   4 use base qw(Exporter);
   5 our @EXPORT_OK = qw(create_invoice_item
   6                     create_sales_invoice
   7                     create_credit_note
   8                     create_order_item
   9                     create_sales_order
  10                     create_purchase_order
  11                     create_delivery_order_item
  12                     create_sales_delivery_order
  13                     create_purchase_delivery_order
  14                     create_project create_department
  15                     create_ap_transaction
  16                     create_ar_transaction
  17                     create_gl_transaction
  18                    );
  19 our %EXPORT_TAGS = (ALL => \@EXPORT_OK);
  20
  21 use SL::DB::Invoice;
  22 use SL::DB::InvoiceItem;
  23 use SL::DB::Employee;
  24 use SL::Dev::Part qw(new_part);
  25 use SL::Dev::CustomerVendor qw(new_vendor new_customer);
  26 use SL::DB::Project;
  27 use SL::DB::ProjectStatus;
  28 use SL::DB::ProjectType;
  29 use SL::Form;
  30 use DateTime;
  31 use List::Util qw(sum);
  32 use Data::Dumper;
  33 use SL::Locale::String qw(t8);
  34 use SL::DATEV;
  35
  36 my %record_type_to_item_type = ( sales_invoice        => 'SL::DB::InvoiceItem',
  37                                  credit_note          => 'SL::DB::InvoiceItem',
  38                                  sales_order          => 'SL::DB::OrderItem',
  39                                  purchase_order       => 'SL::DB::OrderItem',
  40                                  sales_delivery_order => 'SL::DB::DeliveryOrderItem',
  41                                );
  42
  43 sub create_sales_invoice {
  44   my (%params) = @_;
  45
  46   my $record_type = 'sales_invoice';
  47   my $invoiceitems = delete $params{invoiceitems} // _create_two_items($record_type);
  48   _check_items($invoiceitems, $record_type);
  49
  50   my $customer = delete $params{customer} // new_customer(name => 'Testcustomer')->save;
  51   die "illegal customer" unless defined $customer && ref($customer) eq 'SL::DB::Customer';
  52
  53   my $invoice = SL::DB::Invoice->new(
  54     invoice      => 1,
  55     type         => 'invoice',
  56     customer_id  => $customer->id,
  57     taxzone_id   => $customer->taxzone->id,
  58     invnumber    => delete $params{invnumber}   // undef,
  59     currency_id  => $params{currency_id} // $::instance_conf->get_currency_id,
  60     taxincluded  => $params{taxincluded} // 0,
  61     employee_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
  62     salesman_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
  63     transdate    => $params{transdate}   // DateTime->today_local->to_kivitendo,
  64     payment_id   => $params{payment_id}  // undef,
  65     gldate       => DateTime->today,
  66     invoiceitems => $invoiceitems,
  67   );
  68   $invoice->assign_attributes(%params) if %params;
  69
  70   $invoice->post;
  71   return $invoice;
  72 }
  73
  74 sub create_credit_note {
  75   my (%params) = @_;
  76
  77   my $record_type = 'credit_note';
  78   my $invoiceitems = delete $params{invoiceitems} // _create_two_items($record_type);
  79   _check_items($invoiceitems, $record_type);
  80
  81   my $customer = delete $params{customer} // new_customer(name => 'Testcustomer')->save;
  82   die "illegal customer" unless defined $customer && ref($customer) eq 'SL::DB::Customer';
  83
  84   # adjust qty for credit note items
  85   $_->qty( $_->qty * -1) foreach @{$invoiceitems};
  86
  87   my $invoice = SL::DB::Invoice->new(
  88     invoice      => 1,
  89     type         => 'credit_note',
  90     customer_id  => $customer->id,
  91     taxzone_id   => $customer->taxzone->id,
  92     invnumber    => delete $params{invnumber}   // undef,
  93     currency_id  => $params{currency_id} // $::instance_conf->get_currency_id,
  94     taxincluded  => $params{taxincluded} // 0,
  95     employee_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
  96     salesman_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
  97     transdate    => $params{transdate}   // DateTime->today_local->to_kivitendo,
  98     payment_id   => $params{payment_id}  // undef,
  99     gldate       => DateTime->today,
 100     invoiceitems => $invoiceitems,
 101   );
 102   $invoice->assign_attributes(%params) if %params;
 103
 104   $invoice->post;
 105   return $invoice;
 106 }
 107
 108 sub create_sales_delivery_order {
 109   my (%params) = @_;
 110
 111   my $record_type = 'sales_delivery_order';
 112   my $orderitems = delete $params{orderitems} // _create_two_items($record_type);
 113   _check_items($orderitems, $record_type);
 114
 115   my $customer = $params{customer} // new_customer(name => 'Testcustomer')->save;
 116   die "illegal customer" unless ref($customer) eq 'SL::DB::Customer';
 117
 118   my $delivery_order = SL::DB::DeliveryOrder->new(
 119     'is_sales'   => 'true',
 120     'closed'     => undef,
 121     customer_id  => $customer->id,
 122     taxzone_id   => $customer->taxzone_id,
 123     donumber     => $params{donumber}    // undef,
 124     currency_id  => $params{currency_id} // $::instance_conf->get_currency_id,
 125     taxincluded  => $params{taxincluded} // 0,
 126     employee_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
 127     salesman_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
 128     transdate    => $params{transdate}   // DateTime->today,
 129     orderitems   => $orderitems,
 130   );
 131   $delivery_order->assign_attributes(%params) if %params;
 132   $delivery_order->save;
 133   return $delivery_order;
 134 }
 135
 136 sub create_purchase_delivery_order {
 137   my (%params) = @_;
 138
 139   my $record_type = 'purchase_delivery_order';
 140   my $orderitems = delete $params{orderitems} // _create_two_items($record_type);
 141   _check_items($orderitems, $record_type);
 142
 143   my $vendor = $params{vendor} // new_vendor(name => 'Testvendor')->save;
 144   die "illegal customer" unless ref($vendor) eq 'SL::DB::Vendor';
 145
 146   my $delivery_order = SL::DB::DeliveryOrder->new(
 147     'is_sales'   => 'false',
 148     'closed'     => undef,
 149     vendor_id    => $vendor->id,
 150     taxzone_id   => $vendor->taxzone_id,
 151     donumber     => $params{donumber}    // undef,
 152     currency_id  => $params{currency_id} // $::instance_conf->get_currency_id,
 153     taxincluded  => $params{taxincluded} // 0,
 154     employee_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
 155     salesman_id  => $params{employee_id} // SL::DB::Manager::Employee->current->id,
 156     transdate    => $params{transdate}   // DateTime->today,
 157     orderitems   => $orderitems,
 158   );
 159   $delivery_order->assign_attributes(%params) if %params;
 160   $delivery_order->save;
 161   return $delivery_order;
 162 }
 163
 164 sub create_sales_order {
 165   my (%params) = @_;
 166
 167   my $record_type = 'sales_order';
 168   my $orderitems = delete $params{orderitems} // _create_two_items($record_type);
 169   _check_items($orderitems, $record_type);
 170
 171   my $save = delete $params{save} // 0;
 172
 173   my $customer = $params{customer} // new_customer(name => 'Testcustomer')->save;
 174   die "illegal customer" unless ref($customer) eq 'SL::DB::Customer';
 175
 176   my $order = SL::DB::Order->new(
 177     customer_id  => delete $params{customer_id} // $customer->id,
 178     taxzone_id   => delete $params{taxzone_id}  // $customer->taxzone->id,
 179     currency_id  => delete $params{currency_id} // $::instance_conf->get_currency_id,
 180     taxincluded  => delete $params{taxincluded} // 0,
 181     employee_id  => delete $params{employee_id} // SL::DB::Manager::Employee->current->id,
 182     salesman_id  => delete $params{employee_id} // SL::DB::Manager::Employee->current->id,
 183     transdate    => delete $params{transdate}   // DateTime->today,
 184     orderitems   => $orderitems,
 185   );
 186   $order->assign_attributes(%params) if %params;
 187
 188   if ( $save ) {
 189     $order->calculate_prices_and_taxes;
 190     $order->save;
 191   }
 192   return $order;
 193 }
 194
 195 sub create_purchase_order {
 196   my (%params) = @_;
 197
 198   my $record_type = 'purchase_order';
 199   my $orderitems = delete $params{orderitems} // _create_two_items($record_type);
 200   _check_items($orderitems, $record_type);
 201
 202   my $save = delete $params{save} // 0;
 203
 204   my $vendor = $params{vendor} // new_vendor(name => 'Testvendor')->save;
 205   die "illegal vendor" unless ref($vendor) eq 'SL::DB::Vendor';
 206
 207   my $order = SL::DB::Order->new(
 208     vendor_id    => delete $params{vendor_id}   // $vendor->id,
 209     taxzone_id   => delete $params{taxzone_id}  // $vendor->taxzone->id,
 210     currency_id  => delete $params{currency_id} // $::instance_conf->get_currency_id,
 211     taxincluded  => delete $params{taxincluded} // 0,
 212     transdate    => delete $params{transdate}   // DateTime->today,
 213     'closed'     => undef,
 214     orderitems   => $orderitems,
 215   );
 216   $order->assign_attributes(%params) if %params;
 217
 218   if ( $save ) {
 219     $order->calculate_prices_and_taxes; # not tested for purchase orders
 220     $order->save;
 221   }
 222   return $order;
 223 };
 224
 225 sub _check_items {
 226   my ($items, $record_type) = @_;
 227
 228   if  ( scalar @{$items} == 0 or grep { ref($_) ne $record_type_to_item_type{"$record_type"} } @{$items} ) {
 229     die "Error: items must be an arrayref of " . $record_type_to_item_type{"$record_type"} . "objects.";
 230   }
 231 }
 232
 233 sub create_invoice_item {
 234   my (%params) = @_;
 235
 236   return _create_item(record_type => 'sales_invoice', %params);
 237 }
 238
 239 sub create_order_item {
 240   my (%params) = @_;
 241
 242   return _create_item(record_type => 'sales_order', %params);
 243 }
 244
 245 sub create_delivery_order_item {
 246   my (%params) = @_;
 247
 248   return _create_item(record_type => 'sales_delivery_order', %params);
 249 }
 250
 251 sub _create_item {
 252   my (%params) = @_;
 253
 254   my $record_type = delete($params{record_type});
 255   my $part        = delete($params{part});
 256
 257   die "illegal record type: $record_type, must be one of: " . join(' ', keys %record_type_to_item_type) unless $record_type_to_item_type{ $record_type };
 258   die "part missing as param" unless $part && ref($part) eq 'SL::DB::Part';
 259
 260   my ($sellprice, $lastcost);
 261
 262   if ( $record_type =~ /^sales/ ) {
 263     $sellprice = delete $params{sellprice} // $part->sellprice;
 264     $lastcost  = delete $params{lastcost}  // $part->lastcost;
 265   } else {
 266     $sellprice = delete $params{sellprice} // $part->lastcost;
 267     $lastcost  = delete $params{lastcost}  // 0; # $part->lastcost;
 268   }
 269
 270   my $item = "$record_type_to_item_type{$record_type}"->new(
 271     parts_id    => $part->id,
 272     sellprice   => $sellprice,
 273     lastcost    => $lastcost,
 274     description => $part->description,
 275     unit        => $part->unit,
 276     qty         => $params{qty} || 5,
 277   );
 278   $item->assign_attributes(%params) if %params;
 279   return $item;
 280 }
 281
 282 sub _create_two_items {
 283   my ($record_type) = @_;
 284
 285   my $part1 = new_part(description => 'Testpart 1',
 286                        sellprice   => 12,
 287                       )->save;
 288   my $part2 = new_part(description => 'Testpart 2',
 289                        sellprice   => 10,
 290                       )->save;
 291   my $item1 = _create_item(record_type => $record_type, part => $part1, qty => 5);
 292   my $item2 = _create_item(record_type => $record_type, part => $part2, qty => 8);
 293   return [ $item1, $item2 ];
 294 }
 295
 296 sub create_project {
 297   my (%params) = @_;
 298   my $project = SL::DB::Project->new(
 299     projectnumber     => delete $params{projectnumber} // 1,
 300     description       => delete $params{description} // "Test project",
 301     active            => 1,
 302     valid             => 1,
 303     project_status_id => SL::DB::Manager::ProjectStatus->find_by(name => "running")->id,
 304     project_type_id   => SL::DB::Manager::ProjectType->find_by(description => "Standard")->id,
 305   )->save;
 306   $project->assign_attributes(%params) if %params;
 307   return $project;
 308 }
 309
 310 sub create_department {
 311   my (%params) = @_;
 312
 313   my $department = SL::DB::Department->new(
 314     'description' => delete $params{description} // 'Test Department',
 315   )->save;
 316
 317   $department->assign_attributes(%params) if %params;
 318   return $department;
 319
 320 }
 321
 322 sub create_ap_transaction {
 323   my (%params) = @_;
 324
 325   my $vendor = delete $params{vendor};
 326   if ( $vendor ) {
 327     die "vendor missing or not a SL::DB::Vendor object" unless ref($vendor) eq 'SL::DB::Vendor';
 328   } else {
 329     # use default SL/Dev vendor if it exists, or create a new one
 330     $vendor = SL::DB::Manager::Vendor->find_by(name => 'Testlieferant') // new_vendor->save;
 331   };
 332
 333   my $taxincluded = $params{taxincluded} // 1;
 334   delete $params{taxincluded};
 335
 336   my $bookings    = delete $params{bookings};
 337   # default bookings
 338   unless ( $bookings ) {
 339     my $chart_postage   = SL::DB::Manager::Chart->find_by(description => 'Porto');
 340     my $chart_telephone = SL::DB::Manager::Chart->find_by(description => 'Telefon');
 341     $bookings = [
 342                   {
 343                     chart  => $chart_postage,
 344                     amount => 1000,
 345                   },
 346                   {
 347                     chart  => $chart_telephone,
 348                     amount => $taxincluded ? 1190 : 1000,
 349                   },
 350                 ]
 351   };
 352
 353   # optional params:
 354   my $project_id         = delete $params{globalproject_id};
 355
 356   # if amount or netamount are given, then it compares them to the final values, and dies if they don't match
 357   my $expected_amount    = delete $params{amount};
 358   my $expected_netamount = delete $params{netamount};
 359
 360   my $dec = delete $params{dec} // 2;
 361
 362   my $today      = DateTime->today_local;
 363   my $transdate  = delete $params{transdate} // $today;
 364   die "transdate hat to be DateTime object" unless ref($transdate) eq 'DateTime';
 365
 366   my $gldate     = delete $params{gldate} // $today;
 367   die "gldate hat to be DateTime object" unless ref($gldate) eq 'DateTime';
 368
 369   my $ap_chart = delete $params{ap_chart} // SL::DB::Manager::Chart->find_by( accno => '1600' );
 370   die "no ap_chart found or not an AP chart" unless $ap_chart and $ap_chart->link eq 'AP';
 371
 372   my $ap_transaction = SL::DB::PurchaseInvoice->new(
 373     vendor_id        => $vendor->id,
 374     invoice          => 0,
 375     transactions     => [],
 376     globalproject_id => $project_id,
 377     invnumber        => delete $params{invnumber} // 'test ap_transaction',
 378     notes            => delete $params{notes}     // 'test ap_transaction',
 379     transdate        => $transdate,
 380     gldate           => $gldate,
 381     taxincluded      => $taxincluded,
 382     taxzone_id       => $vendor->taxzone_id, # taxzone_id shouldn't have any effect on ap transactions
 383     currency_id      => $::instance_conf->get_currency_id,
 384     type             => undef, # isn't set for ap
 385     employee_id      => SL::DB::Manager::Employee->current->id,
 386   );
 387   # $ap_transaction->assign_attributes(%params) if %params;
 388
 389   foreach my $booking ( @{$bookings} ) {
 390     my $chart = delete $booking->{chart};
 391     die "illegal chart" unless ref($chart) eq 'SL::DB::Chart';
 392
 393     my $tax = _transaction_tax_helper($booking, $chart, $transdate); # will die if tax can't be found
 394
 395     $ap_transaction->add_ap_amount_row(
 396       amount     => $booking->{amount}, # add_ap_amount_row expects the user input amount, does its own calculate_tax
 397       chart      => $chart,
 398       tax_id     => $tax->id,
 399       project_id => $booking->{project_id},
 400     );
 401   }
 402
 403   my $acc_trans_sum = sum map { $_->amount  } grep { $_->chart_link =~ 'AP_amount' } @{$ap_transaction->transactions};
 404   # $main::lxdebug->message(0, sprintf("accno: %s    amount: %s   chart_link: %s\n",
 405   #                                    $_->amount,
 406   #                                    $_->chart->accno,
 407   #                                    $_->chart_link
 408   #                                   )) foreach @{$ap_transaction->transactions};
 409
 410   # determine netamount and amount from the transactions that were added via bookings
 411   $ap_transaction->netamount( -1 * sum map { $_->amount  } grep { $_->chart_link =~ 'AP_amount' } @{$ap_transaction->transactions} );
 412   # $main::lxdebug->message(0, sprintf('found netamount %s', $ap_transaction->netamount));
 413
 414   my $taxamount = -1 * sum map { $_->amount  } grep { $_->chart_link =~ /tax/ } @{$ap_transaction->transactions};
 415   $ap_transaction->amount( $ap_transaction->netamount + $taxamount );
 416   # additional check, add up all transactions before AP-transaction is added
 417   my $refamount = -1 * sum map { $_->amount  } @{$ap_transaction->transactions};
 418   die "refamount = $refamount, ap_transaction->amount = " . $ap_transaction->amount unless $refamount == $ap_transaction->amount;
 419
 420   # if amount or netamount were passed as params, check if the values are still
 421   # the same after recalculating them from the acc_trans entries
 422   if (defined $expected_amount) {
 423     die "amount doesn't match acc_trans amounts: $expected_amount != " . $ap_transaction->amount unless $expected_amount == $ap_transaction->amount;
 424   }
 425   if (defined $expected_netamount) {
 426     die "netamount doesn't match acc_trans netamounts: $expected_netamount != " . $ap_transaction->netamount unless $expected_netamount == $ap_transaction->netamount;
 427   }
 428
 429   $ap_transaction->create_ap_row(chart => $ap_chart);
 430   $ap_transaction->save;
 431   # $main::lxdebug->message(0, sprintf("created ap_transaction with invnumber %s and trans_id %s",
 432   #                                     $ap_transaction->invnumber,
 433   #                                     $ap_transaction->id));
 434   return $ap_transaction;
 435 }
 436
 437 sub create_ar_transaction {
 438   my (%params) = @_;
 439
 440   my $customer = delete $params{customer};
 441   if ( $customer ) {
 442     die "customer missing or not a SL::DB::Customer object" unless ref($customer) eq 'SL::DB::Customer';
 443   } else {
 444     # use default SL/Dev vendor if it exists, or create a new one
 445     $customer = SL::DB::Manager::Customer->find_by(name => 'Testkunde') // new_customer->save;
 446   };
 447
 448   my $taxincluded = $params{taxincluded} // 1;
 449   delete $params{taxincluded};
 450
 451   my $bookings    = delete $params{bookings};
 452   # default bookings
 453   unless ( $bookings ) {
 454     my $chart_19 = SL::DB::Manager::Chart->find_by(accno => '8400');
 455     my $chart_7  = SL::DB::Manager::Chart->find_by(accno => '8300');
 456     my $chart_0  = SL::DB::Manager::Chart->find_by(accno => '8200');
 457     $bookings = [
 458                   {
 459                     chart  => $chart_19,
 460                     amount => $taxincluded ? 119 : 100,
 461                   },
 462                   {
 463                     chart  => $chart_7,
 464                     amount => $taxincluded ? 107 : 100,
 465                   },
 466                   {
 467                     chart  => $chart_0,
 468                     amount => 100,
 469                   },
 470                 ]
 471   };
 472
 473   # optional params:
 474   my $project_id = delete $params{globalproject_id};
 475
 476   # if amount or netamount are given, then it compares them to the final values, and dies if they don't match
 477   my $expected_amount    = delete $params{amount};
 478   my $expected_netamount = delete $params{netamount};
 479
 480   my $dec = delete $params{dec} // 2;
 481
 482   my $today      = DateTime->today_local;
 483   my $transdate  = delete $params{transdate} // $today;
 484   die "transdate hat to be DateTime object" unless ref($transdate) eq 'DateTime';
 485
 486   my $gldate     = delete $params{gldate} // $today;
 487   die "gldate hat to be DateTime object" unless ref($gldate) eq 'DateTime';
 488
 489   my $ar_chart = delete $params{ar_chart} // SL::DB::Manager::Chart->find_by( accno => '1400' );
 490   die "no ar_chart found or not an AR chart" unless $ar_chart and $ar_chart->link eq 'AR';
 491
 492   my $ar_transaction = SL::DB::Invoice->new(
 493     customer_id      => $customer->id,
 494     invoice          => 0,
 495     transactions     => [],
 496     globalproject_id => $project_id,
 497     invnumber        => delete $params{invnumber} // 'test ar_transaction',
 498     notes            => delete $params{notes}     // 'test ar_transaction',
 499     transdate        => $transdate,
 500     gldate           => $gldate,
 501     taxincluded      => $taxincluded,
 502     taxzone_id       => $customer->taxzone_id, # taxzone_id shouldn't have any effect on ar transactions
 503     currency_id      => $::instance_conf->get_currency_id,
 504     type             => undef, # isn't set for ar
 505     employee_id      => SL::DB::Manager::Employee->current->id,
 506   );
 507   # $ar_transaction->assign_attributes(%params) if %params;
 508
 509   foreach my $booking ( @{$bookings} ) {
 510     my $chart = delete $booking->{chart};
 511     die "illegal chart" unless ref($chart) eq 'SL::DB::Chart';
 512
 513     my $tax = _transaction_tax_helper($booking, $chart, $transdate); # will die if tax can't be found
 514
 515     $ar_transaction->add_ar_amount_row(
 516       amount     => $booking->{amount}, # add_ar_amount_row expects the user input amount, does its own calculate_tax
 517       chart      => $chart,
 518       tax_id     => $tax->id,
 519       project_id => $booking->{project_id},
 520     );
 521   }
 522
 523   my $acc_trans_sum = sum map { $_->amount  } grep { $_->chart_link =~ 'AR_amount' } @{$ar_transaction->transactions};
 524   # $main::lxdebug->message(0, sprintf("accno: %s    amount: %s   chart_link: %s\n",
 525   #                                    $_->amount,
 526   #                                    $_->chart->accno,
 527   #                                    $_->chart_link
 528   #                                   )) foreach @{$ar_transaction->transactions};
 529
 530   # determine netamount and amount from the transactions that were added via bookings
 531   $ar_transaction->netamount( 1 * sum map { $_->amount  } grep { $_->chart_link =~ 'AR_amount' } @{$ar_transaction->transactions} );
 532   # $main::lxdebug->message(0, sprintf('found netamount %s', $ar_transaction->netamount));
 533
 534   my $taxamount = 1 * sum map { $_->amount  } grep { $_->chart_link =~ /tax/ } @{$ar_transaction->transactions};
 535   $ar_transaction->amount( $ar_transaction->netamount + $taxamount );
 536   # additional check, add up all transactions before AP-transaction is added
 537   my $refamount = 1 * sum map { $_->amount  } @{$ar_transaction->transactions};
 538   die "refamount = $refamount, ar_transaction->amount = " . $ar_transaction->amount unless $refamount == $ar_transaction->amount;
 539
 540   # if amount or netamount were passed as params, check if the values are still
 541   # the same after recalculating them from the acc_trans entries
 542   if (defined $expected_amount) {
 543     die "amount doesn't match acc_trans amounts: $expected_amount != " . $ar_transaction->amount unless $expected_amount == $ar_transaction->amount;
 544   }
 545   if (defined $expected_netamount) {
 546     die "netamount doesn't match acc_trans netamounts: $expected_netamount != " . $ar_transaction->netamount unless $expected_netamount == $ar_transaction->netamount;
 547   }
 548
 549   $ar_transaction->create_ar_row(chart => $ar_chart);
 550   $ar_transaction->save;
 551   # $main::lxdebug->message(0, sprintf("created ar_transaction with invnumber %s and trans_id %s",
 552   #                                     $ar_transaction->invnumber,
 553   #                                     $ar_transaction->id));
 554   return $ar_transaction;
 555 }
 556
 557 sub create_gl_transaction {
 558   my (%params) = @_;
 559
 560   my $ob_transaction = delete $params{ob_transaction} // 0;
 561   my $cb_transaction = delete $params{cb_transaction} // 0;
 562   my $dec            = delete $params{rec} // 2;
 563
 564   my $taxincluded = defined $params{taxincluded} ? $params{taxincluded} : 1;
 565
 566   my $today      = DateTime->today_local;
 567   my $transdate  = delete $params{transdate} // $today;
 568   my $gldate     = delete $params{gldate}    // $today;
 569
 570   my $reference   = delete $params{reference}   // 'reference';
 571   my $description = delete $params{description} // 'description';
 572
 573   my $department_id = delete $params{department_id};
 574
 575   my $bookings = delete $params{bookings};
 576   unless ( $bookings && scalar @{$bookings} ) {
 577     # default bookings if left empty
 578     my $expense_chart = SL::DB::Manager::Chart->find_by(accno => '4660') or die "Can't find expense chart 4660\n"; # Reisekosten
 579     my $cash_chart    = SL::DB::Manager::Chart->find_by(accno => '1000') or die "Can't find cash chart 1000\n";    # Kasse
 580
 581     $taxincluded = 0;
 582
 583     $reference   = 'Reise';
 584     $description = 'Reise';
 585
 586     $bookings = [
 587                   {
 588                     chart  => $expense_chart, # has default tax of 19%
 589                     credit => 84.03,
 590                     taxkey => 9,
 591                   },
 592                   {
 593                     chart  => $cash_chart,
 594                     debit  => 100,
 595                     taxkey => 0,
 596                   },
 597     ];
 598   }
 599
 600   my $gl_transaction = SL::DB::GLTransaction->new(
 601     reference      => $reference,
 602     description    => $description,
 603     transdate      => $transdate,
 604     gldate         => $gldate,
 605     taxincluded    => $taxincluded,
 606     type           => undef,
 607     ob_transaction => $ob_transaction,
 608     cb_transaction => $cb_transaction,
 609     storno         => 0,
 610     storno_id      => undef,
 611     transactions   => [],
 612   );
 613
 614   my @acc_trans;
 615   if ( scalar @{$bookings} ) {
 616     # there are several ways of determining the tax:
 617     # * tax_id : fetches SL::DB::Tax object via id (as used in dropdown in interface)
 618     # * tax : SL::DB::Tax object (where $tax->id = tax_id)
 619     # * taxkey : tax is determined from startdate
 620     # * none of the above defined: use the default tax for that chart
 621
 622     foreach my $booking ( @{$bookings} ) {
 623       my $chart = delete $booking->{chart};
 624       die "illegal chart" unless ref($chart) eq 'SL::DB::Chart';
 625
 626       die t8('Empty transaction!')
 627         unless $booking->{debit} or $booking->{credit}; # must exist and not be 0
 628       die t8('Cannot post transaction with a debit and credit entry for the same account!')
 629         if defined($booking->{debit}) and defined($booking->{credit});
 630
 631       my $tax = _transaction_tax_helper($booking, $chart, $transdate); # will die if tax can't be found
 632
 633       $gl_transaction->add_chart_booking(
 634         chart      => $chart,
 635         debit      => $booking->{debit},
 636         credit     => $booking->{credit},
 637         tax_id     => $tax->id,
 638         source     => $booking->{source} // '',
 639         memo       => $booking->{memo}   // '',
 640         project_id => $booking->{project_id}
 641       );
 642     }
 643   };
 644
 645   $gl_transaction->post;
 646
 647   return $gl_transaction;
 648 }
 649
 650 sub _transaction_tax_helper {
 651   # checks for hash-entries with key tax, tax_id or taxkey
 652   # returns an SL::DB::Tax object
 653   # can be used for booking hashref in ar_transaction, ap_transaction and gl_transaction
 654   # will modify hashref, e.g. removing taxkey if tax_id was also supplied
 655
 656   my ($booking, $chart, $transdate) = @_;
 657
 658   die "_transaction_tax_helper: chart missing"     unless $chart && ref($chart) eq 'SL::DB::Chart';
 659   die "_transaction_tax_helper: transdate missing" unless $transdate && ref($transdate) eq 'DateTime';
 660
 661   my $tax;
 662
 663   if ( defined $booking->{tax_id} ) { # tax_id may be 0
 664     delete $booking->{taxkey}; # ignore any taxkeys that may have been added, tax_id has precedence
 665     $tax = SL::DB::Tax->new(id => $booking->{tax_id})->load( with => [ 'chart' ] );
 666   } elsif ( $booking->{tax} ) {
 667     die "illegal tax entry" unless ref($booking->{tax}) eq 'SL::DB::Tax';
 668     $tax = $booking->{tax};
 669   } elsif ( defined $booking->{taxkey} ) {
 670     # If a taxkey is given, find the taxkey entry for that chart that
 671     # matches the stored taxkey and with the correct transdate. This will only work
 672     # if kivitendo has that taxkey configured for that chart, i.e. it should barf if
 673     # e.g. the bank chart is called with taxkey 3.
 674
 675     # example query:
 676     #   select *
 677     #     from taxkeys
 678     #    where     taxkey_id = 3
 679     #          and chart_id = (select id from chart where accno = '8400')
 680     #          and startdate <= '2018-01-01'
 681     # order by startdate desc
 682     #    limit 1;
 683
 684     my $taxkey = SL::DB::Manager::TaxKey->get_first(
 685       query        => [ and => [ chart_id  => $chart->id,
 686                                  startdate => { le => $transdate },
 687                                  taxkey    => $booking->{taxkey}
 688                                ]
 689                       ],
 690       sort_by      => "startdate DESC",
 691       limit        => 1,
 692       with_objects => [ qw(tax) ],
 693     );
 694     die sprintf("Chart %s doesn't have a taxkey chart configured for taxkey %s", $chart->accno, $booking->{taxkey})
 695       unless $taxkey;
 696
 697     $tax = $taxkey->tax;
 698   } else {
 699     # use default tax for that chart if neither tax_id, tax or taxkey were defined
 700     my $active_taxkey = $chart->get_active_taxkey($transdate);
 701     $tax = $active_taxkey->tax;
 702     # $main::lxdebug->message(0, sprintf("found default taxrate %s for chart %s", $tax->rate, $chart->displayable_name));
 703   };
 704
 705   die "no tax" unless $tax && ref($tax) eq 'SL::DB::Tax';
 706   return $tax;
 707 };
 708
 709 1;
 710
 711 __END__
 712
 713 =head1 NAME
 714
 715 SL::Dev::Record - create record objects for testing, with minimal defaults
 716
 717 =head1 FUNCTIONS
 718
 719 =head2 C<create_sales_invoice %PARAMS>
 720
 721 Creates a new sales invoice (table ar, invoice = 1).
 722
 723 If neither customer nor invoiceitems are passed as params a customer and two
 724 parts are created and used for building the invoice.
 725
 726 Minimal usage example:
 727
 728   my $invoice = SL::Dev::Record::create_sales_invoice();
 729
 730 Example with params:
 731
 732   my $invoice2 = SL::Dev::Record::create_sales_invoice(
 733     invnumber   => 777,
 734     transdate   => DateTime->today->subtract(days => 7),
 735     taxincluded => 1,
 736   );
 737
 738 =head2 C<create_credit_note %PARAMS>
 739
 740 Create a credit note (sales). Use positive quantities when adding items.
 741
 742 Example including creation of parts and of credit_note:
 743
 744   my $part1 = SL::Dev::Part::new_part(   partnumber => 'T4254')->save;
 745   my $part2 = SL::Dev::Part::new_service(partnumber => 'Serv1')->save;
 746   my $credit_note = SL::Dev::Record::create_credit_note(
 747     invnumber    => '34',
 748     taxincluded  => 0,
 749     invoiceitems => [ SL::Dev::Record::create_invoice_item(part => $part1, qty =>  3, sellprice => 70),
 750                       SL::Dev::Record::create_invoice_item(part => $part2, qty => 10, sellprice => 50),
 751                     ]
 752   );
 753
 754 =head2 C<create_sales_order %PARAMS>
 755
 756 Examples:
 757
 758 Create a sales order and save it directly via rose, without running
 759 calculate_prices_and_taxes:
 760
 761   my $order = SL::Dev::Record::create_sales_order()->save;
 762
 763 Let create_sales_order run calculate_prices_and_taxes and save:
 764
 765   my $order = SL::Dev::Record::create_sales_order(save => 1);
 766
 767
 768 Example including creation of part and of sales order:
 769
 770   my $part1 = SL::Dev::Part::new_part(   partnumber => 'T4254')->save;
 771   my $part2 = SL::Dev::Part::new_service(partnumber => 'Serv1')->save;
 772   my $order = SL::Dev::Record::create_sales_order(
 773     save         => 1,
 774     taxincluded  => 0,
 775     orderitems => [ SL::Dev::Record::create_order_item(part => $part1, qty =>  3, sellprice => 70),
 776                     SL::Dev::Record::create_order_item(part => $part2, qty => 10, sellprice => 50),
 777                   ]
 778   );
 779
 780 Example: create 100 orders with the same part for 100 new customers:
 781
 782   my $part1 = SL::Dev::Part::new_part(partnumber => 'T6256')->save;
 783   SL::Dev::Record::create_sales_order(
 784     save         => 1,
 785     taxincluded  => 0,
 786     orderitems => [ SL::Dev::Record::create_order_item(part => $part1, qty => 1, sellprice => 9) ]
 787   ) for 1 .. 100;
 788
 789 =head2 C<create_purchase_order %PARAMS>
 790
 791 See comments for C<create_sales_order>.
 792
 793 Example:
 794
 795   my $purchase_order = SL::Dev::Record::create_purchase_order(save => 1);
 796
 797
 798 =head2 C<create_item %PARAMS>
 799
 800 Creates an item from a part object that can be added to a record.
 801
 802 Required params:
 803
 804   record_type (sales_invoice, sales_order, sales_delivery_order)
 805   part        (an SL::DB::Part object)
 806
 807 Example including creation of part and of invoice:
 808
 809   my $part    = SL::Dev::Part::new_part(  partnumber  => 'T4254')->save;
 810   my $item    = SL::Dev::Record::create_invoice_item(part => $part, qty => 2.5);
 811   my $invoice = SL::Dev::Record::create_sales_invoice(
 812     taxincluded  => 0,
 813     invoiceitems => [ $item ],
 814   );
 815
 816 =head2 C<create_project %PARAMS>
 817
 818 Creates a default project.
 819
 820 Minimal example, creating a project with status "running" and type "Standard":
 821
 822   my $project = SL::Dev::Record::create_project();
 823
 824   $project = SL::Dev::Record::create_project(
 825     projectnumber => 'p1',
 826     description   => 'Test project',
 827   )
 828
 829 If C<$params{description}> or C<$params{projectnumber}> exists, this will override the
 830 default value 'Test project'.
 831
 832 C<%params> should only contain alterable keys from the object Project.
 833
 834 =head2 C<create_department %PARAMS>
 835
 836 Creates a default department.
 837
 838 Minimal example:
 839
 840   my $department = SL::Dev::Record::create_department();
 841
 842   my $department = SL::Dev::Record::create_department(
 843     description => 'Hawaii',
 844   )
 845
 846 If C<$params{description}> exists, this will override the
 847 default value 'Test Department'.
 848
 849 C<%params> should only contain alterable keys from the object Department.
 850
 851 =head2 C<create_ap_transaction %PARAMS>
 852
 853 Creates a new AP transaction (table ap, invoice = 0), and will try to add as
 854 many defaults as possible.
 855
 856 Possible parameters:
 857  * vendor (SL::DB::Vendor object, defaults to SL::Dev default vendor)
 858  * taxincluded (0 or 1, defaults to 1)
 859  * transdate (DateTime object, defaults to current date)
 860  * bookings (arrayref for the charts to be booked, see examples below)
 861  * amount (to check if final amount matches this amount)
 862  * netamount (to check if final amount matches this amount)
 863  * dec (number of decimals to round to, defaults to 2)
 864  * ap_chart (SL::DB::Chart object, default to accno 1600)
 865  * invnumber (defaults to 'test ap_transaction')
 866  * notes (defaults to 'test ap_transaction')
 867  * globalproject_id
 868
 869 Currently doesn't support exchange rates.
 870
 871 Minimal usage example, creating an AP transaction with a default vendor and
 872 default bookings (telephone, postage):
 873
 874   use SL::Dev::Record qw(create_ap_transaction);
 875   my $invoice = create_ap_transaction();
 876
 877 Create an AP transaction with a specific vendor and specific charts:
 878
 879   my $vendor = SL::Dev::CustomerVendor::new_vendor(name => 'My Vendor')->save;
 880   my $chart_postage   = SL::DB::Manager::Chart->find_by(description => 'Porto');
 881   my $chart_telephone = SL::DB::Manager::Chart->find_by(description => 'Telefon');
 882
 883   my $ap_transaction = create_ap_transaction(
 884     vendor      => $vendor,
 885     invnumber   => 'test invoice taxincluded',
 886     taxincluded => 1,
 887     amount      => 2190, # optional param for checking whether final amount matches
 888     netamount   => 2000, # optional param for checking whether final netamount matches
 889     bookings    => [
 890                      {
 891                        chart  => $chart_postage,
 892                        amount => 1000,
 893                      },
 894                      {
 895                        chart  => $chart_telephone,
 896                        amount => 1190,
 897                      },
 898                    ]
 899   );
 900
 901 Or the same example with tax not included, but an old transdate and old taxrate (16%):
 902
 903   my $ap_transaction = create_ap_transaction(
 904     vendor      => $vendor,
 905     invnumber   => 'test invoice tax not included',
 906     transdate   => DateTime->new(year => 2000, month => 10, day => 1),
 907     taxincluded => 0,
 908     amount      => 2160, # optional param for checking whether final amount matches
 909     netamount   => 2000, # optional param for checking whether final netamount matches
 910     bookings    => [
 911                      {
 912                        chart  => $chart_postage,
 913                        amount => 1000,
 914                      },
 915                      {
 916                        chart  => $chart_telephone,
 917                        amount => 1000,
 918                      },
 919                  ]
 920   );
 921
 922 Don't use the default tax, e.g. postage with 19%:
 923
 924   my $tax_9          = SL::DB::Manager::Tax->find_by(taxkey => 9, rate => 0.19);
 925   my $chart_postage  = SL::DB::Manager::Chart->find_by(description => 'Porto');
 926   my $ap_transaction = create_ap_transaction(
 927     invnumber   => 'postage with tax',
 928     taxincluded => 0,
 929     bookings    => [
 930                      {
 931                        chart  => $chart_postage,
 932                        amount => 1000,
 933                        tax    => $tax_9,
 934                      },
 935                    ],
 936   );
 937
 938 =head2 C<create_ar_transaction %PARAMS>
 939
 940 See C<create_ap_transaction>, except use customer instead of vendor.
 941
 942 =head2 C<create_gl_transaction %PARAMS>
 943
 944 Creates a new GL transaction (table gl), which is basically a wrapper around
 945 SL::DB::GLTransaction->new(...) and add_chart_booking and post, while setting
 946 as many defaults as possible.
 947
 948 Possible parameters:
 949
 950  * taxincluded (0 or 1, defaults to 1)
 951  * transdate (DateTime object, defaults to current date)
 952  * dec (number of decimals to round to, defaults to 2)
 953  * bookings (arrayref for the charts and taxes to be booked, see examples below)
 954
 955 bookings must include a least:
 956
 957  * chart as an SL::DB::Chart object
 958  * credit or debit, as positive numbers
 959  * tax_id, tax (an SL::DB::Tax object) or taxkey (e.g. 9)
 960
 961 Can't be used to create storno transactions.
 962
 963 Minimal usage example, using all the defaults, creating a GL transaction with
 964 travel expenses:
 965
 966   use SL::Dev::Record qw(create_gl_transaction);
 967   $gl_transaction = create_gl_transaction();
 968
 969 Create a GL transaction with a specific charts and taxes (the default taxes for
 970 those charts are used if none are explicitly given in bookings):
 971
 972   my $cash           = SL::DB::Manager::Chart->find_by( description => 'Kasse'          );
 973   my $betriebsbedarf = SL::DB::Manager::Chart->find_by( description => 'Betriebsbedarf' );
 974   $gl_transaction = create_gl_transaction(
 975     reference   => 'betriebsbedarf',
 976     taxincluded => 1,
 977     bookings    => [
 978                      {
 979                        chart  => $betriebsbedarf,
 980                        memo   => 'foo 1',
 981                        source => 'foo 1',
 982                        credit => 119,
 983                      },
 984                      {
 985                        chart  => $betriebsbedarf,
 986                        memo   => 'foo 2',
 987                        source => 'foo 2',
 988                        credit => 119,
 989                      },
 990                      {
 991                        chart  => $cash,
 992                        debit  => 238,
 993                        memo   => 'foo 1+2',
 994                        source => 'foo 1+2',
 995                      },
 996                    ],
 997   );
 998
 999
1000 =head1 BUGS
1001
1002 Nothing here yet.
1003
1004 =head1 AUTHOR
1005
1006 G. Richardson E<lt>grichardson@kivitec.deE<gt>
1007
1008 =cut