SL/Dispatcher.pm

   1 package SL::Dispatcher;
   2
   3 use strict;
   4
   5 # Force scripts/locales.pl to parse these templates:
   6 #   parse_html_template('login_screen/auth_db_unreachable')
   7 #   parse_html_template('login_screen/user_login')
   8 #   parse_html_template('generic/error')
   9
  10 BEGIN {
  11   use SL::System::Process;
  12   my $exe_dir = SL::System::Process::exe_dir;
  13
  14   unshift @INC, "${exe_dir}/modules/override"; # Use our own versions of various modules (e.g. YAML).
  15   push    @INC, "${exe_dir}/modules/fallback"; # Only use our own versions of modules if there's no system version.
  16   unshift @INC, $exe_dir;
  17 }
  18
  19 use Carp;
  20 use CGI qw( -no_xhtml);
  21 use Config::Std;
  22 use DateTime;
  23 use Encode;
  24 use English qw(-no_match_vars);
  25 use FCGI;
  26 use File::Basename;
  27 use IO::File;
  28 use List::MoreUtils qw(all);
  29 use List::Util qw(first);
  30 use SL::ArchiveZipFixes;
  31 use SL::Auth;
  32 use SL::Dispatcher::AuthHandler;
  33 use SL::LXDebug;
  34 use SL::LxOfficeConf;
  35 use SL::Locale;
  36 use SL::ClientJS;
  37 use SL::Common;
  38 use SL::Form;
  39 use SL::Helper::DateTime;
  40 use SL::InstanceConfiguration;
  41 use SL::Template::Plugin::HTMLFixes;
  42 use SL::User;
  43
  44 # Trailing new line is added so that Perl will not add the line
  45 # number 'die' was called in.
  46 use constant END_OF_REQUEST => "END-OF-REQUEST\n";
  47
  48 my %fcgi_file_cache;
  49
  50 sub new {
  51   my ($class, $interface) = @_;
  52
  53   my $self           = bless {}, $class;
  54   $self->{interface} = lc($interface || 'cgi');
  55   $self->{auth_handler} = SL::Dispatcher::AuthHandler->new;
  56
  57   SL::ArchiveZipFixes->apply_fixes;
  58
  59   return $self;
  60 }
  61
  62 sub interface_type {
  63   my ($self) = @_;
  64   return $self->{interface} eq 'cgi' ? 'CGI' : 'FastCGI';
  65 }
  66
  67 sub is_admin_request {
  68   my %params = @_;
  69   return ($params{script} eq 'admin.pl') || (($params{routing_type} eq 'controller') && ($params{script_name} eq 'Admin'));
  70 }
  71
  72 sub pre_request_checks {
  73   my (%params) = @_;
  74
  75   _check_for_old_config_files();
  76
  77   if (!$::auth->session_tables_present && !is_admin_request(%params)) {
  78     show_error('login_screen/auth_db_unreachable');
  79   }
  80
  81   if ($::request->type !~ m/^ (?: html | js | json ) $/x) {
  82     die $::locale->text("Invalid request type '#1'", $::request->type);
  83   }
  84 }
  85
  86 sub pre_request_initialization {
  87   my ($self, %params) = @_;
  88
  89   $self->unrequire_bin_mozilla;
  90
  91   $::locale        = Locale->new($::lx_office_conf{system}->{language});
  92   $::form          = Form->new;
  93   $::instance_conf = SL::InstanceConfiguration->new;
  94   $::request       = SL::Request->new(
  95     cgi            => CGI->new({}),
  96     layout         => SL::Layout::None->new,
  97   );
  98
  99   my $session_result = $::auth->restore_session;
 100   $::auth->create_or_refresh_session;
 101
 102   if ($params{client}) {
 103     $::auth->set_client($params{client}) || die("cannot find client " . $params{client});
 104
 105     if ($params{login}) {
 106       die "cannot find user " . $params{login}            unless %::myconfig = $::auth->read_user(login => $params{login});
 107       die "cannot find locale for user " . $params{login} unless $::locale   = Locale->new($::myconfig{countrycode});
 108
 109       $::form->{login} = $params{login}; # normaly implicit at login
 110     }
 111   }
 112
 113   return $session_result;
 114 }
 115
 116 sub render_error_ajax {
 117   my ($error) = @_;
 118
 119   SL::ClientJS->new
 120     ->error($error)
 121     ->render(SL::Controller::Base->new);
 122 }
 123
 124 sub show_error {
 125   $::lxdebug->enter_sub;
 126   my $template             = shift;
 127   my $error_type           = shift || '';
 128   my %params               = @_;
 129
 130   $::myconfig{countrycode} = delete($params{countrycode}) || $::lx_office_conf{system}->{language};
 131   $::locale                = Locale->new($::myconfig{countrycode});
 132   $::form->{error}         = $::locale->text('The session is invalid or has expired.') if ($error_type eq 'session');
 133   $::form->{error}         = $::locale->text('Incorrect password!')                    if ($error_type eq 'password');
 134   $::form->{error}         = $::locale->text('The action is missing or invalid.')      if ($error_type eq 'action');
 135
 136   return render_error_ajax($::form->{error}) if $::request->is_ajax;
 137
 138   $::form->header;
 139   print $::form->parse_html_template($template, \%params);
 140   $::lxdebug->leave_sub;
 141
 142   ::end_of_request();
 143 }
 144
 145 sub pre_startup_setup {
 146   my ($self) = @_;
 147
 148   SL::LxOfficeConf->read;
 149
 150   eval {
 151     package main;
 152     require "bin/mozilla/common.pl";
 153     require "bin/mozilla/installationcheck.pl";
 154   } or die $EVAL_ERROR;
 155
 156   # canonial globals. if it's not here, chances are it will get refactored someday.
 157   {
 158     no warnings 'once';
 159     $::lxdebug     = LXDebug->new;
 160     $::auth        = SL::Auth->new;
 161     $::form        = undef;
 162     $::request     = undef;
 163     %::myconfig    = User->get_default_myconfig;
 164   }
 165
 166   $SIG{__WARN__} = sub {
 167     $::lxdebug->warn(@_);
 168   };
 169
 170   $SIG{__DIE__} = sub { Carp::confess( @_ ) } if $::lx_office_conf{debug}->{backtrace_on_die};
 171
 172   $self->_cache_file_modification_times;
 173 }
 174
 175 sub pre_startup_checks {
 176   ::verify_installation();
 177 }
 178
 179 sub pre_startup {
 180   my ($self) = @_;
 181   $self->pre_startup_setup;
 182   $self->pre_startup_checks;
 183 }
 184
 185 sub require_main_code {
 186   $::lxdebug->enter_sub;
 187   my ($script, $suffix) = @_;
 188
 189   eval {
 190     package main;
 191     require "bin/mozilla/$script$suffix";
 192   } or die $EVAL_ERROR;
 193
 194   if (-f "bin/mozilla/custom_$script$suffix") {
 195     eval {
 196       package main;
 197       require "bin/mozilla/custom_$script$suffix";
 198     };
 199     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 200   }
 201   if ($::form->{login} && -f "bin/mozilla/$::form->{login}_$script") {
 202     eval {
 203       package main;
 204       require "bin/mozilla/$::form->{login}_$script";
 205     };
 206     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 207   }
 208   $::lxdebug->leave_sub;
 209 }
 210
 211 sub _require_controller {
 212   my $controller =  shift;
 213   $controller    =~ s|[^A-Za-z0-9_]||g;
 214   $controller    =  "SL/Controller/${controller}";
 215
 216   eval {
 217     package main;
 218     require "${controller}.pm";
 219   } or die $EVAL_ERROR;
 220 }
 221
 222 sub _run_controller {
 223   "SL::Controller::$_[0]"->new->_run_action($_[1]);
 224 }
 225
 226 sub handle_all_requests {
 227   my ($self) = @_;
 228
 229   my $restart;
 230   my $request = FCGI::Request();
 231   while ($request->Accept() >= 0) {
 232     $self->handle_request($request);
 233     if (($self->interface_type eq 'FastCGI') && _memory_usage_is_too_high()) {
 234       $request->LastCall();
 235       $restart = 1;
 236     }
 237   }
 238
 239   exec $0 if $restart;
 240 }
 241
 242 sub handle_request {
 243   my $self         = shift;
 244   $self->{request} = shift;
 245
 246   $::lxdebug->enter_sub;
 247   $::lxdebug->begin_request;
 248
 249   my ($script, $path, $suffix, $script_name, $action, $routing_type);
 250
 251   my $session_result = $self->pre_request_initialization;
 252
 253   $::form->read_cgi_input;
 254
 255   my %routing;
 256   eval { %routing = $self->_route_request($ENV{SCRIPT_NAME}); 1; } or return;
 257   ($routing_type, $script_name, $action) = @routing{qw(type controller action)};
 258   $::lxdebug->log_request($routing_type, $script_name, $action);
 259
 260   $::request->type(lc($routing{request_type} || 'html'));
 261
 262   if ($routing_type eq 'old') {
 263     $::form->{action}  =  lc $::form->{action};
 264     $::form->{action}  =~ s/( |-|,|\#)/_/g;
 265
 266    ($script, $path, $suffix) = fileparse($script_name, ".pl");
 267     require_main_code($script, $suffix) unless $script eq 'admin';
 268
 269     $::form->{script} = $script . $suffix;
 270
 271   } else {
 272     _require_controller($script_name);
 273     $::form->{script} = "controller.pl";
 274   }
 275
 276   eval {
 277     pre_request_checks(script => $script, action => $action, routing_type => $routing_type, script_name => $script_name);
 278
 279     if (   SL::System::InstallationLock->is_locked
 280         && !is_admin_request(script => $script, script_name => $script_name, routing_type => $routing_type)) {
 281       $::form->error($::locale->text('System currently down for maintenance!'));
 282     }
 283
 284     # For compatibility with a lot of database upgrade scripts etc:
 285     # Re-write request to old 'login.pl?action=login' to new
 286     # 'LoginScreen' controller. Make sure to load its code!
 287     if (($script eq 'login') && ($action eq 'login')) {
 288       ($routing_type, $script, $script_name, $action) = qw(controller controller LoginScreen login);
 289       _require_controller('LoginScreen');
 290     }
 291
 292     if (   (($script eq 'login') && !$action)
 293         || ($script eq 'admin')
 294         || (SL::Auth::SESSION_EXPIRED() == $session_result)) {
 295       $self->redirect_to_login(script => $script, error => 'session');
 296
 297     }
 298
 299     my %auth_result = $self->{auth_handler}->handle(
 300       routing_type => $routing_type,
 301       script       => $script,
 302       controller   => $script_name,
 303       action       => $action,
 304     );
 305
 306     ::end_of_request() unless $auth_result{auth_ok};
 307
 308     delete @{ $::form }{ grep { m/^\{AUTH\}/ } keys %{ $::form } } unless $auth_result{keep_auth_vars};
 309
 310     if ($action) {
 311       $::form->set_standard_title;
 312       if ($routing_type eq 'old') {
 313         ::call_sub('::' . $::locale->findsub($action));
 314       } else {
 315         _run_controller($script_name, $action);
 316       }
 317     } else {
 318       $::form->error($::locale->text('action= not defined!'));
 319     }
 320
 321     1;
 322   } or do {
 323     if (substr($EVAL_ERROR, 0, length(END_OF_REQUEST())) ne END_OF_REQUEST()) {
 324       my $error = $EVAL_ERROR;
 325       print STDERR $error;
 326
 327       if ($::request->is_ajax) {
 328         eval { render_error_ajax($error) };
 329       } else {
 330         $::form->{label_error} = $::request->{cgi}->pre($error);
 331         chdir SL::System::Process::exe_dir;
 332         eval { show_error('generic/error') };
 333       }
 334     }
 335   };
 336
 337   $::form->footer;
 338
 339   if ($self->_interface_is_fcgi) {
 340     # fcgi? send send reponse on its way before cleanup.
 341     $self->{request}->Flush;
 342     $self->{request}->Finish;
 343   }
 344
 345   $::lxdebug->end_request(routing_type => $routing_type, script_name => $script_name, action => $action);
 346
 347   # cleanup
 348   $::auth->save_session;
 349   $::auth->expire_sessions;
 350   $::auth->reset;
 351
 352   $::locale   = undef;
 353   $::form     = undef;
 354   $::myconfig = ();
 355   $::request  = undef;
 356
 357   SL::DBConnect::Cache->reset_all;
 358   Form::disconnect_standard_dbh;
 359
 360   $self->_watch_for_changed_files;
 361
 362   $::lxdebug->leave_sub;
 363 }
 364
 365 sub redirect_to_login {
 366   my ($self, %params) = @_;
 367   my $action          = ($params{script} // '') =~ m/^admin/i ? 'Admin/login' : 'LoginScreen/user_login';
 368   $action            .= '&error=' . $params{error} if $params{error};
 369
 370   print $::request->cgi->redirect("controller.pl?action=${action}");
 371   ::end_of_request();
 372 }
 373
 374 sub unrequire_bin_mozilla {
 375   my $self = shift;
 376   return unless $self->_interface_is_fcgi;
 377
 378   for (keys %INC) {
 379     next unless m#^bin/mozilla/#;
 380     next if /\bcommon.pl$/;
 381     next if /\binstallationcheck.pl$/;
 382     delete $INC{$_};
 383   }
 384 }
 385
 386 sub _interface_is_fcgi {
 387   my $self = shift;
 388   return $self->{interface} =~ m/^(?:fastcgi|fcgid|fcgi)$/;
 389 }
 390
 391 sub _route_request {
 392   my ($self, $script_name) = @_;
 393
 394   return $script_name =~ m/dispatcher\.pl$/ ? (type => 'old',        $self->_route_dispatcher_request)
 395        : $script_name =~ m/controller\.pl/  ? (type => 'controller', $self->_route_controller_request)
 396        :                                      (type => 'old',        controller => $script_name, action => $::form->{action});
 397 }
 398
 399 sub _route_dispatcher_request {
 400   my ($self)  = @_;
 401   my $name_re = qr{[a-z]\w*};
 402   my ($script_name, $action);
 403
 404   eval {
 405     die "Unroutable request -- invalid module name.\n" if !$::form->{M} || ($::form->{M} !~ m/^${name_re}$/);
 406     $script_name = $::form->{M} . '.pl';
 407
 408     if ($::form->{A}) {
 409       $action = $::form->{A};
 410
 411     } else {
 412       $action = first { m/^A_${name_re}$/ } keys %{ $::form };
 413       die "Unroutable request -- invalid action name.\n" if !$action;
 414
 415       delete $::form->{$action};
 416       $action = substr $action, 2;
 417     }
 418
 419     delete @{$::form}{qw(M A)};
 420
 421     1;
 422   } or do {
 423     $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 424     show_error('generic/error');
 425   };
 426
 427   return (controller => $script_name, action => $action);
 428 }
 429
 430 sub _route_controller_request {
 431   my ($self) = @_;
 432   my ($controller, $action, $request_type);
 433
 434   eval {
 435     # Redirect simple requests to controller.pl without any GET/POST
 436     # param to the login page.
 437     $self->redirect_to_login(error => 'action') if !$::form->{action};
 438
 439     # Show an error if the »action« parameter doesn't match the
 440     # pattern »Controller/action«.
 441     $::form->{action}      =~ m|^ ( [A-Z] [A-Za-z0-9_]* ) / ( [a-z] [a-z0-9_]* ) ( \. [a-zA-Z]+ )? $|x || die "Unroutable request -- invalid controller/action.\n";
 442     ($controller, $action) =  ($1, $2);
 443     delete $::form->{action};
 444
 445     $request_type = $3 ? lc(substr($3, 1)) : 'html';
 446
 447     1;
 448   } or do {
 449     $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 450     show_error('generic/error');
 451   };
 452
 453   return (controller => $controller, action => $action, request_type => $request_type);
 454 }
 455
 456 sub _cache_file_modification_times {
 457   my ($self) = @_;
 458
 459   return unless $self->_interface_is_fcgi && $::lx_office_conf{debug}->{restart_fcgi_process_on_changes};
 460
 461   require File::Find;
 462   require POSIX;
 463
 464   my $wanted = sub {
 465     return unless $File::Find::name =~ m/\.(?:pm|f?pl|html|conf|conf\.default)$/;
 466     $fcgi_file_cache{ $File::Find::name } = (stat $File::Find::name)[9];
 467   };
 468
 469   my $cwd = POSIX::getcwd();
 470   File::Find::find($wanted, map { "${cwd}/${_}" } qw(config bin SL templates/webpages));
 471   map { my $name = "${cwd}/${_}"; $fcgi_file_cache{$name} = (stat $name)[9] } qw(admin.pl dispatcher.fpl);
 472 }
 473
 474 sub _watch_for_changed_files {
 475   my ($self) = @_;
 476
 477   return unless $self->_interface_is_fcgi && $::lx_office_conf{debug}->{restart_fcgi_process_on_changes};
 478
 479   my $ok = all { (stat($_))[9] == $fcgi_file_cache{$_} } keys %fcgi_file_cache;
 480   return if $ok;
 481   $::lxdebug->message(LXDebug::DEBUG1(), "Program modifications detected. Restarting.");
 482   exit;
 483 }
 484
 485 sub get_standard_filehandles {
 486   my $self = shift;
 487
 488   return $self->{interface} =~ m/f(?:ast)cgi/i ? $self->{request}->GetHandles() : (\*STDIN, \*STDOUT, \*STDERR);
 489 }
 490
 491 sub _check_for_old_config_files {
 492   my @old_files = grep { -f "config/${_}" } qw(authentication.pl console.conf lx-erp.conf lx-erp-local.conf);
 493   return unless @old_files;
 494
 495   $::form->{title} = $::locale->text('Old configuration files');
 496   $::form->header;
 497   print $::form->parse_html_template('login_screen/old_configuration_files', { FILES => \@old_files });
 498
 499   ::end_of_request();
 500 }
 501
 502 sub _parse_number_with_unit {
 503   my ($number) = @_;
 504
 505   return undef   unless defined $number;
 506   return $number unless $number =~ m{^ \s* (\d+) \s* ([kmg])b \s* $}xi;
 507
 508   my %factors = (K => 1024, M => 1024 * 1024, G => 1024 * 1024 * 1024);
 509
 510   return $1 * $factors{uc $2};
 511 }
 512
 513 sub _memory_usage_is_too_high {
 514   return undef unless $::lx_office_conf{system};
 515
 516   my %limits = (
 517     rss  => _parse_number_with_unit($::lx_office_conf{system}->{memory_limit_rss}),
 518     size => _parse_number_with_unit($::lx_office_conf{system}->{memory_limit_vsz}),
 519   );
 520
 521   # $::lxdebug->dump(0, "limits", \%limits);
 522
 523   return undef unless $limits{rss} || $limits{vsz};
 524
 525   my %usage;
 526
 527   my $in = IO::File->new("/proc/$$/status", "r") or return undef;
 528
 529   while (<$in>) {
 530     chomp;
 531     $usage{lc $1} = _parse_number_with_unit($2) if m{^ vm(rss|size): \s* (\d+ \s* [kmg]b) \s* $}ix;
 532   }
 533
 534   $in->close;
 535
 536   # $::lxdebug->dump(0, "usage", \%usage);
 537
 538   foreach my $type (keys %limits) {
 539     next if !$limits{$type};
 540     next if $limits{$type} >= ($usage{$type} // 0);
 541
 542     $::lxdebug->message(LXDebug::WARN(), "Exiting due to memory size limit reached for type '${type}': limit " . $limits{$type} . " bytes, usage " . $usage{$type} . " bytes");
 543
 544     return 1;
 545   }
 546
 547   return 0;
 548 }
 549
 550 package main;
 551
 552 use strict;
 553
 554 sub end_of_request {
 555   die SL::Dispatcher->END_OF_REQUEST;
 556 }
 557
 558 1;