SL/Dispatcher.pm

   1 package SL::Dispatcher;
   2
   3 use strict;
   4
   5 BEGIN {
   6   unshift @INC, "modules/override"; # Use our own versions of various modules (e.g. YAML).
   7   push    @INC, "modules/fallback"; # Only use our own versions of modules if there's no system version.
   8 }
   9
  10 use CGI qw( -no_xhtml);
  11 use Config::Std;
  12 use DateTime;
  13 use Encode;
  14 use English qw(-no_match_vars);
  15 use File::Basename;
  16 use List::MoreUtils qw(all);
  17 use List::Util qw(first);
  18 use POSIX;
  19 use SL::Auth;
  20 use SL::Dispatcher::AuthHandler;
  21 use SL::LXDebug;
  22 use SL::LxOfficeConf;
  23 use SL::Locale;
  24 use SL::Common;
  25 use SL::Form;
  26 use SL::Helper::DateTime;
  27 use SL::InstanceConfiguration;
  28 use SL::Template::Plugin::HTMLFixes;
  29
  30 # Trailing new line is added so that Perl will not add the line
  31 # number 'die' was called in.
  32 use constant END_OF_REQUEST => "END-OF-REQUEST\n";
  33
  34 my %fcgi_file_cache;
  35
  36 sub new {
  37   my ($class, $interface) = @_;
  38
  39   my $self           = bless {}, $class;
  40   $self->{interface} = lc($interface || 'cgi');
  41   $self->{auth_handler} = SL::Dispatcher::AuthHandler->new;
  42
  43   return $self;
  44 }
  45
  46 sub interface_type {
  47   my ($self) = @_;
  48   return $self->{interface} eq 'cgi' ? 'CGI' : 'FastCGI';
  49 }
  50
  51 sub pre_request_checks {
  52   _check_for_old_config_files();
  53
  54   if (!$::auth->session_tables_present) {
  55     if ($::form->{script} eq 'admin.pl') {
  56       ::run();
  57       ::end_of_request();
  58     } else {
  59       show_error('login/auth_db_unreachable');
  60     }
  61   }
  62 }
  63
  64 sub show_error {
  65   $::lxdebug->enter_sub;
  66   my $template             = shift;
  67   my $error_type           = shift || '';
  68   my %params               = @_;
  69
  70   $::locale                = Locale->new($::lx_office_conf{system}->{language});
  71   $::form->{error}         = $::locale->text('The session is invalid or has expired.') if ($error_type eq 'session');
  72   $::form->{error}         = $::locale->text('Incorrect password!.')                   if ($error_type eq 'password');
  73   $::myconfig{countrycode} = $::lx_office_conf{system}->{language};
  74
  75   $::form->header;
  76   print $::form->parse_html_template($template, \%params);
  77   $::lxdebug->leave_sub;
  78
  79   ::end_of_request();
  80 }
  81
  82 sub pre_startup_setup {
  83   my ($self) = @_;
  84
  85   SL::LxOfficeConf->read;
  86
  87   eval {
  88     package main;
  89     require "bin/mozilla/common.pl";
  90     require "bin/mozilla/installationcheck.pl";
  91   } or die $EVAL_ERROR;
  92
  93   # canonial globals. if it's not here, chances are it will get refactored someday.
  94   {
  95     no warnings 'once';
  96     $::lxdebug     = LXDebug->new;
  97     $::auth        = SL::Auth->new;
  98     $::form        = undef;
  99     %::myconfig    = ();
 100     $::request     = undef;
 101   }
 102
 103   $SIG{__WARN__} = sub {
 104     $::lxdebug->warn(@_);
 105   };
 106
 107   $self->_cache_file_modification_times;
 108 }
 109
 110 sub pre_startup_checks {
 111   ::verify_installation();
 112 }
 113
 114 sub pre_startup {
 115   my ($self) = @_;
 116   $self->pre_startup_setup;
 117   $self->pre_startup_checks;
 118 }
 119
 120 sub require_main_code {
 121   $::lxdebug->enter_sub;
 122   my ($script, $suffix) = @_;
 123
 124   eval {
 125     package main;
 126     require "bin/mozilla/$script$suffix";
 127   } or die $EVAL_ERROR;
 128
 129   if (-f "bin/mozilla/custom_$script$suffix") {
 130     eval {
 131       package main;
 132       require "bin/mozilla/custom_$script$suffix";
 133     };
 134     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 135   }
 136   if ($::form->{login} && -f "bin/mozilla/$::form->{login}_$script") {
 137     eval {
 138       package main;
 139       require "bin/mozilla/$::form->{login}_$script";
 140     };
 141     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 142   }
 143   $::lxdebug->leave_sub;
 144 }
 145
 146 sub _require_controller {
 147   my $controller =  shift;
 148   $controller    =~ s|[^A-Za-z0-9_]||g;
 149   $controller    =  "SL/Controller/${controller}";
 150
 151   eval {
 152     package main;
 153     require "${controller}.pm";
 154   } or die $EVAL_ERROR;
 155 }
 156
 157 sub _run_controller {
 158   "SL::Controller::$_[0]"->new->_run_action($_[1]);
 159 }
 160
 161 sub handle_request {
 162   my $self         = shift;
 163   $self->{request} = shift;
 164
 165   $::lxdebug->enter_sub;
 166   $::lxdebug->begin_request;
 167
 168   my ($script, $path, $suffix, $script_name, $action, $routing_type);
 169
 170   $self->unrequire_bin_mozilla;
 171
 172   $::locale        = Locale->new($::lx_office_conf{system}->{language});
 173   $::form          = Form->new;
 174   $::instance_conf = SL::InstanceConfiguration->new;
 175   $::request       = { cgi => CGI->new({}) };
 176
 177   my $session_result = $::auth->restore_session;
 178   $::auth->create_or_refresh_session;
 179
 180   $::form->read_cgi_input;
 181
 182   eval { ($routing_type, $script_name, $action) = _route_request($ENV{SCRIPT_NAME}); 1; } or return;
 183
 184   if ($routing_type eq 'old') {
 185     $::form->{action}  =  lc $::form->{action};
 186     $::form->{action}  =~ s/( |-|,|\#)/_/g;
 187
 188    ($script, $path, $suffix) = fileparse($script_name, ".pl");
 189     require_main_code($script, $suffix);
 190
 191     $::form->{script} = $script . $suffix;
 192
 193   } else {
 194     _require_controller($script_name);
 195     $::form->{script} = "controller.pl";
 196   }
 197
 198   eval {
 199     pre_request_checks();
 200
 201     $::form->error($::locale->text('System currently down for maintenance!')) if -e ($::lx_office_conf{paths}->{userspath} . "/nologin") && $script ne 'admin';
 202
 203     if ($script eq 'login' or $script eq 'admin') {
 204       $::form->{titlebar} = "Lx-Office " . $::locale->text('Version') . " $::form->{version}";
 205       ::run($session_result);
 206
 207     } else {
 208       show_error('login/password_error', 'session') if SL::Auth::SESSION_EXPIRED == $session_result;
 209
 210       my $auth_level = $self->{auth_handler}->handle(
 211         routing_type => $routing_type,
 212         script       => $script,
 213         controller   => $script_name,
 214         action       => $action,
 215       );
 216
 217       delete @{ $::form }{ grep { m/^\{AUTH\}/ } keys %{ $::form } };
 218
 219       if ($action) {
 220         $::instance_conf->init if $auth_level eq 'user';
 221
 222         map { $::form->{$_} = $::myconfig{$_} } qw(charset)
 223           unless $action eq 'save' && $::form->{type} eq 'preferences';
 224
 225         $::form->set_standard_title;
 226         if ($routing_type eq 'old') {
 227           ::call_sub('::' . $::locale->findsub($action));
 228         } else {
 229           _run_controller($script_name, $action);
 230         }
 231       } else {
 232         $::form->error($::locale->text('action= not defined!'));
 233       }
 234     }
 235
 236     1;
 237   } or do {
 238     if ($EVAL_ERROR ne END_OF_REQUEST) {
 239       print STDERR $EVAL_ERROR;
 240       $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 241       eval { show_error('generic/error') };
 242     }
 243   };
 244
 245   # cleanup
 246   $::auth->save_session;
 247   $::auth->expire_sessions;
 248   $::auth->reset;
 249
 250   $::locale   = undef;
 251   $::form     = undef;
 252   $::myconfig = ();
 253   $::request  = undef;
 254   Form::disconnect_standard_dbh;
 255
 256   $::lxdebug->end_request;
 257
 258   $self->_watch_for_changed_files;
 259
 260   $::lxdebug->leave_sub;
 261 }
 262
 263 sub unrequire_bin_mozilla {
 264   my $self = shift;
 265   return unless $self->_interface_is_fcgi;
 266
 267   for (keys %INC) {
 268     next unless m#^bin/mozilla/#;
 269     next if /\bcommon.pl$/;
 270     next if /\binstallationcheck.pl$/;
 271     delete $INC{$_};
 272   }
 273 }
 274
 275 sub _interface_is_fcgi {
 276   my $self = shift;
 277   return $self->{interface} =~ m/^(?:fastcgi|fcgid|fcgi)$/;
 278 }
 279
 280 sub _route_request {
 281   my $script_name = shift;
 282
 283   return $script_name =~ m/dispatcher\.pl$/ ? ('old',        _route_dispatcher_request())
 284        : $script_name =~ m/controller\.pl/  ? ('controller', _route_controller_request())
 285        :                                      ('old',        $script_name, $::form->{action});
 286 }
 287
 288 sub _route_dispatcher_request {
 289   my $name_re = qr{[a-z]\w*};
 290   my ($script_name, $action);
 291
 292   eval {
 293     die "Unroutable request -- inavlid module name.\n" if !$::form->{M} || ($::form->{M} !~ m/^${name_re}$/);
 294     $script_name = $::form->{M} . '.pl';
 295
 296     if ($::form->{A}) {
 297       $action = $::form->{A};
 298
 299     } else {
 300       $action = first { m/^A_${name_re}$/ } keys %{ $::form };
 301       die "Unroutable request -- inavlid action name.\n" if !$action;
 302
 303       delete $::form->{$action};
 304       $action = substr $action, 2;
 305     }
 306
 307     delete @{$::form}{qw(M A)};
 308
 309     1;
 310   } or do {
 311     $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 312     show_error('generic/error');
 313   };
 314
 315   return ($script_name, $action);
 316 }
 317
 318 sub _route_controller_request {
 319   my ($controller, $action);
 320
 321   eval {
 322     $::form->{action}      =~ m|^ ( [A-Z] [A-Za-z0-9_]* ) / ( [a-z] [a-z0-9_]* ) $|x || die "Unroutable request -- inavlid controller/action.\n";
 323     ($controller, $action) =  ($1, $2);
 324     delete $::form->{action};
 325
 326     1;
 327   } or do {
 328     $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 329     show_error('generic/error');
 330   };
 331
 332   return ($controller, $action);
 333 }
 334
 335 sub _cache_file_modification_times {
 336   my ($self) = @_;
 337
 338   return unless $self->_interface_is_fcgi && $::lx_office_conf{debug}->{restart_fcgi_process_on_changes};
 339
 340   require File::Find;
 341   require POSIX;
 342
 343   my $wanted = sub {
 344     return unless $File::Find::name =~ m/\.(?:pm|f?pl|html|conf|conf\.default)$/;
 345     $fcgi_file_cache{ $File::Find::name } = (stat $File::Find::name)[9];
 346   };
 347
 348   my $cwd = POSIX::getcwd();
 349   File::Find::find($wanted, map { "${cwd}/${_}" } qw(config bin SL templates/webpages));
 350   map { my $name = "${cwd}/${_}"; $fcgi_file_cache{$name} = (stat $name)[9] } qw(admin.pl dispatcher.fpl);
 351 }
 352
 353 sub _watch_for_changed_files {
 354   my ($self) = @_;
 355
 356   return unless $self->_interface_is_fcgi && $::lx_office_conf{debug}->{restart_fcgi_process_on_changes};
 357
 358   my $ok = all { (stat($_))[9] == $fcgi_file_cache{$_} } keys %fcgi_file_cache;
 359   return if $ok;
 360   $::lxdebug->message(LXDebug::DEBUG1(), "Program modifications detected. Restarting.");
 361   exit;
 362 }
 363
 364 sub get_standard_filehandles {
 365   my $self = shift;
 366
 367   return $self->{interface} =~ m/f(?:ast)cgi/i ? $self->{request}->GetHandles() : (\*STDIN, \*STDOUT, \*STDERR);
 368 }
 369
 370 sub _check_for_old_config_files {
 371   my @old_files = grep { -f "config/${_}" } qw(authentication.pl console.conf lx-erp.conf lx-erp-local.conf);
 372   return unless @old_files;
 373
 374   $::form->{title}      = $::locale->text('Old configuration files');
 375   $::form->header;
 376   print $::form->parse_html_template('login/old_configuration_files', { FILES => \@old_files });
 377
 378   ::end_of_request();
 379 }
 380
 381 package main;
 382
 383 use strict;
 384
 385 sub end_of_request {
 386   die SL::Dispatcher->END_OF_REQUEST;
 387 }
 388
 389 1;