SL/Dispatcher.pm

   1 package SL::Dispatcher;
   2
   3 use strict;
   4
   5 BEGIN {
   6   unshift @INC, "modules/override"; # Use our own versions of various modules (e.g. YAML).
   7   push    @INC, "modules/fallback"; # Only use our own versions of modules if there's no system version.
   8   push    @INC, "SL";               # FCGI won't find modules that are not properly named. Help it by inclduging SL
   9 }
  10
  11 use CGI qw( -no_xhtml);
  12 use English qw(-no_match_vars);
  13 use SL::Auth;
  14 use SL::LXDebug;
  15 use SL::Locale;
  16 use SL::Common;
  17 use Form;
  18 use List::Util qw(first);
  19 use Moose;
  20 use Rose::DB;
  21 use Rose::DB::Object;
  22 use File::Basename;
  23
  24 # Trailing new line is added so that Perl will not add the line
  25 # number 'die' was called in.
  26 use constant END_OF_REQUEST => "END-OF-REQUEST\n";
  27
  28 sub pre_request_checks {
  29   show_error('login/auth_db_unreachable') unless $::auth->session_tables_present;
  30   $::auth->expire_sessions;
  31 }
  32
  33 sub show_error {
  34   $::lxdebug->enter_sub;
  35   my $template             = shift;
  36   my $error_type           = shift || '';
  37
  38   $::locale                = Locale->new($::language);
  39   $::form->{error}         = $::locale->text('The session is invalid or has expired.') if ($error_type eq 'session');
  40   $::form->{error}         = $::locale->text('Incorrect password!.')                   if ($error_type eq 'password');
  41   $::myconfig{countrycode} = $::language;
  42   $::form->{stylesheet}    = 'css/lx-office-erp.css';
  43
  44   $::form->header;
  45   print $::form->parse_html_template($template);
  46   $::lxdebug->leave_sub;
  47
  48   ::end_of_request();
  49 }
  50
  51 sub pre_startup_setup {
  52   eval {
  53     package main;
  54     require "config/lx-erp.conf";
  55   };
  56   eval {
  57     package main;
  58     require "config/lx-erp-local.conf";
  59   } if -f "config/lx-erp-local.conf";
  60
  61   eval {
  62     package main;
  63     require "bin/mozilla/common.pl";
  64     require "bin/mozilla/installationcheck.pl";
  65   } or die $EVAL_ERROR;
  66
  67   # dummy globals
  68   {
  69     no warnings 'once';
  70     $::userspath   = "users";
  71     $::templates   = "templates";
  72     $::memberfile  = "users/members";
  73     $::menufile    = "menu.ini";
  74     $::sendmail    = "| /usr/sbin/sendmail -t";
  75     $::lxdebug     = LXDebug->new;
  76     $::auth        = SL::Auth->new;
  77     %::myconfig    = ();
  78     %::called_subs = ();
  79   }
  80 }
  81
  82 sub pre_startup_checks {
  83   ::verify_installation();
  84 }
  85
  86 sub pre_startup {
  87   pre_startup_setup();
  88   pre_startup_checks();
  89 }
  90
  91 sub require_main_code {
  92   my ($script, $suffix) = @_;
  93
  94   eval {
  95     package main;
  96     require "bin/mozilla/$script$suffix";
  97   } or die $EVAL_ERROR;
  98
  99   if (-f "bin/mozilla/custom_$script$suffix") {
 100     eval {
 101       package main;
 102       require "bin/mozilla/custom_$script$suffix";
 103     };
 104     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 105   }
 106   if ($::form->{login} && -f "bin/mozilla/$::form->{login}_$::form->{script}") {
 107     eval {
 108       package main;
 109       require "bin/mozilla/$::form->{login}_$::form->{script}";
 110     };
 111     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 112   }
 113 }
 114
 115 sub handle_request {
 116   $::lxdebug->enter_sub;
 117   $::lxdebug->begin_request;
 118
 119   my $interface = lc(shift || 'cgi');
 120   my ($script_name, $action);
 121
 122   if ($interface =~ m/^(?:fastcgi|fcgid|fcgi)$/) {
 123     $script_name = $ENV{SCRIPT_NAME};
 124     unrequire_bin_mozilla();
 125
 126   } else {
 127     $script_name = $0;
 128   }
 129
 130   $::cgi    = CGI->new('');
 131   $::locale = Locale->new($::language);
 132   $::form   = Form->new;
 133
 134   eval { ($script_name, $action) = _route_request($script_name); 1; } or return;
 135
 136   my ($script, $path, $suffix) = fileparse($script_name, ".pl");
 137   require_main_code($script, $suffix);
 138
 139   $::form->{script} = $script . $suffix;
 140
 141   pre_request_checks();
 142
 143   eval {
 144     if ($script eq 'login' or $script eq 'admin' or $script eq 'kopf') {
 145       $::form->{titlebar} = "Lx-Office " . $::locale->text('Version') . " $::form->{version}";
 146       ::run($::auth->restore_session);
 147
 148     } elsif ($action) {
 149       # copy from am.pl routines
 150       $::form->error($::locale->text('System currently down for maintenance!')) if -e "$main::userspath/nologin" && $script ne 'admin';
 151
 152       my $session_result = $::auth->restore_session;
 153
 154       show_error('login/password_error', 'session') if SL::Auth::SESSION_EXPIRED == $session_result;
 155       %::myconfig = $::auth->read_user($::form->{login});
 156
 157       show_error('login/password_error', 'password') unless $::myconfig{login};
 158
 159       $::locale = Locale->new($::myconfig{countrycode});
 160
 161       show_error('login/password_error', 'password') if SL::Auth::OK != $::auth->authenticate($::form->{login}, $::form->{password}, 0);
 162
 163       $::auth->set_session_value('login', $::form->{login}, 'password', $::form->{password});
 164       $::auth->create_or_refresh_session;
 165       delete $::form->{password};
 166
 167       map { $::form->{$_} = $::myconfig{$_} } qw(stylesheet charset)
 168         unless $action eq 'save' && $::form->{type} eq 'preferences';
 169
 170       $::form->set_standard_title;
 171       ::call_sub('::' . $::locale->findsub($action));
 172
 173     } else {
 174       $::form->error($::locale->text('action= not defined!'));
 175     }
 176
 177     1;
 178   } or do {
 179     if ($EVAL_ERROR ne END_OF_REQUEST) {
 180       $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 181       eval { show_error('generic/error') };
 182     }
 183   };
 184
 185   # cleanup
 186   $::locale   = undef;
 187   $::form     = undef;
 188   $::myconfig = ();
 189   Form::disconnect_standard_dbh();
 190
 191   $::lxdebug->end_request;
 192   $::lxdebug->leave_sub;
 193 }
 194
 195 sub unrequire_bin_mozilla {
 196   for (keys %INC) {
 197     next unless m#^bin/mozilla/#;
 198     next if /\bcommon.pl$/;
 199     next if /\binstallationcheck.pl$/;
 200     delete $INC{$_};
 201   }
 202 }
 203
 204 sub _route_request {
 205   my $script_name = shift;
 206
 207   return $script_name =~ m/dispatcher\.pl$/ ? _route_dispatcher_request() : ($script_name, $::form->{action});
 208 }
 209
 210 sub _route_dispatcher_request {
 211   my $name_re = qr{[a-z]\w*};
 212   my ($script_name, $action);
 213
 214   eval {
 215     die "Unroutable request -- inavlid module name.\n" if !$::form->{M} || ($::form->{M} !~ m/^${name_re}$/);
 216     $script_name = $::form->{M} . '.pl';
 217
 218     if ($::form->{A}) {
 219       $action = $::form->{A};
 220
 221     } else {
 222       $action = first { m/^A_${name_re}$/ } keys %{ $::form };
 223       die "Unroutable request -- inavlid action name.\n" if !$action;
 224
 225       delete $::form->{$action};
 226       $action = substr $action, 2;
 227     }
 228
 229     delete @{$::form}{qw(M A)};
 230
 231     1;
 232   } or do {
 233     $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 234     show_error('generic/error');
 235   };
 236
 237   return ($script_name, $action);
 238 }
 239
 240 package main;
 241
 242 use strict;
 243
 244 sub end_of_request {
 245   die SL::Dispatcher->END_OF_REQUEST;
 246 }
 247
 248 1;