SL/IC.pm

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (C) 2001
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #  Contributors:
  16 #
  17 # This program is free software; you can redistribute it and/or modify
  18 # it under the terms of the GNU General Public License as published by
  19 # the Free Software Foundation; either version 2 of the License, or
  20 # (at your option) any later version.
  21 #
  22 # This program is distributed in the hope that it will be useful,
  23 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  24 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25 # GNU General Public License for more details.
  26 # You should have received a copy of the GNU General Public License
  27 # along with this program; if not, write to the Free Software
  28 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
  29 # MA 02110-1335, USA.
  30 #======================================================================
  31 #
  32 # Inventory Control backend
  33 #
  34 #======================================================================
  35
  36 package IC;
  37
  38 use Data::Dumper;
  39 use List::MoreUtils qw(all any uniq);
  40 use YAML;
  41
  42 use SL::CVar;
  43 use SL::DBUtils;
  44 use SL::HTML::Restrict;
  45 use SL::TransNumber;
  46 use SL::Util qw(trim);
  47 use SL::DB;
  48 use Carp;
  49
  50 use strict;
  51
  52 sub retrieve_buchungsgruppen {
  53   $main::lxdebug->enter_sub();
  54
  55   my ($self, $myconfig, $form) = @_;
  56
  57   my ($query, $sth);
  58
  59   my $dbh = $form->get_standard_dbh;
  60
  61   # get buchungsgruppen
  62   $query = qq|SELECT id, description FROM buchungsgruppen ORDER BY sortkey|;
  63   $form->{BUCHUNGSGRUPPEN} = selectall_hashref_query($form, $dbh, $query);
  64
  65   $main::lxdebug->leave_sub();
  66 }
  67
  68 sub assembly_item {
  69   $main::lxdebug->enter_sub();
  70
  71   my ($self, $myconfig, $form) = @_;
  72
  73   my $i = $form->{assembly_rows};
  74   my $var;
  75   my $where = qq|1 = 1|;
  76   my @values;
  77
  78   my %columns = ("partnumber" => "p", "description" => "p", "partsgroup" => "pg");
  79
  80   while (my ($column, $table) = each(%columns)) {
  81     next unless ($form->{"${column}_$i"});
  82     $where .= qq| AND ${table}.${column} ILIKE ?|;
  83     push(@values, like($form->{"${column}_$i"}));
  84   }
  85
  86   if ($form->{id}) {
  87     $where .= qq| AND NOT (p.id = ?)|;
  88     push(@values, conv_i($form->{id}));
  89   }
  90
  91   # Search for part ID overrides all other criteria.
  92   if ($form->{"id_${i}"}) {
  93     $where  = qq|p.id = ?|;
  94     @values = ($form->{"id_${i}"});
  95   }
  96
  97   if ($form->{partnumber}) {
  98     $where .= qq| ORDER BY p.partnumber|;
  99   } else {
 100     $where .= qq| ORDER BY p.description|;
 101   }
 102
 103   my $query =
 104     qq|SELECT p.id, p.partnumber, p.description, p.sellprice,
 105        p.classification_id,
 106        p.weight, p.onhand, p.unit, pg.partsgroup, p.lastcost,
 107        p.price_factor_id, pfac.factor AS price_factor, p.notes as longdescription
 108        FROM parts p
 109        LEFT JOIN partsgroup pg ON (p.partsgroup_id = pg.id)
 110        LEFT JOIN price_factors pfac ON pfac.id = p.price_factor_id
 111        WHERE $where|;
 112   $form->{item_list} = selectall_hashref_query($form, SL::DB->client->dbh, $query, @values);
 113
 114   $main::lxdebug->leave_sub();
 115 }
 116
 117 #
 118 # Report for Wares.
 119 # Warning, deep magic ahead.
 120 # This function gets all parts from the database according to the filters specified
 121 #
 122 # specials:
 123 #   sort revers  - sorting field + direction
 124 #   top100
 125 #
 126 # simple filter strings (every one of those also has a column flag prefixed with 'l_' associated):
 127 #   partnumber ean description partsgroup microfiche drawing
 128 #
 129 # column flags:
 130 #   l_partnumber l_description l_listprice l_sellprice l_lastcost l_priceupdate l_weight l_unit l_rop l_image l_drawing l_microfiche l_partsgroup
 131 #   l_warehouse  l_bin
 132 #
 133 # exclusives:
 134 #   itemstatus  = active | onhand | short | obsolete | orphaned
 135 #   searchitems = part | assembly | service
 136 #
 137 # joining filters:
 138 #   make model                               - makemodel
 139 #   serialnumber transdatefrom transdateto   - invoice/orderitems
 140 #   warehouse                                - warehouse
 141 #   bin                                      - bin
 142 #
 143 # binary flags:
 144 #   bought sold onorder ordered rfq quoted   - aggreg joins with invoices/orders
 145 #   l_linetotal l_subtotal                   - aggreg joins to display totals (complicated) - NOT IMPLEMENTED here, implementation at frontend
 146 #   l_soldtotal                              - aggreg join to display total of sold quantity
 147 #   onhand                                   - as above, but masking the simple itemstatus results (doh!)
 148 #   short                                    - NOT IMPLEMENTED as form filter, only as itemstatus option
 149 #   l_serialnumber                           - belonges to serialnumber filter
 150 #   l_deliverydate                           - displays deliverydate is sold etc. flags are active
 151 #   l_soldtotal                              - aggreg join to display total of sold quantity, works as long as there's no bullshit in soldtotal
 152 #
 153 # not working:
 154 #   onhand                                   - as above, but masking the simple itemstatus results (doh!)
 155 #   warehouse onhand
 156 #   search by overrides of description
 157 #   soldtotal drops option default warehouse and bin
 158 #   soldtotal can not work if there are no documents checked
 159 #
 160 # disabled sanity checks and changes:
 161 #  - searchitems = assembly will no longer disable bought
 162 #  - searchitems = service  will no longer disable make and model, although services don't have make/model, it doesn't break the query
 163 #  - itemstatus  = orphaned will no longer disable onhand short bought sold onorder ordered rfq quoted transdate[from|to]
 164 #  - itemstatus  = obsolete will no longer disable onhand, short
 165 #  - allow sorting by ean
 166 #  - serialnumber filter also works if l_serialnumber isn't ticked
 167 #  - sorting will now change sorting if the requested sorting column isn't checked and doesn't get checked as a side effect
 168 #
 169 sub all_parts {
 170   $main::lxdebug->enter_sub();
 171
 172   my ($self, $myconfig, $form) = @_;
 173   my $dbh = $form->get_standard_dbh($myconfig);
 174
 175   # sanity backend check
 176   croak "Cannot combine soldtotal with default bin or default warehouse" if ($form->{l_soldtotal} && ($form->{l_bin} || $form->{l_warehouse}));
 177
 178   $form->{parts}     = +{ };
 179   $form->{soldtotal} = undef if $form->{l_soldtotal}; # security fix. top100 insists on putting strings in there...
 180
 181   my @simple_filters       = qw(partnumber ean description partsgroup microfiche drawing onhand);
 182   my @project_filters      = qw(projectnumber projectdescription);
 183   my @makemodel_filters    = qw(make model);
 184   my @invoice_oi_filters   = qw(serialnumber soldtotal);
 185   my @apoe_filters         = qw(transdate);
 186   my @like_filters         = (@simple_filters, @invoice_oi_filters);
 187   my @all_columns          = (@simple_filters, @makemodel_filters, @apoe_filters, @project_filters, qw(serialnumber));
 188   my @simple_l_switches    = (@all_columns, qw(notes listprice sellprice lastcost priceupdate weight unit rop image shop insertdate));
 189   my %no_simple_l_switches = (warehouse => 'wh.description as warehouse', bin => 'bin.description as bin');
 190   my @oe_flags             = qw(bought sold onorder ordered rfq quoted);
 191   my @qsooqr_flags         = qw(invnumber ordnumber quonumber trans_id name module qty);
 192   my @deliverydate_flags   = qw(deliverydate);
 193 #  my @other_flags          = qw(onhand); # ToDO: implement these
 194 #  my @inactive_flags       = qw(l_subtotal short l_linetotal);
 195
 196   my @select_tokens = qw(id factor part_type classification_id);
 197   my @where_tokens  = qw(1=1);
 198   my @group_tokens  = ();
 199   my @bind_vars     = ();
 200   my %joins_needed  = ();
 201
 202   my %joins = (
 203     partsgroup => 'LEFT JOIN partsgroup pg      ON (pg.id       = p.partsgroup_id)',
 204     makemodel  => 'LEFT JOIN makemodel mm       ON (mm.parts_id = p.id)',
 205     pfac       => 'LEFT JOIN price_factors pfac ON (pfac.id     = p.price_factor_id)',
 206     invoice_oi =>
 207       q|LEFT JOIN (
 208          SELECT parts_id, description, serialnumber, trans_id, unit, sellprice, qty,          assemblyitem,         deliverydate, 'invoice'    AS ioi, project_id, id FROM invoice UNION
 209          SELECT parts_id, description, serialnumber, trans_id, unit, sellprice, qty, FALSE AS assemblyitem, NULL AS deliverydate, 'orderitems' AS ioi, project_id, id FROM orderitems
 210        ) AS ioi ON ioi.parts_id = p.id|,
 211     apoe       =>
 212       q|LEFT JOIN (
 213          SELECT id, transdate, 'ir' AS module, ordnumber, quonumber,         invnumber, FALSE AS quotation, NULL AS customer_id,         vendor_id,    NULL AS deliverydate, globalproject_id, 'invoice'    AS ioi FROM ap UNION
 214          SELECT id, transdate, 'is' AS module, ordnumber, quonumber,         invnumber, FALSE AS quotation,         customer_id, NULL AS vendor_id,            deliverydate, globalproject_id, 'invoice'    AS ioi FROM ar UNION
 215          SELECT id, transdate, 'oe' AS module, ordnumber, quonumber, NULL AS invnumber,          quotation,         customer_id,         vendor_id, reqdate AS deliverydate, globalproject_id, 'orderitems' AS ioi FROM oe
 216        ) AS apoe ON ((ioi.trans_id = apoe.id) AND (ioi.ioi = apoe.ioi))|,
 217     cv         =>
 218       q|LEFT JOIN (
 219            SELECT id, name, 'customer' AS cv FROM customer UNION
 220            SELECT id, name, 'vendor'   AS cv FROM vendor
 221          ) AS cv ON cv.id = apoe.customer_id OR cv.id = apoe.vendor_id|,
 222     mv         => 'LEFT JOIN vendor AS mv ON mv.id = mm.make',
 223     project    => 'LEFT JOIN project AS pj ON pj.id = COALESCE(ioi.project_id, apoe.globalproject_id)',
 224     warehouse  => 'LEFT JOIN warehouse AS wh ON wh.id = p.warehouse_id',
 225     bin        => 'LEFT JOIN bin ON bin.id = p.bin_id',
 226   );
 227   my @join_order = qw(partsgroup makemodel mv invoice_oi apoe cv pfac project warehouse bin);
 228
 229   my %table_prefix = (
 230      deliverydate => 'apoe.', serialnumber => 'ioi.',
 231      transdate    => 'apoe.', trans_id     => 'ioi.',
 232      module       => 'apoe.', name         => 'cv.',
 233      ordnumber    => 'apoe.', make         => 'mm.',
 234      quonumber    => 'apoe.', model        => 'mm.',
 235      invnumber    => 'apoe.', partsgroup   => 'pg.',
 236      lastcost     => 'p.',  , soldtotal    => ' ',
 237      factor       => 'pfac.', projectnumber => 'pj.',
 238      'SUM(ioi.qty)' => ' ',   projectdescription => 'pj.',
 239      description  => 'p.',
 240      qty          => 'ioi.',
 241      serialnumber => 'ioi.',
 242      quotation    => 'apoe.',
 243      cv           => 'cv.',
 244      "ioi.id"     => ' ',
 245      "ioi.ioi"    => ' ',
 246   );
 247
 248   # if the join condition in these blocks are met, the column
 249   # of the specified table will gently override (coalesce actually) the original value
 250   # use it to conditionally coalesce values from subtables
 251   my @column_override = (
 252     #  column name,   prefix,  joins_needed,  nick name (in case column is named like another)
 253     [ 'description',  'ioi.',  'invoice_oi'  ],
 254     [ 'deliverydate', 'ioi.',  'invoice_oi'  ],
 255     [ 'transdate',    'apoe.', 'apoe'        ],
 256     [ 'unit',         'ioi.',  'invoice_oi'  ],
 257     [ 'sellprice',    'ioi.',  'invoice_oi'  ],
 258   );
 259
 260   # careful with renames. these are HARD, and any filters done on the original column will break
 261   my %renamed_columns = (
 262     'factor'       => 'price_factor',
 263     'SUM(ioi.qty)' => 'soldtotal',
 264     'ioi.id'       => 'ioi_id',
 265     'ioi.ioi'      => 'ioi',
 266     'projectdescription' => 'projectdescription',
 267     'insertdate'   => 'insertdate',
 268   );
 269
 270   my %real_column = (
 271     projectdescription => 'description',
 272     insertdate         => 'itime::DATE',
 273   );
 274
 275   if ($form->{l_assembly} && $form->{l_lastcost}) {
 276     @simple_l_switches = grep { $_ ne 'lastcost' } @simple_l_switches;
 277   }
 278
 279   my $make_token_builder = sub {
 280     my $joins_needed = shift;
 281     sub {
 282       my ($nick, $alias) = @_;
 283       my ($col) = $real_column{$nick} || $nick;
 284       my @coalesce_tokens =
 285         map  { ($_->[1] || 'p.') . $_->[0] }
 286         grep { !$_->[2] || $joins_needed->{$_->[2]} }
 287         grep { ($_->[3] || $_->[0]) eq $nick }
 288         @column_override, [ $col, $table_prefix{$nick}, undef , $nick ];
 289
 290       my $coalesce = scalar @coalesce_tokens > 1;
 291       return ($coalesce
 292         ? sprintf 'COALESCE(%s)', join ', ', @coalesce_tokens
 293         : shift                              @coalesce_tokens)
 294         . ($alias && ($coalesce || $renamed_columns{$nick})
 295         ?  " AS " . ($renamed_columns{$nick} || $nick)
 296         : '');
 297     }
 298   };
 299
 300   #===== switches and simple filters ========#
 301
 302   # special case transdate
 303   if (grep { trim($form->{$_}) } qw(transdatefrom transdateto)) {
 304     $form->{"l_transdate"} = 1;
 305     push @select_tokens, 'transdate';
 306     for (qw(transdatefrom transdateto)) {
 307       my $value = trim($form->{$_});
 308       next unless $value;
 309       push @where_tokens, sprintf "transdate %s ?", /from$/ ? '>=' : '<=';
 310       push @bind_vars,    $value;
 311     }
 312   }
 313
 314   # special case smart search
 315   if ($form->{all}) {
 316     $form->{"l_$_"} = 1 for qw(partnumber description unit sellprice lastcost cvar_packaging linetotal);
 317     push @where_tokens, "p.partnumber ILIKE ? OR p.description ILIKE ?";
 318     push @bind_vars,    (like($form->{all})) x 2;
 319   }
 320
 321   # special case insertdate
 322   if (grep { trim($form->{$_}) } qw(insertdatefrom insertdateto)) {
 323     $form->{"l_insertdate"} = 1;
 324     push @select_tokens, 'insertdate';
 325
 326     my $token_builder = $make_token_builder->();
 327     my $token = $token_builder->('insertdate');
 328
 329     for (qw(insertdatefrom insertdateto)) {
 330       my $value = trim($form->{$_});
 331       next unless $value;
 332       push @where_tokens, sprintf "$token %s ?", /from$/ ? '>=' : '<=';
 333       push @bind_vars,    $value;
 334     }
 335   }
 336
 337   if ($form->{"partsgroup_id"}) {
 338     $form->{"l_partsgroup"} = '1'; # show the column
 339     push @where_tokens, "pg.id = ?";
 340     push @bind_vars, $form->{"partsgroup_id"};
 341   }
 342
 343   if ($form->{shop} ne '') {
 344     $form->{l_shop} = '1'; # show the column
 345     if ($form->{shop} eq '0' || $form->{shop} eq 'f') {
 346       push @where_tokens, 'NOT p.shop';
 347       $form->{shop} = 'f';
 348     } else {
 349       push @where_tokens, 'p.shop';
 350     }
 351   }
 352
 353   foreach (@like_filters) {
 354     next unless $form->{$_};
 355     $form->{"l_$_"} = '1'; # show the column
 356     push @where_tokens, "$table_prefix{$_}$_ ILIKE ?";
 357     push @bind_vars,    like($form->{$_});
 358   }
 359
 360   foreach (@simple_l_switches) {
 361     next unless $form->{"l_$_"};
 362     push @select_tokens, $_;
 363   }
 364
 365   # Oder Bedingungen fuer Ware Dienstleistung Erzeugnis:
 366   if ($form->{l_part} || $form->{l_assembly} || $form->{l_service} || $form->{l_assortment}) {
 367       my @or_tokens = ();
 368       push @or_tokens, "p.part_type = 'service'"    if $form->{l_service};
 369       push @or_tokens, "p.part_type = 'assembly'"   if $form->{l_assembly};
 370       push @or_tokens, "p.part_type = 'part'"       if $form->{l_part};
 371       push @or_tokens, "p.part_type = 'assortment'" if $form->{l_assortment};
 372       push @where_tokens, join ' OR ', map { "($_)" } @or_tokens;
 373   }
 374   else {
 375       # gar keine Teile
 376       push @where_tokens, q|'F' = 'T'|;
 377   }
 378
 379   if ( $form->{classification_id} > 0 ) {
 380     push @where_tokens, "p.classification_id = ?";
 381     push @bind_vars, $form->{classification_id};
 382   }
 383
 384   for ($form->{itemstatus}) {
 385     push @where_tokens, 'p.id NOT IN
 386         (SELECT DISTINCT parts_id FROM invoice UNION
 387          SELECT DISTINCT parts_id FROM assembly UNION
 388          SELECT DISTINCT parts_id FROM orderitems)'    if /orphaned/;
 389     push @where_tokens, 'p.onhand = 0'                 if /orphaned/;
 390     push @where_tokens, 'NOT p.obsolete'               if /active/;
 391     push @where_tokens, '    p.obsolete',              if /obsolete/;
 392     push @where_tokens, 'p.onhand > 0',                if /onhand/;
 393     push @where_tokens, 'p.onhand < p.rop',            if /short/;
 394   }
 395
 396   my $q_assembly_lastcost =
 397     qq|(SELECT SUM(a_lc.qty * p_lc.lastcost / COALESCE(pfac_lc.factor, 1))
 398         FROM assembly a_lc
 399         LEFT JOIN parts p_lc            ON (a_lc.parts_id        = p_lc.id)
 400         LEFT JOIN price_factors pfac_lc ON (p_lc.price_factor_id = pfac_lc.id)
 401         WHERE (a_lc.id = p.id)) AS lastcost|;
 402   $table_prefix{$q_assembly_lastcost} = ' ';
 403
 404   # special case makemodel search
 405   # all_parts is based upon the assumption that every parameter is named like the column it represents
 406   # unfortunately make would have to match vendor.name which is already taken for vendor.name in bsooqr mode.
 407   # fortunately makemodel doesn't need to be displayed later, so adding a special clause to where_token is sufficient.
 408   if ($form->{make}) {
 409     push @where_tokens, 'mv.name ILIKE ?';
 410     push @bind_vars, like($form->{make});
 411   }
 412   if ($form->{model}) {
 413     push @where_tokens, 'mm.model ILIKE ?';
 414     push @bind_vars, like($form->{model});
 415   }
 416
 417   # special case: sorting by partnumber
 418   # since partnumbers are expected to be prefixed integers, a special sorting is implemented sorting first lexically by prefix and then by suffix.
 419   # and yes, that expression is designed to hold that array of regexes only once, so the map is kinda messy, sorry about that.
 420   # ToDO: implement proper functional sorting
 421   # Nette Idee von Sven, gibt aber Probleme wenn die Artikelnummern groesser als 32bit sind. Korrekt waere es, dass Sort-Natural-Modul zu nehmen
 422   # Ich lass das mal hier drin, damit die Idee erhalten bleibt jb 28.5.2009 bug 1018
 423   #$form->{sort} = join ', ', map { push @select_tokens, $_; ($table_prefix{$_} = "substring(partnumber,'[") . $_ } qw|^[:digit:]]+') [:digit:]]+')::INTEGER|
 424   #  if $form->{sort} eq 'partnumber';
 425
 426   #my $order_clause = " ORDER BY $form->{sort} $sort_order";
 427
 428   my $limit_clause;
 429   $limit_clause = " LIMIT 100"                   if $form->{top100};
 430   $limit_clause = " LIMIT " . $form->{limit} * 1 if $form->{limit} * 1;
 431
 432   #=== joins and complicated filters ========#
 433
 434   my $bsooqr        = any { $form->{$_} } @oe_flags;
 435   my @bsooqr_tokens = ();
 436
 437   push @select_tokens, @qsooqr_flags, 'quotation', 'cv', 'ioi.id', 'ioi.ioi'  if $bsooqr;
 438   push @select_tokens, @deliverydate_flags                                    if $bsooqr && $form->{l_deliverydate};
 439   push @select_tokens, $q_assembly_lastcost                                   if $form->{l_assembly} && $form->{l_lastcost};
 440   push @bsooqr_tokens, q|module = 'ir' AND NOT ioi.assemblyitem|              if $form->{bought};
 441   push @bsooqr_tokens, q|module = 'is' AND NOT ioi.assemblyitem|              if $form->{sold};
 442   push @bsooqr_tokens, q|module = 'oe' AND NOT quotation AND cv = 'customer'| if $form->{ordered};
 443   push @bsooqr_tokens, q|module = 'oe' AND NOT quotation AND cv = 'vendor'|   if $form->{onorder};
 444   push @bsooqr_tokens, q|module = 'oe' AND     quotation AND cv = 'customer'| if $form->{quoted};
 445   push @bsooqr_tokens, q|module = 'oe' AND     quotation AND cv = 'vendor'|   if $form->{rfq};
 446   push @where_tokens, join ' OR ', map { "($_)" } @bsooqr_tokens              if $bsooqr;
 447
 448   $joins_needed{partsgroup}  = 1;
 449   $joins_needed{pfac}        = 1;
 450   $joins_needed{project}     = 1 if grep { $form->{$_} || $form->{"l_$_"} } @project_filters;
 451   $joins_needed{makemodel}   = 1 if grep { $form->{$_} || $form->{"l_$_"} } @makemodel_filters;
 452   $joins_needed{mv}          = 1 if $joins_needed{makemodel};
 453   $joins_needed{cv}          = 1 if $bsooqr;
 454   $joins_needed{apoe}        = 1 if $joins_needed{project} || $joins_needed{cv}   || grep { $form->{$_} || $form->{"l_$_"} } @apoe_filters;
 455   $joins_needed{invoice_oi}  = 1 if $joins_needed{project} || $joins_needed{apoe} || grep { $form->{$_} || $form->{"l_$_"} } @invoice_oi_filters;
 456   $joins_needed{bin}         = 1 if $form->{l_bin};
 457   $joins_needed{warehouse}   = 1 if $form->{l_warehouse};
 458
 459   # special case for description search.
 460   # up in the simple filter section the description filter got interpreted as something like: WHERE description ILIKE '%$form->{description}%'
 461   # now we'd like to search also for the masked description entered in orderitems and invoice, so...
 462   # find the old entries in of @where_tokens and @bind_vars, and adjust them
 463   if ($joins_needed{invoice_oi}) {
 464     for (my ($wi, $bi) = (0)x2; $wi <= $#where_tokens; $bi++ if $where_tokens[$wi++] =~ /\?/) {
 465       next unless $where_tokens[$wi] =~ /\bdescription ILIKE/;
 466       splice @where_tokens, $wi, 1, 'p.description ILIKE ? OR ioi.description ILIKE ?';
 467       splice @bind_vars,    $bi, 0, $bind_vars[$bi];
 468       last;
 469     }
 470   }
 471
 472   # now the master trick: soldtotal.
 473   if ($form->{l_soldtotal}) {
 474     push @where_tokens, 'NOT ioi.qty = 0';
 475     push @group_tokens, @select_tokens;
 476      map { s/.*\sAS\s+//si } @group_tokens;
 477     push @select_tokens, 'SUM(ioi.qty)';
 478   }
 479
 480   #============= build query ================#
 481
 482   my $token_builder = $make_token_builder->(\%joins_needed);
 483
 484   my @sort_cols    = (@simple_filters, qw(id priceupdate onhand invnumber ordnumber quonumber name serialnumber soldtotal deliverydate insertdate shop));
 485      $form->{sort} = 'id' unless grep { $form->{"l_$_"} } grep { $form->{sort} eq $_ } @sort_cols; # sort by id if unknown or invisible column
 486   my $sort_order   = ($form->{revers} ? ' DESC' : ' ASC');
 487   my $order_clause = " ORDER BY " . $token_builder->($form->{sort}) . ($form->{revers} ? ' DESC' : ' ASC');
 488
 489   my $select_clause = join ', ',    map { $token_builder->($_, 1) } @select_tokens;
 490   my $join_clause   = join ' ',     @joins{ grep $joins_needed{$_}, @join_order };
 491   my $where_clause  = join ' AND ', map { "($_)" } @where_tokens;
 492   my $group_clause  = @group_tokens ? ' GROUP BY ' . join ', ',    map { $token_builder->($_) } @group_tokens : '';
 493
 494   # key of %no_simple_l_switch is the logical l_switch.
 495   # the assigned value is the 'not so simple
 496   # select token'
 497   my $no_simple_select_clause;
 498   foreach my $no_simple_l_switch (keys %no_simple_l_switches) {
 499     next unless $form->{"l_${no_simple_l_switch}"};
 500     $no_simple_select_clause .= ', '. $no_simple_l_switches{$no_simple_l_switch};
 501   }
 502   $select_clause .= $no_simple_select_clause;
 503
 504   my %oe_flag_to_cvar = (
 505     bought   => 'invoice',
 506     sold     => 'invoice',
 507     onorder  => 'orderitems',
 508     ordered  => 'orderitems',
 509     rfq      => 'orderitems',
 510     quoted   => 'orderitems',
 511   );
 512
 513   my ($cvar_where, @cvar_values) = CVar->build_filter_query(
 514     module         => 'IC',
 515     trans_id_field => $bsooqr ? 'ioi.id': 'p.id',
 516     filter         => $form,
 517     sub_module     => $bsooqr ? [ uniq grep { $oe_flag_to_cvar{$form->{$_}} } @oe_flags ] : undef,
 518   );
 519
 520   if ($cvar_where) {
 521     $where_clause .= qq| AND ($cvar_where)|;
 522     push @bind_vars, @cvar_values;
 523   }
 524
 525   my $query = <<"  SQL";
 526     SELECT DISTINCT $select_clause
 527     FROM parts p
 528     $join_clause
 529     WHERE $where_clause
 530     $group_clause
 531     $order_clause
 532     $limit_clause
 533   SQL
 534
 535   $form->{parts} = selectall_hashref_query($form, $dbh, $query, @bind_vars);
 536
 537   map { $_->{onhand} *= 1 } @{ $form->{parts} };
 538
 539   # fix qty sign in ap. those are saved negative
 540   if ($bsooqr && $form->{bought}) {
 541     for my $row (@{ $form->{parts} }) {
 542       $row->{qty} *= -1 if $row->{module} eq 'ir';
 543     }
 544   }
 545
 546   # post processing for assembly parts lists (bom)
 547   # for each part get the assembly parts and add them into the partlist.
 548   my @assemblies;
 549   if ($form->{l_assembly} && $form->{bom}) {
 550     $query =
 551       qq|SELECT p.id, p.partnumber, p.description, a.qty AS onhand,
 552            p.unit, p.notes, p.itime::DATE as insertdate,
 553            p.sellprice, p.listprice, p.lastcost,
 554            p.rop, p.weight, p.priceupdate,
 555            p.image, p.drawing, p.microfiche,
 556            pfac.factor
 557          FROM parts p
 558          INNER JOIN assembly a ON (p.id = a.parts_id)
 559          $joins{pfac}
 560          WHERE a.id = ?|;
 561     my $sth = prepare_query($form, $dbh, $query);
 562
 563     foreach my $item (@{ $form->{parts} }) {
 564       push(@assemblies, $item);
 565       do_statement($form, $sth, $query, conv_i($item->{id}));
 566
 567       while (my $ref = $sth->fetchrow_hashref("NAME_lc")) {
 568         $ref->{assemblyitem} = 1;
 569         map { $ref->{$_} /= $ref->{factor} || 1 } qw(sellprice listprice lastcost);
 570         push(@assemblies, $ref);
 571       }
 572       $sth->finish;
 573     }
 574
 575     # copy assemblies to $form->{parts}
 576     $form->{parts} = \@assemblies;
 577   }
 578
 579   if ($form->{l_pricegroups} ) {
 580     my $query = <<SQL;
 581        SELECT parts_id, price, pricegroup_id
 582        FROM prices
 583        WHERE parts_id = ?
 584 SQL
 585
 586     my $sth = prepare_query($form, $dbh, $query);
 587
 588     foreach my $part (@{ $form->{parts} }) {
 589       do_statement($form, $sth, $query, conv_i($part->{id}));
 590
 591       while (my $ref = $sth->fetchrow_hashref("NAME_lc")) {
 592         $part->{"pricegroup_$ref->{pricegroup_id}"} = $ref->{price};
 593       }
 594       $sth->finish;
 595     }
 596   }
 597
 598   $main::lxdebug->leave_sub();
 599
 600   return $form->{parts};
 601 }
 602
 603 # get partnumber, description, unit, sellprice and soldtotal with choice through $sortorder for Top100
 604 sub get_parts {
 605   $main::lxdebug->enter_sub();
 606
 607   my ($self, $myconfig, $form, $sortorder) = @_;
 608   my $dbh   = $form->get_standard_dbh;
 609   my $order = qq| p.partnumber|;
 610   my $where = qq|1 = 1|;
 611   my @values;
 612
 613   if ($sortorder eq "all") {
 614     $where .= qq| AND (partnumber ILIKE ?) AND (description ILIKE ?)|;
 615     push(@values, like($form->{partnumber}), like($form->{description}));
 616
 617   } elsif ($sortorder eq "partnumber") {
 618     $where .= qq| AND (partnumber ILIKE ?)|;
 619     push(@values, like($form->{partnumber}));
 620
 621   } elsif ($sortorder eq "description") {
 622     $where .= qq| AND (description ILIKE ?)|;
 623     push(@values, like($form->{description}));
 624     $order = "description";
 625
 626   }
 627
 628   my $query =
 629     qq|SELECT id, partnumber, description, unit, sellprice,
 630        classification_id
 631        FROM parts
 632        WHERE $where ORDER BY $order|;
 633
 634   my $sth = prepare_execute_query($form, $dbh, $query, @values);
 635
 636   my $j = 0;
 637   while (my $ref = $sth->fetchrow_hashref("NAME_lc")) {
 638     if (($ref->{partnumber} eq "*") && ($ref->{description} eq "")) {
 639       next;
 640     }
 641
 642     $j++;
 643     $form->{"type_and_classific_$j"} = $::request->presenter->type_abbreviation($ref->{part_type}).
 644                                        $::request->presenter->classification_abbreviation($ref->{classification_id});
 645     $form->{"id_$j"}          = $ref->{id};
 646     $form->{"partnumber_$j"}  = $ref->{partnumber};
 647     $form->{"description_$j"} = $ref->{description};
 648     $form->{"unit_$j"}        = $ref->{unit};
 649     $form->{"sellprice_$j"}   = $ref->{sellprice};
 650     $form->{"soldtotal_$j"}   = get_soldtotal($dbh, $ref->{id});
 651   }    #while
 652   $form->{rows} = $j;
 653   $sth->finish;
 654
 655   $main::lxdebug->leave_sub();
 656
 657   return $self;
 658 }    #end get_parts()
 659
 660 # gets sum of sold part with part_id
 661 sub get_soldtotal {
 662   $main::lxdebug->enter_sub();
 663
 664   my ($dbh, $id) = @_;
 665
 666   my $query = qq|SELECT sum(qty) FROM invoice WHERE parts_id = ?|;
 667   my ($sum) = selectrow_query($main::form, $dbh, $query, conv_i($id));
 668   $sum ||= 0;
 669
 670   $main::lxdebug->leave_sub();
 671
 672   return $sum;
 673 }    #end get_soldtotal
 674
 675 sub follow_account_chain {
 676   $main::lxdebug->enter_sub(2);
 677
 678   my ($self, $form, $dbh, $transdate, $accno_id, $accno) = @_;
 679
 680   my @visited_accno_ids = ($accno_id);
 681
 682   my ($query, $sth);
 683
 684   $form->{ACCOUNT_CHAIN_BY_ID} ||= {
 685     map { $_->{id} => $_ }
 686       selectall_hashref_query($form, $dbh, <<SQL, $transdate) };
 687     SELECT c.id, c.new_chart_id, date(?) >= c.valid_from AS is_valid, cnew.accno
 688     FROM chart c
 689     LEFT JOIN chart cnew ON c.new_chart_id = cnew.id
 690     WHERE NOT c.new_chart_id IS NULL AND (c.new_chart_id > 0)
 691 SQL
 692
 693   while (1) {
 694     my $ref = $form->{ACCOUNT_CHAIN_BY_ID}->{$accno_id};
 695     last unless ($ref && $ref->{"is_valid"} &&
 696                  !grep({ $_ == $ref->{"new_chart_id"} } @visited_accno_ids));
 697     $accno_id = $ref->{"new_chart_id"};
 698     $accno = $ref->{"accno"};
 699     push(@visited_accno_ids, $accno_id);
 700   }
 701
 702   $main::lxdebug->leave_sub(2);
 703
 704   return ($accno_id, $accno);
 705 }
 706
 707 sub retrieve_accounts {
 708   $main::lxdebug->enter_sub;
 709
 710   my $self     = shift;
 711   my $myconfig = shift;
 712   my $form     = shift;
 713   my $dbh      = $form->get_standard_dbh;
 714   my %args     = @_;     # index => part_id
 715
 716   $form->{taxzone_id} *= 1;
 717
 718   return unless grep $_, values %args; # shortfuse if no part_id supplied
 719
 720   # transdate madness.
 721   my $transdate = "";
 722   if ($form->{type} eq "invoice" or $form->{type} eq "credit_note") {
 723     # use deliverydate for sales and purchase invoice, if it exists
 724     # also use deliverydate for credit notes
 725     if (!$form->{deliverydate}) {
 726       $transdate = $form->{invdate};
 727     } else {
 728       $transdate = $form->{deliverydate};
 729     }
 730   } elsif ($form->{script} eq 'ir.pl') {
 731     # when a purchase invoice is opened from the report of purchase invoices
 732     # $form->{type} isn't set, but $form->{script} is, not sure why this is or
 733     # whether this distinction matters in some other scenario. Otherwise one
 734     # could probably take out this elsif and add a
 735     # " or $form->{script} eq 'ir.pl' "
 736     # to the above if-statement
 737     if (!$form->{deliverydate}) {
 738       $transdate = $form->{invdate};
 739     } else {
 740       $transdate = $form->{deliverydate};
 741     }
 742   } elsif (($form->{type} eq "credit_note") and $form->{deliverydate}) {
 743     # if credit_note has a deliverydate, use this instead of invdate
 744     # useful for credit_notes of invoices from an old period with different tax
 745     # if there is no deliverydate then invdate is used, old default (see next elsif)
 746     # Falls hier der Stichtag für Steuern anders bestimmt wird,
 747     # entsprechend auch bei Taxkeys.pm anpassen
 748     $transdate = $form->{deliverydate};
 749   } elsif (($form->{type} eq "credit_note") || ($form->{script} eq 'ir.pl')) {
 750     $transdate = $form->{invdate};
 751   } else {
 752     $transdate = $form->{transdate};
 753   }
 754
 755   if ($transdate eq "") {
 756     $transdate = DateTime->today_local->to_lxoffice;
 757   } else {
 758     $transdate = $dbh->quote($transdate);
 759   }
 760   #/transdate
 761   my $inc_exp = $form->{"vc"} eq "customer" ? "income_accno_id" : "expense_accno_id";
 762
 763   my @part_ids = grep { $_ } values %args;
 764   my $in       = join ',', ('?') x @part_ids;
 765
 766   my %accno_by_part = map { $_->{id} => $_ }
 767     selectall_hashref_query($form, $dbh, <<SQL, @part_ids);
 768     SELECT
 769       p.id, p.part_type,
 770       bg.inventory_accno_id,
 771       tc.income_accno_id AS income_accno_id,
 772       tc.expense_accno_id AS expense_accno_id,
 773       c1.accno AS inventory_accno,
 774       c2.accno AS income_accno,
 775       c3.accno AS expense_accno
 776     FROM parts p
 777     LEFT JOIN buchungsgruppen bg ON p.buchungsgruppen_id = bg.id
 778     LEFT JOIN taxzone_charts tc on bg.id = tc.buchungsgruppen_id
 779     LEFT JOIN chart c1 ON bg.inventory_accno_id = c1.id
 780     LEFT JOIN chart c2 ON tc.income_accno_id = c2.id
 781     LEFT JOIN chart c3 ON tc.expense_accno_id = c3.id
 782     WHERE
 783     tc.taxzone_id = '$form->{taxzone_id}'
 784     and
 785     p.id IN ($in)
 786 SQL
 787
 788   my $query_tax = <<SQL;
 789     SELECT c.accno, t.taxdescription AS description, t.rate, t.taxnumber
 790     FROM tax t
 791     LEFT JOIN chart c ON c.id = t.chart_id
 792     WHERE t.id IN
 793       (SELECT tk.tax_id
 794        FROM taxkeys tk
 795        WHERE tk.chart_id = ? AND startdate <= ?
 796        ORDER BY startdate DESC LIMIT 1)
 797 SQL
 798   my $sth_tax = prepare_query($::form, $dbh, $query_tax);
 799
 800   while (my ($index => $part_id) = each %args) {
 801     my $ref = $accno_by_part{$part_id} or next;
 802
 803     $ref->{"inventory_accno_id"} = undef unless $ref->{"part_type"} eq 'part';
 804
 805     my %accounts;
 806     for my $type (qw(inventory income expense)) {
 807       next unless $ref->{"${type}_accno_id"};
 808       ($accounts{"${type}_accno_id"}, $accounts{"${type}_accno"}) =
 809         $self->follow_account_chain($form, $dbh, $transdate, $ref->{"${type}_accno_id"}, $ref->{"${type}_accno"});
 810     }
 811
 812     $form->{"${_}_accno_$index"} = $accounts{"${_}_accno"} for qw(inventory income expense);
 813
 814     $sth_tax->execute($accounts{$inc_exp}, quote_db_date($transdate)) || $::form->dberror($query_tax);
 815     $ref = $sth_tax->fetchrow_hashref or next;
 816
 817     $form->{"taxaccounts_$index"} = $ref->{"accno"};
 818     $form->{"taxaccounts"} .= "$ref->{accno} "if $form->{"taxaccounts"} !~ /$ref->{accno}/;
 819
 820     $form->{"$ref->{accno}_${_}"} = $ref->{$_} for qw(rate description taxnumber);
 821   }
 822
 823   $sth_tax->finish;
 824
 825   $::lxdebug->leave_sub;
 826 }
 827
 828 sub get_basic_part_info {
 829   $main::lxdebug->enter_sub();
 830
 831   my $self     = shift;
 832   my %params   = @_;
 833
 834   Common::check_params(\%params, qw(id));
 835
 836   my @ids      = 'ARRAY' eq ref $params{id} ? @{ $params{id} } : ($params{id});
 837
 838   if (!scalar @ids) {
 839     $main::lxdebug->leave_sub();
 840     return ();
 841   }
 842
 843   my $myconfig = \%main::myconfig;
 844   my $form     = $main::form;
 845
 846   my $dbh      = $form->get_standard_dbh($myconfig);
 847
 848   my $query    = qq|SELECT * FROM parts WHERE id IN (| . join(', ', ('?') x scalar(@ids)) . qq|)|;
 849
 850   my $info     = selectall_hashref_query($form, $dbh, $query, map { conv_i($_) } @ids);
 851
 852   if ('' eq ref $params{id}) {
 853     $info = $info->[0] || { };
 854
 855     $main::lxdebug->leave_sub();
 856     return $info;
 857   }
 858
 859   my %info_map = map { $_->{id} => $_ } @{ $info };
 860
 861   $main::lxdebug->leave_sub();
 862
 863   return %info_map;
 864 }
 865
 866 sub prepare_parts_for_printing {
 867   $main::lxdebug->enter_sub();
 868
 869   my $self     = shift;
 870   my %params   = @_;
 871
 872   my $myconfig = $params{myconfig} || \%main::myconfig;
 873   my $form     = $params{form}     || $main::form;
 874
 875   my $dbh      = $params{dbh} || $form->get_standard_dbh($myconfig);
 876
 877   my $prefix   = $params{prefix} || 'id_';
 878   my $rowcount = defined $params{rowcount} ? $params{rowcount} : $form->{rowcount};
 879
 880   my @part_ids = keys %{ { map { $_ => 1 } grep { $_ } map { $form->{"${prefix}${_}"} } (1 .. $rowcount) } };
 881
 882   if (!@part_ids) {
 883     $main::lxdebug->leave_sub();
 884     return;
 885   }
 886
 887   my $placeholders = join ', ', ('?') x scalar(@part_ids);
 888   my $query        = qq|SELECT mm.parts_id, mm.model, mm.lastcost, v.name AS make
 889                         FROM makemodel mm
 890                         LEFT JOIN vendor v ON (mm.make = v.id)
 891                         WHERE mm.parts_id IN ($placeholders)|;
 892
 893   my %makemodel    = ();
 894
 895   my $sth          = prepare_execute_query($form, $dbh, $query, @part_ids);
 896
 897   while (my $ref = $sth->fetchrow_hashref()) {
 898     $makemodel{$ref->{parts_id}} ||= [];
 899     push @{ $makemodel{$ref->{parts_id}} }, $ref;
 900   }
 901
 902   $sth->finish();
 903
 904   my @columns = qw(ean image microfiche drawing);
 905
 906   $query      = qq|SELECT id, | . join(', ', @columns) . qq|
 907                    FROM parts
 908                    WHERE id IN ($placeholders)|;
 909
 910   my %data    = selectall_as_map($form, $dbh, $query, 'id', \@columns, @part_ids);
 911
 912   my %template_arrays;
 913   map { $template_arrays{$_} = [] } (qw(make model), @columns);
 914
 915   foreach my $i (1 .. $rowcount) {
 916     my $id = $form->{"${prefix}${i}"};
 917
 918     next if (!$id);
 919
 920     foreach (@columns) {
 921       push @{ $template_arrays{$_} }, $data{$id}->{$_};
 922     }
 923
 924     push @{ $template_arrays{make} },  [];
 925     push @{ $template_arrays{model} }, [];
 926
 927     next if (!$makemodel{$id});
 928
 929     foreach my $ref (@{ $makemodel{$id} }) {
 930       map { push @{ $template_arrays{$_}->[-1] }, $ref->{$_} } qw(make model);
 931     }
 932   }
 933
 934   my $parts = SL::DB::Manager::Part->get_all(query => [ id => \@part_ids ]);
 935   my %parts_by_id = map { $_->id => $_ } @$parts;
 936
 937   for my $i (1..$rowcount) {
 938     my $id = $form->{"${prefix}${i}"};
 939     next unless $id;
 940     my $prt = $parts_by_id{$id};
 941     my $type_abbr = $::request->presenter->type_abbreviation($prt->part_type);
 942     push @{ $template_arrays{part_type}         }, $prt->part_type;
 943     push @{ $template_arrays{part_abbreviation} }, $type_abbr;
 944     push @{ $template_arrays{type_and_classific}}, $type_abbr.$::request->presenter->classification_abbreviation($prt->classification_id);
 945     push @{ $template_arrays{separate}  },  $::request->presenter->separate_abbreviation($prt->classification_id);
 946   }
 947
 948   $main::lxdebug->leave_sub();
 949   return %template_arrays;
 950 }
 951
 952 sub normalize_text_blocks {
 953   $main::lxdebug->enter_sub();
 954
 955   my $self     = shift;
 956   my %params   = @_;
 957
 958   my $form     = $params{form}     || $main::form;
 959
 960   # check if feature is enabled (select normalize_part_descriptions from defaults)
 961   return unless ($::instance_conf->get_normalize_part_descriptions);
 962
 963   foreach (qw(description notes)) {
 964     $form->{$_} =~ s/\s+$//s;
 965     $form->{$_} =~ s/^\s+//s;
 966     $form->{$_} =~ s/ {2,}/ /g;
 967   }
 968    $main::lxdebug->leave_sub();
 969 }
 970
 971
 972 1;