SL/Dispatcher.pm

   1 package SL::Dispatcher;
   2
   3 use strict;
   4
   5 # Force scripts/locales.pl to parse these templates:
   6 #   parse_html_template('login_screen/auth_db_unreachable')
   7 #   parse_html_template('login_screen/user_login')
   8 #   parse_html_template('generic/error')
   9
  10 BEGIN {
  11   use SL::System::Process;
  12   my $exe_dir = SL::System::Process::exe_dir;
  13
  14   unshift @INC, "${exe_dir}/modules/override"; # Use our own versions of various modules (e.g. YAML).
  15   push    @INC, "${exe_dir}/modules/fallback"; # Only use our own versions of modules if there's no system version.
  16   unshift @INC, $exe_dir;
  17 }
  18
  19 use CGI qw( -no_xhtml);
  20 use Config::Std;
  21 use DateTime;
  22 use Encode;
  23 use English qw(-no_match_vars);
  24 use File::Basename;
  25 use List::MoreUtils qw(all);
  26 use List::Util qw(first);
  27 use POSIX;
  28 use SL::Auth;
  29 use SL::Dispatcher::AuthHandler;
  30 use SL::LXDebug;
  31 use SL::LxOfficeConf;
  32 use SL::Locale;
  33 use SL::Common;
  34 use SL::Form;
  35 use SL::Helper::DateTime;
  36 use SL::InstanceConfiguration;
  37 use SL::Template::Plugin::HTMLFixes;
  38 use SL::Layout::None;
  39
  40 # Trailing new line is added so that Perl will not add the line
  41 # number 'die' was called in.
  42 use constant END_OF_REQUEST => "END-OF-REQUEST\n";
  43
  44 my %fcgi_file_cache;
  45
  46 sub new {
  47   my ($class, $interface) = @_;
  48
  49   my $self           = bless {}, $class;
  50   $self->{interface} = lc($interface || 'cgi');
  51   $self->{auth_handler} = SL::Dispatcher::AuthHandler->new;
  52
  53   return $self;
  54 }
  55
  56 sub interface_type {
  57   my ($self) = @_;
  58   return $self->{interface} eq 'cgi' ? 'CGI' : 'FastCGI';
  59 }
  60
  61 sub pre_request_checks {
  62   _check_for_old_config_files();
  63
  64   if (!$::auth->session_tables_present) {
  65     if ($::form->{script} eq 'admin.pl') {
  66       ::run();
  67       ::end_of_request();
  68     } else {
  69       show_error('login_screen/auth_db_unreachable');
  70     }
  71   }
  72 }
  73
  74 sub show_error {
  75   $::lxdebug->enter_sub;
  76   my $template             = shift;
  77   my $error_type           = shift || '';
  78   my %params               = @_;
  79
  80   $::myconfig{countrycode} = delete($params{countrycode}) || $::lx_office_conf{system}->{language};
  81   $::locale                = Locale->new($::myconfig{countrycode});
  82   $::form->{error}         = $::locale->text('The session is invalid or has expired.') if ($error_type eq 'session');
  83   $::form->{error}         = $::locale->text('Incorrect password!')                    if ($error_type eq 'password');
  84
  85   $::form->header(no_menu => 1);
  86   print $::form->parse_html_template($template, \%params);
  87   $::lxdebug->leave_sub;
  88
  89   ::end_of_request();
  90 }
  91
  92 sub pre_startup_setup {
  93   my ($self) = @_;
  94
  95   SL::LxOfficeConf->read;
  96
  97   eval {
  98     package main;
  99     require "bin/mozilla/common.pl";
 100     require "bin/mozilla/installationcheck.pl";
 101   } or die $EVAL_ERROR;
 102
 103   # canonial globals. if it's not here, chances are it will get refactored someday.
 104   {
 105     no warnings 'once';
 106     $::lxdebug     = LXDebug->new;
 107     $::auth        = SL::Auth->new;
 108     $::form        = undef;
 109     %::myconfig    = ();
 110     $::request     = undef;
 111   }
 112
 113   $SIG{__WARN__} = sub {
 114     $::lxdebug->warn(@_);
 115   };
 116
 117   $self->_cache_file_modification_times;
 118 }
 119
 120 sub pre_startup_checks {
 121   ::verify_installation();
 122 }
 123
 124 sub pre_startup {
 125   my ($self) = @_;
 126   $self->pre_startup_setup;
 127   $self->pre_startup_checks;
 128 }
 129
 130 sub require_main_code {
 131   $::lxdebug->enter_sub;
 132   my ($script, $suffix) = @_;
 133
 134   eval {
 135     package main;
 136     require "bin/mozilla/$script$suffix";
 137   } or die $EVAL_ERROR;
 138
 139   if (-f "bin/mozilla/custom_$script$suffix") {
 140     eval {
 141       package main;
 142       require "bin/mozilla/custom_$script$suffix";
 143     };
 144     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 145   }
 146   if ($::form->{login} && -f "bin/mozilla/$::form->{login}_$script") {
 147     eval {
 148       package main;
 149       require "bin/mozilla/$::form->{login}_$script";
 150     };
 151     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 152   }
 153   $::lxdebug->leave_sub;
 154 }
 155
 156 sub _require_controller {
 157   my $controller =  shift;
 158   $controller    =~ s|[^A-Za-z0-9_]||g;
 159   $controller    =  "SL/Controller/${controller}";
 160
 161   eval {
 162     package main;
 163     require "${controller}.pm";
 164   } or die $EVAL_ERROR;
 165 }
 166
 167 sub _run_controller {
 168   "SL::Controller::$_[0]"->new->_run_action($_[1]);
 169 }
 170
 171 sub handle_request {
 172   my $self         = shift;
 173   $self->{request} = shift;
 174
 175   $::lxdebug->enter_sub;
 176   $::lxdebug->begin_request;
 177
 178   my ($script, $path, $suffix, $script_name, $action, $routing_type);
 179
 180   $self->unrequire_bin_mozilla;
 181
 182   $::locale        = Locale->new($::lx_office_conf{system}->{language});
 183   $::form          = Form->new;
 184   $::instance_conf = SL::InstanceConfiguration->new;
 185   $::request       = {
 186     cgi => CGI->new({}),
 187     layout => SL::Layout::None->new,
 188   };
 189
 190   my $session_result = $::auth->restore_session;
 191   $::auth->create_or_refresh_session;
 192
 193   $::form->read_cgi_input;
 194
 195   eval { ($routing_type, $script_name, $action) = _route_request($ENV{SCRIPT_NAME}); 1; } or return;
 196
 197   if ($routing_type eq 'old') {
 198     $::form->{action}  =  lc $::form->{action};
 199     $::form->{action}  =~ s/( |-|,|\#)/_/g;
 200
 201    ($script, $path, $suffix) = fileparse($script_name, ".pl");
 202     require_main_code($script, $suffix);
 203
 204     $::form->{script} = $script . $suffix;
 205
 206   } else {
 207     _require_controller($script_name);
 208     $::form->{script} = "controller.pl";
 209   }
 210
 211   eval {
 212     pre_request_checks();
 213
 214     $::form->error($::locale->text('System currently down for maintenance!')) if -e ($::lx_office_conf{paths}->{userspath} . "/nologin") && $script ne 'admin';
 215
 216     # For compatibility with a lot of database upgrade scripts etc:
 217     # Re-write request to old 'login.pl?action=login' to new
 218     # 'LoginScreen' controller. Make sure to load its code!
 219     if (($script eq 'login') && ($action eq 'login')) {
 220       ($routing_type, $script, $script_name, $action) = qw(controller controller LoginScreen login);
 221       _require_controller('LoginScreen');
 222     }
 223
 224     if (($script eq 'login') && !$action) {
 225       print $::request->{cgi}->redirect('controller.pl?action=LoginScreen/user_login');
 226
 227     } elsif ($script eq 'admin') {
 228       $::form->{titlebar} = "kivitendo " . $::locale->text('Version') . " $::form->{version}";
 229       ::run($session_result);
 230
 231     } else {
 232       if (SL::Auth::SESSION_EXPIRED == $session_result) {
 233         print $::request->{cgi}->redirect('controller.pl?action=LoginScreen/user_login&error=session');
 234       }
 235
 236       my %auth_result = $self->{auth_handler}->handle(
 237         routing_type => $routing_type,
 238         script       => $script,
 239         controller   => $script_name,
 240         action       => $action,
 241       );
 242
 243       delete @{ $::form }{ grep { m/^\{AUTH\}/ } keys %{ $::form } } unless $auth_result{keep_auth_vars};
 244
 245       if ($action) {
 246         $::instance_conf->init if $auth_result{auth_level} eq 'user';
 247
 248         map { $::form->{$_} = $::myconfig{$_} } qw(charset)
 249           unless $action eq 'save' && $::form->{type} eq 'preferences';
 250
 251         $::form->set_standard_title;
 252         if ($routing_type eq 'old') {
 253           ::call_sub('::' . $::locale->findsub($action));
 254         } else {
 255           _run_controller($script_name, $action);
 256         }
 257       } else {
 258         $::form->error($::locale->text('action= not defined!'));
 259       }
 260     }
 261
 262     1;
 263   } or do {
 264     if ($EVAL_ERROR ne END_OF_REQUEST) {
 265       print STDERR $EVAL_ERROR;
 266       $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 267       chdir SL::System::Process::exe_dir;
 268       eval { show_error('generic/error') };
 269     }
 270   };
 271
 272   $::form->footer;
 273
 274   # cleanup
 275   $::auth->save_session;
 276   $::auth->expire_sessions;
 277   $::auth->reset;
 278
 279   $::locale   = undef;
 280   $::form     = undef;
 281   $::myconfig = ();
 282   $::request  = undef;
 283   Form::disconnect_standard_dbh;
 284
 285   $::lxdebug->end_request;
 286
 287   $self->_watch_for_changed_files;
 288
 289   $::lxdebug->leave_sub;
 290 }
 291
 292 sub unrequire_bin_mozilla {
 293   my $self = shift;
 294   return unless $self->_interface_is_fcgi;
 295
 296   for (keys %INC) {
 297     next unless m#^bin/mozilla/#;
 298     next if /\bcommon.pl$/;
 299     next if /\binstallationcheck.pl$/;
 300     delete $INC{$_};
 301   }
 302 }
 303
 304 sub _interface_is_fcgi {
 305   my $self = shift;
 306   return $self->{interface} =~ m/^(?:fastcgi|fcgid|fcgi)$/;
 307 }
 308
 309 sub _route_request {
 310   my $script_name = shift;
 311
 312   return $script_name =~ m/dispatcher\.pl$/ ? ('old',        _route_dispatcher_request())
 313        : $script_name =~ m/controller\.pl/  ? ('controller', _route_controller_request())
 314        :                                      ('old',        $script_name, $::form->{action});
 315 }
 316
 317 sub _route_dispatcher_request {
 318   my $name_re = qr{[a-z]\w*};
 319   my ($script_name, $action);
 320
 321   eval {
 322     die "Unroutable request -- inavlid module name.\n" if !$::form->{M} || ($::form->{M} !~ m/^${name_re}$/);
 323     $script_name = $::form->{M} . '.pl';
 324
 325     if ($::form->{A}) {
 326       $action = $::form->{A};
 327
 328     } else {
 329       $action = first { m/^A_${name_re}$/ } keys %{ $::form };
 330       die "Unroutable request -- inavlid action name.\n" if !$action;
 331
 332       delete $::form->{$action};
 333       $action = substr $action, 2;
 334     }
 335
 336     delete @{$::form}{qw(M A)};
 337
 338     1;
 339   } or do {
 340     $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 341     show_error('generic/error');
 342   };
 343
 344   return ($script_name, $action);
 345 }
 346
 347 sub _route_controller_request {
 348   my ($controller, $action);
 349
 350   eval {
 351     $::form->{action}      =~ m|^ ( [A-Z] [A-Za-z0-9_]* ) / ( [a-z] [a-z0-9_]* ) $|x || die "Unroutable request -- inavlid controller/action.\n";
 352     ($controller, $action) =  ($1, $2);
 353     delete $::form->{action};
 354
 355     1;
 356   } or do {
 357     $::form->{label_error} = $::request->{cgi}->pre($EVAL_ERROR);
 358     show_error('generic/error');
 359   };
 360
 361   return ($controller, $action);
 362 }
 363
 364 sub _cache_file_modification_times {
 365   my ($self) = @_;
 366
 367   return unless $self->_interface_is_fcgi && $::lx_office_conf{debug}->{restart_fcgi_process_on_changes};
 368
 369   require File::Find;
 370   require POSIX;
 371
 372   my $wanted = sub {
 373     return unless $File::Find::name =~ m/\.(?:pm|f?pl|html|conf|conf\.default)$/;
 374     $fcgi_file_cache{ $File::Find::name } = (stat $File::Find::name)[9];
 375   };
 376
 377   my $cwd = POSIX::getcwd();
 378   File::Find::find($wanted, map { "${cwd}/${_}" } qw(config bin SL templates/webpages));
 379   map { my $name = "${cwd}/${_}"; $fcgi_file_cache{$name} = (stat $name)[9] } qw(admin.pl dispatcher.fpl);
 380 }
 381
 382 sub _watch_for_changed_files {
 383   my ($self) = @_;
 384
 385   return unless $self->_interface_is_fcgi && $::lx_office_conf{debug}->{restart_fcgi_process_on_changes};
 386
 387   my $ok = all { (stat($_))[9] == $fcgi_file_cache{$_} } keys %fcgi_file_cache;
 388   return if $ok;
 389   $::lxdebug->message(LXDebug::DEBUG1(), "Program modifications detected. Restarting.");
 390   exit;
 391 }
 392
 393 sub get_standard_filehandles {
 394   my $self = shift;
 395
 396   return $self->{interface} =~ m/f(?:ast)cgi/i ? $self->{request}->GetHandles() : (\*STDIN, \*STDOUT, \*STDERR);
 397 }
 398
 399 sub _check_for_old_config_files {
 400   my @old_files = grep { -f "config/${_}" } qw(authentication.pl console.conf lx-erp.conf lx-erp-local.conf);
 401   return unless @old_files;
 402
 403   $::form->{title} = $::locale->text('Old configuration files');
 404   $::form->header;
 405   print $::form->parse_html_template('login_screen/old_configuration_files', { FILES => \@old_files });
 406
 407   ::end_of_request();
 408 }
 409
 410 package main;
 411
 412 use strict;
 413
 414 sub end_of_request {
 415   die SL::Dispatcher->END_OF_REQUEST;
 416 }
 417
 418 1;