SL/Dispatcher.pm

   1 package SL::Dispatcher;
   2
   3 use strict;
   4
   5 BEGIN {
   6   unshift @INC, "modules/override"; # Use our own versions of various modules (e.g. YAML).
   7   push    @INC, "modules/fallback"; # Only use our own versions of modules if there's no system version.
   8 }
   9
  10 use CGI qw( -no_xhtml);
  11 use Config::Std;
  12 use DateTime;
  13 use Encode;
  14 use English qw(-no_match_vars);
  15 use File::Basename;
  16 use List::MoreUtils qw(all);
  17 use List::Util qw(first);
  18 use POSIX;
  19 use SL::Auth;
  20 use SL::LXDebug;
  21 use SL::LxOfficeConf;
  22 use SL::Locale;
  23 use SL::Common;
  24 use SL::Form;
  25 use SL::Helper::DateTime;
  26 use SL::InstanceConfiguration;
  27 use SL::Template::Plugin::HTMLFixes;
  28
  29 # Trailing new line is added so that Perl will not add the line
  30 # number 'die' was called in.
  31 use constant END_OF_REQUEST => "END-OF-REQUEST\n";
  32
  33 my %fcgi_file_cache;
  34
  35 sub new {
  36   my ($class, $interface) = @_;
  37
  38   my $self           = bless {}, $class;
  39   $self->{interface} = lc($interface || 'cgi');
  40
  41   return $self;
  42 }
  43
  44 sub interface_type {
  45   my ($self) = @_;
  46   return $self->{interface} eq 'cgi' ? 'CGI' : 'FastCGI';
  47 }
  48
  49 sub pre_request_checks {
  50   _check_for_old_config_files();
  51
  52   if (!$::auth->session_tables_present) {
  53     if ($::form->{script} eq 'admin.pl') {
  54       ::run();
  55       ::end_of_request();
  56     } else {
  57       show_error('login/auth_db_unreachable');
  58     }
  59   }
  60 }
  61
  62 sub show_error {
  63   $::lxdebug->enter_sub;
  64   my $template             = shift;
  65   my $error_type           = shift || '';
  66
  67   $::locale                = Locale->new($::lx_office_conf{system}->{language});
  68   $::form->{error}         = $::locale->text('The session is invalid or has expired.') if ($error_type eq 'session');
  69   $::form->{error}         = $::locale->text('Incorrect password!.')                   if ($error_type eq 'password');
  70   $::myconfig{countrycode} = $::lx_office_conf{system}->{language};
  71   $::form->{stylesheet}    = 'css/lx-office-erp.css';
  72
  73   $::form->header;
  74   print $::form->parse_html_template($template);
  75   $::lxdebug->leave_sub;
  76
  77   ::end_of_request();
  78 }
  79
  80 sub pre_startup_setup {
  81   my ($self) = @_;
  82
  83   SL::LxOfficeConf->read;
  84
  85   eval {
  86     package main;
  87     require "bin/mozilla/common.pl";
  88     require "bin/mozilla/installationcheck.pl";
  89   } or die $EVAL_ERROR;
  90
  91   # canonial globals. if it's not here, chances are it will get refactored someday.
  92   {
  93     no warnings 'once';
  94     $::lxdebug     = LXDebug->new;
  95     $::auth        = SL::Auth->new;
  96     $::form        = undef;
  97     %::myconfig    = ();
  98     $::request     = undef;
  99   }
 100
 101   $SIG{__WARN__} = sub {
 102     $::lxdebug->warn(@_);
 103   };
 104
 105   $self->_cache_file_modification_times;
 106 }
 107
 108 sub pre_startup_checks {
 109   ::verify_installation();
 110 }
 111
 112 sub pre_startup {
 113   my ($self) = @_;
 114   $self->pre_startup_setup;
 115   $self->pre_startup_checks;
 116 }
 117
 118 sub require_main_code {
 119   $::lxdebug->enter_sub;
 120   my ($script, $suffix) = @_;
 121
 122   eval {
 123     package main;
 124     require "bin/mozilla/$script$suffix";
 125   } or die $EVAL_ERROR;
 126
 127   if (-f "bin/mozilla/custom_$script$suffix") {
 128     eval {
 129       package main;
 130       require "bin/mozilla/custom_$script$suffix";
 131     };
 132     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 133   }
 134   if ($::form->{login} && -f "bin/mozilla/$::form->{login}_$script") {
 135     eval {
 136       package main;
 137       require "bin/mozilla/$::form->{login}_$script";
 138     };
 139     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 140   }
 141   $::lxdebug->leave_sub;
 142 }
 143
 144 sub _require_controller {
 145   my $controller =  shift;
 146   $controller    =~ s|[^A-Za-z0-9_]||g;
 147
 148   eval {
 149     package main;
 150     require "SL/Controller/${controller}.pm";
 151   } or die $EVAL_ERROR;
 152 }
 153
 154 sub _run_controller {
 155   "SL::Controller::$_[0]"->new->_run_action($_[1]);
 156 }
 157
 158 sub handle_request {
 159   my $self         = shift;
 160   $self->{request} = shift;
 161
 162   $::lxdebug->enter_sub;
 163   $::lxdebug->begin_request;
 164
 165   my ($script, $path, $suffix, $script_name, $action, $routing_type);
 166
 167   $script_name = $ENV{SCRIPT_NAME};
 168
 169   $self->unrequire_bin_mozilla;
 170
 171   $::locale        = Locale->new($::lx_office_conf{system}->{language});
 172   $::form          = Form->new;
 173   $::instance_conf = SL::InstanceConfiguration->new;
 174   $::request       = { cgi => CGI->new({}) };
 175
 176   my $session_result = $::auth->restore_session;
 177   $::auth->create_or_refresh_session;
 178
 179   $::form->read_cgi_input;
 180
 181   eval { ($routing_type, $script_name, $action) = _route_request($script_name); 1; } or return;
 182
 183   if ($routing_type eq 'old') {
 184     $::form->{action}  =  lc $::form->{action};
 185     $::form->{action}  =~ s/( |-|,|\#)/_/g;
 186
 187    ($script, $path, $suffix) = fileparse($script_name, ".pl");
 188     require_main_code($script, $suffix);
 189
 190     $::form->{script} = $script . $suffix;
 191
 192   } else {
 193     _require_controller($script_name);
 194     $::form->{script} = "controller.pl";
 195   }
 196
 197   eval {
 198     pre_request_checks();
 199
 200     $::form->error($::locale->text('System currently down for maintenance!')) if -e ($::lx_office_conf{paths}->{userspath} . "/nologin") && $script ne 'admin';
 201
 202     if ($script eq 'login' or $script eq 'admin') {
 203       $::form->{titlebar} = "Lx-Office " . $::locale->text('Version') . " $::form->{version}";
 204       ::run($session_result);
 205
 206     } else {
 207       show_error('login/password_error', 'session') if SL::Auth::SESSION_EXPIRED == $session_result;
 208       %::myconfig = $::auth->read_user(login => $::form->{login});
 209
 210       show_error('login/password_error', 'password') unless $::myconfig{login};
 211
 212       $::locale = Locale->new($::myconfig{countrycode});
 213
 214       show_error('login/password_error', 'password') if SL::Auth::OK != $::auth->authenticate($::form->{login}, $::form->{password});
 215
 216       $::auth->store_credentials_in_session(login => $::form->{login}, password => $::form->{password});
 217       $::auth->create_or_refresh_session;
 218       $::auth->delete_session_value('FLASH');
 219       delete $::form->{password};
 220
 221       if ($action) {
 222         $::instance_conf->init;
 223
 224         map { $::form->{$_} = $::myconfig{$_} } qw(stylesheet charset)
 225           unless $action eq 'save' && $::form->{type} eq 'preferences';
 226
 227         $::form->set_standard_title;
 228         if ($routing_type eq 'old') {
 229           ::call_sub('::' . $::locale->findsub($action));
 230         } else {
 231           _run_controller($script_name, $action);
 232         }
 233       } else {
 234         $::form->error($::locale->text('action= not defined!'));
 235       }
 236     }
 237
 238     1;
 239   } or do {
 240     if ($EVAL_ERROR ne END_OF_REQUEST) {
 241       print STDERR $EVAL_ERROR;
 242       $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 243       eval { show_error('generic/error') };
 244     }
 245   };
 246
 247   # cleanup
 248   $::auth->save_session;
 249   $::auth->expire_sessions;
 250   $::auth->reset;
 251
 252   $::locale   = undef;
 253   $::form     = undef;
 254   $::myconfig = ();
 255   $::request  = undef;
 256   Form::disconnect_standard_dbh;
 257
 258   $::lxdebug->end_request;
 259
 260   $self->_watch_for_changed_files;
 261
 262   $::lxdebug->leave_sub;
 263 }
 264
 265 sub unrequire_bin_mozilla {
 266   my $self = shift;
 267   return unless $self->_interface_is_fcgi;
 268
 269   for (keys %INC) {
 270     next unless m#^bin/mozilla/#;
 271     next if /\bcommon.pl$/;
 272     next if /\binstallationcheck.pl$/;
 273     delete $INC{$_};
 274   }
 275 }
 276
 277 sub _interface_is_fcgi {
 278   my $self = shift;
 279   return $self->{interface} =~ m/^(?:fastcgi|fcgid|fcgi)$/;
 280 }
 281
 282 sub _route_request {
 283   my $script_name = shift;
 284
 285   return $script_name =~ m/dispatcher\.pl$/ ? ('old',        _route_dispatcher_request())
 286        : $script_name =~ m/controller\.pl/  ? ('controller', _route_controller_request())
 287        :                                      ('old',        $script_name, $::form->{action});
 288 }
 289
 290 sub _route_dispatcher_request {
 291   my $name_re = qr{[a-z]\w*};
 292   my ($script_name, $action);
 293
 294   eval {
 295     die "Unroutable request -- inavlid module name.\n" if !$::form->{M} || ($::form->{M} !~ m/^${name_re}$/);
 296     $script_name = $::form->{M} . '.pl';
 297
 298     if ($::form->{A}) {
 299       $action = $::form->{A};
 300
 301     } else {
 302       $action = first { m/^A_${name_re}$/ } keys %{ $::form };
 303       die "Unroutable request -- inavlid action name.\n" if !$action;
 304
 305       delete $::form->{$action};
 306       $action = substr $action, 2;
 307     }
 308
 309     delete @{$::form}{qw(M A)};
 310
 311     1;
 312   } or do {
 313     $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 314     show_error('generic/error');
 315   };
 316
 317   return ($script_name, $action);
 318 }
 319
 320 sub _route_controller_request {
 321   my ($controller, $action);
 322
 323   eval {
 324     $::form->{action}      =~ m|^ ( [A-Z] [A-Za-z0-9_]* ) / ( [a-z] [a-z0-9_]* ) $|x || die "Unroutable request -- inavlid controller/action.\n";
 325     ($controller, $action) =  ($1, $2);
 326     delete $::form->{action};
 327
 328     1;
 329   } or do {
 330     $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 331     show_error('generic/error');
 332   };
 333
 334   return ($controller, $action);
 335 }
 336
 337 sub _cache_file_modification_times {
 338   my ($self) = @_;
 339
 340   return unless $self->_interface_is_fcgi && $::lx_office_conf{debug}->{restart_fcgi_process_on_changes};
 341
 342   require File::Find;
 343   require POSIX;
 344
 345   my $wanted = sub {
 346     return unless $File::Find::name =~ m/\.(?:pm|f?pl|html|conf|conf\.default)$/;
 347     $fcgi_file_cache{ $File::Find::name } = (stat $File::Find::name)[9];
 348   };
 349
 350   my $cwd = POSIX::getcwd();
 351   File::Find::find($wanted, map { "${cwd}/${_}" } qw(config bin SL templates/webpages));
 352   map { my $name = "${cwd}/${_}"; $fcgi_file_cache{$name} = (stat $name)[9] } qw(admin.pl dispatcher.fpl);
 353 }
 354
 355 sub _watch_for_changed_files {
 356   my ($self) = @_;
 357
 358   return unless $self->_interface_is_fcgi && $::lx_office_conf{debug}->{restart_fcgi_process_on_changes};
 359
 360   my $ok = all { (stat($_))[9] == $fcgi_file_cache{$_} } keys %fcgi_file_cache;
 361   return if $ok;
 362   $::lxdebug->message(LXDebug::DEBUG1(), "Program modifications detected. Restarting.");
 363   exit;
 364 }
 365
 366 sub get_standard_filehandles {
 367   my $self = shift;
 368
 369   return $self->{interface} =~ m/f(?:ast)cgi/i ? $self->{request}->GetHandles() : (\*STDIN, \*STDOUT, \*STDERR);
 370 }
 371
 372 sub _check_for_old_config_files {
 373   my @old_files = grep { -f "config/${_}" } qw(authentication.pl console.conf lx-erp.conf lx-erp-local.conf);
 374   return unless @old_files;
 375
 376   $::form->{title}      = $::locale->text('Old configuration files');
 377   $::form->{stylesheet} = 'lx-office-erp.css';
 378   $::form->header;
 379   print $::form->parse_html_template('login/old_configuration_files', { FILES => \@old_files });
 380
 381   ::end_of_request();
 382 }
 383
 384 package main;
 385
 386 use strict;
 387
 388 sub end_of_request {
 389   die SL::Dispatcher->END_OF_REQUEST;
 390 }
 391
 392 1;