SL/Dispatcher.pm

   1 package SL::Dispatcher;
   2
   3 use strict;
   4
   5 BEGIN {
   6   unshift @INC, "modules/override"; # Use our own versions of various modules (e.g. YAML).
   7   push    @INC, "modules/fallback"; # Only use our own versions of modules if there's no system version.
   8   push    @INC, "SL";               # FCGI won't find modules that are not properly named. Help it by inclduging SL
   9 }
  10
  11 use CGI qw( -no_xhtml);
  12 use English qw(-no_match_vars);
  13 use SL::Auth;
  14 use SL::LXDebug;
  15 use SL::Locale;
  16 use SL::Common;
  17 use Form;
  18 use List::Util qw(first);
  19 use Moose;
  20 use Rose::DB;
  21 use Rose::DB::Object;
  22 use File::Basename;
  23
  24 # Trailing new line is added so that Perl will not add the line
  25 # number 'die' was called in.
  26 use constant END_OF_REQUEST => "END-OF-REQUEST\n";
  27
  28 sub pre_request_checks {
  29   show_error('login/auth_db_unreachable') unless $::auth->session_tables_present;
  30   $::auth->expire_sessions;
  31 }
  32
  33 sub show_error {
  34   $::lxdebug->enter_sub;
  35   my $template             = shift;
  36   my $error_type           = shift || '';
  37
  38   $::locale                = Locale->new($::language);
  39   $::form->{error}         = $::locale->text('The session is invalid or has expired.') if ($error_type eq 'session');
  40   $::form->{error}         = $::locale->text('Incorrect password!.')                   if ($error_type eq 'password');
  41   $::myconfig{countrycode} = $::language;
  42   $::form->{stylesheet}    = 'css/lx-office-erp.css';
  43
  44   $::form->header;
  45   print $::form->parse_html_template($template);
  46   $::lxdebug->leave_sub;
  47
  48   ::end_of_request();
  49 }
  50
  51 sub pre_startup_setup {
  52   eval {
  53     package main;
  54     require "config/lx-erp.conf";
  55   };
  56   eval {
  57     package main;
  58     require "config/lx-erp-local.conf";
  59   } if -f "config/lx-erp-local.conf";
  60
  61   eval {
  62     package main;
  63     require "bin/mozilla/common.pl";
  64     require "bin/mozilla/installationcheck.pl";
  65   } or die $EVAL_ERROR;
  66
  67   # dummy globals
  68   {
  69     no warnings 'once';
  70     $::userspath  = "users";
  71     $::templates  = "templates";
  72     $::memberfile = "users/members";
  73     $::sendmail   = "| /usr/sbin/sendmail -t";
  74     $::lxdebug    = LXDebug->new;
  75     $::auth       = SL::Auth->new;
  76     %::myconfig   = ();
  77   }
  78 }
  79
  80 sub pre_startup_checks {
  81   ::verify_installation();
  82 }
  83
  84 sub pre_startup {
  85   pre_startup_setup();
  86   pre_startup_checks();
  87 }
  88
  89 sub require_main_code {
  90   my ($script, $suffix) = @_;
  91
  92   eval {
  93     package main;
  94     require "bin/mozilla/$script$suffix";
  95   } or die $EVAL_ERROR;
  96
  97   if (-f "bin/mozilla/custom_$script$suffix") {
  98     eval {
  99       package main;
 100       require "bin/mozilla/custom_$script$suffix";
 101     };
 102     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 103   }
 104   if ($::form->{login} && -f "bin/mozilla/$::form->{login}_$::form->{script}") {
 105     eval {
 106       package main;
 107       require "bin/mozilla/$::form->{login}_$::form->{script}";
 108     };
 109     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 110   }
 111 }
 112
 113 sub handle_request {
 114   $::lxdebug->enter_sub;
 115   $::lxdebug->begin_request;
 116
 117   my $interface = lc(shift || 'cgi');
 118   my ($script_name, $action);
 119
 120   if ($interface =~ m/^(?:fastcgi|fcgid|fcgi)$/) {
 121     $script_name = $ENV{SCRIPT_NAME};
 122     unrequire_bin_mozilla();
 123
 124   } else {
 125     $script_name = $0;
 126   }
 127
 128   $::cgi    = CGI->new('');
 129   $::locale = Locale->new($::language);
 130   $::form   = Form->new;
 131
 132   eval { ($script_name, $action) = _route_request($script_name); 1; } or return;
 133
 134   my ($script, $path, $suffix) = fileparse($script_name, ".pl");
 135   require_main_code($script, $suffix);
 136
 137   $::form->{script} = $script . $suffix;
 138
 139   pre_request_checks();
 140
 141   eval {
 142     if ($script eq 'login' or $script eq 'admin' or $script eq 'kopf') {
 143       $::form->{titlebar} = "Lx-Office " . $::locale->text('Version') . " $::form->{version}";
 144       ::run($::auth->restore_session);
 145
 146     } elsif ($action) {
 147       # copy from am.pl routines
 148       $::form->error($::locale->text('System currently down for maintenance!')) if -e "$main::userspath/nologin" && $script ne 'admin';
 149
 150       my $session_result = $::auth->restore_session;
 151
 152       show_error('login/password_error', 'session') if SL::Auth::SESSION_EXPIRED == $session_result;
 153       %::myconfig = $::auth->read_user($::form->{login});
 154
 155       show_error('login/password_error', 'password') unless $::myconfig{login};
 156
 157       $::locale = Locale->new($::myconfig{countrycode});
 158
 159       show_error('login/password_error', 'password') if SL::Auth::OK != $::auth->authenticate($::form->{login}, $::form->{password}, 0);
 160
 161       $::auth->set_session_value('login', $::form->{login}, 'password', $::form->{password});
 162       $::auth->create_or_refresh_session;
 163       delete $::form->{password};
 164
 165       map { $::form->{$_} = $::myconfig{$_} } qw(stylesheet charset)
 166         unless $action eq 'save' && $::form->{type} eq 'preferences';
 167
 168       $::form->set_standard_title;
 169       ::call_sub('::' . $::locale->findsub($action));
 170
 171     } else {
 172       $::form->error($::locale->text('action= not defined!'));
 173     }
 174
 175     1;
 176   } or do {
 177     if ($EVAL_ERROR ne END_OF_REQUEST) {
 178       $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 179       eval { show_error('generic/error') };
 180     }
 181   };
 182
 183   # cleanup
 184   $::locale   = undef;
 185   $::form     = undef;
 186   $::myconfig = ();
 187   Form::disconnect_standard_dbh();
 188
 189   $::lxdebug->end_request;
 190   $::lxdebug->leave_sub;
 191 }
 192
 193 sub unrequire_bin_mozilla {
 194   for (keys %INC) {
 195     next unless m#^bin/mozilla/#;
 196     next if /\bcommon.pl$/;
 197     next if /\binstallationcheck.pl$/;
 198     delete $INC{$_};
 199   }
 200 }
 201
 202 sub _route_request {
 203   my $script_name = shift;
 204
 205   return $script_name =~ m/dispatcher\.pl$/ ? _route_dispatcher_request() : ($script_name, $::form->{action});
 206 }
 207
 208 sub _route_dispatcher_request {
 209   my $action_re = '[a-z0-9_\-]+';
 210   my ($script_name, $action);
 211
 212   eval {
 213     die "Unroutable request -- inavlid module name.\n" if !$::form->{M} || ($::form->{M} !~ m/^$action_re$/);
 214     $script_name = $::form->{M} . '.pl';
 215
 216     if ($::form->{A}) {
 217       $action = $::form->{A};
 218
 219     } else {
 220       $action = first { m/^A_${action_re}$/ } keys %{ $::form };
 221       die "Unroutable request -- inavlid action name.\n" if !$action;
 222
 223       delete $::form->{$action};
 224       $action = substr $action, 2;
 225     }
 226
 227     delete @{$::form}{qw(M A)};
 228
 229     1;
 230   } or do {
 231     $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 232     show_error('generic/error');
 233   };
 234
 235   return ($script_name, $action);
 236 }
 237
 238 package main;
 239
 240 use strict;
 241
 242 sub end_of_request {
 243   die SL::Dispatcher->END_OF_REQUEST;
 244 }
 245
 246 1;