SL/Dispatcher.pm

   1 package SL::Dispatcher;
   2
   3 use strict;
   4
   5 BEGIN {
   6   unshift @INC, "modules/override"; # Use our own versions of various modules (e.g. YAML).
   7   push    @INC, "modules/fallback"; # Only use our own versions of modules if there's no system version.
   8 }
   9
  10 use CGI qw( -no_xhtml);
  11 use Config::Std;
  12 use DateTime;
  13 use Encode;
  14 use English qw(-no_match_vars);
  15 use File::Basename;
  16 use List::MoreUtils qw(all);
  17 use List::Util qw(first);
  18 use POSIX;
  19 use SL::Auth;
  20 use SL::Dispatcher::AuthHandler;
  21 use SL::LXDebug;
  22 use SL::LxOfficeConf;
  23 use SL::Locale;
  24 use SL::Common;
  25 use SL::Form;
  26 use SL::Helper::DateTime;
  27 use SL::InstanceConfiguration;
  28 use SL::Template::Plugin::HTMLFixes;
  29
  30 # Trailing new line is added so that Perl will not add the line
  31 # number 'die' was called in.
  32 use constant END_OF_REQUEST => "END-OF-REQUEST\n";
  33
  34 my %fcgi_file_cache;
  35
  36 sub new {
  37   my ($class, $interface) = @_;
  38
  39   my $self           = bless {}, $class;
  40   $self->{interface} = lc($interface || 'cgi');
  41   $self->{auth_handler} = SL::Dispatcher::AuthHandler->new;
  42
  43   return $self;
  44 }
  45
  46 sub interface_type {
  47   my ($self) = @_;
  48   return $self->{interface} eq 'cgi' ? 'CGI' : 'FastCGI';
  49 }
  50
  51 sub pre_request_checks {
  52   _check_for_old_config_files();
  53
  54   if (!$::auth->session_tables_present) {
  55     if ($::form->{script} eq 'admin.pl') {
  56       ::run();
  57       ::end_of_request();
  58     } else {
  59       show_error('login_screen/auth_db_unreachable');
  60     }
  61   }
  62 }
  63
  64 sub show_error {
  65   $::lxdebug->enter_sub;
  66   my $template             = shift;
  67   my $error_type           = shift || '';
  68   my %params               = @_;
  69
  70   $::myconfig{countrycode} = delete($params{countrycode}) || $::lx_office_conf{system}->{language};
  71   $::locale                = Locale->new($::myconfig{countrycode});
  72   $::form->{error}         = $::locale->text('The session is invalid or has expired.') if ($error_type eq 'session');
  73   $::form->{error}         = $::locale->text('Incorrect password!')                    if ($error_type eq 'password');
  74
  75   $::form->header;
  76   print $::form->parse_html_template($template, \%params);
  77   $::lxdebug->leave_sub;
  78
  79   ::end_of_request();
  80 }
  81
  82 sub pre_startup_setup {
  83   my ($self) = @_;
  84
  85   SL::LxOfficeConf->read;
  86
  87   eval {
  88     package main;
  89     require "bin/mozilla/common.pl";
  90     require "bin/mozilla/installationcheck.pl";
  91   } or die $EVAL_ERROR;
  92
  93   # canonial globals. if it's not here, chances are it will get refactored someday.
  94   {
  95     no warnings 'once';
  96     $::lxdebug     = LXDebug->new;
  97     $::auth        = SL::Auth->new;
  98     $::form        = undef;
  99     %::myconfig    = ();
 100     $::request     = undef;
 101   }
 102
 103   $SIG{__WARN__} = sub {
 104     $::lxdebug->warn(@_);
 105   };
 106
 107   $self->_cache_file_modification_times;
 108 }
 109
 110 sub pre_startup_checks {
 111   ::verify_installation();
 112 }
 113
 114 sub pre_startup {
 115   my ($self) = @_;
 116   $self->pre_startup_setup;
 117   $self->pre_startup_checks;
 118 }
 119
 120 sub require_main_code {
 121   $::lxdebug->enter_sub;
 122   my ($script, $suffix) = @_;
 123
 124   eval {
 125     package main;
 126     require "bin/mozilla/$script$suffix";
 127   } or die $EVAL_ERROR;
 128
 129   if (-f "bin/mozilla/custom_$script$suffix") {
 130     eval {
 131       package main;
 132       require "bin/mozilla/custom_$script$suffix";
 133     };
 134     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 135   }
 136   if ($::form->{login} && -f "bin/mozilla/$::form->{login}_$script") {
 137     eval {
 138       package main;
 139       require "bin/mozilla/$::form->{login}_$script";
 140     };
 141     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 142   }
 143   $::lxdebug->leave_sub;
 144 }
 145
 146 sub _require_controller {
 147   my $controller =  shift;
 148   $controller    =~ s|[^A-Za-z0-9_]||g;
 149   $controller    =  "SL/Controller/${controller}";
 150
 151   eval {
 152     package main;
 153     require "${controller}.pm";
 154   } or die $EVAL_ERROR;
 155 }
 156
 157 sub _run_controller {
 158   "SL::Controller::$_[0]"->new->_run_action($_[1]);
 159 }
 160
 161 sub handle_request {
 162   my $self         = shift;
 163   $self->{request} = shift;
 164
 165   $::lxdebug->enter_sub;
 166   $::lxdebug->begin_request;
 167
 168   my ($script, $path, $suffix, $script_name, $action, $routing_type);
 169
 170   $self->unrequire_bin_mozilla;
 171
 172   $::locale        = Locale->new($::lx_office_conf{system}->{language});
 173   $::form          = Form->new;
 174   $::instance_conf = SL::InstanceConfiguration->new;
 175   $::request       = { cgi => CGI->new({}) };
 176
 177   my $session_result = $::auth->restore_session;
 178   $::auth->create_or_refresh_session;
 179
 180   $::form->read_cgi_input;
 181
 182   eval { ($routing_type, $script_name, $action) = _route_request($ENV{SCRIPT_NAME}); 1; } or return;
 183
 184   if ($routing_type eq 'old') {
 185     $::form->{action}  =  lc $::form->{action};
 186     $::form->{action}  =~ s/( |-|,|\#)/_/g;
 187
 188    ($script, $path, $suffix) = fileparse($script_name, ".pl");
 189     require_main_code($script, $suffix);
 190
 191     $::form->{script} = $script . $suffix;
 192
 193   } else {
 194     _require_controller($script_name);
 195     $::form->{script} = "controller.pl";
 196   }
 197
 198   eval {
 199     pre_request_checks();
 200
 201     $::form->error($::locale->text('System currently down for maintenance!')) if -e ($::lx_office_conf{paths}->{userspath} . "/nologin") && $script ne 'admin';
 202
 203     # For compatibility with a lot of database upgrade scripts etc:
 204     # Re-write request to old 'login.pl?action=login' to new
 205     # 'LoginScreen' controller. Make sure to load its code!
 206     if (($script eq 'login') && ($action eq 'login')) {
 207       ($routing_type, $script, $script_name, $action) = qw(controller controller LoginScreen login);
 208       _require_controller('LoginScreen');
 209     }
 210
 211     if (($script eq 'login') && !$action) {
 212       print $::request->{cgi}->redirect('controller.pl?action=LoginScreen/user_login');
 213
 214     } elsif ($script eq 'admin') {
 215       $::form->{titlebar} = "kivitendo " . $::locale->text('Version') . " $::form->{version}";
 216       ::run($session_result);
 217
 218     } else {
 219       show_error('login_screen/user_login', 'session') if SL::Auth::SESSION_EXPIRED == $session_result;
 220
 221       my %auth_result = $self->{auth_handler}->handle(
 222         routing_type => $routing_type,
 223         script       => $script,
 224         controller   => $script_name,
 225         action       => $action,
 226       );
 227
 228       delete @{ $::form }{ grep { m/^\{AUTH\}/ } keys %{ $::form } } unless $auth_result{keep_auth_vars};
 229
 230       if ($action) {
 231         $::instance_conf->init if $auth_result{auth_level} eq 'user';
 232
 233         map { $::form->{$_} = $::myconfig{$_} } qw(charset)
 234           unless $action eq 'save' && $::form->{type} eq 'preferences';
 235
 236         $::form->set_standard_title;
 237         if ($routing_type eq 'old') {
 238           ::call_sub('::' . $::locale->findsub($action));
 239         } else {
 240           _run_controller($script_name, $action);
 241         }
 242       } else {
 243         $::form->error($::locale->text('action= not defined!'));
 244       }
 245     }
 246
 247     1;
 248   } or do {
 249     if ($EVAL_ERROR ne END_OF_REQUEST) {
 250       print STDERR $EVAL_ERROR;
 251       $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 252       eval { show_error('generic/error') };
 253     }
 254   };
 255
 256   # cleanup
 257   $::auth->save_session;
 258   $::auth->expire_sessions;
 259   $::auth->reset;
 260
 261   $::locale   = undef;
 262   $::form     = undef;
 263   $::myconfig = ();
 264   $::request  = undef;
 265   Form::disconnect_standard_dbh;
 266
 267   $::lxdebug->end_request;
 268
 269   $self->_watch_for_changed_files;
 270
 271   $::lxdebug->leave_sub;
 272 }
 273
 274 sub unrequire_bin_mozilla {
 275   my $self = shift;
 276   return unless $self->_interface_is_fcgi;
 277
 278   for (keys %INC) {
 279     next unless m#^bin/mozilla/#;
 280     next if /\bcommon.pl$/;
 281     next if /\binstallationcheck.pl$/;
 282     delete $INC{$_};
 283   }
 284 }
 285
 286 sub _interface_is_fcgi {
 287   my $self = shift;
 288   return $self->{interface} =~ m/^(?:fastcgi|fcgid|fcgi)$/;
 289 }
 290
 291 sub _route_request {
 292   my $script_name = shift;
 293
 294   return $script_name =~ m/dispatcher\.pl$/ ? ('old',        _route_dispatcher_request())
 295        : $script_name =~ m/controller\.pl/  ? ('controller', _route_controller_request())
 296        :                                      ('old',        $script_name, $::form->{action});
 297 }
 298
 299 sub _route_dispatcher_request {
 300   my $name_re = qr{[a-z]\w*};
 301   my ($script_name, $action);
 302
 303   eval {
 304     die "Unroutable request -- inavlid module name.\n" if !$::form->{M} || ($::form->{M} !~ m/^${name_re}$/);
 305     $script_name = $::form->{M} . '.pl';
 306
 307     if ($::form->{A}) {
 308       $action = $::form->{A};
 309
 310     } else {
 311       $action = first { m/^A_${name_re}$/ } keys %{ $::form };
 312       die "Unroutable request -- inavlid action name.\n" if !$action;
 313
 314       delete $::form->{$action};
 315       $action = substr $action, 2;
 316     }
 317
 318     delete @{$::form}{qw(M A)};
 319
 320     1;
 321   } or do {
 322     $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 323     show_error('generic/error');
 324   };
 325
 326   return ($script_name, $action);
 327 }
 328
 329 sub _route_controller_request {
 330   my ($controller, $action);
 331
 332   eval {
 333     $::form->{action}      =~ m|^ ( [A-Z] [A-Za-z0-9_]* ) / ( [a-z] [a-z0-9_]* ) $|x || die "Unroutable request -- inavlid controller/action.\n";
 334     ($controller, $action) =  ($1, $2);
 335     delete $::form->{action};
 336
 337     1;
 338   } or do {
 339     $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 340     show_error('generic/error');
 341   };
 342
 343   return ($controller, $action);
 344 }
 345
 346 sub _cache_file_modification_times {
 347   my ($self) = @_;
 348
 349   return unless $self->_interface_is_fcgi && $::lx_office_conf{debug}->{restart_fcgi_process_on_changes};
 350
 351   require File::Find;
 352   require POSIX;
 353
 354   my $wanted = sub {
 355     return unless $File::Find::name =~ m/\.(?:pm|f?pl|html|conf|conf\.default)$/;
 356     $fcgi_file_cache{ $File::Find::name } = (stat $File::Find::name)[9];
 357   };
 358
 359   my $cwd = POSIX::getcwd();
 360   File::Find::find($wanted, map { "${cwd}/${_}" } qw(config bin SL templates/webpages));
 361   map { my $name = "${cwd}/${_}"; $fcgi_file_cache{$name} = (stat $name)[9] } qw(admin.pl dispatcher.fpl);
 362 }
 363
 364 sub _watch_for_changed_files {
 365   my ($self) = @_;
 366
 367   return unless $self->_interface_is_fcgi && $::lx_office_conf{debug}->{restart_fcgi_process_on_changes};
 368
 369   my $ok = all { (stat($_))[9] == $fcgi_file_cache{$_} } keys %fcgi_file_cache;
 370   return if $ok;
 371   $::lxdebug->message(LXDebug::DEBUG1(), "Program modifications detected. Restarting.");
 372   exit;
 373 }
 374
 375 sub get_standard_filehandles {
 376   my $self = shift;
 377
 378   return $self->{interface} =~ m/f(?:ast)cgi/i ? $self->{request}->GetHandles() : (\*STDIN, \*STDOUT, \*STDERR);
 379 }
 380
 381 sub _check_for_old_config_files {
 382   my @old_files = grep { -f "config/${_}" } qw(authentication.pl console.conf lx-erp.conf lx-erp-local.conf);
 383   return unless @old_files;
 384
 385   $::form->{title} = $::locale->text('Old configuration files');
 386   $::form->header;
 387   print $::form->parse_html_template('login_screen/old_configuration_files', { FILES => \@old_files });
 388
 389   ::end_of_request();
 390 }
 391
 392 package main;
 393
 394 use strict;
 395
 396 sub end_of_request {
 397   die SL::Dispatcher->END_OF_REQUEST;
 398 }
 399
 400 1;