SL/LXDebug.pm

   1 package LXDebug;
   2
   3 use constant NONE               =>  0;
   4 use constant INFO               =>  1;
   5 use constant DEBUG1             =>  1 << 1;
   6 use constant DEBUG2             =>  1 << 2;
   7 use constant QUERY              =>  1 << 3;
   8 use constant TRACE              =>  1 << 4;
   9 use constant BACKTRACE_ON_ERROR =>  1 << 5;
  10 use constant REQUEST_TIMER      =>  1 << 6;
  11 use constant WARN               =>  1 << 7;
  12 use constant ALL                => (1 << 8) - 1;
  13 use constant DEVEL              => INFO | QUERY | TRACE | BACKTRACE_ON_ERROR | REQUEST_TIMER;
  14
  15 use constant FILE_TARGET   => 0;
  16 use constant STDERR_TARGET => 1;
  17
  18 use POSIX qw(strftime getppid);
  19 use Time::HiRes qw(gettimeofday tv_interval);
  20 use YAML;
  21
  22 use strict;
  23
  24 my $data_dumper_available;
  25
  26 our $global_level;
  27 our $watch_form;
  28 our $file_name;
  29
  30 BEGIN {
  31   eval("use Data::Dumper");
  32   $data_dumper_available = $@ ? 0 : 1;
  33
  34   $global_level      = NONE;
  35   $watch_form        = 0;
  36 }
  37
  38 sub new {
  39   my $type = shift;
  40   my $self = {};
  41
  42   $self->{"calldepth"}  = 0;
  43   $self->{"file"}       = $file_name || "/tmp/lx-office-debug.log";
  44   $self->{"target"}     = FILE_TARGET;
  45   $self->{"level"}      = 0;
  46
  47   while ($_[0]) {
  48     $self->{ $_[0] } = $_[1];
  49     shift;
  50     shift;
  51   }
  52
  53   bless($self, $type);
  54 }
  55
  56 sub set_target {
  57   my ($self, $target, $file) = @_;
  58
  59   if ((FILE_TARGET == $target) && $file) {
  60     $self->{"file"}   = $file;
  61     $self->{"target"} = FILE_TARGET;
  62
  63   } elsif (STDERR_TARGET == $target) {
  64     $self->{"target"} = STDERR_TARGET;
  65   }
  66 }
  67
  68 sub enter_sub {
  69   my $self  = shift;
  70   my $level = shift || 0;
  71
  72   return 1 unless ($global_level & TRACE);          # ignore if traces aren't active
  73   return 1 if $level && !($global_level & $level);  # ignore if level of trace isn't active
  74
  75   my ($package, $filename, $line, $subroutine) = caller(1);
  76   my ($dummy1, $self_filename, $self_line) = caller(0);
  77
  78   my $indent = " " x $self->{"calldepth"}++;
  79   my $time = $self->get_request_time || '';
  80
  81   if (!defined($package)) {
  82     $self->_write('sub' . $level, $indent . "\\ $time top-level?\n");
  83   } else {
  84     $self->_write('sub' . $level, $indent
  85                     . "\\ $time ${subroutine} in "
  86                     . "${self_filename}:${self_line} called from "
  87                     . "${filename}:${line}\n");
  88   }
  89   return 1;
  90 }
  91
  92 sub leave_sub {
  93   my $self  = shift;
  94   my $level = shift || 0;
  95
  96   return 1 unless ($global_level & TRACE);           # ignore if traces aren't active
  97   return 1 if $level && !($global_level & $level);   # ignore if level of trace isn't active
  98
  99   my ($package, $filename, $line, $subroutine) = caller(1);
 100   my ($dummy1, $self_filename, $self_line) = caller(0);
 101
 102   my $indent = " " x --$self->{"calldepth"};
 103   my $time = $self->want_request_timer ? $self->get_request_time : '';
 104
 105   if (!defined($package)) {
 106     $self->_write('sub' . $level, $indent . "/ $time top-level?\n");
 107   } else {
 108     $self->_write('sub' . $level, $indent . "/ $time ${subroutine} in " . "${self_filename}:${self_line}\n");
 109   }
 110   return 1;
 111 }
 112
 113 sub show_backtrace {
 114   my ($self, $force) = @_;
 115
 116   return 1 unless ($force || ($global_level & BACKTRACE_ON_ERROR));
 117
 118   $self->message(BACKTRACE_ON_ERROR, "Starting full caller dump:");
 119   my $level = 0;
 120   while (my ($dummy, $filename, $line, $subroutine) = caller $level) {
 121     $self->message(BACKTRACE_ON_ERROR, "  ${subroutine} from ${filename}:${line}");
 122     $level++;
 123   }
 124
 125   return 1;
 126 }
 127
 128 sub message {
 129   no warnings;
 130   my ($self, $level, $message) = @_;
 131
 132   $self->_write(level2string($level), $message) if (($self->{"level"} | $global_level) & $level || !$level);
 133 }
 134 sub warn {
 135   no warnings;
 136   my ($self, $message) = @_;
 137   $self->message(WARN, $message);
 138 }
 139
 140 sub dump {
 141   my ($self, $level, $name, $variable) = @_;
 142
 143   if ($data_dumper_available) {
 144     my $password;
 145     if ($variable && ('Form' eq ref $variable) && defined $variable->{password}) {
 146       $password             = $variable->{password};
 147       $variable->{password} = 'X' x 8;
 148     }
 149
 150     my $dumper = Data::Dumper->new([$variable]);
 151     $dumper->Sortkeys(1);
 152     $self->message($level, "dumping ${name}:\n" . $dumper->Dump());
 153
 154     $variable->{password} = $password if (defined $password);
 155
 156     # Data::Dumper does not reset the iterator belonging to this hash
 157     # if 'Sortkeys' is true. Therefore clear the iterator manually.
 158     # See "perldoc -f each".
 159     if ($variable && (('HASH' eq ref $variable) || ('Form' eq ref $variable))) {
 160       keys %{ $variable };
 161     }
 162
 163   } else {
 164     $self->message($level,
 165                    "dumping ${name}: Data::Dumper not available; "
 166                      . "variable cannot be dumped");
 167   }
 168 }
 169
 170 sub dump_yaml {
 171   my ($self, $level, $name, $variable) = @_;
 172
 173   $self->message($level, "dumping ${name}:\n" . YAML::Dump($variable));
 174 }
 175
 176 sub dump_sql_result {
 177   my ($self, $level, $prefix, $results) = @_;
 178
 179   if (!$results || !scalar @{ $results }) {
 180     $self->message($level, "Empty result set");
 181     return;
 182   }
 183
 184   my %column_lengths = map { $_, length $_ } keys %{ $results->[0] };
 185
 186   foreach my $row (@{ $results }) {
 187     map { $column_lengths{$_} = length $row->{$_} if (length $row->{$_} > $column_lengths{$_}) } keys %{ $row };
 188   }
 189
 190   my @sorted_names = sort keys %column_lengths;
 191   my $format       = join '|', map { '%' . $column_lengths{$_} . 's' } @sorted_names;
 192
 193   $prefix .= ' ' if $prefix;
 194
 195   $self->message($level, $prefix . sprintf($format, @sorted_names));
 196   $self->message($level, $prefix . join('+', map { '-' x $column_lengths{$_} } @sorted_names));
 197
 198   foreach my $row (@{ $results }) {
 199     $self->message($level, $prefix . sprintf($format, map { $row->{$_} } @sorted_names));
 200   }
 201   $self->message($level, $prefix . sprintf('(%d row%s)', scalar @{ $results }, scalar @{ $results } > 1 ? 's' : ''));
 202 }
 203
 204 sub enable_sub_tracing {
 205   my ($self) = @_;
 206   $global_level |= TRACE;
 207 }
 208
 209 sub disable_sub_tracing {
 210   my ($self) = @_;
 211   $global_level &= ~ TRACE;
 212 }
 213
 214 sub is_tracing_enabled {
 215   my ($self) = @_;
 216   return $global_level & TRACE;
 217 }
 218
 219 sub _write {
 220   no warnings;
 221   my ($self, $prefix, $message) = @_;
 222   my $date = strftime("%Y-%m-%d %H:%M:%S $$ [" . getppid() . "] ${prefix}: ", localtime(time()));
 223   local *FILE;
 224
 225   chomp($message);
 226
 227   if ((FILE_TARGET == $self->{"target"})
 228       && open(FILE, ">>" . $self->{"file"})) {
 229     print(FILE "${date}${message}\n");
 230     close(FILE);
 231
 232   } elsif (STDERR_TARGET == $self->{"target"}) {
 233     print(STDERR "${date}${message}\n");
 234   }
 235 }
 236
 237 sub level2string {
 238   no warnings;
 239   # use $_[0] as a bit mask and return levelstrings separated by /
 240   join '/', qw(info debug1 debug2 query trace error_call_trace request_timer WARNING)[ grep { (reverse split //, sprintf "%08b", $_[0])[$_] } 0..7 ]
 241 }
 242
 243 sub begin_request {
 244   my $self = shift;
 245   return 1 unless want_request_timer();
 246   $self->set_request_timer;
 247 }
 248
 249 sub end_request {
 250   my $self = shift;
 251   return 1 unless want_request_timer();
 252   $self->_write("time", $self->get_request_time);
 253
 254   $self->{calldepth} = 0;
 255 }
 256
 257 sub log_time {
 258   my $self = shift;
 259   return 1 unless want_request_timer();
 260   $self->_write("time", $self->get_request_time);
 261 }
 262
 263 sub get_request_time {
 264   my $self = shift;
 265   return $self->want_request_timer && $self->{request_start} ? tv_interval($self->{request_start}) : undef;
 266 }
 267
 268 sub set_request_timer {
 269   my $self = shift;
 270   $self->{request_start} = [gettimeofday];
 271 }
 272
 273 sub want_request_timer {
 274   $global_level & REQUEST_TIMER;
 275 }
 276
 277 1;