SL/Helper/Csv/Dispatcher.pm

   1 package SL::Helper::Csv::Dispatcher;
   2
   3 use strict;
   4
   5 use Data::Dumper;
   6 use Carp;
   7 use Scalar::Util qw(weaken);
   8 use List::MoreUtils qw(all pairwise);
   9 use Rose::Object::MakeMethods::Generic scalar => [ qw(
  10   _specs _row_class _row_spec _errors
  11 ) ];
  12
  13 use SL::Helper::Csv::Error;
  14
  15 sub new {
  16   my ($class, $parent) = @_;
  17   my $self = bless { }, $class;
  18
  19   weaken($self->{_csv} = $parent);
  20   $self->_errors([]);
  21
  22   return $self;
  23 }
  24
  25 sub dispatch {
  26   my ($self, $line) = @_;
  27
  28   my $class = $self->_class_by_line($line);
  29   croak 'no class given' unless $class;
  30
  31   eval "require " . $class;
  32   my $obj = $class->new;
  33
  34   my $specs = $self->_specs_by_line($line);
  35   for my $spec (@{ $specs }) {
  36     $self->apply($obj, $spec, $line->{$spec->{key}});
  37   }
  38
  39   return $obj;
  40 }
  41
  42 sub _class_by_line {
  43   my ($self, $line) = @_;
  44
  45   # initialize lookup hash if not already done
  46   if ($self->_csv->is_multiplexed && ! defined $self->_row_class ) {
  47     $self->_row_class({ map { $_->{row_ident} => $_->{class} } @{ $self->_csv->profile } });
  48   }
  49
  50   if ($self->_csv->is_multiplexed) {
  51     return $self->_row_class->{$line->{datatype}};
  52   } else {
  53     return $self->_csv->profile->[0]->{class};
  54   }
  55 }
  56
  57 sub _specs_by_line {
  58   my ($self, $line) = @_;
  59
  60   # initialize lookup hash if not already done
  61   if ($self->_csv->is_multiplexed && ! defined $self->_row_spec ) {
  62     $self->_row_spec({ pairwise { no warnings 'once'; $a->{row_ident} => $b } @{ $self->_csv->profile }, @{ $self->_specs } });
  63   }
  64
  65   if ($self->_csv->is_multiplexed) {
  66     return $self->_row_spec->{$line->{datatype}};
  67   } else {
  68     return $self->_specs->[0];
  69   }
  70 }
  71
  72
  73 sub apply {
  74   my ($self, $obj, $spec, $value) = @_;
  75   return unless $value;
  76
  77   for my $step (@{ $spec->{steps} }) {
  78     my ($acc, $class, $index) = @$step;
  79     if ($class) {
  80
  81       # autovifify
  82       if (defined $index) {
  83         if (! $obj->$acc || !$obj->$acc->[$index]) {
  84           my @objects = $obj->$acc;
  85           $obj->$acc(@objects, map { $class->new } 0 .. $index - @objects);
  86         }
  87         $obj = $obj->$acc->[$index];
  88       } else {
  89         if (! $obj->$acc) {
  90           $obj->$acc($class->new);
  91         }
  92         $obj = $obj->$acc;
  93       }
  94
  95     } else {
  96       $obj->$acc($value);
  97     }
  98   }
  99 }
 100
 101 sub is_known {
 102   my ($self, $col) = @_;
 103   return grep { $col eq $_->{key} } $self->_specs;
 104 }
 105
 106 sub parse_profile {
 107   my ($self, %params) = @_;
 108
 109   my $profile;
 110   my $class;
 111   my @specs;
 112
 113   my $i = 0;
 114   foreach my $header (@{ $self->_csv->header }) {
 115     if ($self->_csv->profile) {
 116       $profile = $self->_csv->profile->[$i]->{profile};
 117       $class   = $self->_csv->profile->[$i]->{class};
 118     }
 119
 120     my $spec = $self->_parse_profile(profile => $profile,
 121                                      class   => $class,
 122                                      header  => $header);
 123     push @specs, $spec;
 124     $i++;
 125   }
 126
 127   $self->_specs(\@specs);
 128
 129   $self->_csv->_push_error($self->errors);
 130
 131   return ! $self->errors;
 132 }
 133
 134 sub _parse_profile {
 135   my ($self, %params) = @_;
 136
 137   my $profile = $params{profile};
 138   my $class   = $params{class};
 139   my $header  = $params{header};
 140
 141   my @specs;
 142
 143   for my $col (@$header) {
 144     next unless $col;
 145     if ($self->_csv->strict_profile) {
 146       if (exists $profile->{$col}) {
 147         push @specs, $self->make_spec($col, $profile->{$col}, $class);
 148       } else {
 149         $self->unknown_column($col, undef);
 150       }
 151     } else {
 152       if (exists $profile->{$col}) {
 153         push @specs, $self->make_spec($col, $profile->{$col}, $class);
 154       } else {
 155         push @specs, $self->make_spec($col, $col, $class);
 156       }
 157     }
 158   }
 159
 160   return \@specs;
 161 }
 162
 163 sub make_spec {
 164   my ($self, $col, $path, $cur_class) = @_;
 165
 166   my $spec = { key => $col, steps => [] };
 167
 168   return unless $path;
 169
 170   return unless $cur_class;
 171
 172   for my $step_index ( split /\.(?!\d)/, $path ) {
 173     my ($step, $index) = split /\./, $step_index;
 174     if ($cur_class->can($step)) {
 175       if (my $rel = $cur_class->meta->relationship($step)) { #a
 176         if ($index && ! $rel->isa('Rose::DB::Object::Metadata::Relationship::OneToMany')) {
 177           $self->_push_error([
 178             $path,
 179             undef,
 180             "Profile path error. Indexed relationship is not OneToMany around here: '$step_index'",
 181             undef,
 182             0,
 183           ]);
 184           return;
 185         } else {
 186           my $next_class = $cur_class->meta->relationship($step)->class;
 187           push @{ $spec->{steps} }, [ $step, $next_class, $index ];
 188           $cur_class = $next_class;
 189           eval "require $cur_class; 1" or die "could not load class '$cur_class'";
 190         }
 191       } else { # simple dispatch
 192         push @{ $spec->{steps} }, [ $step ];
 193         last;
 194       }
 195     } else {
 196       $self->unknown_column($col, $path);
 197     }
 198   }
 199
 200   return $spec;
 201 }
 202
 203 sub unknown_column {
 204   my ($self, $col, $path) = @_;
 205   return if $self->_csv->ignore_unknown_columns;
 206
 207   $self->_push_error([
 208     $col,
 209     undef,
 210     "header field '$col' is not recognized",
 211     undef,
 212     0,
 213   ]);
 214 }
 215
 216 sub _csv {
 217   $_[0]->{_csv};
 218 }
 219
 220 sub errors {
 221   @{ $_[0]->_errors }
 222 }
 223
 224 sub _push_error {
 225   my ($self, @errors) = @_;
 226   my @new_errors = ($self->errors, map { SL::Helper::Csv::Error->new(@$_) } @errors);
 227   $self->_errors(\@new_errors);
 228 }
 229
 230 1;