SL/LXDebug.pm

   1 package LXDebug;
   2
   3 use constant {
   4   NONE   => 0,
   5   INFO   => 1,
   6   DEBUG1 => 2,
   7   DEBUG2 => 3,
   8
   9   FILE_TARGET   => 0,
  10   STDERR_TARGET => 1 };
  11
  12 use POSIX qw(strftime);
  13
  14 my $data_dumper_available;
  15
  16 BEGIN {
  17   eval("use Data::Dumper");
  18   $data_dumper_available = $@ ? 0 : 1;
  19
  20   $global_level      = NONE;
  21   $global_trace_subs = 0;
  22 }
  23
  24 sub new {
  25   my $type = shift;
  26   my $self = {};
  27
  28   $self->{"calldepth"}  = 0;
  29   $self->{"file"}       = "/tmp/lx-office-debug.log";
  30   $self->{"target"}     = FILE_TARGET;
  31   $self->{"level"}      = 0;
  32   $self->{"trace_subs"} = 0;
  33
  34   while ($_[0]) {
  35     $self->{ $_[0] } = $_[1];
  36     shift;
  37     shift;
  38   }
  39
  40   bless($self, $type);
  41 }
  42
  43 sub set_target {
  44   my ($self, $target, $file) = @_;
  45
  46   if ((FILE_TARGET == $target) && $file) {
  47     $self->{"file"}   = $file;
  48     $self->{"target"} = FILE_TARGET;
  49
  50   } elsif (STDERR_TARGET == $target) {
  51     $self->{"target"} = STDERR_TARGET;
  52   }
  53 }
  54
  55 sub enter_sub {
  56   my ($self) = @_;
  57
  58   if (!$self->{"trace_subs"} && !$global_trace_subs) {
  59     return;
  60   }
  61
  62   my ($package, $filename, $line, $subroutine) = caller(1);
  63   my ($dummy1, $self_filename, $self_line) = caller(0);
  64
  65   my $indent = "  " x $self->{"calldepth"};
  66   $self->{"calldepth"} += 1;
  67
  68   if (!defined($package)) {
  69     $self->_write("enter_sub", $indent . "top-level?\n");
  70   } else {
  71     $self->_write("enter_sub",
  72                   $indent
  73                     . "${subroutine} in "
  74                     . "${self_filename}:${self_line} called from "
  75                     . "${filename}:${line}\n");
  76   }
  77 }
  78
  79 sub leave_sub {
  80   my ($self) = @_;
  81
  82   if (!$self->{"trace_subs"} && !$global_trace_subs) {
  83     return;
  84   }
  85
  86   my ($package, $filename, $line, $subroutine) = caller(1);
  87   my ($dummy1, $self_filename, $self_line) = caller(0);
  88
  89   $self->{"calldepth"} -= 1;
  90   my $indent = "  " x $self->{"calldepth"};
  91
  92   if (!defined($package)) {
  93     $self->_write("leave_sub", $indent . "top-level?\n");
  94   } else {
  95     $self->_write("leave_sub",
  96             $indent . "${subroutine} in " . "${self_filename}:${self_line}\n");
  97   }
  98 }
  99
 100 sub message {
 101   my ($self, $level, $message) = @_;
 102   my ($log_level) = $self->{"level"};
 103
 104   if ($global_level && ($global_level > $log_level)) {
 105     $log_level = $global_level;
 106   }
 107
 108   if ($log_level >= $level) {
 109     $self->_write(INFO == $level
 110                   ? "info"
 111                   : DEBUG1 == $level ? "debug1" : "debug2",
 112                   $message);
 113   }
 114 }
 115
 116 sub dump {
 117   my ($self, $level, $name, $variable) = @_;
 118
 119   if ($data_dumper_available) {
 120     $self->message($level, "dumping ${name}:\n" . Dumper($variable));
 121   } else {
 122     $self->message($level,
 123                    "dumping ${name}: Data::Dumper not available; "
 124                      . "variable cannot be dumped");
 125   }
 126 }
 127
 128 sub enable_sub_tracing {
 129   my ($self) = @_;
 130   $self->{"trace_subs"} = 1;
 131 }
 132
 133 sub disable_sub_tracing {
 134   my ($self) = @_;
 135   $self->{"trace_subs"} = 1;
 136 }
 137
 138 sub _write {
 139   my ($self, $prefix, $message) = @_;
 140   my $date = strftime("%Y-%m-%d %H:%M:%S $$ ${prefix}: ", localtime(time()));
 141   local *FILE;
 142
 143   chomp($message);
 144
 145   if ((FILE_TARGET == $self->{"target"})
 146       && open(FILE, ">>" . $self->{"file"})) {
 147     print(FILE "${date}${message}\n");
 148     close(FILE);
 149
 150       } elsif (STDERR_TARGET == $self->{"target"}) {
 151     print(STDERR "${date}${message}\n");
 152   }
 153 }
 154
 155 1;