SL/IC.pm

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (C) 2001
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #  Contributors:
  16 #
  17 # This program is free software; you can redistribute it and/or modify
  18 # it under the terms of the GNU General Public License as published by
  19 # the Free Software Foundation; either version 2 of the License, or
  20 # (at your option) any later version.
  21 #
  22 # This program is distributed in the hope that it will be useful,
  23 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  24 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25 # GNU General Public License for more details.
  26 # You should have received a copy of the GNU General Public License
  27 # along with this program; if not, write to the Free Software
  28 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
  29 # MA 02110-1335, USA.
  30 #======================================================================
  31 #
  32 # Inventory Control backend
  33 #
  34 #======================================================================
  35
  36 package IC;
  37
  38 use Data::Dumper;
  39 use List::MoreUtils qw(all any uniq);
  40
  41 use SL::CVar;
  42 use SL::DBUtils;
  43 use SL::HTML::Restrict;
  44 use SL::TransNumber;
  45 use SL::Util qw(trim);
  46 use SL::DB;
  47 use SL::Presenter::Part qw(type_abbreviation classification_abbreviation separate_abbreviation);
  48 use Carp;
  49
  50 use strict;
  51
  52 sub retrieve_buchungsgruppen {
  53   $main::lxdebug->enter_sub();
  54
  55   my ($self, $myconfig, $form) = @_;
  56
  57   my ($query, $sth);
  58
  59   my $dbh = $form->get_standard_dbh;
  60
  61   # get buchungsgruppen
  62   $query = qq|SELECT id, description FROM buchungsgruppen ORDER BY sortkey|;
  63   $form->{BUCHUNGSGRUPPEN} = selectall_hashref_query($form, $dbh, $query);
  64
  65   $main::lxdebug->leave_sub();
  66 }
  67
  68 sub assembly_item {
  69   $main::lxdebug->enter_sub();
  70
  71   my ($self, $myconfig, $form) = @_;
  72
  73   my $i = $form->{assembly_rows};
  74   my $var;
  75   my $where = qq|1 = 1|;
  76   my @values;
  77
  78   my %columns = ("partnumber" => "p", "description" => "p", "partsgroup" => "pg");
  79
  80   while (my ($column, $table) = each(%columns)) {
  81     next unless ($form->{"${column}_$i"});
  82     $where .= qq| AND ${table}.${column} ILIKE ?|;
  83     push(@values, like($form->{"${column}_$i"}));
  84   }
  85
  86   if ($form->{id}) {
  87     $where .= qq| AND NOT (p.id = ?)|;
  88     push(@values, conv_i($form->{id}));
  89   }
  90
  91   # Search for part ID overrides all other criteria.
  92   if ($form->{"id_${i}"}) {
  93     $where  = qq|p.id = ?|;
  94     @values = ($form->{"id_${i}"});
  95   }
  96
  97   if ($form->{partnumber}) {
  98     $where .= qq| ORDER BY p.partnumber|;
  99   } else {
 100     $where .= qq| ORDER BY p.description|;
 101   }
 102
 103   my $query =
 104     qq|SELECT p.id, p.partnumber, p.description, p.sellprice,
 105        p.classification_id,
 106        p.weight, p.onhand, p.unit, pg.partsgroup, p.lastcost,
 107        p.price_factor_id, pfac.factor AS price_factor, p.notes as longdescription
 108        FROM parts p
 109        LEFT JOIN partsgroup pg ON (p.partsgroup_id = pg.id)
 110        LEFT JOIN price_factors pfac ON pfac.id = p.price_factor_id
 111        WHERE $where|;
 112   $form->{item_list} = selectall_hashref_query($form, SL::DB->client->dbh, $query, @values);
 113
 114   $main::lxdebug->leave_sub();
 115 }
 116
 117 #
 118 # Report for Wares.
 119 # Warning, deep magic ahead.
 120 # This function gets all parts from the database according to the filters specified
 121 #
 122 # specials:
 123 #   sort revers  - sorting field + direction
 124 #   top100
 125 #
 126 # simple filter strings (every one of those also has a column flag prefixed with 'l_' associated):
 127 #   partnumber ean description partsgroup microfiche drawing
 128 #
 129 # column flags:
 130 #   l_partnumber l_description l_listprice l_sellprice l_lastcost l_priceupdate l_weight l_unit l_rop l_image l_drawing l_microfiche l_partsgroup
 131 #   l_warehouse  l_bin
 132 #
 133 # exclusives:
 134 #   itemstatus  = active | onhand | short | obsolete | orphaned
 135 #   searchitems = part | assembly | service
 136 #
 137 # joining filters:
 138 #   make model                               - makemodel
 139 #   serialnumber transdatefrom transdateto   - invoice/orderitems
 140 #   warehouse                                - warehouse
 141 #   bin                                      - bin
 142 #
 143 # binary flags:
 144 #   bought sold onorder ordered rfq quoted   - aggreg joins with invoices/orders
 145 #   l_linetotal l_subtotal                   - aggreg joins to display totals (complicated) - NOT IMPLEMENTED here, implementation at frontend
 146 #   l_soldtotal                              - aggreg join to display total of sold quantity
 147 #   onhand                                   - as above, but masking the simple itemstatus results (doh!)
 148 #   short                                    - NOT IMPLEMENTED as form filter, only as itemstatus option
 149 #   l_serialnumber                           - belonges to serialnumber filter
 150 #   l_deliverydate                           - displays deliverydate is sold etc. flags are active
 151 #   l_soldtotal                              - aggreg join to display total of sold quantity, works as long as there's no bullshit in soldtotal
 152 #
 153 # not working:
 154 #   onhand                                   - as above, but masking the simple itemstatus results (doh!)
 155 #   warehouse onhand
 156 #   search by overrides of description
 157 #   soldtotal drops option default warehouse and bin
 158 #   soldtotal can not work if there are no documents checked
 159 #
 160 # disabled sanity checks and changes:
 161 #  - searchitems = assembly will no longer disable bought
 162 #  - searchitems = service  will no longer disable make and model, although services don't have make/model, it doesn't break the query
 163 #  - itemstatus  = orphaned will no longer disable onhand short bought sold onorder ordered rfq quoted transdate[from|to]
 164 #  - itemstatus  = obsolete will no longer disable onhand, short
 165 #  - allow sorting by ean
 166 #  - serialnumber filter also works if l_serialnumber isn't ticked
 167 #  - sorting will now change sorting if the requested sorting column isn't checked and doesn't get checked as a side effect
 168 #
 169 sub all_parts {
 170   $main::lxdebug->enter_sub();
 171
 172   my ($self, $myconfig, $form) = @_;
 173   my $dbh = $form->get_standard_dbh($myconfig);
 174
 175   # sanity backend check
 176   croak "Cannot combine soldtotal with default bin or default warehouse" if ($form->{l_soldtotal} && ($form->{l_bin} || $form->{l_warehouse}));
 177
 178   $form->{parts}     = +{ };
 179   $form->{soldtotal} = undef if $form->{l_soldtotal}; # security fix. top100 insists on putting strings in there...
 180
 181   my @simple_filters       = qw(partnumber ean description partsgroup microfiche drawing onhand);
 182   my @project_filters      = qw(projectnumber projectdescription);
 183   my @makemodel_filters    = qw(make model);
 184   my @invoice_oi_filters   = qw(serialnumber soldtotal);
 185   my @apoe_filters         = qw(transdate);
 186   my @like_filters         = (@simple_filters, @invoice_oi_filters);
 187   my @all_columns          = (@simple_filters, @makemodel_filters, @apoe_filters, @project_filters, qw(serialnumber));
 188   my @simple_l_switches    = (@all_columns, qw(notes listprice sellprice lastcost priceupdate weight unit rop image shop insertdate));
 189   my %no_simple_l_switches = (warehouse => 'wh.description as warehouse', bin => 'bin.description as bin');
 190   my @oe_flags             = qw(bought sold onorder ordered rfq quoted);
 191   my @qsooqr_flags         = qw(invnumber ordnumber quonumber trans_id name module qty);
 192   my @deliverydate_flags   = qw(deliverydate);
 193 #  my @other_flags          = qw(onhand); # ToDO: implement these
 194 #  my @inactive_flags       = qw(l_subtotal short l_linetotal);
 195
 196   my @select_tokens = qw(id factor part_type classification_id);
 197   my @where_tokens  = qw(1=1);
 198   my @group_tokens  = ();
 199   my @bind_vars     = ();
 200   my %joins_needed  = ();
 201
 202   my %joins = (
 203     partsgroup => 'LEFT JOIN partsgroup pg      ON (pg.id       = p.partsgroup_id)',
 204     makemodel  => 'LEFT JOIN makemodel mm       ON (mm.parts_id = p.id)',
 205     pfac       => 'LEFT JOIN price_factors pfac ON (pfac.id     = p.price_factor_id)',
 206     invoice_oi =>
 207       q|LEFT JOIN (
 208          SELECT parts_id, description, serialnumber, trans_id, unit, sellprice, qty,          assemblyitem,         deliverydate, 'invoice'    AS ioi, project_id, id FROM invoice UNION
 209          SELECT parts_id, description, serialnumber, trans_id, unit, sellprice, qty, FALSE AS assemblyitem, NULL AS deliverydate, 'orderitems' AS ioi, project_id, id FROM orderitems
 210        ) AS ioi ON ioi.parts_id = p.id|,
 211     apoe       =>
 212       q|LEFT JOIN (
 213          SELECT id, transdate, 'ir' AS module, ordnumber, quonumber,         invnumber, FALSE AS quotation, NULL AS customer_id,         vendor_id,    NULL AS deliverydate, globalproject_id, 'invoice'    AS ioi FROM ap UNION
 214          SELECT id, transdate, 'is' AS module, ordnumber, quonumber,         invnumber, FALSE AS quotation,         customer_id, NULL AS vendor_id,            deliverydate, globalproject_id, 'invoice'    AS ioi FROM ar UNION
 215          SELECT id, transdate, 'oe' AS module, ordnumber, quonumber, NULL AS invnumber,          quotation,         customer_id,         vendor_id, reqdate AS deliverydate, globalproject_id, 'orderitems' AS ioi FROM oe
 216        ) AS apoe ON ((ioi.trans_id = apoe.id) AND (ioi.ioi = apoe.ioi))|,
 217     cv         =>
 218       q|LEFT JOIN (
 219            SELECT id, name, 'customer' AS cv FROM customer UNION
 220            SELECT id, name, 'vendor'   AS cv FROM vendor
 221          ) AS cv ON cv.id = apoe.customer_id OR cv.id = apoe.vendor_id|,
 222     mv         => 'LEFT JOIN vendor AS mv ON mv.id = mm.make',
 223     project    => 'LEFT JOIN project AS pj ON pj.id = COALESCE(ioi.project_id, apoe.globalproject_id)',
 224     warehouse  => 'LEFT JOIN warehouse AS wh ON wh.id = p.warehouse_id',
 225     bin        => 'LEFT JOIN bin ON bin.id = p.bin_id',
 226   );
 227   my @join_order = qw(partsgroup makemodel mv invoice_oi apoe cv pfac project warehouse bin);
 228
 229   my %table_prefix = (
 230      deliverydate => 'apoe.', serialnumber => 'ioi.',
 231      transdate    => 'apoe.', trans_id     => 'ioi.',
 232      module       => 'apoe.', name         => 'cv.',
 233      ordnumber    => 'apoe.', make         => 'mm.',
 234      quonumber    => 'apoe.', model        => 'mm.',
 235      invnumber    => 'apoe.', partsgroup   => 'pg.',
 236      lastcost     => 'p.',  , soldtotal    => ' ',
 237      factor       => 'pfac.', projectnumber => 'pj.',
 238      'SUM(ioi.qty)' => ' ',   projectdescription => 'pj.',
 239      description  => 'p.',
 240      qty          => 'ioi.',
 241      serialnumber => 'ioi.',
 242      quotation    => 'apoe.',
 243      cv           => 'cv.',
 244      "ioi.id"     => ' ',
 245      "ioi.ioi"    => ' ',
 246   );
 247
 248   # if the join condition in these blocks are met, the column
 249   # of the specified table will gently override (coalesce actually) the original value
 250   # use it to conditionally coalesce values from subtables
 251   my @column_override = (
 252     #  column name,   prefix,  joins_needed,  nick name (in case column is named like another)
 253     [ 'description',  'ioi.',  'invoice_oi'  ],
 254     [ 'deliverydate', 'ioi.',  'invoice_oi'  ],
 255     [ 'transdate',    'apoe.', 'apoe'        ],
 256     [ 'unit',         'ioi.',  'invoice_oi'  ],
 257     [ 'sellprice',    'ioi.',  'invoice_oi'  ],
 258   );
 259
 260   # careful with renames. these are HARD, and any filters done on the original column will break
 261   my %renamed_columns = (
 262     'factor'       => 'price_factor',
 263     'SUM(ioi.qty)' => 'soldtotal',
 264     'ioi.id'       => 'ioi_id',
 265     'ioi.ioi'      => 'ioi',
 266     'projectdescription' => 'projectdescription',
 267     'insertdate'   => 'insertdate',
 268   );
 269
 270   my %real_column = (
 271     projectdescription => 'description',
 272     insertdate         => 'itime::DATE',
 273   );
 274
 275   my $make_token_builder = sub {
 276     my $joins_needed = shift;
 277     sub {
 278       my ($nick, $alias) = @_;
 279       my ($col) = $real_column{$nick} || $nick;
 280       my @coalesce_tokens =
 281         map  { ($_->[1] || 'p.') . $_->[0] }
 282         grep { !$_->[2] || $joins_needed->{$_->[2]} }
 283         grep { ($_->[3] || $_->[0]) eq $nick }
 284         @column_override, [ $col, $table_prefix{$nick}, undef , $nick ];
 285
 286       my $coalesce = scalar @coalesce_tokens > 1;
 287       return ($coalesce
 288         ? sprintf 'COALESCE(%s)', join ', ', @coalesce_tokens
 289         : shift                              @coalesce_tokens)
 290         . ($alias && ($coalesce || $renamed_columns{$nick})
 291         ?  " AS " . ($renamed_columns{$nick} || $nick)
 292         : '');
 293     }
 294   };
 295
 296   #===== switches and simple filters ========#
 297
 298   # special case transdate
 299   if (grep { trim($form->{$_}) } qw(transdatefrom transdateto)) {
 300     $form->{"l_transdate"} = 1;
 301     push @select_tokens, 'transdate';
 302     for (qw(transdatefrom transdateto)) {
 303       my $value = trim($form->{$_});
 304       next unless $value;
 305       push @where_tokens, sprintf "transdate %s ?", /from$/ ? '>=' : '<=';
 306       push @bind_vars,    $value;
 307     }
 308   }
 309
 310   # special case smart search
 311   if ($form->{all}) {
 312     $form->{"l_$_"}       = 1 for qw(partnumber description unit sellprice lastcost linetotal);
 313     $form->{l_service}    = 1 if $form->{searchitems} eq 'service'    || $form->{searchitems} eq '';
 314     $form->{l_assembly}   = 1 if $form->{searchitems} eq 'assembly'   || $form->{searchitems} eq '';
 315     $form->{l_part}       = 1 if $form->{searchitems} eq 'part'       || $form->{searchitems} eq '';
 316     $form->{l_assortment} = 1 if $form->{searchitems} eq 'assortment' || $form->{searchitems} eq '';
 317     push @where_tokens, "p.partnumber ILIKE ? OR p.description ILIKE ?";
 318     push @bind_vars,    (like($form->{all})) x 2;
 319   }
 320
 321   # special case insertdate
 322   if (grep { trim($form->{$_}) } qw(insertdatefrom insertdateto)) {
 323     $form->{"l_insertdate"} = 1;
 324     push @select_tokens, 'insertdate';
 325
 326     my $token_builder = $make_token_builder->();
 327     my $token = $token_builder->('insertdate');
 328
 329     for (qw(insertdatefrom insertdateto)) {
 330       my $value = trim($form->{$_});
 331       next unless $value;
 332       push @where_tokens, sprintf "$token %s ?", /from$/ ? '>=' : '<=';
 333       push @bind_vars,    $value;
 334     }
 335   }
 336
 337   if ($form->{"partsgroup_id"}) {
 338     $form->{"l_partsgroup"} = '1'; # show the column
 339     push @where_tokens, "pg.id = ?";
 340     push @bind_vars, $form->{"partsgroup_id"};
 341   }
 342
 343   if ($form->{shop} ne '') {
 344     $form->{l_shop} = '1'; # show the column
 345     if ($form->{shop} eq '0' || $form->{shop} eq 'f') {
 346       push @where_tokens, 'NOT p.shop';
 347       $form->{shop} = 'f';
 348     } else {
 349       push @where_tokens, 'p.shop';
 350     }
 351   }
 352
 353   foreach (@like_filters) {
 354     next unless $form->{$_};
 355     $form->{"l_$_"} = '1'; # show the column
 356     push @where_tokens, "$table_prefix{$_}$_ ILIKE ?";
 357     push @bind_vars,    like($form->{$_});
 358   }
 359
 360   foreach (@simple_l_switches) {
 361     next unless $form->{"l_$_"};
 362     push @select_tokens, $_;
 363   }
 364
 365   # Oder Bedingungen fuer Ware Dienstleistung Erzeugnis:
 366   if ($form->{l_part} || $form->{l_assembly} || $form->{l_service} || $form->{l_assortment}) {
 367       my @or_tokens = ();
 368       push @or_tokens, "p.part_type = 'service'"    if $form->{l_service};
 369       push @or_tokens, "p.part_type = 'assembly'"   if $form->{l_assembly};
 370       push @or_tokens, "p.part_type = 'part'"       if $form->{l_part};
 371       push @or_tokens, "p.part_type = 'assortment'" if $form->{l_assortment};
 372       push @where_tokens, join ' OR ', map { "($_)" } @or_tokens;
 373   }
 374   else {
 375       # gar keine Teile
 376       push @where_tokens, q|'F' = 'T'|;
 377   }
 378
 379   if ( $form->{classification_id} > 0 ) {
 380     push @where_tokens, "p.classification_id = ?";
 381     push @bind_vars, $form->{classification_id};
 382   }
 383
 384   for ($form->{itemstatus}) {
 385     push @where_tokens, 'p.id NOT IN
 386         (SELECT DISTINCT parts_id FROM invoice UNION
 387          SELECT DISTINCT parts_id FROM assembly UNION
 388          SELECT DISTINCT parts_id FROM orderitems)'    if /orphaned/;
 389     push @where_tokens, 'p.onhand = 0'                 if /orphaned/;
 390     push @where_tokens, 'NOT p.obsolete'               if /active/;
 391     push @where_tokens, '    p.obsolete',              if /obsolete/;
 392     push @where_tokens, 'p.onhand > 0',                if /onhand/;
 393     push @where_tokens, 'p.onhand < p.rop',            if /short/;
 394   }
 395
 396   my $q_assembly_lastcost =
 397     qq|(SELECT SUM(a_lc.qty * p_lc.lastcost / COALESCE(pfac_lc.factor, 1))
 398         FROM assembly a_lc
 399         LEFT JOIN parts p_lc            ON (a_lc.parts_id        = p_lc.id)
 400         LEFT JOIN price_factors pfac_lc ON (p_lc.price_factor_id = pfac_lc.id)
 401         WHERE (a_lc.id = p.id)) AS assembly_lastcost|;
 402   $table_prefix{$q_assembly_lastcost} = ' ';
 403
 404   # special case makemodel search
 405   # all_parts is based upon the assumption that every parameter is named like the column it represents
 406   # unfortunately make would have to match vendor.name which is already taken for vendor.name in bsooqr mode.
 407   # fortunately makemodel doesn't need to be displayed later, so adding a special clause to where_token is sufficient.
 408   if ($form->{make}) {
 409     push @where_tokens, 'mv.name ILIKE ?';
 410     push @bind_vars, like($form->{make});
 411   }
 412   if ($form->{model}) {
 413     push @where_tokens, 'mm.model ILIKE ?';
 414     push @bind_vars, like($form->{model});
 415   }
 416
 417   # special case: sorting by partnumber
 418   # since partnumbers are expected to be prefixed integers, a special sorting is implemented sorting first lexically by prefix and then by suffix.
 419   # and yes, that expression is designed to hold that array of regexes only once, so the map is kinda messy, sorry about that.
 420   # ToDO: implement proper functional sorting
 421   # Nette Idee von Sven, gibt aber Probleme wenn die Artikelnummern groesser als 32bit sind. Korrekt waere es, dass Sort-Natural-Modul zu nehmen
 422   # Ich lass das mal hier drin, damit die Idee erhalten bleibt jb 28.5.2009 bug 1018
 423   #$form->{sort} = join ', ', map { push @select_tokens, $_; ($table_prefix{$_} = "substring(partnumber,'[") . $_ } qw|^[:digit:]]+') [:digit:]]+')::INTEGER|
 424   #  if $form->{sort} eq 'partnumber';
 425
 426   #my $order_clause = " ORDER BY $form->{sort} $sort_order";
 427
 428   my $limit_clause;
 429   $limit_clause = " LIMIT 100"                   if $form->{top100};
 430   $limit_clause = " LIMIT " . $form->{limit} * 1 if $form->{limit} * 1;
 431
 432   #=== joins and complicated filters ========#
 433
 434   my $bsooqr        = any { $form->{$_} } @oe_flags;
 435   my @bsooqr_tokens = ();
 436
 437   push @select_tokens, @qsooqr_flags, 'quotation', 'cv', 'ioi.id', 'ioi.ioi'  if $bsooqr;
 438   push @select_tokens, @deliverydate_flags                                    if $bsooqr && $form->{l_deliverydate};
 439   push @select_tokens, $q_assembly_lastcost                                   if $form->{l_assembly} && $form->{l_lastcost};
 440   push @bsooqr_tokens, q|module = 'ir' AND NOT ioi.assemblyitem|              if $form->{bought};
 441   push @bsooqr_tokens, q|module = 'is' AND NOT ioi.assemblyitem|              if $form->{sold};
 442   push @bsooqr_tokens, q|module = 'oe' AND NOT quotation AND cv = 'customer'| if $form->{ordered};
 443   push @bsooqr_tokens, q|module = 'oe' AND NOT quotation AND cv = 'vendor'|   if $form->{onorder};
 444   push @bsooqr_tokens, q|module = 'oe' AND     quotation AND cv = 'customer'| if $form->{quoted};
 445   push @bsooqr_tokens, q|module = 'oe' AND     quotation AND cv = 'vendor'|   if $form->{rfq};
 446   push @where_tokens, join ' OR ', map { "($_)" } @bsooqr_tokens              if $bsooqr;
 447
 448   $joins_needed{partsgroup}  = 1;
 449   $joins_needed{pfac}        = 1;
 450   $joins_needed{project}     = 1 if grep { $form->{$_} || $form->{"l_$_"} } @project_filters;
 451   $joins_needed{makemodel}   = 1 if grep { $form->{$_} || $form->{"l_$_"} } @makemodel_filters;
 452   $joins_needed{mv}          = 1 if $joins_needed{makemodel};
 453   $joins_needed{cv}          = 1 if $bsooqr;
 454   $joins_needed{apoe}        = 1 if $joins_needed{project} || $joins_needed{cv}   || grep { $form->{$_} || $form->{"l_$_"} } @apoe_filters;
 455   $joins_needed{invoice_oi}  = 1 if $joins_needed{project} || $joins_needed{apoe} || grep { $form->{$_} || $form->{"l_$_"} } @invoice_oi_filters;
 456   $joins_needed{bin}         = 1 if $form->{l_bin};
 457   $joins_needed{warehouse}   = 1 if $form->{l_warehouse};
 458
 459   # special case for description search.
 460   # up in the simple filter section the description filter got interpreted as something like: WHERE description ILIKE '%$form->{description}%'
 461   # now we'd like to search also for the masked description entered in orderitems and invoice, so...
 462   # find the old entries in of @where_tokens and @bind_vars, and adjust them
 463   if ($joins_needed{invoice_oi}) {
 464     for (my ($wi, $bi) = (0)x2; $wi <= $#where_tokens; $bi++ if $where_tokens[$wi++] =~ /\?/) {
 465       next unless $where_tokens[$wi] =~ /\bdescription ILIKE/;
 466       splice @where_tokens, $wi, 1, 'p.description ILIKE ? OR ioi.description ILIKE ?';
 467       splice @bind_vars,    $bi, 0, $bind_vars[$bi];
 468       last;
 469     }
 470   }
 471
 472   # now the master trick: soldtotal.
 473   if ($form->{l_soldtotal}) {
 474     push @where_tokens, 'NOT ioi.qty = 0';
 475     push @group_tokens, @select_tokens;
 476      map { s/.*\sAS\s+//si } @group_tokens;
 477     push @select_tokens, 'SUM(ioi.qty)';
 478   }
 479
 480   #============= build query ================#
 481
 482   my $token_builder = $make_token_builder->(\%joins_needed);
 483
 484   my @sort_cols    = (@simple_filters, qw(id onhand invnumber ordnumber quonumber name serialnumber soldtotal deliverydate insertdate shop));
 485      $form->{sort} = 'id' unless grep { $form->{"l_$_"} } grep { $form->{sort} eq $_ } @sort_cols; # sort by id if unknown or invisible column
 486   my $sort_order   = ($form->{revers} ? ' DESC' : ' ASC');
 487   my $order_clause = " ORDER BY " . $token_builder->($form->{sort}) . ($form->{revers} ? ' DESC' : ' ASC');
 488
 489   my $select_clause = join ', ',    map { $token_builder->($_, 1) } @select_tokens;
 490   my $join_clause   = join ' ',     @joins{ grep $joins_needed{$_}, @join_order };
 491   my $where_clause  = join ' AND ', map { "($_)" } @where_tokens;
 492   my $group_clause  = @group_tokens ? ' GROUP BY ' . join ', ',    map { $token_builder->($_) } @group_tokens : '';
 493
 494   # key of %no_simple_l_switch is the logical l_switch.
 495   # the assigned value is the 'not so simple
 496   # select token'
 497   my $no_simple_select_clause;
 498   foreach my $no_simple_l_switch (keys %no_simple_l_switches) {
 499     next unless $form->{"l_${no_simple_l_switch}"};
 500     $no_simple_select_clause .= ', '. $no_simple_l_switches{$no_simple_l_switch};
 501   }
 502   $select_clause .= $no_simple_select_clause;
 503
 504   my %oe_flag_to_cvar = (
 505     bought   => 'invoice',
 506     sold     => 'invoice',
 507     onorder  => 'orderitems',
 508     ordered  => 'orderitems',
 509     rfq      => 'orderitems',
 510     quoted   => 'orderitems',
 511   );
 512
 513   my ($cvar_where, @cvar_values) = CVar->build_filter_query(
 514     module         => 'IC',
 515     trans_id_field => $bsooqr ? 'ioi.id': 'p.id',
 516     filter         => $form,
 517     sub_module     => $bsooqr ? [ uniq grep { $oe_flag_to_cvar{$form->{$_}} } @oe_flags ] : undef,
 518   );
 519
 520   if ($cvar_where) {
 521     $where_clause .= qq| AND ($cvar_where)|;
 522     push @bind_vars, @cvar_values;
 523   }
 524
 525   # simple search for assemblies by items used in assemblies
 526   if ($form->{bom} eq '2' && $form->{l_assembly}) {
 527     # nuke where clause and bind vars
 528     $where_clause = ' 1=1 AND p.id in (SELECT id from assembly where parts_id IN ' .
 529                     ' (select id from parts where 1=1';
 530     @bind_vars    = ();
 531     # use only like filter for items used in assemblies
 532     foreach (@like_filters) {
 533       next unless $form->{$_};
 534       $form->{"l_$_"} = '1'; # show the column
 535       $where_clause .= " AND $_ ILIKE ? ";
 536       push @bind_vars,    like($form->{$_});
 537     }
 538     $where_clause .='))';
 539   }
 540
 541   my $query = <<"  SQL";
 542     SELECT DISTINCT $select_clause
 543     FROM parts p
 544     $join_clause
 545     WHERE $where_clause
 546     $group_clause
 547     $order_clause
 548     $limit_clause
 549   SQL
 550   $form->{parts} = selectall_hashref_query($form, $dbh, $query, @bind_vars);
 551
 552   map { $_->{onhand} *= 1 } @{ $form->{parts} };
 553
 554   # fix qty sign in ap. those are saved negative
 555   if ($bsooqr && $form->{bought}) {
 556     for my $row (@{ $form->{parts} }) {
 557       $row->{qty} *= -1 if $row->{module} eq 'ir';
 558     }
 559   }
 560
 561   # post processing for assembly parts lists (bom)
 562   # for each part get the assembly parts and add them into the partlist.
 563   my @assemblies;
 564   if ($form->{l_assembly} && $form->{bom}) {
 565     $query =
 566       qq|SELECT p.id, p.partnumber, p.description, a.qty AS onhand,
 567            p.unit, p.notes, p.itime::DATE as insertdate,
 568            p.sellprice, p.listprice, p.lastcost,
 569            p.rop, p.weight,
 570            p.image, p.drawing, p.microfiche,
 571            pfac.factor
 572          FROM parts p
 573          INNER JOIN assembly a ON (p.id = a.parts_id)
 574          $joins{pfac}
 575          WHERE a.id = ?|;
 576     my $sth = prepare_query($form, $dbh, $query);
 577
 578     foreach my $item (@{ $form->{parts} }) {
 579       push(@assemblies, $item);
 580       do_statement($form, $sth, $query, conv_i($item->{id}));
 581
 582       while (my $ref = $sth->fetchrow_hashref("NAME_lc")) {
 583         $ref->{assemblyitem} = 1;
 584         map { $ref->{$_} /= $ref->{factor} || 1 } qw(sellprice listprice lastcost);
 585         push(@assemblies, $ref);
 586       }
 587       $sth->finish;
 588     }
 589
 590     # copy assemblies to $form->{parts}
 591     $form->{parts} = \@assemblies;
 592   }
 593
 594   if ($form->{l_pricegroups} ) {
 595     my $query = <<SQL;
 596        SELECT parts_id, price, pricegroup_id
 597        FROM prices
 598        WHERE parts_id = ?
 599 SQL
 600
 601     my $sth = prepare_query($form, $dbh, $query);
 602
 603     foreach my $part (@{ $form->{parts} }) {
 604       do_statement($form, $sth, $query, conv_i($part->{id}));
 605
 606       while (my $ref = $sth->fetchrow_hashref("NAME_lc")) {
 607         $part->{"pricegroup_$ref->{pricegroup_id}"} = $ref->{price};
 608       }
 609       $sth->finish;
 610     }
 611   }
 612
 613   $main::lxdebug->leave_sub();
 614
 615   return $form->{parts};
 616 }
 617
 618 # get partnumber, description, unit, sellprice and soldtotal with choice through $sortorder for Top100
 619 sub get_parts {
 620   $main::lxdebug->enter_sub();
 621
 622   my ($self, $myconfig, $form, $sortorder) = @_;
 623   my $dbh   = $form->get_standard_dbh;
 624   my $order = qq| p.partnumber|;
 625   my $where = qq|1 = 1|;
 626   my @values;
 627
 628   if ($sortorder eq "all") {
 629     $where .= qq| AND (partnumber ILIKE ?) AND (description ILIKE ?)|;
 630     push(@values, like($form->{partnumber}), like($form->{description}));
 631
 632   } elsif ($sortorder eq "partnumber") {
 633     $where .= qq| AND (partnumber ILIKE ?)|;
 634     push(@values, like($form->{partnumber}));
 635
 636   } elsif ($sortorder eq "description") {
 637     $where .= qq| AND (description ILIKE ?)|;
 638     push(@values, like($form->{description}));
 639     $order = "description";
 640
 641   }
 642
 643   my $query =
 644     qq|SELECT id, partnumber, description, unit, sellprice,
 645        classification_id
 646        FROM parts
 647        WHERE $where ORDER BY $order|;
 648
 649   my $sth = prepare_execute_query($form, $dbh, $query, @values);
 650
 651   my $j = 0;
 652   while (my $ref = $sth->fetchrow_hashref("NAME_lc")) {
 653     if (($ref->{partnumber} eq "*") && ($ref->{description} eq "")) {
 654       next;
 655     }
 656
 657     $j++;
 658     $form->{"type_and_classific_$j"} = type_abbreviation($ref->{part_type}).
 659                                        classification_abbreviation($ref->{classification_id});
 660     $form->{"id_$j"}          = $ref->{id};
 661     $form->{"partnumber_$j"}  = $ref->{partnumber};
 662     $form->{"description_$j"} = $ref->{description};
 663     $form->{"unit_$j"}        = $ref->{unit};
 664     $form->{"sellprice_$j"}   = $ref->{sellprice};
 665     $form->{"soldtotal_$j"}   = get_soldtotal($dbh, $ref->{id});
 666   }    #while
 667   $form->{rows} = $j;
 668   $sth->finish;
 669
 670   $main::lxdebug->leave_sub();
 671
 672   return $self;
 673 }    #end get_parts()
 674
 675 # gets sum of sold part with part_id
 676 sub get_soldtotal {
 677   $main::lxdebug->enter_sub();
 678
 679   my ($dbh, $id) = @_;
 680
 681   my $query = qq|SELECT sum(qty) FROM invoice WHERE parts_id = ?|;
 682   my ($sum) = selectrow_query($main::form, $dbh, $query, conv_i($id));
 683   $sum ||= 0;
 684
 685   $main::lxdebug->leave_sub();
 686
 687   return $sum;
 688 }    #end get_soldtotal
 689
 690 sub follow_account_chain {
 691   $main::lxdebug->enter_sub(2);
 692
 693   my ($self, $form, $dbh, $transdate, $accno_id, $accno) = @_;
 694
 695   my @visited_accno_ids = ($accno_id);
 696
 697   my ($query, $sth);
 698
 699   $form->{ACCOUNT_CHAIN_BY_ID} ||= {
 700     map { $_->{id} => $_ }
 701       selectall_hashref_query($form, $dbh, <<SQL, $transdate) };
 702     SELECT c.id, c.new_chart_id, date(?) >= c.valid_from AS is_valid, cnew.accno
 703     FROM chart c
 704     LEFT JOIN chart cnew ON c.new_chart_id = cnew.id
 705     WHERE NOT c.new_chart_id IS NULL AND (c.new_chart_id > 0)
 706 SQL
 707
 708   while (1) {
 709     my $ref = $form->{ACCOUNT_CHAIN_BY_ID}->{$accno_id};
 710     last unless ($ref && $ref->{"is_valid"} &&
 711                  !grep({ $_ == $ref->{"new_chart_id"} } @visited_accno_ids));
 712     $accno_id = $ref->{"new_chart_id"};
 713     $accno = $ref->{"accno"};
 714     push(@visited_accno_ids, $accno_id);
 715   }
 716
 717   $main::lxdebug->leave_sub(2);
 718
 719   return ($accno_id, $accno);
 720 }
 721
 722 sub retrieve_accounts {
 723   $main::lxdebug->enter_sub;
 724
 725   my $self     = shift;
 726   my $myconfig = shift;
 727   my $form     = shift;
 728   my $dbh      = $form->get_standard_dbh;
 729   my %args     = @_;     # index => part_id
 730
 731   $form->{taxzone_id} *= 1;
 732
 733   return unless grep $_, values %args; # shortfuse if no part_id supplied
 734
 735   # transdate madness.
 736   my $transdate = "";
 737   if (($form->{type} eq "invoice") or ($form->{type} eq "credit_note") or ($form->{script} eq 'ir.pl')) {
 738     # use deliverydate for sales and purchase invoice, if it exists
 739     # also use deliverydate for credit notes
 740     $transdate = $form->{tax_point} || $form->{deliverydate} || $form->{invdate};
 741   } else {
 742     my $deliverydate;
 743     $deliverydate = $form->{reqdate} if any { $_ eq $form->{type} } qw(sales_order request_quotation purchase_order);
 744     $transdate = $form->{tax_point} || $deliverydate || $form->{transdate};
 745   }
 746
 747   if ($transdate eq "") {
 748     $transdate = DateTime->today_local->to_lxoffice;
 749   } else {
 750     $transdate = $dbh->quote($transdate);
 751   }
 752   #/transdate
 753   my $inc_exp = $form->{"vc"} eq "customer" ? "income_accno_id" : "expense_accno_id";
 754
 755   my @part_ids = grep { $_ } values %args;
 756   my $in       = join ',', ('?') x @part_ids;
 757
 758   my %accno_by_part = map { $_->{id} => $_ }
 759     selectall_hashref_query($form, $dbh, <<SQL, @part_ids);
 760     SELECT
 761       p.id, p.part_type,
 762       bg.inventory_accno_id,
 763       tc.income_accno_id AS income_accno_id,
 764       tc.expense_accno_id AS expense_accno_id,
 765       c1.accno AS inventory_accno,
 766       c2.accno AS income_accno,
 767       c3.accno AS expense_accno
 768     FROM parts p
 769     LEFT JOIN buchungsgruppen bg ON p.buchungsgruppen_id = bg.id
 770     LEFT JOIN taxzone_charts tc on bg.id = tc.buchungsgruppen_id
 771     LEFT JOIN chart c1 ON bg.inventory_accno_id = c1.id
 772     LEFT JOIN chart c2 ON tc.income_accno_id = c2.id
 773     LEFT JOIN chart c3 ON tc.expense_accno_id = c3.id
 774     WHERE
 775     tc.taxzone_id = '$form->{taxzone_id}'
 776     and
 777     p.id IN ($in)
 778 SQL
 779
 780   my $query_tax = <<SQL;
 781     SELECT c.accno, t.taxdescription AS description, t.id as tax_id, t.rate,
 782            c.accno as taxnumber
 783     FROM tax t
 784     LEFT JOIN chart c ON c.id = t.chart_id
 785     WHERE t.id IN
 786       (SELECT tk.tax_id
 787        FROM taxkeys tk
 788        WHERE tk.chart_id = ? AND startdate <= ?
 789        ORDER BY startdate DESC LIMIT 1)
 790 SQL
 791   my $sth_tax = prepare_query($::form, $dbh, $query_tax);
 792
 793   while (my ($index => $part_id) = each %args) {
 794     my $ref = $accno_by_part{$part_id} or next;
 795
 796     $ref->{"inventory_accno_id"} = undef unless $ref->{"part_type"} eq 'part';
 797
 798     my %accounts;
 799     for my $type (qw(inventory income expense)) {
 800       next unless $ref->{"${type}_accno_id"};
 801       ($accounts{"${type}_accno_id"}, $accounts{"${type}_accno"}) =
 802         $self->follow_account_chain($form, $dbh, $transdate, $ref->{"${type}_accno_id"}, $ref->{"${type}_accno"});
 803     }
 804
 805     $form->{"${_}_accno_$index"} = $accounts{"${_}_accno"} for qw(inventory income expense);
 806
 807     $sth_tax->execute($accounts{$inc_exp}, quote_db_date($transdate)) || $::form->dberror($query_tax);
 808     $ref = $sth_tax->fetchrow_hashref or next;
 809
 810     $form->{"taxaccounts_$index"} = $ref->{"accno"};
 811     $form->{"taxaccounts"} .= "$ref->{accno} "if $form->{"taxaccounts"} !~ /$ref->{accno}/;
 812
 813     $form->{"$ref->{accno}_${_}"} = $ref->{$_} for qw(rate description taxnumber tax_id);
 814   }
 815
 816   $sth_tax->finish;
 817
 818   $::lxdebug->leave_sub;
 819 }
 820
 821 sub get_basic_part_info {
 822   $main::lxdebug->enter_sub();
 823
 824   my $self     = shift;
 825   my %params   = @_;
 826
 827   Common::check_params(\%params, qw(id));
 828
 829   my @ids      = 'ARRAY' eq ref $params{id} ? @{ $params{id} } : ($params{id});
 830
 831   if (!scalar @ids) {
 832     $main::lxdebug->leave_sub();
 833     return ();
 834   }
 835
 836   my $myconfig = \%main::myconfig;
 837   my $form     = $main::form;
 838
 839   my $dbh      = $form->get_standard_dbh($myconfig);
 840
 841   my $query    = qq|SELECT * FROM parts WHERE id IN (| . join(', ', ('?') x scalar(@ids)) . qq|)|;
 842
 843   my $info     = selectall_hashref_query($form, $dbh, $query, map { conv_i($_) } @ids);
 844
 845   if ('' eq ref $params{id}) {
 846     $info = $info->[0] || { };
 847
 848     $main::lxdebug->leave_sub();
 849     return $info;
 850   }
 851
 852   my %info_map = map { $_->{id} => $_ } @{ $info };
 853
 854   $main::lxdebug->leave_sub();
 855
 856   return %info_map;
 857 }
 858
 859 sub prepare_parts_for_printing {
 860   $main::lxdebug->enter_sub();
 861
 862   my $self     = shift;
 863   my %params   = @_;
 864
 865   my $myconfig = $params{myconfig} || \%main::myconfig;
 866   my $form     = $params{form}     || $main::form;
 867
 868   my $dbh      = $params{dbh} || $form->get_standard_dbh($myconfig);
 869
 870   my $prefix   = $params{prefix} || 'id_';
 871   my $rowcount = defined $params{rowcount} ? $params{rowcount} : $form->{rowcount};
 872
 873   my @part_ids = keys %{ { map { $_ => 1 } grep { $_ } map { $form->{"${prefix}${_}"} } (1 .. $rowcount) } };
 874
 875   if (!@part_ids) {
 876     $main::lxdebug->leave_sub();
 877     return;
 878   }
 879
 880   my $placeholders = join ', ', ('?') x scalar(@part_ids);
 881   my $query        = qq|SELECT mm.parts_id, mm.model, mm.lastcost, v.name AS make
 882                         FROM makemodel mm
 883                         LEFT JOIN vendor v ON (mm.make = v.id)
 884                         WHERE mm.parts_id IN ($placeholders)|;
 885
 886   my %makemodel    = ();
 887
 888   my $sth          = prepare_execute_query($form, $dbh, $query, @part_ids);
 889
 890   while (my $ref = $sth->fetchrow_hashref()) {
 891     $makemodel{$ref->{parts_id}} ||= [];
 892     push @{ $makemodel{$ref->{parts_id}} }, $ref;
 893   }
 894
 895   $sth->finish();
 896
 897   $query           = qq|SELECT
 898                         cp.parts_id,
 899                         cp.customer_partnumber AS customer_model,
 900                         c.name                 AS customer_make
 901                         FROM part_customer_prices cp
 902                         LEFT JOIN customer c ON (cp.customer_id = c.id)
 903                         WHERE cp.parts_id IN ($placeholders)|;
 904
 905   my %customermodel = ();
 906
 907   $sth              = prepare_execute_query($form, $dbh, $query, @part_ids);
 908
 909   while (my $ref = $sth->fetchrow_hashref()) {
 910     $customermodel{$ref->{parts_id}} ||= [];
 911     push @{ $customermodel{$ref->{parts_id}} }, $ref;
 912   }
 913
 914   $sth->finish();
 915
 916   my @columns = qw(ean image microfiche drawing);
 917
 918   $query      = qq|SELECT id, | . join(', ', @columns) . qq|
 919                    FROM parts
 920                    WHERE id IN ($placeholders)|;
 921
 922   my %data    = selectall_as_map($form, $dbh, $query, 'id', \@columns, @part_ids);
 923
 924   my %template_arrays;
 925   map { $template_arrays{$_} = [] } (qw(make model customer_make customer_model), @columns);
 926
 927   foreach my $i (1 .. $rowcount) {
 928     my $id = $form->{"${prefix}${i}"};
 929
 930     next if (!$id);
 931
 932     foreach (@columns) {
 933       push @{ $template_arrays{$_} }, $data{$id}->{$_};
 934     }
 935
 936     push @{ $template_arrays{make} },  [];
 937     push @{ $template_arrays{model} }, [];
 938
 939     if ($makemodel{$id}) {
 940       foreach my $ref (@{ $makemodel{$id} }) {
 941         map { push @{ $template_arrays{$_}->[-1] }, $ref->{$_} } qw(make model);
 942       }
 943     }
 944
 945     push @{ $template_arrays{customer_make} },  [];
 946     push @{ $template_arrays{customer_model} }, [];
 947
 948     if ($customermodel{$id}) {
 949       foreach my $ref (@{ $customermodel{$id} }) {
 950         push @{ $template_arrays{$_}->[-1] }, $ref->{$_} for qw(customer_make customer_model);
 951       }
 952     }
 953
 954   }
 955
 956   my $parts = SL::DB::Manager::Part->get_all(query => [ id => \@part_ids ]);
 957   my %parts_by_id = map { $_->id => $_ } @$parts;
 958
 959   for my $i (1..$rowcount) {
 960     my $id = $form->{"${prefix}${i}"};
 961     next unless $id;
 962     my $prt = $parts_by_id{$id};
 963     my $type_abbr = type_abbreviation($prt->part_type);
 964     push @{ $template_arrays{part_type}         }, $prt->part_type;
 965     push @{ $template_arrays{part_abbreviation} }, $type_abbr;
 966     push @{ $template_arrays{type_and_classific}}, $type_abbr . classification_abbreviation($prt->classification_id);
 967     push @{ $template_arrays{separate}  }, separate_abbreviation($prt->classification_id);
 968   }
 969
 970   $main::lxdebug->leave_sub();
 971   return %template_arrays;
 972 }
 973
 974 1;