SL/Dispatcher.pm

   1 package SL::Dispatcher;
   2
   3 use strict;
   4
   5 BEGIN {
   6   unshift @INC, "modules/override"; # Use our own versions of various modules (e.g. YAML).
   7   push    @INC, "modules/fallback"; # Only use our own versions of modules if there's no system version.
   8   push    @INC, "SL";               # FCGI won't find modules that are not properly named. Help it by inclduging SL
   9 }
  10
  11 use CGI qw( -no_xhtml);
  12 use English qw(-no_match_vars);
  13 use SL::Auth;
  14 use SL::LXDebug;
  15 use SL::Locale;
  16 use SL::Common;
  17 use Form;
  18 use List::Util qw(first);
  19 use Moose;
  20 use Rose::DB;
  21 use Rose::DB::Object;
  22 use File::Basename;
  23
  24 # Trailing new line is added so that Perl will not add the line
  25 # number 'die' was called in.
  26 use constant END_OF_REQUEST => "END-OF-REQUEST\n";
  27
  28 sub pre_request_checks {
  29   show_error('login/auth_db_unreachable') unless $::auth->session_tables_present;
  30   $::auth->expire_sessions;
  31 }
  32
  33 sub show_error {
  34   $::lxdebug->enter_sub;
  35   my $template             = shift;
  36   my $error_type           = shift || '';
  37
  38   $::locale                = Locale->new($::language);
  39   $::form->{error}         = $::locale->text('The session is invalid or has expired.') if ($error_type eq 'session');
  40   $::form->{error}         = $::locale->text('Incorrect password!.')                   if ($error_type eq 'password');
  41   $::myconfig{countrycode} = $::language;
  42   $::form->{stylesheet}    = 'css/lx-office-erp.css';
  43
  44   $::form->header;
  45   print $::form->parse_html_template($template);
  46   $::lxdebug->leave_sub;
  47
  48   ::end_of_request();
  49 }
  50
  51 sub pre_startup_setup {
  52   eval {
  53     package main;
  54     require "config/lx-erp.conf";
  55   };
  56   eval {
  57     package main;
  58     require "config/lx-erp-local.conf";
  59   } if -f "config/lx-erp-local.conf";
  60
  61   eval {
  62     package main;
  63     require "bin/mozilla/common.pl";
  64     require "bin/mozilla/installationcheck.pl";
  65   } or die $EVAL_ERROR;
  66
  67   # dummy globals
  68   {
  69     no warnings 'once';
  70     $::userspath  = "users";
  71     $::templates  = "templates";
  72     $::memberfile = "users/members";
  73     $::menufile   = "menu.ini";
  74     $::sendmail   = "| /usr/sbin/sendmail -t";
  75     $::lxdebug    = LXDebug->new;
  76     $::auth       = SL::Auth->new;
  77     %::myconfig   = ();
  78   }
  79 }
  80
  81 sub pre_startup_checks {
  82   ::verify_installation();
  83 }
  84
  85 sub pre_startup {
  86   pre_startup_setup();
  87   pre_startup_checks();
  88 }
  89
  90 sub require_main_code {
  91   my ($script, $suffix) = @_;
  92
  93   eval {
  94     package main;
  95     require "bin/mozilla/$script$suffix";
  96   } or die $EVAL_ERROR;
  97
  98   if (-f "bin/mozilla/custom_$script$suffix") {
  99     eval {
 100       package main;
 101       require "bin/mozilla/custom_$script$suffix";
 102     };
 103     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 104   }
 105   if ($::form->{login} && -f "bin/mozilla/$::form->{login}_$::form->{script}") {
 106     eval {
 107       package main;
 108       require "bin/mozilla/$::form->{login}_$::form->{script}";
 109     };
 110     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 111   }
 112 }
 113
 114 sub handle_request {
 115   $::lxdebug->enter_sub;
 116   $::lxdebug->begin_request;
 117
 118   my $interface = lc(shift || 'cgi');
 119   my ($script_name, $action);
 120
 121   if ($interface =~ m/^(?:fastcgi|fcgid|fcgi)$/) {
 122     $script_name = $ENV{SCRIPT_NAME};
 123     unrequire_bin_mozilla();
 124
 125   } else {
 126     $script_name = $0;
 127   }
 128
 129   $::cgi    = CGI->new('');
 130   $::locale = Locale->new($::language);
 131   $::form   = Form->new;
 132
 133   eval { ($script_name, $action) = _route_request($script_name); 1; } or return;
 134
 135   my ($script, $path, $suffix) = fileparse($script_name, ".pl");
 136   require_main_code($script, $suffix);
 137
 138   $::form->{script} = $script . $suffix;
 139
 140   pre_request_checks();
 141
 142   eval {
 143     if ($script eq 'login' or $script eq 'admin' or $script eq 'kopf') {
 144       $::form->{titlebar} = "Lx-Office " . $::locale->text('Version') . " $::form->{version}";
 145       ::run($::auth->restore_session);
 146
 147     } elsif ($action) {
 148       # copy from am.pl routines
 149       $::form->error($::locale->text('System currently down for maintenance!')) if -e "$main::userspath/nologin" && $script ne 'admin';
 150
 151       my $session_result = $::auth->restore_session;
 152
 153       show_error('login/password_error', 'session') if SL::Auth::SESSION_EXPIRED == $session_result;
 154       %::myconfig = $::auth->read_user($::form->{login});
 155
 156       show_error('login/password_error', 'password') unless $::myconfig{login};
 157
 158       $::locale = Locale->new($::myconfig{countrycode});
 159
 160       show_error('login/password_error', 'password') if SL::Auth::OK != $::auth->authenticate($::form->{login}, $::form->{password}, 0);
 161
 162       $::auth->set_session_value('login', $::form->{login}, 'password', $::form->{password});
 163       $::auth->create_or_refresh_session;
 164       delete $::form->{password};
 165
 166       map { $::form->{$_} = $::myconfig{$_} } qw(stylesheet charset)
 167         unless $action eq 'save' && $::form->{type} eq 'preferences';
 168
 169       $::form->set_standard_title;
 170       ::call_sub('::' . $::locale->findsub($action));
 171
 172     } else {
 173       $::form->error($::locale->text('action= not defined!'));
 174     }
 175
 176     1;
 177   } or do {
 178     if ($EVAL_ERROR ne END_OF_REQUEST) {
 179       $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 180       eval { show_error('generic/error') };
 181     }
 182   };
 183
 184   # cleanup
 185   $::locale   = undef;
 186   $::form     = undef;
 187   $::myconfig = ();
 188   Form::disconnect_standard_dbh();
 189
 190   $::lxdebug->end_request;
 191   $::lxdebug->leave_sub;
 192 }
 193
 194 sub unrequire_bin_mozilla {
 195   for (keys %INC) {
 196     next unless m#^bin/mozilla/#;
 197     next if /\bcommon.pl$/;
 198     next if /\binstallationcheck.pl$/;
 199     delete $INC{$_};
 200   }
 201 }
 202
 203 sub _route_request {
 204   my $script_name = shift;
 205
 206   return $script_name =~ m/dispatcher\.pl$/ ? _route_dispatcher_request() : ($script_name, $::form->{action});
 207 }
 208
 209 sub _route_dispatcher_request {
 210   my $name_re = qr{[a-z]\w*};
 211   my ($script_name, $action);
 212
 213   eval {
 214     die "Unroutable request -- inavlid module name.\n" if !$::form->{M} || ($::form->{M} !~ m/^${name_re}$/);
 215     $script_name = $::form->{M} . '.pl';
 216
 217     if ($::form->{A}) {
 218       $action = $::form->{A};
 219
 220     } else {
 221       $action = first { m/^A_${name_re}$/ } keys %{ $::form };
 222       die "Unroutable request -- inavlid action name.\n" if !$action;
 223
 224       delete $::form->{$action};
 225       $action = substr $action, 2;
 226     }
 227
 228     delete @{$::form}{qw(M A)};
 229
 230     1;
 231   } or do {
 232     $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 233     show_error('generic/error');
 234   };
 235
 236   return ($script_name, $action);
 237 }
 238
 239 package main;
 240
 241 use strict;
 242
 243 sub end_of_request {
 244   die SL::Dispatcher->END_OF_REQUEST;
 245 }
 246
 247 1;