SL/Layout/MenuLeft.pm

   1 package SL::Layout::MenuLeft;
   2
   3 use strict;
   4 use parent qw(SL::Layout::Base);
   5
   6 use URI;
   7
   8 use List::MoreUtils qw(apply);
   9
  10 sub stylesheets {
  11   qw(css/icons16.css css/icons24.css)
  12 }
  13
  14 sub javascripts_inline {
  15   my $self = shift;
  16   my $sections = [ section_menu($self->menu) ];
  17   $self->render('menu/menu', { no_menu => 1, no_output => 1 },
  18     sections  => $sections,
  19   )
  20 }
  21
  22 sub pre_content {
  23   "<div id='html-menu'></div>\n";
  24 }
  25
  26 sub start_content {
  27   "<div id='content' class='html-menu'>\n";
  28 }
  29
  30 sub end_content {
  31   "</div>\n";
  32 }
  33
  34 sub section_menu {
  35   $::lxdebug->enter_sub(2);
  36   my ($menu, $level, $id_prefix) = @_;
  37   my @menuorder = $menu->access_control(\%::myconfig, $level);
  38   my @items;
  39
  40   my $id = 0;
  41
  42   for my $item (@menuorder) {
  43     my $menuitem   = $menu->{$item};
  44     my $olabel     = apply { s/.*--// } $item;
  45     my $ml         = apply { s/--.*// } $item;
  46     my $icon_class = apply { y/ /-/   } $item;
  47     my $spacer     = "s" . (0 + $item =~ s/--/--/g);
  48
  49     next if $level && $item ne "$level--$olabel";
  50
  51     my $label         = $::locale->text($olabel);
  52
  53     $menuitem->{module} ||= $::form->{script};
  54     $menuitem->{action} ||= "section_menu";
  55     $menuitem->{href}   ||= "$menuitem->{module}?action=$menuitem->{action}";
  56
  57     # add other params
  58     foreach my $key (keys %$menuitem) {
  59       next if $key =~ /target|module|action|href/;
  60       $menuitem->{href} .= "&" . $::form->escape($key, 1) . "=";
  61       my ($value, $conf) = split(/=/, $menuitem->{$key}, 2);
  62       $value = $::myconfig{$value} . "/$conf" if ($conf);
  63       $menuitem->{href} .= $::form->escape($value, 1);
  64     }
  65
  66     my $anchor = $menuitem->{href};
  67
  68     my @common_args = ($label, $spacer, "$id_prefix\_$id");
  69
  70     if (!$level) { # toplevel
  71       push @items, [ @common_args, "icon24 $icon_class", 'm' ];
  72       #  make_image(size => 24, label => $item),
  73       push @items, section_menu($menu, $item, "$id_prefix\_$id");
  74     } elsif ($menuitem->{submenu}) {
  75       push @items, [ @common_args, "icon16 submenu", 'sm' ];
  76       #make_image(label => 'submenu'),
  77       push @items, section_menu($menu, $item, "$id_prefix\_$id");
  78     } elsif ($menuitem->{module}) {
  79       push @items, [ @common_args, "icon16 $icon_class", 'i', $anchor ];
  80       #make_image(size => 16, label => $item),
  81     }
  82   } continue {
  83     $id++;
  84   }
  85
  86   $::lxdebug->leave_sub(2);
  87   return @items;
  88 }
  89
  90 sub _calc_framesize {
  91   my $is_lynx_browser   = $ENV{HTTP_USER_AGENT} =~ /links/i;
  92   my $is_mobile_browser = $ENV{HTTP_USER_AGENT} =~ /mobile/i;
  93   my $is_mobile_style   = $::form->{stylesheet} =~ /mobile/i;
  94
  95   return  $is_mobile_browser && $is_mobile_style ?  130
  96         : $is_lynx_browser                       ?  240
  97         :                                           200;
  98 }
  99
 100 sub _show_images {
 101   # don't show images in links
 102   _calc_framesize() != 240;
 103 }
 104
 105 1;