SL/Dispatcher.pm

   1 package SL::Dispatcher;
   2
   3 use strict;
   4
   5 # Force scripts/locales.pl to parse these templates:
   6 #   parse_html_template('login_screen/auth_db_unreachable')
   7 #   parse_html_template('login_screen/user_login')
   8 #   parse_html_template('generic/error')
   9
  10 BEGIN {
  11   use SL::System::Process;
  12   my $exe_dir = SL::System::Process::exe_dir;
  13
  14   unshift @INC, "${exe_dir}/modules/override"; # Use our own versions of various modules (e.g. YAML).
  15   push    @INC, "${exe_dir}/modules/fallback"; # Only use our own versions of modules if there's no system version.
  16   unshift @INC, $exe_dir;
  17 }
  18
  19 use CGI qw( -no_xhtml);
  20 use Config::Std;
  21 use DateTime;
  22 use Encode;
  23 use English qw(-no_match_vars);
  24 use File::Basename;
  25 use List::MoreUtils qw(all);
  26 use List::Util qw(first);
  27 use POSIX;
  28 use SL::Auth;
  29 use SL::Dispatcher::AuthHandler;
  30 use SL::LXDebug;
  31 use SL::LxOfficeConf;
  32 use SL::Locale;
  33 use SL::Common;
  34 use SL::Form;
  35 use SL::Helper::DateTime;
  36 use SL::Controller::LoginScreen;
  37 use SL::InstanceConfiguration;
  38 use SL::Template::Plugin::HTMLFixes;
  39
  40 # Trailing new line is added so that Perl will not add the line
  41 # number 'die' was called in.
  42 use constant END_OF_REQUEST => "END-OF-REQUEST\n";
  43
  44 my %fcgi_file_cache;
  45
  46 sub new {
  47   my ($class, $interface) = @_;
  48
  49   my $self           = bless {}, $class;
  50   $self->{interface} = lc($interface || 'cgi');
  51   $self->{auth_handler} = SL::Dispatcher::AuthHandler->new;
  52
  53   return $self;
  54 }
  55
  56 sub interface_type {
  57   my ($self) = @_;
  58   return $self->{interface} eq 'cgi' ? 'CGI' : 'FastCGI';
  59 }
  60
  61 sub pre_request_checks {
  62   _check_for_old_config_files();
  63
  64   if (!$::auth->session_tables_present) {
  65     if ($::form->{script} eq 'admin.pl') {
  66       ::run();
  67       ::end_of_request();
  68     } else {
  69       show_error('login_screen/auth_db_unreachable');
  70     }
  71   }
  72 }
  73
  74 sub show_error {
  75   $::lxdebug->enter_sub;
  76   my $template             = shift;
  77   my $error_type           = shift || '';
  78   my %params               = @_;
  79
  80   $::myconfig{countrycode} = delete($params{countrycode}) || $::lx_office_conf{system}->{language};
  81   $::locale                = Locale->new($::myconfig{countrycode});
  82   $::form->{error}         = $::locale->text('The session is invalid or has expired.') if ($error_type eq 'session');
  83   $::form->{error}         = $::locale->text('Incorrect password!')                    if ($error_type eq 'password');
  84
  85   $::form->header;
  86   print $::form->parse_html_template($template, \%params);
  87   $::lxdebug->leave_sub;
  88
  89   ::end_of_request();
  90 }
  91
  92 sub pre_startup_setup {
  93   my ($self) = @_;
  94
  95   SL::LxOfficeConf->read;
  96
  97   eval {
  98     package main;
  99     require "bin/mozilla/common.pl";
 100     require "bin/mozilla/installationcheck.pl";
 101   } or die $EVAL_ERROR;
 102
 103   # canonial globals. if it's not here, chances are it will get refactored someday.
 104   {
 105     no warnings 'once';
 106     $::lxdebug     = LXDebug->new;
 107     $::auth        = SL::Auth->new;
 108     $::form        = undef;
 109     %::myconfig    = ();
 110     $::request     = undef;
 111   }
 112
 113   $SIG{__WARN__} = sub {
 114     $::lxdebug->warn(@_);
 115   };
 116
 117   $self->_cache_file_modification_times;
 118 }
 119
 120 sub pre_startup_checks {
 121   ::verify_installation();
 122 }
 123
 124 sub pre_startup {
 125   my ($self) = @_;
 126   $self->pre_startup_setup;
 127   $self->pre_startup_checks;
 128 }
 129
 130 sub require_main_code {
 131   $::lxdebug->enter_sub;
 132   my ($script, $suffix) = @_;
 133
 134   eval {
 135     package main;
 136     require "bin/mozilla/$script$suffix";
 137   } or die $EVAL_ERROR;
 138
 139   if (-f "bin/mozilla/custom_$script$suffix") {
 140     eval {
 141       package main;
 142       require "bin/mozilla/custom_$script$suffix";
 143     };
 144     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 145   }
 146   if ($::form->{login} && -f "bin/mozilla/$::form->{login}_$script") {
 147     eval {
 148       package main;
 149       require "bin/mozilla/$::form->{login}_$script";
 150     };
 151     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 152   }
 153   $::lxdebug->leave_sub;
 154 }
 155
 156 sub _require_controller {
 157   my $controller =  shift;
 158   $controller    =~ s|[^A-Za-z0-9_]||g;
 159   $controller    =  "SL/Controller/${controller}";
 160
 161   eval {
 162     package main;
 163     require "${controller}.pm";
 164   } or die $EVAL_ERROR;
 165 }
 166
 167 sub _run_controller {
 168   "SL::Controller::$_[0]"->new->_run_action($_[1]);
 169 }
 170
 171 sub handle_request {
 172   my $self         = shift;
 173   $self->{request} = shift;
 174
 175   $::lxdebug->enter_sub;
 176   $::lxdebug->begin_request;
 177
 178   my ($script, $path, $suffix, $script_name, $action, $routing_type);
 179
 180   $self->unrequire_bin_mozilla;
 181
 182   $::locale        = Locale->new($::lx_office_conf{system}->{language});
 183   $::form          = Form->new;
 184   $::instance_conf = SL::InstanceConfiguration->new;
 185   $::request       = { cgi => CGI->new({}) };
 186
 187   my $session_result = $::auth->restore_session;
 188   $::auth->create_or_refresh_session;
 189
 190   $::form->read_cgi_input;
 191
 192   eval { ($routing_type, $script_name, $action) = _route_request($ENV{SCRIPT_NAME}); 1; } or return;
 193
 194   if ($routing_type eq 'old') {
 195     $::form->{action}  =  lc $::form->{action};
 196     $::form->{action}  =~ s/( |-|,|\#)/_/g;
 197
 198    ($script, $path, $suffix) = fileparse($script_name, ".pl");
 199     require_main_code($script, $suffix);
 200
 201     $::form->{script} = $script . $suffix;
 202
 203   } else {
 204     _require_controller($script_name);
 205     $::form->{script} = "controller.pl";
 206   }
 207
 208   eval {
 209     pre_request_checks();
 210
 211     $::form->error($::locale->text('System currently down for maintenance!')) if -e ($::lx_office_conf{paths}->{userspath} . "/nologin") && $script ne 'admin';
 212
 213     # For compatibility with a lot of database upgrade scripts etc:
 214     # Re-write request to old 'login.pl?action=login' to new
 215     # 'LoginScreen' controller. Make sure to load its code!
 216     if (($script eq 'login') && ($action eq 'login')) {
 217       ($routing_type, $script, $script_name, $action) = qw(controller controller LoginScreen login);
 218       _require_controller('LoginScreen');
 219     }
 220
 221     if (($script eq 'login') && !$action) {
 222       print $::request->{cgi}->redirect('controller.pl?action=LoginScreen/user_login');
 223
 224     } elsif ($script eq 'admin') {
 225       $::form->{titlebar} = "kivitendo " . $::locale->text('Version') . " $::form->{version}";
 226       ::run($session_result);
 227
 228     } else {
 229       show_error('login_screen/user_login', 'session') if SL::Auth::SESSION_EXPIRED == $session_result;
 230
 231       my %auth_result = $self->{auth_handler}->handle(
 232         routing_type => $routing_type,
 233         script       => $script,
 234         controller   => $script_name,
 235         action       => $action,
 236       );
 237
 238       delete @{ $::form }{ grep { m/^\{AUTH\}/ } keys %{ $::form } } unless $auth_result{keep_auth_vars};
 239
 240       if ($action) {
 241         $::instance_conf->init if $auth_result{auth_level} eq 'user';
 242
 243         map { $::form->{$_} = $::myconfig{$_} } qw(charset)
 244           unless $action eq 'save' && $::form->{type} eq 'preferences';
 245
 246         $::form->set_standard_title;
 247         if ($routing_type eq 'old') {
 248           ::call_sub('::' . $::locale->findsub($action));
 249         } else {
 250           _run_controller($script_name, $action);
 251         }
 252       } else {
 253         $::form->error($::locale->text('action= not defined!'));
 254       }
 255     }
 256
 257     1;
 258   } or do {
 259     if ($EVAL_ERROR ne END_OF_REQUEST) {
 260       print STDERR $EVAL_ERROR;
 261       $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 262       chdir SL::System::Process::exe_dir;
 263       eval { show_error('generic/error') };
 264     }
 265   };
 266
 267   # cleanup
 268   $::auth->save_session;
 269   $::auth->expire_sessions;
 270   $::auth->reset;
 271
 272   $::locale   = undef;
 273   $::form     = undef;
 274   $::myconfig = ();
 275   $::request  = undef;
 276   Form::disconnect_standard_dbh;
 277
 278   $::lxdebug->end_request;
 279
 280   $self->_watch_for_changed_files;
 281
 282   $::lxdebug->leave_sub;
 283 }
 284
 285 sub unrequire_bin_mozilla {
 286   my $self = shift;
 287   return unless $self->_interface_is_fcgi;
 288
 289   for (keys %INC) {
 290     next unless m#^bin/mozilla/#;
 291     next if /\bcommon.pl$/;
 292     next if /\binstallationcheck.pl$/;
 293     delete $INC{$_};
 294   }
 295 }
 296
 297 sub _interface_is_fcgi {
 298   my $self = shift;
 299   return $self->{interface} =~ m/^(?:fastcgi|fcgid|fcgi)$/;
 300 }
 301
 302 sub _route_request {
 303   my $script_name = shift;
 304
 305   return $script_name =~ m/dispatcher\.pl$/ ? ('old',        _route_dispatcher_request())
 306        : $script_name =~ m/controller\.pl/  ? ('controller', _route_controller_request())
 307        :                                      ('old',        $script_name, $::form->{action});
 308 }
 309
 310 sub _route_dispatcher_request {
 311   my $name_re = qr{[a-z]\w*};
 312   my ($script_name, $action);
 313
 314   eval {
 315     die "Unroutable request -- inavlid module name.\n" if !$::form->{M} || ($::form->{M} !~ m/^${name_re}$/);
 316     $script_name = $::form->{M} . '.pl';
 317
 318     if ($::form->{A}) {
 319       $action = $::form->{A};
 320
 321     } else {
 322       $action = first { m/^A_${name_re}$/ } keys %{ $::form };
 323       die "Unroutable request -- inavlid action name.\n" if !$action;
 324
 325       delete $::form->{$action};
 326       $action = substr $action, 2;
 327     }
 328
 329     delete @{$::form}{qw(M A)};
 330
 331     1;
 332   } or do {
 333     $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 334     show_error('generic/error');
 335   };
 336
 337   return ($script_name, $action);
 338 }
 339
 340 sub _route_controller_request {
 341   my ($controller, $action);
 342
 343   eval {
 344     $::form->{action}      =~ m|^ ( [A-Z] [A-Za-z0-9_]* ) / ( [a-z] [a-z0-9_]* ) $|x || die "Unroutable request -- inavlid controller/action.\n";
 345     ($controller, $action) =  ($1, $2);
 346     delete $::form->{action};
 347
 348     1;
 349   } or do {
 350     $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 351     show_error('generic/error');
 352   };
 353
 354   return ($controller, $action);
 355 }
 356
 357 sub _cache_file_modification_times {
 358   my ($self) = @_;
 359
 360   return unless $self->_interface_is_fcgi && $::lx_office_conf{debug}->{restart_fcgi_process_on_changes};
 361
 362   require File::Find;
 363   require POSIX;
 364
 365   my $wanted = sub {
 366     return unless $File::Find::name =~ m/\.(?:pm|f?pl|html|conf|conf\.default)$/;
 367     $fcgi_file_cache{ $File::Find::name } = (stat $File::Find::name)[9];
 368   };
 369
 370   my $cwd = POSIX::getcwd();
 371   File::Find::find($wanted, map { "${cwd}/${_}" } qw(config bin SL templates/webpages));
 372   map { my $name = "${cwd}/${_}"; $fcgi_file_cache{$name} = (stat $name)[9] } qw(admin.pl dispatcher.fpl);
 373 }
 374
 375 sub _watch_for_changed_files {
 376   my ($self) = @_;
 377
 378   return unless $self->_interface_is_fcgi && $::lx_office_conf{debug}->{restart_fcgi_process_on_changes};
 379
 380   my $ok = all { (stat($_))[9] == $fcgi_file_cache{$_} } keys %fcgi_file_cache;
 381   return if $ok;
 382   $::lxdebug->message(LXDebug::DEBUG1(), "Program modifications detected. Restarting.");
 383   exit;
 384 }
 385
 386 sub get_standard_filehandles {
 387   my $self = shift;
 388
 389   return $self->{interface} =~ m/f(?:ast)cgi/i ? $self->{request}->GetHandles() : (\*STDIN, \*STDOUT, \*STDERR);
 390 }
 391
 392 sub _check_for_old_config_files {
 393   my @old_files = grep { -f "config/${_}" } qw(authentication.pl console.conf lx-erp.conf lx-erp-local.conf);
 394   return unless @old_files;
 395
 396   $::form->{title} = $::locale->text('Old configuration files');
 397   $::form->header;
 398   print $::form->parse_html_template('login_screen/old_configuration_files', { FILES => \@old_files });
 399
 400   ::end_of_request();
 401 }
 402
 403 package main;
 404
 405 use strict;
 406
 407 sub end_of_request {
 408   die SL::Dispatcher->END_OF_REQUEST;
 409 }
 410
 411 1;