SL/Dispatcher.pm

   1 package SL::Dispatcher;
   2
   3 use strict;
   4
   5 BEGIN {
   6   unshift @INC, "modules/override"; # Use our own versions of various modules (e.g. YAML).
   7   push    @INC, "modules/fallback"; # Only use our own versions of modules if there's no system version.
   8   push    @INC, "SL";               # FCGI won't find modules that are not properly named. Help it by inclduging SL
   9 }
  10
  11 use CGI qw( -no_xhtml);
  12 use English qw(-no_match_vars);
  13 use SL::Auth;
  14 use SL::LXDebug;
  15 use SL::Locale;
  16 use SL::Common;
  17 use Form;
  18 use List::Util qw(first);
  19 use File::Basename;
  20
  21 # Trailing new line is added so that Perl will not add the line
  22 # number 'die' was called in.
  23 use constant END_OF_REQUEST => "END-OF-REQUEST\n";
  24
  25 sub pre_request_checks {
  26   if (!$::auth->session_tables_present) {
  27     if ($::form->{script} eq 'admin.pl') {
  28       ::run();
  29       ::end_of_request();
  30     } else {
  31       show_error('login/auth_db_unreachable');
  32     }
  33   }
  34   $::auth->expire_sessions;
  35 }
  36
  37 sub show_error {
  38   $::lxdebug->enter_sub;
  39   my $template             = shift;
  40   my $error_type           = shift || '';
  41
  42   $::locale                = Locale->new($::language);
  43   $::form->{error}         = $::locale->text('The session is invalid or has expired.') if ($error_type eq 'session');
  44   $::form->{error}         = $::locale->text('Incorrect password!.')                   if ($error_type eq 'password');
  45   $::myconfig{countrycode} = $::language;
  46   $::form->{stylesheet}    = 'css/lx-office-erp.css';
  47
  48   $::form->header;
  49   print $::form->parse_html_template($template);
  50   $::lxdebug->leave_sub;
  51
  52   ::end_of_request();
  53 }
  54
  55 sub pre_startup_setup {
  56   eval {
  57     package main;
  58     require "config/lx-erp.conf";
  59   };
  60   eval {
  61     package main;
  62     require "config/lx-erp-local.conf";
  63   } if -f "config/lx-erp-local.conf";
  64
  65   eval {
  66     package main;
  67     require "bin/mozilla/common.pl";
  68     require "bin/mozilla/installationcheck.pl";
  69   } or die $EVAL_ERROR;
  70
  71   # canonial globals. if it's not here, chances are it will get refactored someday.
  72   {
  73     no warnings 'once';
  74     $::userspath   = "users";
  75     $::templates   = "templates";
  76     $::memberfile  = "users/members";
  77     $::menufile    = "menu.ini";
  78     $::sendmail    = "| /usr/sbin/sendmail -t";
  79     $::lxdebug     = LXDebug->new;
  80     $::auth        = SL::Auth->new;
  81     $::form        = undef;
  82     %::myconfig    = ();
  83     %::called_subs = (); # currently used for recursion detection
  84   }
  85
  86   $SIG{__WARN__} = sub {
  87     $::lxdebug->warn(@_);
  88   }
  89 }
  90
  91 sub pre_startup_checks {
  92   ::verify_installation();
  93 }
  94
  95 sub pre_startup {
  96   pre_startup_setup();
  97   pre_startup_checks();
  98 }
  99
 100 sub require_main_code {
 101   $::lxdebug->enter_sub;
 102   my ($script, $suffix) = @_;
 103
 104   eval {
 105     package main;
 106     require "bin/mozilla/$script$suffix";
 107   } or die $EVAL_ERROR;
 108
 109   if (-f "bin/mozilla/custom_$script$suffix") {
 110     eval {
 111       package main;
 112       require "bin/mozilla/custom_$script$suffix";
 113     };
 114     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 115   }
 116   if ($::form->{login} && -f "bin/mozilla/$::form->{login}_$script") {
 117     eval {
 118       package main;
 119       require "bin/mozilla/$::form->{login}_$script";
 120     };
 121     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 122   }
 123   $::lxdebug->leave_sub;
 124 }
 125
 126 sub handle_request {
 127   $::lxdebug->enter_sub;
 128   $::lxdebug->begin_request;
 129
 130   my $interface = lc(shift || 'cgi');
 131   my ($script_name, $action);
 132
 133   $script_name = $ENV{SCRIPT_NAME};
 134
 135   unrequire_bin_mozilla($interface);
 136
 137   $::cgi         = CGI->new('');
 138   $::locale      = Locale->new($::language);
 139   $::form        = Form->new;
 140   %::called_subs = ();
 141
 142   eval { ($script_name, $action) = _route_request($script_name); 1; } or return;
 143
 144   my ($script, $path, $suffix) = fileparse($script_name, ".pl");
 145   require_main_code($script, $suffix);
 146
 147   $::form->{script} = $script . $suffix;
 148
 149   pre_request_checks();
 150
 151   eval {
 152     my $session_result = $::auth->restore_session;
 153     $::auth->create_or_refresh_session;
 154
 155     $::form->error($::locale->text('System currently down for maintenance!')) if -e "$::userspath/nologin" && $script ne 'admin';
 156
 157     if ($script eq 'login' or $script eq 'admin' or $script eq 'kopf') {
 158       $::form->{titlebar} = "Lx-Office " . $::locale->text('Version') . " $::form->{version}";
 159       ::run($session_result);
 160
 161     } else {
 162       show_error('login/password_error', 'session') if SL::Auth::SESSION_EXPIRED == $session_result;
 163       %::myconfig = $::auth->read_user($::form->{login});
 164
 165       show_error('login/password_error', 'password') unless $::myconfig{login};
 166
 167       $::locale = Locale->new($::myconfig{countrycode});
 168
 169       show_error('login/password_error', 'password') if SL::Auth::OK != $::auth->authenticate($::form->{login}, $::form->{password}, 0);
 170
 171       $::auth->set_session_value('login', $::form->{login}, 'password', $::form->{password});
 172       $::auth->create_or_refresh_session;
 173       $::auth->delete_session_value('FLASH')->save_session();
 174       delete $::form->{password};
 175
 176       if ($action) {
 177         map { $::form->{$_} = $::myconfig{$_} } qw(stylesheet charset)
 178           unless $action eq 'save' && $::form->{type} eq 'preferences';
 179
 180         $::form->set_standard_title;
 181         ::call_sub('::' . $::locale->findsub($action));
 182       } else {
 183         $::form->error($::locale->text('action= not defined!'));
 184       }
 185     }
 186
 187     1;
 188   } or do {
 189     if ($EVAL_ERROR ne END_OF_REQUEST) {
 190       $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 191       eval { show_error('generic/error') };
 192     }
 193   };
 194
 195   # cleanup
 196   $::locale   = undef;
 197   $::form     = undef;
 198   $::myconfig = ();
 199   Form::disconnect_standard_dbh();
 200
 201   $::lxdebug->end_request;
 202   $::lxdebug->leave_sub;
 203 }
 204
 205 sub unrequire_bin_mozilla {
 206   return unless $_[0] =~ m/^(?:fastcgi|fcgid|fcgi)$/;
 207
 208   for (keys %INC) {
 209     next unless m#^bin/mozilla/#;
 210     next if /\bcommon.pl$/;
 211     next if /\binstallationcheck.pl$/;
 212     delete $INC{$_};
 213   }
 214 }
 215
 216 sub _route_request {
 217   my $script_name = shift;
 218
 219   return $script_name =~ m/dispatcher\.pl$/ ? _route_dispatcher_request() : ($script_name, $::form->{action});
 220 }
 221
 222 sub _route_dispatcher_request {
 223   my $name_re = qr{[a-z]\w*};
 224   my ($script_name, $action);
 225
 226   eval {
 227     die "Unroutable request -- inavlid module name.\n" if !$::form->{M} || ($::form->{M} !~ m/^${name_re}$/);
 228     $script_name = $::form->{M} . '.pl';
 229
 230     if ($::form->{A}) {
 231       $action = $::form->{A};
 232
 233     } else {
 234       $action = first { m/^A_${name_re}$/ } keys %{ $::form };
 235       die "Unroutable request -- inavlid action name.\n" if !$action;
 236
 237       delete $::form->{$action};
 238       $action = substr $action, 2;
 239     }
 240
 241     delete @{$::form}{qw(M A)};
 242
 243     1;
 244   } or do {
 245     $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 246     show_error('generic/error');
 247   };
 248
 249   return ($script_name, $action);
 250 }
 251
 252 package main;
 253
 254 use strict;
 255
 256 sub end_of_request {
 257   die SL::Dispatcher->END_OF_REQUEST;
 258 }
 259
 260 1;