SL/Dispatcher.pm

   1 package SL::Dispatcher;
   2
   3 use strict;
   4
   5 BEGIN {
   6   unshift @INC, "modules/override"; # Use our own versions of various modules (e.g. YAML).
   7   push    @INC, "modules/fallback"; # Only use our own versions of modules if there's no system version.
   8   push    @INC, "SL";               # FCGI won't find modules that are not properly named. Help it by inclduging SL
   9 }
  10
  11 use CGI qw( -no_xhtml);
  12 use English qw(-no_match_vars);
  13 use SL::Auth;
  14 use SL::LXDebug;
  15 use SL::Locale;
  16 use SL::Common;
  17 use Form;
  18 use List::Util qw(first);
  19 use File::Basename;
  20
  21 # Trailing new line is added so that Perl will not add the line
  22 # number 'die' was called in.
  23 use constant END_OF_REQUEST => "END-OF-REQUEST\n";
  24
  25 sub pre_request_checks {
  26   if (!$::auth->session_tables_present) {
  27     if ($::form->{script} eq 'admin.pl') {
  28       ::run();
  29       ::end_of_request();
  30     } else {
  31       show_error('login/auth_db_unreachable');
  32     }
  33   }
  34   $::auth->expire_sessions;
  35 }
  36
  37 sub show_error {
  38   $::lxdebug->enter_sub;
  39   my $template             = shift;
  40   my $error_type           = shift || '';
  41
  42   $::locale                = Locale->new($::language);
  43   $::form->{error}         = $::locale->text('The session is invalid or has expired.') if ($error_type eq 'session');
  44   $::form->{error}         = $::locale->text('Incorrect password!.')                   if ($error_type eq 'password');
  45   $::myconfig{countrycode} = $::language;
  46   $::form->{stylesheet}    = 'css/lx-office-erp.css';
  47
  48   $::form->header;
  49   print $::form->parse_html_template($template);
  50   $::lxdebug->leave_sub;
  51
  52   ::end_of_request();
  53 }
  54
  55 sub pre_startup_setup {
  56   eval {
  57     package main;
  58     require "config/lx-erp.conf";
  59   };
  60   eval {
  61     package main;
  62     require "config/lx-erp-local.conf";
  63   } if -f "config/lx-erp-local.conf";
  64
  65   eval {
  66     package main;
  67     require "bin/mozilla/common.pl";
  68     require "bin/mozilla/installationcheck.pl";
  69   } or die $EVAL_ERROR;
  70
  71   # canonial globals. if it's not here, chances are it will get refactored someday.
  72   {
  73     no warnings 'once';
  74     $::userspath   = "users";
  75     $::templates   = "templates";
  76     $::memberfile  = "users/members";
  77     $::menufile    = "menu.ini";
  78     $::sendmail    = "| /usr/sbin/sendmail -t";
  79     $::lxdebug     = LXDebug->new;
  80     $::auth        = SL::Auth->new;
  81     $::form        = undef;
  82     %::myconfig    = ();
  83     %::called_subs = (); # currently used for recursion detection
  84   }
  85 }
  86
  87 sub pre_startup_checks {
  88   ::verify_installation();
  89 }
  90
  91 sub pre_startup {
  92   pre_startup_setup();
  93   pre_startup_checks();
  94 }
  95
  96 sub require_main_code {
  97   my ($script, $suffix) = @_;
  98
  99   eval {
 100     package main;
 101     require "bin/mozilla/$script$suffix";
 102   } or die $EVAL_ERROR;
 103
 104   if (-f "bin/mozilla/custom_$script$suffix") {
 105     eval {
 106       package main;
 107       require "bin/mozilla/custom_$script$suffix";
 108     };
 109     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 110   }
 111   if ($::form->{login} && -f "bin/mozilla/$::form->{login}_$script") {
 112     eval {
 113       package main;
 114       require "bin/mozilla/$::form->{login}_$script";
 115     };
 116     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 117   }
 118 }
 119
 120 sub handle_request {
 121   $::lxdebug->enter_sub;
 122   $::lxdebug->begin_request;
 123
 124   my $interface = lc(shift || 'cgi');
 125   my ($script_name, $action);
 126
 127   if ($interface =~ m/^(?:fastcgi|fcgid|fcgi)$/) {
 128     $script_name = $ENV{SCRIPT_NAME};
 129     unrequire_bin_mozilla();
 130
 131   } else {
 132     $script_name = $0;
 133   }
 134
 135   $::cgi         = CGI->new('');
 136   $::locale      = Locale->new($::language);
 137   $::form        = Form->new;
 138   %::called_subs = ();
 139
 140   eval { ($script_name, $action) = _route_request($script_name); 1; } or return;
 141
 142   my ($script, $path, $suffix) = fileparse($script_name, ".pl");
 143   require_main_code($script, $suffix);
 144
 145   $::form->{script} = $script . $suffix;
 146
 147   pre_request_checks();
 148
 149   eval {
 150     $::form->error($::locale->text('System currently down for maintenance!')) if -e "$::userspath/nologin" && $script ne 'admin';
 151
 152     if ($script eq 'login' or $script eq 'admin' or $script eq 'kopf') {
 153       $::form->{titlebar} = "Lx-Office " . $::locale->text('Version') . " $::form->{version}";
 154       ::run($::auth->restore_session);
 155
 156     } elsif ($action) {
 157       # copy from am.pl routines
 158       my $session_result = $::auth->restore_session;
 159
 160       show_error('login/password_error', 'session') if SL::Auth::SESSION_EXPIRED == $session_result;
 161       %::myconfig = $::auth->read_user($::form->{login});
 162
 163       show_error('login/password_error', 'password') unless $::myconfig{login};
 164
 165       $::locale = Locale->new($::myconfig{countrycode});
 166
 167       show_error('login/password_error', 'password') if SL::Auth::OK != $::auth->authenticate($::form->{login}, $::form->{password}, 0);
 168
 169       $::auth->set_session_value('login', $::form->{login}, 'password', $::form->{password});
 170       $::auth->create_or_refresh_session;
 171       delete $::form->{password};
 172
 173       map { $::form->{$_} = $::myconfig{$_} } qw(stylesheet charset)
 174         unless $action eq 'save' && $::form->{type} eq 'preferences';
 175
 176       $::form->set_standard_title;
 177       ::call_sub('::' . $::locale->findsub($action));
 178
 179     } else {
 180       $::form->error($::locale->text('action= not defined!'));
 181     }
 182
 183     1;
 184   } or do {
 185     if ($EVAL_ERROR ne END_OF_REQUEST) {
 186       $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 187       eval { show_error('generic/error') };
 188     }
 189   };
 190
 191   # cleanup
 192   $::locale   = undef;
 193   $::form     = undef;
 194   $::myconfig = ();
 195   Form::disconnect_standard_dbh();
 196
 197   $::lxdebug->end_request;
 198   $::lxdebug->leave_sub;
 199 }
 200
 201 sub unrequire_bin_mozilla {
 202   for (keys %INC) {
 203     next unless m#^bin/mozilla/#;
 204     next if /\bcommon.pl$/;
 205     next if /\binstallationcheck.pl$/;
 206     delete $INC{$_};
 207   }
 208 }
 209
 210 sub _route_request {
 211   my $script_name = shift;
 212
 213   return $script_name =~ m/dispatcher\.pl$/ ? _route_dispatcher_request() : ($script_name, $::form->{action});
 214 }
 215
 216 sub _route_dispatcher_request {
 217   my $name_re = qr{[a-z]\w*};
 218   my ($script_name, $action);
 219
 220   eval {
 221     die "Unroutable request -- inavlid module name.\n" if !$::form->{M} || ($::form->{M} !~ m/^${name_re}$/);
 222     $script_name = $::form->{M} . '.pl';
 223
 224     if ($::form->{A}) {
 225       $action = $::form->{A};
 226
 227     } else {
 228       $action = first { m/^A_${name_re}$/ } keys %{ $::form };
 229       die "Unroutable request -- inavlid action name.\n" if !$action;
 230
 231       delete $::form->{$action};
 232       $action = substr $action, 2;
 233     }
 234
 235     delete @{$::form}{qw(M A)};
 236
 237     1;
 238   } or do {
 239     $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 240     show_error('generic/error');
 241   };
 242
 243   return ($script_name, $action);
 244 }
 245
 246 package main;
 247
 248 use strict;
 249
 250 sub end_of_request {
 251   die SL::Dispatcher->END_OF_REQUEST;
 252 }
 253
 254 1;