SL/Dispatcher.pm

   1 package SL::Dispatcher;
   2
   3 use strict;
   4
   5 BEGIN {
   6   unshift @INC, "modules/override"; # Use our own versions of various modules (e.g. YAML).
   7   push    @INC, "modules/fallback"; # Only use our own versions of modules if there's no system version.
   8 }
   9
  10 use CGI qw( -no_xhtml);
  11 use Config::Std;
  12 use DateTime;
  13 use Encode;
  14 use English qw(-no_match_vars);
  15 use File::Basename;
  16 use List::MoreUtils qw(all);
  17 use List::Util qw(first);
  18 use POSIX;
  19 use SL::Auth;
  20 use SL::LXDebug;
  21 use SL::LxOfficeConf;
  22 use SL::Locale;
  23 use SL::Common;
  24 use SL::Form;
  25 use SL::Helper::DateTime;
  26 use SL::InstanceConfiguration;
  27 use SL::Template::Plugin::HTMLFixes;
  28
  29 # Trailing new line is added so that Perl will not add the line
  30 # number 'die' was called in.
  31 use constant END_OF_REQUEST => "END-OF-REQUEST\n";
  32
  33 my %fcgi_file_cache;
  34
  35 sub new {
  36   my ($class, $interface) = @_;
  37
  38   my $self           = bless {}, $class;
  39   $self->{interface} = lc($interface || 'cgi');
  40
  41   return $self;
  42 }
  43
  44 sub interface_type {
  45   my ($self) = @_;
  46   return $self->{interface} eq 'cgi' ? 'CGI' : 'FastCGI';
  47 }
  48
  49 sub pre_request_checks {
  50   _check_for_old_config_files();
  51
  52   if (!$::auth->session_tables_present) {
  53     if ($::form->{script} eq 'admin.pl') {
  54       ::run();
  55       ::end_of_request();
  56     } else {
  57       show_error('login/auth_db_unreachable');
  58     }
  59   }
  60 }
  61
  62 sub show_error {
  63   $::lxdebug->enter_sub;
  64   my $template             = shift;
  65   my $error_type           = shift || '';
  66
  67   $::locale                = Locale->new($::lx_office_conf{system}->{language});
  68   $::form->{error}         = $::locale->text('The session is invalid or has expired.') if ($error_type eq 'session');
  69   $::form->{error}         = $::locale->text('Incorrect password!.')                   if ($error_type eq 'password');
  70   $::myconfig{countrycode} = $::lx_office_conf{system}->{language};
  71
  72   $::form->header;
  73   print $::form->parse_html_template($template);
  74   $::lxdebug->leave_sub;
  75
  76   ::end_of_request();
  77 }
  78
  79 sub pre_startup_setup {
  80   my ($self) = @_;
  81
  82   SL::LxOfficeConf->read;
  83
  84   eval {
  85     package main;
  86     require "bin/mozilla/common.pl";
  87     require "bin/mozilla/installationcheck.pl";
  88   } or die $EVAL_ERROR;
  89
  90   # canonial globals. if it's not here, chances are it will get refactored someday.
  91   {
  92     no warnings 'once';
  93     $::lxdebug     = LXDebug->new;
  94     $::auth        = SL::Auth->new;
  95     $::form        = undef;
  96     %::myconfig    = ();
  97     $::request     = undef;
  98   }
  99
 100   $SIG{__WARN__} = sub {
 101     $::lxdebug->warn(@_);
 102   };
 103
 104   $self->_cache_file_modification_times;
 105 }
 106
 107 sub pre_startup_checks {
 108   ::verify_installation();
 109 }
 110
 111 sub pre_startup {
 112   my ($self) = @_;
 113   $self->pre_startup_setup;
 114   $self->pre_startup_checks;
 115 }
 116
 117 sub require_main_code {
 118   $::lxdebug->enter_sub;
 119   my ($script, $suffix) = @_;
 120
 121   eval {
 122     package main;
 123     require "bin/mozilla/$script$suffix";
 124   } or die $EVAL_ERROR;
 125
 126   if (-f "bin/mozilla/custom_$script$suffix") {
 127     eval {
 128       package main;
 129       require "bin/mozilla/custom_$script$suffix";
 130     };
 131     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 132   }
 133   if ($::form->{login} && -f "bin/mozilla/$::form->{login}_$script") {
 134     eval {
 135       package main;
 136       require "bin/mozilla/$::form->{login}_$script";
 137     };
 138     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 139   }
 140   $::lxdebug->leave_sub;
 141 }
 142
 143 sub _require_controller {
 144   my $controller =  shift;
 145   $controller    =~ s|[^A-Za-z0-9_]||g;
 146
 147   eval {
 148     package main;
 149     require "SL/Controller/${controller}.pm";
 150   } or die $EVAL_ERROR;
 151 }
 152
 153 sub _run_controller {
 154   "SL::Controller::$_[0]"->new->_run_action($_[1]);
 155 }
 156
 157 sub handle_request {
 158   my $self         = shift;
 159   $self->{request} = shift;
 160
 161   $::lxdebug->enter_sub;
 162   $::lxdebug->begin_request;
 163
 164   my ($script, $path, $suffix, $script_name, $action, $routing_type);
 165
 166   $script_name = $ENV{SCRIPT_NAME};
 167
 168   $self->unrequire_bin_mozilla;
 169
 170   $::locale        = Locale->new($::lx_office_conf{system}->{language});
 171   $::form          = Form->new;
 172   $::instance_conf = SL::InstanceConfiguration->new;
 173   $::request       = { cgi => CGI->new({}) };
 174
 175   my $session_result = $::auth->restore_session;
 176   $::auth->create_or_refresh_session;
 177
 178   $::form->read_cgi_input;
 179
 180   eval { ($routing_type, $script_name, $action) = _route_request($script_name); 1; } or return;
 181
 182   if ($routing_type eq 'old') {
 183     $::form->{action}  =  lc $::form->{action};
 184     $::form->{action}  =~ s/( |-|,|\#)/_/g;
 185
 186    ($script, $path, $suffix) = fileparse($script_name, ".pl");
 187     require_main_code($script, $suffix);
 188
 189     $::form->{script} = $script . $suffix;
 190
 191   } else {
 192     _require_controller($script_name);
 193     $::form->{script} = "controller.pl";
 194   }
 195
 196   eval {
 197     pre_request_checks();
 198
 199     $::form->error($::locale->text('System currently down for maintenance!')) if -e ($::lx_office_conf{paths}->{userspath} . "/nologin") && $script ne 'admin';
 200
 201     if ($script eq 'login' or $script eq 'admin') {
 202       $::form->{titlebar} = "Lx-Office " . $::locale->text('Version') . " $::form->{version}";
 203       ::run($session_result);
 204
 205     } else {
 206       show_error('login/password_error', 'session') if SL::Auth::SESSION_EXPIRED == $session_result;
 207
 208       my $login = $::auth->get_session_value('login');
 209       show_error('login/password_error', 'password') if not defined $login;
 210
 211       %::myconfig = $::auth->read_user(login => $login);
 212
 213       show_error('login/password_error', 'password') unless $::myconfig{login};
 214
 215       $::locale = Locale->new($::myconfig{countrycode});
 216
 217       show_error('login/password_error', 'password') if SL::Auth::OK != $::auth->authenticate($login, undef);
 218
 219       $::auth->create_or_refresh_session;
 220       $::auth->delete_session_value('FLASH');
 221       delete $::form->{password};
 222
 223       if ($action) {
 224         $::instance_conf->init;
 225
 226         map { $::form->{$_} = $::myconfig{$_} } qw(charset)
 227           unless $action eq 'save' && $::form->{type} eq 'preferences';
 228
 229         $::form->set_standard_title;
 230         if ($routing_type eq 'old') {
 231           ::call_sub('::' . $::locale->findsub($action));
 232         } else {
 233           _run_controller($script_name, $action);
 234         }
 235       } else {
 236         $::form->error($::locale->text('action= not defined!'));
 237       }
 238     }
 239
 240     1;
 241   } or do {
 242     if ($EVAL_ERROR ne END_OF_REQUEST) {
 243       print STDERR $EVAL_ERROR;
 244       $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 245       eval { show_error('generic/error') };
 246     }
 247   };
 248
 249   # cleanup
 250   $::auth->save_session;
 251   $::auth->expire_sessions;
 252   $::auth->reset;
 253
 254   $::locale   = undef;
 255   $::form     = undef;
 256   $::myconfig = ();
 257   $::request  = undef;
 258   Form::disconnect_standard_dbh;
 259
 260   $::lxdebug->end_request;
 261
 262   $self->_watch_for_changed_files;
 263
 264   $::lxdebug->leave_sub;
 265 }
 266
 267 sub unrequire_bin_mozilla {
 268   my $self = shift;
 269   return unless $self->_interface_is_fcgi;
 270
 271   for (keys %INC) {
 272     next unless m#^bin/mozilla/#;
 273     next if /\bcommon.pl$/;
 274     next if /\binstallationcheck.pl$/;
 275     delete $INC{$_};
 276   }
 277 }
 278
 279 sub _interface_is_fcgi {
 280   my $self = shift;
 281   return $self->{interface} =~ m/^(?:fastcgi|fcgid|fcgi)$/;
 282 }
 283
 284 sub _route_request {
 285   my $script_name = shift;
 286
 287   return $script_name =~ m/dispatcher\.pl$/ ? ('old',        _route_dispatcher_request())
 288        : $script_name =~ m/controller\.pl/  ? ('controller', _route_controller_request())
 289        :                                      ('old',        $script_name, $::form->{action});
 290 }
 291
 292 sub _route_dispatcher_request {
 293   my $name_re = qr{[a-z]\w*};
 294   my ($script_name, $action);
 295
 296   eval {
 297     die "Unroutable request -- inavlid module name.\n" if !$::form->{M} || ($::form->{M} !~ m/^${name_re}$/);
 298     $script_name = $::form->{M} . '.pl';
 299
 300     if ($::form->{A}) {
 301       $action = $::form->{A};
 302
 303     } else {
 304       $action = first { m/^A_${name_re}$/ } keys %{ $::form };
 305       die "Unroutable request -- inavlid action name.\n" if !$action;
 306
 307       delete $::form->{$action};
 308       $action = substr $action, 2;
 309     }
 310
 311     delete @{$::form}{qw(M A)};
 312
 313     1;
 314   } or do {
 315     $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 316     show_error('generic/error');
 317   };
 318
 319   return ($script_name, $action);
 320 }
 321
 322 sub _route_controller_request {
 323   my ($controller, $action);
 324
 325   eval {
 326     $::form->{action}      =~ m|^ ( [A-Z] [A-Za-z0-9_]* ) / ( [a-z] [a-z0-9_]* ) $|x || die "Unroutable request -- inavlid controller/action.\n";
 327     ($controller, $action) =  ($1, $2);
 328     delete $::form->{action};
 329
 330     1;
 331   } or do {
 332     $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 333     show_error('generic/error');
 334   };
 335
 336   return ($controller, $action);
 337 }
 338
 339 sub _cache_file_modification_times {
 340   my ($self) = @_;
 341
 342   return unless $self->_interface_is_fcgi && $::lx_office_conf{debug}->{restart_fcgi_process_on_changes};
 343
 344   require File::Find;
 345   require POSIX;
 346
 347   my $wanted = sub {
 348     return unless $File::Find::name =~ m/\.(?:pm|f?pl|html|conf|conf\.default)$/;
 349     $fcgi_file_cache{ $File::Find::name } = (stat $File::Find::name)[9];
 350   };
 351
 352   my $cwd = POSIX::getcwd();
 353   File::Find::find($wanted, map { "${cwd}/${_}" } qw(config bin SL templates/webpages));
 354   map { my $name = "${cwd}/${_}"; $fcgi_file_cache{$name} = (stat $name)[9] } qw(admin.pl dispatcher.fpl);
 355 }
 356
 357 sub _watch_for_changed_files {
 358   my ($self) = @_;
 359
 360   return unless $self->_interface_is_fcgi && $::lx_office_conf{debug}->{restart_fcgi_process_on_changes};
 361
 362   my $ok = all { (stat($_))[9] == $fcgi_file_cache{$_} } keys %fcgi_file_cache;
 363   return if $ok;
 364   $::lxdebug->message(LXDebug::DEBUG1(), "Program modifications detected. Restarting.");
 365   exit;
 366 }
 367
 368 sub get_standard_filehandles {
 369   my $self = shift;
 370
 371   return $self->{interface} =~ m/f(?:ast)cgi/i ? $self->{request}->GetHandles() : (\*STDIN, \*STDOUT, \*STDERR);
 372 }
 373
 374 sub _check_for_old_config_files {
 375   my @old_files = grep { -f "config/${_}" } qw(authentication.pl console.conf lx-erp.conf lx-erp-local.conf);
 376   return unless @old_files;
 377
 378   $::form->{title}      = $::locale->text('Old configuration files');
 379   $::form->header;
 380   print $::form->parse_html_template('login/old_configuration_files', { FILES => \@old_files });
 381
 382   ::end_of_request();
 383 }
 384
 385 package main;
 386
 387 use strict;
 388
 389 sub end_of_request {
 390   die SL::Dispatcher->END_OF_REQUEST;
 391 }
 392
 393 1;