SL/Dispatcher.pm

   1 package SL::Dispatcher;
   2
   3 use strict;
   4
   5 BEGIN {
   6   unshift @INC, "modules/override"; # Use our own versions of various modules (e.g. YAML).
   7   push    @INC, "modules/fallback"; # Only use our own versions of modules if there's no system version.
   8   push    @INC, "SL";               # FCGI won't find modules that are not properly named. Help it by inclduging SL
   9 }
  10
  11 use CGI qw( -no_xhtml);
  12 use English qw(-no_match_vars);
  13 use SL::Auth;
  14 use SL::LXDebug;
  15 use SL::Locale;
  16 use SL::Common;
  17 use Form;
  18 use List::Util qw(first);
  19 use Moose;
  20 use Rose::DB;
  21 use Rose::DB::Object;
  22 use File::Basename;
  23
  24 # Trailing new line is added so that Perl will not add the line
  25 # number 'die' was called in.
  26 use constant END_OF_REQUEST => "END-OF-REQUEST\n";
  27
  28 sub pre_request_checks {
  29   if (!$::auth->session_tables_present) {
  30     if ($::form->{script} eq 'admin.pl') {
  31       ::run();
  32       ::end_of_request();
  33     } else {
  34       show_error('login/auth_db_unreachable');
  35     }
  36   }
  37   $::auth->expire_sessions;
  38 }
  39
  40 sub show_error {
  41   $::lxdebug->enter_sub;
  42   my $template             = shift;
  43   my $error_type           = shift || '';
  44
  45   $::locale                = Locale->new($::language);
  46   $::form->{error}         = $::locale->text('The session is invalid or has expired.') if ($error_type eq 'session');
  47   $::form->{error}         = $::locale->text('Incorrect password!.')                   if ($error_type eq 'password');
  48   $::myconfig{countrycode} = $::language;
  49   $::form->{stylesheet}    = 'css/lx-office-erp.css';
  50
  51   $::form->header;
  52   print $::form->parse_html_template($template);
  53   $::lxdebug->leave_sub;
  54
  55   ::end_of_request();
  56 }
  57
  58 sub pre_startup_setup {
  59   eval {
  60     package main;
  61     require "config/lx-erp.conf";
  62   };
  63   eval {
  64     package main;
  65     require "config/lx-erp-local.conf";
  66   } if -f "config/lx-erp-local.conf";
  67
  68   eval {
  69     package main;
  70     require "bin/mozilla/common.pl";
  71     require "bin/mozilla/installationcheck.pl";
  72   } or die $EVAL_ERROR;
  73
  74   # canonial globals. if it's not here, chances are it will get refactored someday.
  75   {
  76     no warnings 'once';
  77     $::userspath   = "users";
  78     $::templates   = "templates";
  79     $::memberfile  = "users/members";
  80     $::menufile    = "menu.ini";
  81     $::sendmail    = "| /usr/sbin/sendmail -t";
  82     $::lxdebug     = LXDebug->new;
  83     $::auth        = SL::Auth->new;
  84     $::form        = undef;
  85     %::myconfig    = ();
  86     %::called_subs = (); # currently used for recursion detection
  87   }
  88 }
  89
  90 sub pre_startup_checks {
  91   ::verify_installation();
  92 }
  93
  94 sub pre_startup {
  95   pre_startup_setup();
  96   pre_startup_checks();
  97 }
  98
  99 sub require_main_code {
 100   my ($script, $suffix) = @_;
 101
 102   eval {
 103     package main;
 104     require "bin/mozilla/$script$suffix";
 105   } or die $EVAL_ERROR;
 106
 107   if (-f "bin/mozilla/custom_$script$suffix") {
 108     eval {
 109       package main;
 110       require "bin/mozilla/custom_$script$suffix";
 111     };
 112     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 113   }
 114   if ($::form->{login} && -f "bin/mozilla/$::form->{login}_$script") {
 115     eval {
 116       package main;
 117       require "bin/mozilla/$::form->{login}_$script";
 118     };
 119     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 120   }
 121 }
 122
 123 sub handle_request {
 124   $::lxdebug->enter_sub;
 125   $::lxdebug->begin_request;
 126
 127   my $interface = lc(shift || 'cgi');
 128   my ($script_name, $action);
 129
 130   if ($interface =~ m/^(?:fastcgi|fcgid|fcgi)$/) {
 131     $script_name = $ENV{SCRIPT_NAME};
 132     unrequire_bin_mozilla();
 133
 134   } else {
 135     $script_name = $0;
 136   }
 137
 138   $::cgi         = CGI->new('');
 139   $::locale      = Locale->new($::language);
 140   $::form        = Form->new;
 141   %::called_subs = ();
 142
 143   eval { ($script_name, $action) = _route_request($script_name); 1; } or return;
 144
 145   my ($script, $path, $suffix) = fileparse($script_name, ".pl");
 146   require_main_code($script, $suffix);
 147
 148   $::form->{script} = $script . $suffix;
 149
 150   pre_request_checks();
 151
 152   eval {
 153     if ($script eq 'login' or $script eq 'admin' or $script eq 'kopf') {
 154       $::form->{titlebar} = "Lx-Office " . $::locale->text('Version') . " $::form->{version}";
 155       ::run($::auth->restore_session);
 156
 157     } elsif ($action) {
 158       # copy from am.pl routines
 159       $::form->error($::locale->text('System currently down for maintenance!')) if -e "$main::userspath/nologin" && $script ne 'admin';
 160
 161       my $session_result = $::auth->restore_session;
 162
 163       show_error('login/password_error', 'session') if SL::Auth::SESSION_EXPIRED == $session_result;
 164       %::myconfig = $::auth->read_user($::form->{login});
 165
 166       show_error('login/password_error', 'password') unless $::myconfig{login};
 167
 168       $::locale = Locale->new($::myconfig{countrycode});
 169
 170       show_error('login/password_error', 'password') if SL::Auth::OK != $::auth->authenticate($::form->{login}, $::form->{password}, 0);
 171
 172       $::auth->set_session_value('login', $::form->{login}, 'password', $::form->{password});
 173       $::auth->create_or_refresh_session;
 174       delete $::form->{password};
 175
 176       map { $::form->{$_} = $::myconfig{$_} } qw(stylesheet charset)
 177         unless $action eq 'save' && $::form->{type} eq 'preferences';
 178
 179       $::form->set_standard_title;
 180       ::call_sub('::' . $::locale->findsub($action));
 181
 182     } else {
 183       $::form->error($::locale->text('action= not defined!'));
 184     }
 185
 186     1;
 187   } or do {
 188     if ($EVAL_ERROR ne END_OF_REQUEST) {
 189       $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 190       eval { show_error('generic/error') };
 191     }
 192   };
 193
 194   # cleanup
 195   $::locale   = undef;
 196   $::form     = undef;
 197   $::myconfig = ();
 198   Form::disconnect_standard_dbh();
 199
 200   $::lxdebug->end_request;
 201   $::lxdebug->leave_sub;
 202 }
 203
 204 sub unrequire_bin_mozilla {
 205   for (keys %INC) {
 206     next unless m#^bin/mozilla/#;
 207     next if /\bcommon.pl$/;
 208     next if /\binstallationcheck.pl$/;
 209     delete $INC{$_};
 210   }
 211 }
 212
 213 sub _route_request {
 214   my $script_name = shift;
 215
 216   return $script_name =~ m/dispatcher\.pl$/ ? _route_dispatcher_request() : ($script_name, $::form->{action});
 217 }
 218
 219 sub _route_dispatcher_request {
 220   my $name_re = qr{[a-z]\w*};
 221   my ($script_name, $action);
 222
 223   eval {
 224     die "Unroutable request -- inavlid module name.\n" if !$::form->{M} || ($::form->{M} !~ m/^${name_re}$/);
 225     $script_name = $::form->{M} . '.pl';
 226
 227     if ($::form->{A}) {
 228       $action = $::form->{A};
 229
 230     } else {
 231       $action = first { m/^A_${name_re}$/ } keys %{ $::form };
 232       die "Unroutable request -- inavlid action name.\n" if !$action;
 233
 234       delete $::form->{$action};
 235       $action = substr $action, 2;
 236     }
 237
 238     delete @{$::form}{qw(M A)};
 239
 240     1;
 241   } or do {
 242     $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 243     show_error('generic/error');
 244   };
 245
 246   return ($script_name, $action);
 247 }
 248
 249 package main;
 250
 251 use strict;
 252
 253 sub end_of_request {
 254   die SL::Dispatcher->END_OF_REQUEST;
 255 }
 256
 257 1;