SL/Dispatcher.pm

   1 package SL::Dispatcher;
   2
   3 use strict;
   4
   5 BEGIN {
   6   unshift @INC, "modules/override"; # Use our own versions of various modules (e.g. YAML).
   7   push    @INC, "modules/fallback"; # Only use our own versions of modules if there's no system version.
   8 }
   9
  10 use CGI qw( -no_xhtml);
  11 use Config::Std;
  12 use DateTime;
  13 use Encode;
  14 use English qw(-no_match_vars);
  15 use File::Basename;
  16 use List::MoreUtils qw(all);
  17 use List::Util qw(first);
  18 use POSIX;
  19 use SL::Auth;
  20 use SL::LXDebug;
  21 use SL::LxOfficeConf;
  22 use SL::Locale;
  23 use SL::Common;
  24 use SL::Form;
  25 use SL::Helper::DateTime;
  26 use SL::InstanceConfiguration;
  27 use SL::Template::Plugin::HTMLFixes;
  28
  29 # Trailing new line is added so that Perl will not add the line
  30 # number 'die' was called in.
  31 use constant END_OF_REQUEST => "END-OF-REQUEST\n";
  32
  33 my %fcgi_file_cache;
  34
  35 sub new {
  36   my ($class, $interface) = @_;
  37
  38   my $self           = bless {}, $class;
  39   $self->{interface} = lc($interface || 'cgi');
  40
  41   return $self;
  42 }
  43
  44 sub interface_type {
  45   my ($self) = @_;
  46   return $self->{interface} eq 'cgi' ? 'CGI' : 'FastCGI';
  47 }
  48
  49 sub pre_request_checks {
  50   _check_for_old_config_files();
  51
  52   if (!$::auth->session_tables_present) {
  53     if ($::form->{script} eq 'admin.pl') {
  54       ::run();
  55       ::end_of_request();
  56     } else {
  57       show_error('login/auth_db_unreachable');
  58     }
  59   }
  60 }
  61
  62 sub show_error {
  63   $::lxdebug->enter_sub;
  64   my $template             = shift;
  65   my $error_type           = shift || '';
  66
  67   $::locale                = Locale->new($::lx_office_conf{system}->{language});
  68   $::form->{error}         = $::locale->text('The session is invalid or has expired.') if ($error_type eq 'session');
  69   $::form->{error}         = $::locale->text('Incorrect password!.')                   if ($error_type eq 'password');
  70   $::myconfig{countrycode} = $::lx_office_conf{system}->{language};
  71   $::form->{stylesheet}    = 'css/lx-office-erp.css';
  72
  73   $::form->header;
  74   print $::form->parse_html_template($template);
  75   $::lxdebug->leave_sub;
  76
  77   ::end_of_request();
  78 }
  79
  80 sub pre_startup_setup {
  81   my ($self) = @_;
  82
  83   SL::LxOfficeConf->read;
  84   _init_environment();
  85
  86   eval {
  87     package main;
  88     require "bin/mozilla/common.pl";
  89     require "bin/mozilla/installationcheck.pl";
  90   } or die $EVAL_ERROR;
  91
  92   # canonial globals. if it's not here, chances are it will get refactored someday.
  93   {
  94     no warnings 'once';
  95     $::lxdebug     = LXDebug->new;
  96     $::auth        = SL::Auth->new;
  97     $::form        = undef;
  98     %::myconfig    = ();
  99     %::called_subs = (); # currently used for recursion detection
 100   }
 101
 102   $SIG{__WARN__} = sub {
 103     $::lxdebug->warn(@_);
 104   };
 105
 106   $self->_cache_file_modification_times;
 107 }
 108
 109 sub pre_startup_checks {
 110   ::verify_installation();
 111 }
 112
 113 sub pre_startup {
 114   my ($self) = @_;
 115   $self->pre_startup_setup;
 116   $self->pre_startup_checks;
 117 }
 118
 119 sub require_main_code {
 120   $::lxdebug->enter_sub;
 121   my ($script, $suffix) = @_;
 122
 123   eval {
 124     package main;
 125     require "bin/mozilla/$script$suffix";
 126   } or die $EVAL_ERROR;
 127
 128   if (-f "bin/mozilla/custom_$script$suffix") {
 129     eval {
 130       package main;
 131       require "bin/mozilla/custom_$script$suffix";
 132     };
 133     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 134   }
 135   if ($::form->{login} && -f "bin/mozilla/$::form->{login}_$script") {
 136     eval {
 137       package main;
 138       require "bin/mozilla/$::form->{login}_$script";
 139     };
 140     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 141   }
 142   $::lxdebug->leave_sub;
 143 }
 144
 145 sub _require_controller {
 146   my $controller =  shift;
 147   $controller    =~ s|[^A-Za-z0-9_]||g;
 148
 149   eval {
 150     package main;
 151     require "SL/Controller/${controller}.pm";
 152   } or die $EVAL_ERROR;
 153 }
 154
 155 sub _run_controller {
 156   "SL::Controller::$_[0]"->new->_run_action($_[1]);
 157 }
 158
 159 sub handle_request {
 160   my $self         = shift;
 161   $self->{request} = shift;
 162
 163   $::lxdebug->enter_sub;
 164   $::lxdebug->begin_request;
 165
 166   my ($script, $path, $suffix, $script_name, $action, $routing_type);
 167
 168   $script_name = $ENV{SCRIPT_NAME};
 169
 170   $self->unrequire_bin_mozilla;
 171
 172   $::cgi           = CGI->new('');
 173   $::locale        = Locale->new($::lx_office_conf{system}->{language});
 174   $::form          = Form->new;
 175   %::called_subs   = ();
 176   $::instance_conf = SL::InstanceConfiguration->new;
 177
 178   my $session_result = $::auth->restore_session;
 179   $::auth->create_or_refresh_session;
 180
 181   $::form->read_cgi_input;
 182
 183   eval { ($routing_type, $script_name, $action) = _route_request($script_name); 1; } or return;
 184
 185   if ($routing_type eq 'old') {
 186     $::form->{action}  =  lc $::form->{action};
 187     $::form->{action}  =~ s/( |-|,|\#)/_/g;
 188
 189    ($script, $path, $suffix) = fileparse($script_name, ".pl");
 190     require_main_code($script, $suffix);
 191
 192     $::form->{script} = $script . $suffix;
 193
 194   } else {
 195     _require_controller($script_name);
 196     $::form->{script} = "controller.pl";
 197   }
 198
 199   eval {
 200     pre_request_checks();
 201
 202     $::form->error($::locale->text('System currently down for maintenance!')) if -e ($::lx_office_conf{paths}->{userspath} . "/nologin") && $script ne 'admin';
 203
 204     if ($script eq 'login' or $script eq 'admin') {
 205       $::form->{titlebar} = "Lx-Office " . $::locale->text('Version') . " $::form->{version}";
 206       ::run($session_result);
 207
 208     } else {
 209       show_error('login/password_error', 'session') if SL::Auth::SESSION_EXPIRED == $session_result;
 210       %::myconfig = $::auth->read_user($::form->{login});
 211
 212       show_error('login/password_error', 'password') unless $::myconfig{login};
 213
 214       $::locale = Locale->new($::myconfig{countrycode});
 215
 216       show_error('login/password_error', 'password') if SL::Auth::OK != $::auth->authenticate($::form->{login}, $::form->{password});
 217
 218       $::auth->store_credentials_in_session(login => $::form->{login}, password => $::form->{password});
 219       $::auth->create_or_refresh_session;
 220       $::auth->delete_session_value('FLASH');
 221       delete $::form->{password};
 222
 223       if ($action) {
 224         $::instance_conf->init;
 225
 226         map { $::form->{$_} = $::myconfig{$_} } qw(stylesheet charset)
 227           unless $action eq 'save' && $::form->{type} eq 'preferences';
 228
 229         $::form->set_standard_title;
 230         if ($routing_type eq 'old') {
 231           ::call_sub('::' . $::locale->findsub($action));
 232         } else {
 233           _run_controller($script_name, $action);
 234         }
 235       } else {
 236         $::form->error($::locale->text('action= not defined!'));
 237       }
 238     }
 239
 240     1;
 241   } or do {
 242     if ($EVAL_ERROR ne END_OF_REQUEST) {
 243       print STDERR $EVAL_ERROR;
 244       $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 245       eval { show_error('generic/error') };
 246     }
 247   };
 248
 249   # cleanup
 250   $::auth->save_session;
 251   $::auth->expire_sessions;
 252   $::auth->reset;
 253
 254   $::locale   = undef;
 255   $::form     = undef;
 256   $::myconfig = ();
 257   Form::disconnect_standard_dbh;
 258
 259   $::lxdebug->end_request;
 260
 261   $self->_watch_for_changed_files;
 262
 263   $::lxdebug->leave_sub;
 264 }
 265
 266 sub unrequire_bin_mozilla {
 267   my $self = shift;
 268   return unless $self->_interface_is_fcgi;
 269
 270   for (keys %INC) {
 271     next unless m#^bin/mozilla/#;
 272     next if /\bcommon.pl$/;
 273     next if /\binstallationcheck.pl$/;
 274     delete $INC{$_};
 275   }
 276 }
 277
 278 sub _interface_is_fcgi {
 279   my $self = shift;
 280   return $self->{interface} =~ m/^(?:fastcgi|fcgid|fcgi)$/;
 281 }
 282
 283 sub _route_request {
 284   my $script_name = shift;
 285
 286   return $script_name =~ m/dispatcher\.pl$/ ? ('old',        _route_dispatcher_request())
 287        : $script_name =~ m/controller\.pl/  ? ('controller', _route_controller_request())
 288        :                                      ('old',        $script_name, $::form->{action});
 289 }
 290
 291 sub _route_dispatcher_request {
 292   my $name_re = qr{[a-z]\w*};
 293   my ($script_name, $action);
 294
 295   eval {
 296     die "Unroutable request -- inavlid module name.\n" if !$::form->{M} || ($::form->{M} !~ m/^${name_re}$/);
 297     $script_name = $::form->{M} . '.pl';
 298
 299     if ($::form->{A}) {
 300       $action = $::form->{A};
 301
 302     } else {
 303       $action = first { m/^A_${name_re}$/ } keys %{ $::form };
 304       die "Unroutable request -- inavlid action name.\n" if !$action;
 305
 306       delete $::form->{$action};
 307       $action = substr $action, 2;
 308     }
 309
 310     delete @{$::form}{qw(M A)};
 311
 312     1;
 313   } or do {
 314     $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 315     show_error('generic/error');
 316   };
 317
 318   return ($script_name, $action);
 319 }
 320
 321 sub _route_controller_request {
 322   my ($controller, $action);
 323
 324   eval {
 325     $::form->{action}      =~ m|^ ( [A-Z] [A-Za-z0-9_]* ) / ( [a-z] [a-z0-9_]* ) $|x || die "Unroutable request -- inavlid controller/action.\n";
 326     ($controller, $action) =  ($1, $2);
 327     delete $::form->{action};
 328
 329     1;
 330   } or do {
 331     $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 332     show_error('generic/error');
 333   };
 334
 335   return ($controller, $action);
 336 }
 337
 338 sub _cache_file_modification_times {
 339   my ($self) = @_;
 340
 341   return unless $self->_interface_is_fcgi && $::lx_office_conf{debug}->{restart_fcgi_process_on_changes};
 342
 343   require File::Find;
 344   require POSIX;
 345
 346   my $wanted = sub {
 347     return unless $File::Find::name =~ m/\.(?:pm|f?pl|html|conf|conf\.default)$/;
 348     $fcgi_file_cache{ $File::Find::name } = (stat $File::Find::name)[9];
 349   };
 350
 351   my $cwd = POSIX::getcwd();
 352   File::Find::find($wanted, map { "${cwd}/${_}" } qw(config bin SL templates/webpages));
 353   map { my $name = "${cwd}/${_}"; $fcgi_file_cache{$name} = (stat $name)[9] } qw(admin.pl dispatcher.fpl);
 354 }
 355
 356 sub _watch_for_changed_files {
 357   my ($self) = @_;
 358
 359   return unless $self->_interface_is_fcgi && $::lx_office_conf{debug}->{restart_fcgi_process_on_changes};
 360
 361   my $ok = all { (stat($_))[9] == $fcgi_file_cache{$_} } keys %fcgi_file_cache;
 362   return if $ok;
 363   $::lxdebug->message(LXDebug::DEBUG1(), "Program modifications detected. Restarting.");
 364   exit;
 365 }
 366
 367 sub get_standard_filehandles {
 368   my $self = shift;
 369
 370   return $self->{interface} =~ m/f(?:ast)cgi/i ? $self->{request}->GetHandles() : (\*STDIN, \*STDOUT, \*STDERR);
 371 }
 372
 373 sub _init_environment {
 374   my %key_map = ( lib  => { name => 'PERL5LIB', append_path => 1 },
 375                   path => { name => 'PATH',     append_path => 1 },
 376                 );
 377   my $cfg     = $::lx_office_conf{environment} || {};
 378
 379   while (my ($key, $value) = each %{ $cfg }) {
 380     next unless $value;
 381
 382     my $info = $key_map{$key} || {};
 383     $key     = $info->{name}  || $key;
 384
 385     if ($info->{append_path}) {
 386       $value = ':' . $value unless $value =~ m/^:/ || !$ENV{$key};
 387       $value = $ENV{$key} . $value;
 388     }
 389
 390     $ENV{$key} = $value;
 391   }
 392 }
 393
 394 sub _check_for_old_config_files {
 395   my @old_files = grep { -f "config/${_}" } qw(authentication.pl console.conf lx-erp.conf lx-erp-local.conf);
 396   return unless @old_files;
 397
 398   $::form->{title}      = $::locale->text('Old configuration files');
 399   $::form->{stylesheet} = 'lx-office-erp.css';
 400   $::form->header;
 401   print $::form->parse_html_template('login/old_configuration_files', { FILES => \@old_files });
 402
 403   ::end_of_request();
 404 }
 405
 406 package main;
 407
 408 use strict;
 409
 410 sub end_of_request {
 411   die SL::Dispatcher->END_OF_REQUEST;
 412 }
 413
 414 1;