SL/InstanceConfiguration.pm

   1 package SL::InstanceConfiguration;
   2
   3 use strict;
   4
   5 use Carp;
   6 use SL::DBUtils ();
   7 use SL::System::Process;
   8
   9 use parent qw(Rose::Object);
  10 use Rose::Object::MakeMethods::Generic (
  11   'scalar --get_set_init' => [ qw(data currencies default_currency _table_currencies_exists crm_installed) ],
  12 );
  13
  14 sub init_data {
  15   return {} if !$::auth->client;
  16   return SL::DBUtils::selectfirst_hashref_query($::form, $::form->get_standard_dbh, qq|SELECT * FROM defaults|);
  17 }
  18
  19 sub init__table_currencies_exists {
  20   return 0 if !$::auth->client;
  21   return !!(SL::DBUtils::selectall_hashref_query($::form, $::form->get_standard_dbh, qq|SELECT tablename FROM pg_tables WHERE (schemaname = 'public') AND (tablename = 'currencies')|))[0];
  22 }
  23
  24 sub init_currencies {
  25   my ($self) = @_;
  26
  27   return [] if !$self->_table_currencies_exists;
  28   return [ map { $_->{name} } SL::DBUtils::selectall_hashref_query($::form, $::form->get_standard_dbh, qq|SELECT name FROM currencies ORDER BY id ASC|) ];
  29 }
  30
  31 sub init_default_currency {
  32   my ($self) = @_;
  33
  34   return undef if !$self->_table_currencies_exists || !$self->data->{currency_id};
  35   return (SL::DBUtils::selectfirst_array_query($::form, $::form->get_standard_dbh, qq|SELECT name FROM currencies WHERE id = ?|, $self->data->{currency_id}))[0];
  36 }
  37
  38 sub init_crm_installed {
  39   return -f (SL::System::Process->exe_dir . '/crm/Changelog');
  40 }
  41
  42 sub reload {
  43   my ($self) = @_;
  44
  45   delete @{ $self }{qw(data currencies default_currency)};
  46
  47   return $self;
  48 }
  49
  50 sub get_currencies {
  51   my ($self) = @_;
  52   return @{ $self->currencies };
  53 }
  54
  55 sub AUTOLOAD {
  56   our $AUTOLOAD;
  57
  58   my $self   =  shift;
  59   my $method =  $AUTOLOAD;
  60   $method    =~ s/.*:://;
  61
  62   return if $method eq 'DESTROY';
  63
  64   if ($method =~ m/^get_/) {
  65     $method = substr $method, 4;
  66     return $self->data->{$method} if exists $self->data->{$method};
  67     croak "Invalid method 'get_${method}'";
  68   }
  69
  70   croak "Invalid method '${method}'" if !$self->can($method);
  71   return $self->$method(@_);
  72 }
  73
  74 1;
  75
  76 __END__
  77
  78 =pod
  79
  80 =encoding utf8
  81
  82 =head1 NAME
  83
  84 SL::InstanceConfiguration - Provide instance-specific configuration data
  85
  86 =head1 SYNOPSIS
  87
  88 kivitendo has two configuration levels: installation specific
  89 (provided by the global variable C<%::lx_office_conf>) and instance
  90 specific. The latter is provided by a global instance of this class,
  91 C<$::instance_conf>.
  92
  93 =head1 FUNCTIONS
  94
  95 =over 4
  96
  97 =item C<new>
  98
  99 Creates a new instance. Does not read the configuration.
 100
 101 =item C<crm_installed>
 102
 103 Returns trueish if the CRM component is installed.
 104
 105 =item C<get_currencies>
 106
 107 Returns an array of configured currencies.
 108
 109 =item C<get_default_currency>
 110
 111 Returns the default currency or undef if no currency has been
 112 configured.
 113
 114 =item C<get_accounting_method>
 115
 116 Returns the default accounting method, accrual or cash
 117
 118 =item C<get_inventory_system>
 119
 120 Returns the default inventory system, perpetual or periodic
 121
 122 =item C<get_profit_determination>
 123
 124 Returns the default profit determination method, balance or income
 125
 126 =item C<get_balance_startdate_method>
 127
 128 Returns the default method for determining the startdate for the balance
 129 report.
 130
 131 Valid options:
 132 closed_to start_of_year all_transactions last_ob_or_all_transactions last_ob_or_start_of_year
 133
 134 =item C<get_is_changeable>
 135
 136 =item C<get_ir_changeable>
 137
 138 =item C<get_ar_changeable>
 139
 140 =item C<get_ap_changeable>
 141
 142 =item C<get_gl_changeable>
 143
 144 Returns if and when these record types are changeable or deleteable after
 145 posting. 0 means never, 1 means always and 2 means on the same day.
 146
 147 =item C<get_datev_check_on_sales_invoice>
 148
 149 Returns true if datev check should be performed on sales invoices
 150
 151 =item C<get_datev_check_on_purchase_invoice>
 152
 153 Returns true if datev check should be performed on purchase invoices
 154
 155 =item C<get_datev_check_on_ar_transaction>
 156
 157 Returns true if datev check should be performed on ar transactions
 158
 159 =item C<get_datev_check_on_ap_transaction>
 160
 161 Returns true if datev check should be performed on ap transactions
 162
 163 =item C<get_datev_check_on_gl_transaction>
 164
 165 Returns true if datev check should be performed on gl transactions
 166
 167 =item C<get_show_bestbefore>
 168
 169 Returns the default behavior for showing best before date, true or false
 170
 171 =item C<get_is_show_mark_as_paid>
 172
 173 =item C<get_ir_show_mark_as_paid>
 174
 175 =item C<get_ar_show_mark_as_paid>
 176
 177 =item C<get_ap_show_mark_as_paid>
 178
 179 Returns the default behavior for showing the "mark as paid" button for the
 180 corresponding record type (true or false).
 181
 182 =item C<get_sales_order_show_delete>
 183
 184 =item C<get_purchase_order_show_delete>
 185
 186 =item C<get_sales_delivery_order_show_delete>
 187
 188 =item C<get_purchase_delivery_order_show_delete>
 189
 190 Returns the default behavior for showing the delete button for the
 191 corresponding record type (true or false).
 192
 193 =item C<get_warehouse_id>
 194
 195 Returns the default warehouse_id
 196
 197 =item C<get_bin_id>
 198
 199 Returns the default bin_id
 200
 201 =item C<get_warehouse_id_ignore_onhand>
 202
 203 Returns the default warehouse_id for transfers without checking the
 204 current stock quantity
 205
 206 =item C<get_bin_id_ignore_onhand>
 207
 208 Returns the default bin_id for transfers without checking the
 209 current stock quantity
 210
 211 =item C<get_transfer_default>
 212
 213 =item C<get_transfer_default_use_master_default_bin>
 214
 215 =item C<get_transfer_default_ignore_onhand>
 216
 217 Returns the default behavior for the transfer out default feature (true or false)
 218
 219 =item C<get_max_future_booking_interval>
 220
 221 Returns the maximum interval value for future bookings
 222
 223 =item C<get_webdav>
 224
 225 Returns the configuration for WebDAV
 226
 227 =item C<get_webdav_documents>
 228
 229 Returns the configuration for storing documents in the corresponding WebDAV folder
 230
 231 =item C<get_vertreter>
 232
 233 Returns the configuration for "vertreter"
 234
 235 =item C<get_feature_experimental_assortment>
 236
 237 Returns the configuration for experimental feature "assortment"
 238
 239 =item C<get_feature_experimental_order>
 240
 241 Returns the configuration for the experimental feature "order"
 242
 243 =item C<get_parts_show_image>
 244
 245 Returns the configuarion for show image in parts
 246
 247 =item C<get_parts_image_css>
 248
 249 Returns the css format string for images shown in parts
 250
 251 =item C<get_parts_listing_image>
 252
 253 Returns the configuration for showing the picture in the results when you search for parts
 254
 255 =back
 256
 257 =head1 BUGS
 258
 259 Updates to the I<defaults> table require that the instance
 260 configuration is re-read. This has not been implemented yet.
 261
 262 =head1 AUTHOR
 263
 264 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 265
 266 =cut