SL/Dispatcher.pm

   1 package SL::Dispatcher;
   2
   3 use strict;
   4
   5 # Force scripts/locales.pl to parse these templates:
   6 #   parse_html_template('login_screen/auth_db_unreachable')
   7 #   parse_html_template('login_screen/user_login')
   8 #   parse_html_template('generic/error')
   9
  10 BEGIN {
  11   use SL::System::Process;
  12   my $exe_dir = SL::System::Process::exe_dir;
  13
  14   unshift @INC, "${exe_dir}/modules/override"; # Use our own versions of various modules (e.g. YAML).
  15   push    @INC, "${exe_dir}/modules/fallback"; # Only use our own versions of modules if there's no system version.
  16   unshift @INC, $exe_dir;
  17 }
  18
  19 use Carp;
  20 use CGI qw( -no_xhtml);
  21 use Config::Std;
  22 use DateTime;
  23 use Encode;
  24 use English qw(-no_match_vars);
  25 use File::Basename;
  26 use List::MoreUtils qw(all);
  27 use List::Util qw(first);
  28 use POSIX;
  29 use SL::ArchiveZipFixes;
  30 use SL::Auth;
  31 use SL::Dispatcher::AuthHandler;
  32 use SL::LXDebug;
  33 use SL::LxOfficeConf;
  34 use SL::Locale;
  35 use SL::ClientJS;
  36 use SL::Common;
  37 use SL::Form;
  38 use SL::Helper::DateTime;
  39 use SL::InstanceConfiguration;
  40 use SL::Template::Plugin::HTMLFixes;
  41
  42 # Trailing new line is added so that Perl will not add the line
  43 # number 'die' was called in.
  44 use constant END_OF_REQUEST => "END-OF-REQUEST\n";
  45
  46 my %fcgi_file_cache;
  47
  48 sub new {
  49   my ($class, $interface) = @_;
  50
  51   my $self           = bless {}, $class;
  52   $self->{interface} = lc($interface || 'cgi');
  53   $self->{auth_handler} = SL::Dispatcher::AuthHandler->new;
  54
  55   SL::ArchiveZipFixes->apply_fixes;
  56
  57   return $self;
  58 }
  59
  60 sub interface_type {
  61   my ($self) = @_;
  62   return $self->{interface} eq 'cgi' ? 'CGI' : 'FastCGI';
  63 }
  64
  65 sub is_admin_request {
  66   my %params = @_;
  67   return ($params{script} eq 'admin.pl') || (($params{routing_type} eq 'controller') && ($params{script_name} eq 'Admin'));
  68 }
  69
  70 sub pre_request_checks {
  71   my (%params) = @_;
  72
  73   _check_for_old_config_files();
  74
  75   if (!$::auth->session_tables_present && !is_admin_request(%params)) {
  76     show_error('login_screen/auth_db_unreachable');
  77   }
  78
  79   if ($::request->type !~ m/^ (?: html | js | json ) $/x) {
  80     die $::locale->text("Invalid request type '#1'", $::request->type);
  81   }
  82 }
  83
  84 sub pre_request_initialization {
  85   my ($self, %params) = @_;
  86
  87   $self->unrequire_bin_mozilla;
  88
  89   $::locale        = Locale->new($::lx_office_conf{system}->{language});
  90   $::form          = Form->new;
  91   $::instance_conf = SL::InstanceConfiguration->new;
  92   $::request       = SL::Request->new(
  93     cgi            => CGI->new({}),
  94     layout         => SL::Layout::None->new,
  95   );
  96
  97   my $session_result = $::auth->restore_session;
  98   $::auth->create_or_refresh_session;
  99
 100   if ($params{client}) {
 101     $::auth->set_client($params{client}) || die("cannot find client " . $params{client});
 102
 103     if ($params{login}) {
 104       die "cannot find user " . $params{login}            unless %::myconfig = $::auth->read_user(login => $params{login});
 105       die "cannot find locale for user " . $params{login} unless $::locale   = Locale->new($::myconfig{countrycode});
 106
 107       $::form->{login} = $params{login}; # normaly implicit at login
 108     }
 109   }
 110
 111   return $session_result;
 112 }
 113
 114 sub render_error_ajax {
 115   my ($error) = @_;
 116
 117   SL::ClientJS->new
 118     ->error($error)
 119     ->render(SL::Controller::Base->new);
 120 }
 121
 122 sub show_error {
 123   $::lxdebug->enter_sub;
 124   my $template             = shift;
 125   my $error_type           = shift || '';
 126   my %params               = @_;
 127
 128   $::myconfig{countrycode} = delete($params{countrycode}) || $::lx_office_conf{system}->{language};
 129   $::locale                = Locale->new($::myconfig{countrycode});
 130   $::form->{error}         = $::locale->text('The session is invalid or has expired.') if ($error_type eq 'session');
 131   $::form->{error}         = $::locale->text('Incorrect password!')                    if ($error_type eq 'password');
 132   $::form->{error}         = $::locale->text('The action is missing or invalid.')      if ($error_type eq 'action');
 133
 134   return render_error_ajax($::form->{error}) if $::request->is_ajax;
 135
 136   $::form->header;
 137   print $::form->parse_html_template($template, \%params);
 138   $::lxdebug->leave_sub;
 139
 140   ::end_of_request();
 141 }
 142
 143 sub pre_startup_setup {
 144   my ($self) = @_;
 145
 146   SL::LxOfficeConf->read;
 147
 148   eval {
 149     package main;
 150     require "bin/mozilla/common.pl";
 151     require "bin/mozilla/installationcheck.pl";
 152   } or die $EVAL_ERROR;
 153
 154   # canonial globals. if it's not here, chances are it will get refactored someday.
 155   {
 156     no warnings 'once';
 157     $::lxdebug     = LXDebug->new;
 158     $::auth        = SL::Auth->new;
 159     $::form        = undef;
 160     %::myconfig    = ();
 161     $::request     = undef;
 162   }
 163
 164   $SIG{__WARN__} = sub {
 165     $::lxdebug->warn(@_);
 166   };
 167
 168   $SIG{__DIE__} = sub { Carp::confess( @_ ) } if $::lx_office_conf{debug}->{backtrace_on_die};
 169
 170   $self->_cache_file_modification_times;
 171 }
 172
 173 sub pre_startup_checks {
 174   ::verify_installation();
 175 }
 176
 177 sub pre_startup {
 178   my ($self) = @_;
 179   $self->pre_startup_setup;
 180   $self->pre_startup_checks;
 181 }
 182
 183 sub require_main_code {
 184   $::lxdebug->enter_sub;
 185   my ($script, $suffix) = @_;
 186
 187   eval {
 188     package main;
 189     require "bin/mozilla/$script$suffix";
 190   } or die $EVAL_ERROR;
 191
 192   if (-f "bin/mozilla/custom_$script$suffix") {
 193     eval {
 194       package main;
 195       require "bin/mozilla/custom_$script$suffix";
 196     };
 197     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 198   }
 199   if ($::form->{login} && -f "bin/mozilla/$::form->{login}_$script") {
 200     eval {
 201       package main;
 202       require "bin/mozilla/$::form->{login}_$script";
 203     };
 204     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 205   }
 206   $::lxdebug->leave_sub;
 207 }
 208
 209 sub _require_controller {
 210   my $controller =  shift;
 211   $controller    =~ s|[^A-Za-z0-9_]||g;
 212   $controller    =  "SL/Controller/${controller}";
 213
 214   eval {
 215     package main;
 216     require "${controller}.pm";
 217   } or die $EVAL_ERROR;
 218 }
 219
 220 sub _run_controller {
 221   "SL::Controller::$_[0]"->new->_run_action($_[1]);
 222 }
 223
 224 sub handle_request {
 225   my $self         = shift;
 226   $self->{request} = shift;
 227
 228   $::lxdebug->enter_sub;
 229   $::lxdebug->begin_request;
 230
 231   my ($script, $path, $suffix, $script_name, $action, $routing_type);
 232
 233   my $session_result = $self->pre_request_initialization;
 234
 235   $::form->read_cgi_input;
 236
 237   my %routing;
 238   eval { %routing = $self->_route_request($ENV{SCRIPT_NAME}); 1; } or return;
 239   ($routing_type, $script_name, $action) = @routing{qw(type controller action)};
 240   $::lxdebug->log_request($routing_type, $script_name, $action);
 241
 242   $::request->type(lc($routing{request_type} || 'html'));
 243
 244   if ($routing_type eq 'old') {
 245     $::form->{action}  =  lc $::form->{action};
 246     $::form->{action}  =~ s/( |-|,|\#)/_/g;
 247
 248    ($script, $path, $suffix) = fileparse($script_name, ".pl");
 249     require_main_code($script, $suffix) unless $script eq 'admin';
 250
 251     $::form->{script} = $script . $suffix;
 252
 253   } else {
 254     _require_controller($script_name);
 255     $::form->{script} = "controller.pl";
 256   }
 257
 258   eval {
 259     pre_request_checks(script => $script, action => $action, routing_type => $routing_type, script_name => $script_name);
 260
 261     if (   SL::System::InstallationLock->is_locked
 262         && !is_admin_request(script => $script, script_name => $script_name, routing_type => $routing_type)) {
 263       $::form->error($::locale->text('System currently down for maintenance!'));
 264     }
 265
 266     # For compatibility with a lot of database upgrade scripts etc:
 267     # Re-write request to old 'login.pl?action=login' to new
 268     # 'LoginScreen' controller. Make sure to load its code!
 269     if (($script eq 'login') && ($action eq 'login')) {
 270       ($routing_type, $script, $script_name, $action) = qw(controller controller LoginScreen login);
 271       _require_controller('LoginScreen');
 272     }
 273
 274     if (   (($script eq 'login') && !$action)
 275         || ($script eq 'admin')
 276         || (SL::Auth::SESSION_EXPIRED() == $session_result)) {
 277       $self->redirect_to_login(script => $script, error => 'session');
 278
 279     }
 280
 281     my %auth_result = $self->{auth_handler}->handle(
 282       routing_type => $routing_type,
 283       script       => $script,
 284       controller   => $script_name,
 285       action       => $action,
 286     );
 287
 288     ::end_of_request() unless $auth_result{auth_ok};
 289
 290     delete @{ $::form }{ grep { m/^\{AUTH\}/ } keys %{ $::form } } unless $auth_result{keep_auth_vars};
 291
 292     if ($action) {
 293       $::form->set_standard_title;
 294       if ($routing_type eq 'old') {
 295         ::call_sub('::' . $::locale->findsub($action));
 296       } else {
 297         _run_controller($script_name, $action);
 298       }
 299     } else {
 300       $::form->error($::locale->text('action= not defined!'));
 301     }
 302
 303     1;
 304   } or do {
 305     if (substr($EVAL_ERROR, 0, length(END_OF_REQUEST())) ne END_OF_REQUEST()) {
 306       my $error = $EVAL_ERROR;
 307       print STDERR $error;
 308
 309       if ($::request->is_ajax) {
 310         eval { render_error_ajax($error) };
 311       } else {
 312         $::form->{label_error} = $::request->{cgi}->pre($error);
 313         chdir SL::System::Process::exe_dir;
 314         eval { show_error('generic/error') };
 315       }
 316     }
 317   };
 318
 319   $::form->footer;
 320
 321   # cleanup
 322   $::auth->save_session;
 323   $::auth->expire_sessions;
 324   $::auth->reset;
 325
 326   $::locale   = undef;
 327   $::form     = undef;
 328   $::myconfig = ();
 329   $::request  = undef;
 330   Form::disconnect_standard_dbh;
 331
 332   $::lxdebug->end_request;
 333
 334   $self->_watch_for_changed_files;
 335
 336   $::lxdebug->leave_sub;
 337 }
 338
 339 sub redirect_to_login {
 340   my ($self, %params) = @_;
 341   my $action          = ($params{script} // '') =~ m/^admin/i ? 'Admin/login' : 'LoginScreen/user_login';
 342   $action            .= '&error=' . $params{error} if $params{error};
 343
 344   print $::request->cgi->redirect("controller.pl?action=${action}");
 345   ::end_of_request();
 346 }
 347
 348 sub unrequire_bin_mozilla {
 349   my $self = shift;
 350   return unless $self->_interface_is_fcgi;
 351
 352   for (keys %INC) {
 353     next unless m#^bin/mozilla/#;
 354     next if /\bcommon.pl$/;
 355     next if /\binstallationcheck.pl$/;
 356     delete $INC{$_};
 357   }
 358 }
 359
 360 sub _interface_is_fcgi {
 361   my $self = shift;
 362   return $self->{interface} =~ m/^(?:fastcgi|fcgid|fcgi)$/;
 363 }
 364
 365 sub _route_request {
 366   my ($self, $script_name) = @_;
 367
 368   return $script_name =~ m/dispatcher\.pl$/ ? (type => 'old',        $self->_route_dispatcher_request)
 369        : $script_name =~ m/controller\.pl/  ? (type => 'controller', $self->_route_controller_request)
 370        :                                      (type => 'old',        controller => $script_name, action => $::form->{action});
 371 }
 372
 373 sub _route_dispatcher_request {
 374   my ($self)  = @_;
 375   my $name_re = qr{[a-z]\w*};
 376   my ($script_name, $action);
 377
 378   eval {
 379     die "Unroutable request -- invalid module name.\n" if !$::form->{M} || ($::form->{M} !~ m/^${name_re}$/);
 380     $script_name = $::form->{M} . '.pl';
 381
 382     if ($::form->{A}) {
 383       $action = $::form->{A};
 384
 385     } else {
 386       $action = first { m/^A_${name_re}$/ } keys %{ $::form };
 387       die "Unroutable request -- invalid action name.\n" if !$action;
 388
 389       delete $::form->{$action};
 390       $action = substr $action, 2;
 391     }
 392
 393     delete @{$::form}{qw(M A)};
 394
 395     1;
 396   } or do {
 397     $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 398     show_error('generic/error');
 399   };
 400
 401   return (controller => $script_name, action => $action);
 402 }
 403
 404 sub _route_controller_request {
 405   my ($self) = @_;
 406   my ($controller, $action, $request_type);
 407
 408   eval {
 409     # Redirect simple requests to controller.pl without any GET/POST
 410     # param to the login page.
 411     $self->redirect_to_login(error => 'action') if !$::form->{action};
 412
 413     # Show an error if the »action« parameter doesn't match the
 414     # pattern »Controller/action«.
 415     $::form->{action}      =~ m|^ ( [A-Z] [A-Za-z0-9_]* ) / ( [a-z] [a-z0-9_]* ) ( \. [a-zA-Z]+ )? $|x || die "Unroutable request -- invalid controller/action.\n";
 416     ($controller, $action) =  ($1, $2);
 417     delete $::form->{action};
 418
 419     $request_type = $3 ? lc(substr($3, 1)) : 'html';
 420
 421     1;
 422   } or do {
 423     $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 424     show_error('generic/error');
 425   };
 426
 427   return (controller => $controller, action => $action, request_type => $request_type);
 428 }
 429
 430 sub _cache_file_modification_times {
 431   my ($self) = @_;
 432
 433   return unless $self->_interface_is_fcgi && $::lx_office_conf{debug}->{restart_fcgi_process_on_changes};
 434
 435   require File::Find;
 436   require POSIX;
 437
 438   my $wanted = sub {
 439     return unless $File::Find::name =~ m/\.(?:pm|f?pl|html|conf|conf\.default)$/;
 440     $fcgi_file_cache{ $File::Find::name } = (stat $File::Find::name)[9];
 441   };
 442
 443   my $cwd = POSIX::getcwd();
 444   File::Find::find($wanted, map { "${cwd}/${_}" } qw(config bin SL templates/webpages));
 445   map { my $name = "${cwd}/${_}"; $fcgi_file_cache{$name} = (stat $name)[9] } qw(admin.pl dispatcher.fpl);
 446 }
 447
 448 sub _watch_for_changed_files {
 449   my ($self) = @_;
 450
 451   return unless $self->_interface_is_fcgi && $::lx_office_conf{debug}->{restart_fcgi_process_on_changes};
 452
 453   my $ok = all { (stat($_))[9] == $fcgi_file_cache{$_} } keys %fcgi_file_cache;
 454   return if $ok;
 455   $::lxdebug->message(LXDebug::DEBUG1(), "Program modifications detected. Restarting.");
 456   exit;
 457 }
 458
 459 sub get_standard_filehandles {
 460   my $self = shift;
 461
 462   return $self->{interface} =~ m/f(?:ast)cgi/i ? $self->{request}->GetHandles() : (\*STDIN, \*STDOUT, \*STDERR);
 463 }
 464
 465 sub _check_for_old_config_files {
 466   my @old_files = grep { -f "config/${_}" } qw(authentication.pl console.conf lx-erp.conf lx-erp-local.conf);
 467   return unless @old_files;
 468
 469   $::form->{title} = $::locale->text('Old configuration files');
 470   $::form->header;
 471   print $::form->parse_html_template('login_screen/old_configuration_files', { FILES => \@old_files });
 472
 473   ::end_of_request();
 474 }
 475
 476 package main;
 477
 478 use strict;
 479
 480 sub end_of_request {
 481   die SL::Dispatcher->END_OF_REQUEST;
 482 }
 483
 484 1;